《粉红女郎》要重拍，里面的万人迷令人记忆犹新，她风情万种，美丽妖娆，是个不折不扣的感情专家，可以一语中的地找到你的情感真相！

在Excel中，也有个著名的万人迷，它就是VLookup，只要是找东西，大家首先想到的就是它。

先来个最基本的查找当开胃菜：

Vlookup语法：

Vlookup(根据什么找,到哪里找,找哪个,怎么找)

注意：

1、“根据什么找”中的“什么”一定要位于“到哪里找”区域的第1列！

2、若从“到哪里找”区域中找到多个“什么”，则仅返回第1个找到的“什么”对应的东西；

3、“找哪个”不是实际列号，而是“到哪里找”区域中的第几列，其中，“什么”位于第1列，以此类推；

4、“怎么找”包含0（精确查找）、1或省略（模糊查找），其中，模糊查找时，首列必须升序排列；

公式分析：

= VLOOKUP(G3,C3:E12,2,0)

根据G3单元格的查找客户（第1参数），到C3:E12单元格区域中找（第2参数），其中第1列是客户名称列，即查找依据所在的列，要查找第2列的数据值（第3参数），即查找客户的付款金额，按精确查找的方式进行查找（第4参数），即客户名称与查找客户要完全相同；

再看以下数据，要根据订单号，查找该订单的所有资料，你怎么做？

在I、J、K、L列分别输入VLOOKUP公式，当然可以，但要是数据列较多，就比较麻烦了，告诉你一个公式就能搞定：

公式分析：

=VLOOKUP($H$3,$B$3:$F$12,COLUMN(B1),0)

1、需要在“客户名称”列返回查找区域第2列的值，在“付款金额”列返回查找区域第3列的值……，以此类推，为了实现一个公式就能在不同的列返回对应的数据，我们需要让VLookup的第3参数，即“找哪个”变成动态的，在I3单元格第3参数为2，在J3单元格第3参数为3，那么，COLUMN函数就能帮上忙了：

2、COLUMN函数可以返回指定单元格的列号，COLUMN(B1)返回B1单元格的列号2，由于使用的是单元格相对引用，随着公式向右复制，J3单元格会变成COLUMN(C1)，即返回C1单元格的列号3；

3、再以COLUMN函数的结果作为VLookup函数的第3参数，就能实现让“找哪个”变成动态的了，刚好满足了我们的要求。

想根据条件找到多个符合的数据，VLookup可以做到吗？比如：一个订单号记录了订购的多款产品，想根据订单号查找该订单下的所有产品，怎么做呢？

第1步：首先我们要构造一个辅助序号列，在A3单元格输入公式，并下拉复制到A12单元格：

=(B3=$G$3)+A2

公式分析：

l B3=$G$3：判断B3单元格的销售订单号是否等于G3单元格的查找订单号，若相同，则返回true，否则返回false；

l 逻辑值再与A2相加，true相当于1，false和空相当于0，得到截止当前行，查询订单号出现的总次数；

第2步：在H3单元格输入公式：

=VLOOKUP(ROW(A1),$A$3:$C$12,3,0)

公式分析：

1、为了查找订单号对应的多个产品，根据下图可以看出，只要查找到1~10（10为查询数据总行数，为某订单可能包含的最多产品数）在A列中出现的行位置，再找到相应的第3列即C列的订单产品，就搞定了。

2、我们需要将查找到的第1个产品放入H3列，第2个产品放入H4列，依次向下，直至填完查找订单号包含的所有订单产品；

3、于是，我们在H3单元格查找A列的序号1，即查询订单号第1次出现的位置，并返回该订单下的第1个产品，H4单元格查找序号2……

4、而ROW函数恰好可以满足以上要求，在H3单元格使用ROW(A1)作为VLookup的查找条件，ROW(A1)可以返回指定单元格A1对应的行号1，随着公式向下复制，由于A1为相对引用，到H4单元格将变为以ROW(A2)即2作为查询条件；

第3步：为H列处理错误值，修改H3单元格的公式，并下拉复制到H12：

=IFERROR(VLOOKUP(ROW(A1),$A$3:$C$12,3,0),"")

公式分析：

1、我们并不确定每个查询订单号下到底有多少个产品，因此，我们将上一步的公式从H3单元格一直复制填充到H12，共10格，即查询数据区域的总行数，意思是，某个订单号下，最多最多可能包含的产品个数；

2、但一般来说，某个查询订单号下，不会有这么多个产品的，于是上一步的公式就出现了下面的情况：

3、这些“#N/A”就是没找到第n个产品时出现的错误值，IFERROR函数的作用就是屏蔽掉它们：若VLookup的结果出现错误值，则显示空值””。

好了，这回的VLookup详解就先到这里，今后一定还会跟大家分享更多，相信你已经get到它的要点了，那就找个机会用起来吧！

本文章由丹丹老师编撰，版权归Excel.live所有！

excel是常用的office办公软件之一，而excel扮演者记录，整理和分析数据的功能，也因此特色的函数功能让工作任务事半功倍。

今天小编介绍一下excel里面最好用的函数之一，引用函数VLOOKUP

这个函数的功能就是通过“桥梁”把另一个地方的数据引用过来，小编第一次接触这个函数是工作时是核算产品销售利润，核算的时候头疼的是要减去物流费用，物流费用全部放在另一张表格里，而且顺序和利润核算表里的顺序不一致，这要一个个复制粘贴到另一个表格“查找”，得知结果再回来手动输入那就得累死。而用公式直接下拉下去很方便。

懂EXCEL的朋友知道，不管是LOOKUP函数还是VLOOKUP函数，查询显示的结果都只是一条，示例如下：

从上面可以看到，查询“张潇潇”B3单元格无论LOOKUP和VLOOKUP函数，都只能显示出一条结果。

如果要显示多条结果，那么分析这个问题后我的思路是虽然有四个“张潇潇”，但是我可以把这个值编上序号“张潇潇1”，“张潇潇2”，“张潇潇3”，“张潇潇4”,，然后在查询。

首先是排序，姓名排序，然后F3=COUNTIF($C$3:C4,C4)下拉进行排序，然后B3=C3&F3,最后以B列为桥梁查询。

1如何使用Vlookup对数据进行引用~

这个方法也可以跨表格使用~

2打开函数的步骤~如图所示~

3根据表格进行对函数参数进行设置，

先选中基准单元格,

然后输入采集的数据，（这个步骤必须用$这个符号对采集的数据进行固定，不然在下拉时候数据会变动）

然后对应输入需要得到的数据在采集数据中的第几列，

可以精确查找，也可以模糊查找，如图所示~

4点击确定后，下拉单元格，即可；

然后随便打个其中一个进行检查~

5如果是需要采集其它列的，只要在这个区域范围，那么只需要改动 采集数列的 数字即可，如图所示！

vlookup函数是excel表格中高级的用法，通过vlookup函数我们可以调用符合条件的数据，在大量调用时可以节省我们查找复制excel数据的时间，今天我就教下大家vlookup函数的使用方法吧。

vlookup函数的使用方法

如图我准备了一张员工入职时间表，员工有非常多，如果我要在这里面一一找出张三李四王五等人的入职时间的话，可以通过查找黏贴的方式，但是这样的效率就很低了，特别是要找的人多的话，那使用vlookup函数是最简单的方法。

接下来我们就需要根据vlookup函数的公式来做调整，使vlookup函数的基本公式变成我们excel表格需要的公式，vlookup函数的语法结构是VLOOKUP(lookup_value,table_array, col_index_num, [range_lookup])。

如我们的表格，我们要查找的是人名，那么对应的lookup_value就是D2张三，而table_array查找区域就是A2到B14这个区域，那么table_array就写$A$2:$B$14。

接下来我们再看col_index_num，这个就是返回值代表在查找区域中返回哪一列的数据，而入职时间在第二列，所以这里就填写2就可以了。而[range_lookup]代表精确查找，我们输入0就可以了。

这样子我们就限定了E2是取A2到B14这个区域的入职时间，那么我们输入完公式后，直接按回车键运行一下，就可以取到姓名为张三的入职时间了。

取完一个正确的数据后，我们要把公式应用到下方的单元格中，只需要将鼠标移动到E2单元格的右下角，鼠标符号变成十字加号后按住鼠标左键往下拉就可以了。

这样vlookup函数的使用方法就教大家了，是不是觉得很简单，只要记好vlookup函数的公式，大家都能成为excel高手。

霸气走火就是我，我就是百度经验作者：ixlxt7Xzsl7，百度经验和百家号首发原创内容分享。

Excel 里面有许多函数公式，在工作中Vlookup函数也经常使用，在这里分享一些Vlookup 函数的初步教程，大家可以先学习一下，后续的高级操作会在之后的文章中发布出来。

说起Excel 里面的函数，Vlookup 肯定是需要提及一下的。相信对于很多新手来说这个函数还是比较陌生的，这个函数在日常工作中使用频率还是比较高的，如果你去面试的时候说到会使用这个函数，或许也是一个加分点。

“Lookup”的汉语意思是“查找”，在Excel中与“Lookup”相关的函数有三个：VLOOKUP、HLOOKUO和LOOKUP。下面介绍VLOOKUP函数的用法。Vlookup函数的作用为在表格的首列查找指定的数据，并返回指定的数据所在行中的指定列处的数据。其标准格式为：

VLOOKUP(lookup_value,table_array,col_index_num , range_lookup)

现在在这里分享一下初步的教程，希望你们能够喜欢。

工具/材料

Excel 软件

演示表格数据

方法教程

1.如图一，现在这里我们有两张表（工作表1和2），表中的内容有姓名和各科的成绩。现在我们要把工作表1里面的内容填充工作表2

图一

2.现在我们要在工作表2里面填充上表1里面的数据。

图二

3.现在我们在工作表2里面的 B2单元格里面使用Vlookup 公式。我们可以输入“=Vlookup(”之后会有相关提示.

图三

在图三中，我们可以看到 Vlookup 这个函数的提示操作，其中：第一个输入的是需要查找的值，第二个是被查找的数据表，第三个是我们要找到的结果，第四个写成0即可-精确匹配。

简单的来说，当我们输入“=Vlookup(”之后

我们点击工作表1里面的"小张"那个单元格，然后加上“,”

再A到D四列全部选择，然后加上“,”（注意：不可以选成A1:D12的固定区域，否则会匹配出错。另外在被查找的表中，一定要将包含查找值得列放到选择区域的第一列）

第三个填2 ，即找到值后，返回数据表中第2列的数值，然后加上“,”

最后一个填0，进行精确匹配。

图四

4.当我们把公式输完之后，按下确定键就可以得到工作表1里面对应的数据了，之后的数据我们可以进行横向拖动，即可得到其他数据，

图五

当然我们也可以向下进行拖动，不过需要注意的是必须是相邻排列的项目才行，因为向下拖动之后显示的数据是与上一个项目相邻的数据，上述公式输入都是在英文状态下输入，中文状态下标点符号可能会使公式运行错误，请大家注意。

怎么样？这个函数大家学会了吗？在这里感谢小伙伴提供的建议。有什么不足的地方请大家评论指正，谢谢。

找对比，你会首先想到

Vlookup

函数。但在Excel中只会Vlookup函数是远远不够的。今天兰色对查找公式进行一次全面的整理。

对于一个地方需要用到对比的时候我们肯定想到的是Vlookup函数，但是你在用Excel的时候只会用它可不行，今天我们就一起来梳理下常用的！

地球人都知道：一题多解的只选取最优公式！

1、普通查找VLOOKUP函数

我们需要查找李晓峰的应发工资

公式：=VLOOKUP(H2,B:F,5,0)

2、反向查找INDEX

函数

查找吴刚的员工编号

公式：=INDEX(A:A,MATCH(H2,B:B,0))

反向查找

3、交叉查找VLOOKUP函数：

查找3月办公费的金额

公式：=VLOOKUP(H2,A:F,MATCH(I2,1:1,0),0)

4、多条件查找

VLOOKUP函数

查找上海产品B的销量

公式：=LOOKUP(1,0/((A2:A7=E2)*(B2:B7=F2)),C2:C7)

5、区间查找

根据销量从右表中查找提成比率。

公式：=LOOKUP(A2,$D$2:$E$5)

6、双区间查找

根据销量和比率完成情况，从表中查找返利。

公式：=INDEX(B3:F7,MATCH(D11,A3:A7),MATCH(E11,B2:F2))

7、线型插值

A列是数量，B列是数量对应的系数值。现要求出数字8所对应的系数值。

公式：=TREND(OFFSET(B1,MATCH(D3,A2:A6,1),,2,1),OFFSET(A1,MATCH(D3,A2:A6,1),,2,1),D3)

8、查找最后一个符合条件记录

要求查找A产品的最后一次进价。

公式：=LOOKUP(1,0/(B2:B9=A13),C2:C9)

9、模糊查找

要求根据提供的城市从上表中查找该市名的第2列的值。

公式：=VLOOKUP("*"&A7&"*",A1:B4,2,0)

10、匹配查找

要求根据地址从上表中查找所在城市的提成。

公式：=lookup(9^9.find(A$3:A$6,A10),B$3:B$6)

11、最后一个非空值查找

要求查找最后一次还款日期

公式：=LOOKUP(1,0/(B2:B13<>""),$A2:$A13)

12、多工作表查找

【例10】从各部门中查找员工的基本工资，在哪一个表中不一定。

方法1

公式：=IFERROR(VLOOKUP(A2,服务!A:G,7,0),IFERROR(VLOOKUP(A2,人事!A:G,7,0),IFERROR(VLOOKUP(A2,综合!A:G,7,0),IFERROR(VLOOKUP(A2,财务!A:G,7,0),IFERROR(VLOOKUP(A2,销售!A:G,7,0),"无此人信息")))))

方法2：

公式：=VLOOKUP(A2,INDIRECT(LOOKUP(1,0/COUNTIF(INDIRECT({"销售";"服务";"人事";"综合";"财务"}&"!a:a"),A2),{"销售";"服务";"人事";"综合";"财务"})&"!a:g"),7,0)

13、一对多查找

【例】根据产品查找相对应的所有供应商

公式：

A2 =B2&COUNTIF(B$1:B2,B2)

B11=IFERROR(VLOOKUP($A11&COLUMN(A1),$A:$C,3,0),"")

14、查找销量最大的城市

查找销量最大的城市。注意：注意：注意：数组公式按ctrl+shift+enter三键输入

公式：{=INDEX(A:A,MAX((MAX(B3:B7)=B3:B7)*ROW(B3:B7)))}

15、最接近值查找

根据D4的价格，在B列查找最接近的价格，并返回相对应的日期

注意：注意：注意：数组公式按ctrl+shift+enter三键输入

公式：{=LOOKUP(1,0/(MIN(ABS(B3:B7-D4))=ABS(B3:B7-D4))*ROW(B3:B7),A3:A7)}

15、跨多文件查找

跨多个文件查找，网上大概很难找到这样的教程，仔细想想其实原理和跨多表查找一样，也是借助lookup等函数实现。

文件夹中有N个仓库产品表格，需要在“查询”文件完成查询

仓库表样式

在查询表中设置公式，根据产品名称从指定的文件中sheet1工作表查询

入库单价

公式：=VLOOKUP(A2,INDIRECT(LOOKUP(1,0/COUNTIF(INDIRECT("["&{"仓库1";"仓库2";"仓库3"}&".xlsx]sheet1!a:a"),A2),"["&{"仓库1";"仓库2";"仓库3"}&".xlsx]sheet1")&"!a:b"),2,0)。

如果你在用vlookup函数做多文件查找的时候也可以用iferror+vlookup的模式的这种模式，看起来公式很长，但是这样不会出错。此外，如果一个表用到的函数太多就需要用宏表函数用Files获取所有excel文件名称了。

老男孩PS

：我能想到的基本上都已经列出来了，但是我相信有很多大家可能看不懂，但是看不懂没关系，赶紧收藏起来，然后直接套用就可以了。

虽然我的文章多次提到，并且极力不推荐大家使用合并单元格，但有时候因为领导喜欢，又或者有强迫证，就是想用，然后合并单元格，遇到vlookup函数，又出错了，怎么办？

如下所示一个实际例子：公司里面有很多员工，每个员工的底薪都不一样，底薪如下所示：

该底薪标准数据位于表格的F:G列，然后现在要对员工的底薪标准进行匹配，表格中的A列是合并单元格的状态，然后在D列输入公式=VLOOKUP(A3,F:G,2,0)

这个结果中只有每个业务的第1行是可以正常匹配的，后面的数据都是错误值#N/A

遇到这种情况最简单的处理方式，就是把合并单元格拆分，填充内容，操作步骤是，选中合并的单元格，取消合并，按CTRL+G，查找空值，在公式编辑栏输入=A2，然后按CTRL+ENTER键，最后将A列的数据复制，粘贴成数值数据，把里面的公式去除，整体操作动图如下所示：

如果你们领导非要要求合并单元格，那你就用长长的公式来处理的，在D2输入公式：=VLOOKUP(VLOOKUP("座",$A$2:A2,1),F:G,2,0)

其实就是把A2单元格再使用一个VLOOKUP函数公式，VLOOKUP("座",$A$2:A2,1)代替，这样将A列的合并单元格进行拆分了。

VLOOKUP("座",$A$2:A2,1)函数使用到了模糊查找，混合累计引用方式，"座"这个字符是编码比较大的一个字符，它会查找到最后一个文本，然后返回值。所以能够得到上述的效果。

虽然这个函数能够解释合并单元格的vlookup函数使用，但是小编还是不建议大家使用合并单元格，这样公式就不用这么复杂使用了。你觉得呢？

本节完，欢迎留言讨论，期待你的转发

在平时用Excel进行各类数据处理的时候，很多朋友都会碰到的一个问题就是数据查询，说到查询函数大家可能也会说到的就是Vlookup函数。其实在Excel中还有其他更加实用的数据查找函数公式，今天我们就来完整的学习一遍Excel中12种查询方式。

场景1：正常情况下数据查找

案例：查找出对应人员的语文成绩

函数=VLOOKUP(F5,B:C,2,0)

场景2：向左数据查找

案例：根据学号查询出对应姓名

函数=INDEX(B:B,MATCH(G5,C:C,0))

场景3：多函数条件交叉查询

案例：求出赵二第三周考试成绩

函数=VLOOKUP(I6,B:G,MATCH(J6,B$2:G$2,0),0)

场景4：LOOKUP多条件查询

案例：求出B产品在京东平台的销量

函数=LOOKUP(1,0/(B:B=F6)*(C:C=G6),D:D)

场景5：数据等级区间查询

案例：求出销售额对应的提成比例

函数=LOOKUP(F5,$B$3:$C$6)

场景6：横向纵向区间数据查询

案例：根据当月销售额及完成比例求出对应提成

函数=INDEX(C3:F9,MATCH(I4,B3:B9),MATCH(I5,C2:F2))

场景7：根据规律自动提取数值对应系数

案例：按照规律根据我们需要的数值提取出对应的系数

函数=TREND(OFFSET(B1,MATCH(D3,A2:A6,1),,2,1),OFFSET(A1,MATCH(D3,A2:A6,1),,2,1),D3)

场景8：查找符合条件的最后一个数

案例：查找出王五最后一天的销售额

函数=LOOKUP(1,0/(B:B=J4),F:F)

场景9：通配符模糊查找

案例：查找出姓王的人的销售额

函数=VLOOKUP(G5&"*",C:D,2,0)

场景10：高级匹配查找

案例：从对应完整地址中提取所在城市的提成点数

=lookup(9^9.find(A$3:A$6,A10),B$3:B$6)

场景11：查找最后一个非空的单元格内容

案例：求出对应人员最近一次缴纳社保的月份

函数=LOOKUP(1,0/(E4:E10<>""),$A$4:$A$10)

场景12：轻松实现一对多查询

案例：轻松提取部门人员全天的门禁记录

函数=IFERROR(VLOOKUP(ROW(A1),A:D,4,0),"")，首先需要在A列做辅助列，函数=COUNTIF(B$2:B2,G$2)

现在Excel关于数据查询你学会了吗？

其实无论是计算机考试中还是我们平时的工作中，都是需要用到查询函数，因为不仅是考试考点，学会使用它会使我们的工作简单许多。

vlookup函数通常用于在excel工作簿中搜索某个单元格区域的第一列，然后返回该区域相同行上任何单元格中的值。

当然在使用vlookup函数之前，我们必须对vlookup函数有基本的认识和了解，所以今天小编就来介绍一下vlookup函数的语法，大家可以跟着小编来学习一下。

函数的书写格式：

Vlookup（lookup|_value,table_array,col_index_num,range_lookup）

搜索表区域首列满足条件的元素，确定待检索单元格在区域中的行序号，再进一步返回选定单元格的值。默认情况下，表是以升序排序的。

vlookup函数参数说明如下：

lookup|_value：在表格或区域的第一列中要搜索的值。

table_array：包含数据的单元格区域，即要查找的范围。

col_index_num：参数中返回的搜寻值的列号。

range_lookup：逻辑值，指定希望Vlookup查找精确匹配值（0）还是近似值（1）。

我们已经对vlookup函数有了一个基本的认识，至少语法结构是没什么问题的，所以今天小编就要和大家说一说实际操作的步骤了。

我们今天就利用vlookup函数来查找公司员工信息，大家可以跟着小编来操作一下。 我们需要双击打开excel软件，随意选中一个空白单元格，在编辑框中输入 “=vlookup(”，单击函数栏左边的fX按钮。

在弹出的“函数参数”对话框中，我们想要查询北京主管的员工编号，在lookup_value栏中输入“北京”对应单元格。

在table_array栏中选中A4:C9单元格内容，在col_index_num栏中输入3（表示选取范围的第三列），在range_lookup栏中输入0（表示精确查找）。

单击确定按钮后，我们可以看到，已经查找到北京经理的员工编号了。