求和，一直是Excel中不变的话题，但是对于求和，并不是所有的同学都能够掌握，尤其是条件求和……常见的求和函数有SUM、SUMIF、SUMIFS三种。

一、SUM函数。

作用：对指定范围内的值进行求和运算。

语法：=SUM（数值或单元格引用区域）。

SUM函数常见问题及解决办法：

1、计算结果显示：#####。

原因：SUM函数所在的列太窄，无法显示结果。

方法：

将列宽调整到合适的宽度即可。

2、计算结果明显错误。

原因：数值为文本类型。

方法：

将对应的值调整为“常规”或“数值”类型即可。

3、求和结果不自动更新。

原因：【计算选项】为“手动”。

方法：

1、【公式】-【计算选项】，选择【自动】。

2、按F9强制更新。（缺点：没计算一次都要按F9强制更新）。

二、SUMIF函数。

作用：对指定范围内满足条件的值进行求和。

语法：=SUMIF（条件范围，条件，[求和范围]）。当条件范围和求和范围一样时，求和范围可以省略。

方法：

在目标单元格中输入公式：=SUMIF(D3:D9,H3,C3:C9)。

SUMIF函数常见问题及解决办法：

1、当条件匹配字符超过255个时，将返回不正确的结果。

解决办法：空值条件字符在255个范围之内。

三、SUMIFS函数。

作用：对指定范围内同时满足多个条件的值进行求和。

语法：=SUMIFS（求和范围，条件范围1，条件1，条件范围2，条件2,……条件范围N，条件N）。

方法：

在目标单元格中输入公式：=SUMIFS(C3:C9,D3:D9,H3,E3:E9,I3)。

SUMIFS函数常见问题及解决办法：

1、计算结果为“0”。

原因：条件为文本值。

方法：

将条件中的文本条件用""括起来。正确的公式是：=SUMIFS(C3:C9,D3:D9,"男",E3:E9,"北京")。而不是：=SUMIFS(C3:C9,D3:D9,男,E3:E9,北京)或其中一个没有括号。

结束语：

本文对求和函数SUM、SUMIF、SUMIFS的常见用法及错误进行了分析，希望对大家今后的求和需求有所帮助。另：每个函数的常见错误并不是指定在函数后面制定的，SUMIF函数也可能出现SUMIFS函数的常见错误，所以大家有加以灵活应用哦！

小编今天给大家介绍一下如何计算时长，时长和的问题主要聚焦在1）分钟和时间转换问题2）如何提取时间数据3）处理异常数据如空值等等。来看下面示例：

解决步骤：

1.提取小时数据：

E3=VALUE(IFERROR(LEFT(D3,FIND("小",D3,1)-1),0))

解释为：FIND函数找“小”字在D3字符串的位置，减去1,作为左侧小时的位数，LEFT函数截取左侧的小时数，如果不存在小时或者没有记录则用IFERROR函数用0表示，最后用VALUE函数把截取到的数字字符串转换为数字格式。

2.提取分钟数据：

F3=VALUE(IFERROR(MID(D3,IFERROR(FIND("时",D3,1),0)+1,FIND("分",D3,1)-IFERROR(FIND("时",D3,1),0)-1),0))

解释为：分别用FIND函数找“分”和“时”在D3中的位置。找到后用MID函数截取分钟数，起始位置就是FIND函数找“时”加上1，如果FIND“时”函数错误，用IFERROR把错误值变成0，同理截取的字符串个数就是FIND“分”的位置-FIND“时”的位置再减去1，然后套个IFERROR来排除空值错误显示为0，最后套个VALUE函数转变为数字。

3.统一单位为分钟：

G3=E3*60+F3

解释为小时*60+分钟

4.求和时长

H3=CONCATENATE(INT(SUM(G3:G18)/60),"小时",MOD(SUM(G3:G18),60),"分钟")

解释为：先把统一后的分钟数求和，然后除以60在向下取整作为小时数,再把除以60的余数作为分钟数，用到MOD函数求余数。最后用CONCATENATE函数连接，显示格式为：数字+小时+数字+分钟

当然最后还可以不用统一为分钟，去掉G列，后面总小时数为E列的求和加上F列求和除以60的向下取整，然后F列的余数作为分钟数。

转载自百家号作者：EXCEL学习微课堂

最实用Excel求和函数公式大全，小伙伴快来收藏备用！

一、快速求和：快捷键【ALT+=】快速求和

选取整个区域（B2:G14），点按快捷键【ALT+=】

二、含小计行的总计求和公式

如下图所示，要求在单元格设置累计求和公式，等于各小计之和。

B12=SUM(B2:B11)/2

三、隔列求和

隔列求和，如下图所示的计划与实际对比的表中，要计算全年的计划和实际完成情况，可以直接用sumif求和。

F3单元格公式为：=SUMIF($B$2:$E$2,F$2,$B3:$E3)

四、合并单元格求和

如下图所示，要求在D列对A列的类别求和。

D3=SUM(C3:C10)-SUM(D4:D10)

注：公式输入方法，选取D3：D10,在编辑栏中输入公式后按Ctrl+Enter完成输入。

五、含文本型数字求和

含文本型数字的求和，用sum得不到正确的结果，可以用Sumproduct函数进行求和，如下图所示，用Sum求和得到的结果明显不对。

六、忽略错误值求和

如下图所示，如果一个区域中含有错误值，那么在用sum求和时，结果也会显示错误。如果要忽略错误值求和，可用sumif函数解决。

=SUMIF(G2:C12,"<9E+307")或者=SUMIF(G2:G12,">0")

公式解析：

9E+307是接近最大的数字，一种约定俗成的写法。在excel中，错误值比最大的数字大，因此"<9E+307"就是对小于最大值的数字求和，就实现了我们的目标：忽略错误值只对数字求和。反过来，excel忽略错误值求和，我们也可以这样写公式：=SUMIF(G2:G12,">0")

七、多条件求和

根据条件对数据分类求和也是常遇到的求和方式，如果是单条件用SUMIF函数，如果是多条件就用SUMIFS函数。

如下图，根据销售情况表，求出各销售部门2018年1月20日之前的销售总额

I2单元格公式为：=SUMIFS(F:F,C:C,H2,A:A,"<2018-1-20")

八、模糊条件求和

如果需要进行模糊求和，就需要掌握通配符的使用，其中星号是表示任意多个字符。

如下图，根据销售情况表分别计算出各销售部门销售各种产品（打印机、笔记本、台式机）的总数。H2=SUMIFS($E:$E,$C:$C,$G2,$D:$D,H$1&"*")，由于打印机、笔记本和台式机有多个型号，所有要用通配符“*”。

九、多个表格同一位置求和

1月至12月的12个工作表如果格式完全相同，可以用sum函数的多表求和功能。

如下图所示，要求在汇总表里设置合计公式，汇总12个月员工各产品的销售情况。

B2单元格公式为： =SUM('1月:12月'!B2)

十、多个表格多条件求和

多表多条件求和可以用SUM函数和DSUM函数嵌套使用。

如下图所示，有表1、表2和表3三个工作表，要统计三个表中，张1、张2、张3的销量和。

C2单元格输入公式=

SUM(DSUM(INDIRECT({"表1";"表2";"表3"}&"!A1:D11"),4,A$1:B2))-SUM(C$1:C1)

公式解析：

1、数据区域，跨表引用了3个工作表，所以用工作表引用函数INDIRECT。

2、列数，第4列“销量”。

3、条件区域是从A1开始的活动区域，所以A1是绝对引用，但B2是相对引用。

4、由于是跨表引用，因此DSUM返回的是数组，不是单值，因此要外套sum。

5、因为不同的行是“或条件”所以在统计张2第一周的销量时，结果会包含张1第一周的销量，需要减去张1第一周销量，同样的道理，统计张3第一周的销售时要减去张1和张2第一周的销售和。

十一、按颜色求和

excel中还没提供按颜色求和的函数，需要借用宏表函数获取单元格的颜色值，然后再用sumif函数求和。

1、定义名称：公式 - 定义名称 ，在定义名称窗口中输入名称【颜色】，也可以自定义其它名称），然后在下面引用来源中输入公式：=GET.CELL(63,1月!B2)&T(NOW())

公式解析：

①Get.cell(63,单元格) 可以获取单元格填充颜色值

② &T(NOW) 实现表格在更新时定义名称取值也可以更新

2、获取颜色值：在C列和F列分别输入公式 =颜色，即可获取B列和D列的单元格填充色。

3、通过sumif函数求和。在F3单元格输入公式=SUMIF(C:C,E3,B:B)

我是EXCEL学习微课堂，百家号教育视频原创作者，如果我的分享对您有帮助，欢迎点赞、收藏、评论和转发！更多的EXCEL技能，可以关注百家号“EXCEL学习微课堂”。

与本教程有关的往期分享教程有：

1、Excel秒杀一切的求和函数SUMIFS, 多条件求和就靠它了！

2、EXCEL多条件求和、跨表多条件求和函数DSUM，让你求和效率更高！

本文由“EXCEL学习微课堂”原创，欢迎关注，带你一起长知识！

求和的解法在Excel中是千变万化的，也有很多种方法，但是有一种问题，不知道各位小伙伴们有没有注意到，这也是一位朋友在工作中遇到的一个例子。

下面就给大家举例说明一下这个题目，如何用公式来完成。

问题：求下面三个型号的数量的合计。

关于以上题目的做法，很多朋友也说出了一些基本操作的方法，但是好像都不能奏效。

小A说：可以用透视表的作法。小编在这里拉了一个透视表，但是只出现了大写的型号的合计，而小写的也没有出现。并且在统计的金额上也出现了错误。

如下图所示：

小B说：可以用合并计算的方法。但是好像也没有起到作用，合并计算出来的结果与透视表的结果是一样的，当你去逐一验证的时候又是不对，也没有出现小写的型号。

小C说：再不行的话就用筛选的方法进行原始的合并计算。小编验证了一下，好像也是不行的。

小D说：那就是用sumif的基本用法进行条件求和。小编同样满足了他的要求，但是求和的结果也同上面的是一样的。

上面的众多的方法都尝试过了，但都不是最好的办法，那么说没有好的方法了吗？

并不是的，条条大路通罗马嘛，方法还是有的哈，听小编给大家一一讲来。

大家都知道，Sum、Sumif、Sumifs、Sumproduct在单独使用的时候是不区分英文字母的大小写的，包括之前讲过的Vookup也是一样的。所以大家在使用的时候一定要注意一些单独的字符或者字符串在查找或者求值的过程中要注意区分大小写。在Excel中，基本区分大小写的函数有Find、Exact、Substitute等函数。

下面，我们就使用这些函数进行求和。

方法一：Sum/Sumproduct+Exact组合法

在G5单元格中输入以下的公式：

=SUM(EXACT(F5,$A$2:$A$21)*($B$2:$B$21))

并按组合键确定并填充。

此处也可以将Sum替换成Ssumproduct，直接按Enter键即可。

解析：Exact可以区分大小写。先用此函数将目标查找值与查找区域进行对比，确定符合条件的区域值，EXACT(F5,$A$2:$A$21)返回值为：

{TRUE;FALSE;FALSE;FALSE;FALSE;FALSE;FALSE;FALSE;FALSE;FALSE;FALSE;FALSE;FALSE;FALSE;FALSE;TRUE;FALSE;FALSE;FALSE;FALSE}，在前几期中过，逻辑值是可民认参与运算的，此处就转换为了0，1的值，然后再将数量区域乘上，产生

=SUM({TRUE;FALSE;FALSE;FALSE;FALSE;FALSE;FALSE;FALSE;FALSE;FALSE;FALSE;FALSE;FALSE;FALSE;FALSE;TRUE;FALSE;FALSE;FALSE;FALSE}*{85;37;35;24;72;80;21;43;6;24;73;62;50;13;61;52;47;53;80;8})，然后再用sum函数将以上的相乘的值进行相加。

方法二：Sum/Sumproduct+Substitute组合法

=SUM((SUBSTITUTE($A$2:$A$21,F5,"")="")*($B$2:$B$21))

此处也可以将Sum替换成Sumproduct，直接按Enter键即可。

解析：Substitute是替换函数，此处使用该函数将要查找的目标值替换为空白，然后以此为条件进行逻辑值运算，从面得出结果。SUBSTITUTE($A$2:$A$21,F5,"")的执行结果为：

{"";"AB002";"AB003";"AB004";"AB005";"AB006";"AB007";"Ab001";"Ab002";"Ab003";"Ab004";"Ab005";"Ab006";"Ab007";"ab001";"";"ab003";"ab004";"ab005";"ab006"}，然后再将“=“” ”得出逻辑值为：

{TRUE;FALSE;FALSE;FALSE;FALSE;FALSE;FALSE;FALSE;FALSE;FALSE;FALSE;FALSE;FALSE;FALSE;FALSE;TRUE;FALSE;FALSE;FALSE;FALSE},然后同以上方法中的运算一样，进行求积求和运算即可。

遗留问题：关于在筛选状态下、合并计算求和、透视表求和会出现错误的结果？

以上问题供各位小伙伴自己去解决，这里不再做过多的阐述。

End.

来自：Excel学堂

第一步：检查单元格数值格式是否正确；

若在连接的单元格下面或右边单元格自动求和，

而自动求和没有自动选择连续的数值区域，

说明单元格数值格式可能有误；如图：

选中相应数值区域；

右击；

单击“设置单元格格式”；

查看相应数值格式是否有误；

注意：数字格式对不对，是与实际相关的，不是绝对的；

如：这里明明想表示的是时间数据（时长），时分秒形式，但格式却是“常规”，显然不符；

选中相应数字区域；

若整列或整行均是相同格式数字，也可选中整列或整行；

设置正确的格式；

如：这里由于是时分秒形式的时长数字，建议设置成“自定义”-“[h]:mm:ss”；

否则超出24小时的时长时分秒形式可能无法正常显示；（如何正常以时分秒形式显示超出24小时的时间数字）

第二步：检查数字表达是否正确；

若数字格式正确；

但自动求和还是无法自动选择连续的区域；

说明数字表达可能有误；

数字表达要符合相应数字格式形式；

如：这里不认真看，还真看不出数字表达有何问题；

但双击一个单元格，再选择其它单元格，一对比，显然数字表达有误；

正常情况下不足1小时的前面小时数字显示的是0；

而表格里相应数字均是00；0小时表达为00小时，显然有误；

第三步：检查是否选中了自动重算；

若自动求和数值不对，或数字更新后求和数值不更新；

可能没有正常选中“自动重算”；

单击“文件”；

（本文内容由百度知道网友绿衣人敲门贡献）

excel求和，有汉字怎么办？好烦人啊，有解决的办法吗？有！

很多用excel计算的朋友，会经常遇到这样的情况：

我们得到的excel数据

有人说这个不是很简单吗？我们在后面的单元格输入=B2*C2，往下一拉不就行了吗，来吧我们试试看：

excel出现的结果竟然是这样的：

简单的求和，excel出错了

那应该怎么办呢？假如我们想要的是，待定，未定，这些忽略，目前确定的数量是多少，我们在需要求和的单元格输入=SUMPRODUCT(B2:B6,C2:C6)，哇，竟然没出错，太神奇了！

excel在有汉字的情况下，完美的计算出了结果

这是什么意思呢？我们需要的结果是单价和数量乘积之和，而SUMPRODUCT是专门解决这个问题的函数，函数 SUMPRODUCT 将非数值型的数组元素作为 0 处理，所以汉字就被excel视为0。

怎么样，很简单吧，你学会了吗？快去试试吧！非常感谢您观看文本，如果你有更好的方法适用这个情况，请您留言分享！分享好玩、有趣、实用的手机和电脑技巧，您的支持就是我的最大动力！

求和，是最常见的统计工作，但花样繁多的求和要求和条件，常常让不少人限入苦思冥想不得其解的困惑之中，今天运用EXCEL函数与公式，总结从初级到高级的10个求和技巧，与大家一起学习和交流。

初级篇

1、运用“=”、“+”来计算

这是最基础的求和方法，适合无规律或指定单元格求和。如下图：计算1、3、5月份的销售量。J2单元格：=E2+G2+I2，然后，向下复制

2、运用函数SUM求和

这是基础求和函数，适合连续区域求和，高级应用多为与其他函数结合形成SUM数组公式。说明一点，SUM函数的参数，可以是单元格区间，也可以是单个单元格。如下图：计算1、3、5月份的销售量。J2单元格：=SUM(E2,G2,I2)，然后，向下复制

中级篇

3、忽略文本跨列求和

如下图，计算全部销售人员的销售额。C10单元格：=SUM(A2:I7)

利用Excel中sum函数本身对文本类型数值自动忽略的规定，所以，可以用来直接对跨列的数值型数据求和。

4、单条件求和，运用求和函数：SUMIF。

如图，计算1月份冰箱的销售量。K2单元格：=SUMIF($D$2:$D$18,"冰箱",$E$2:$E$18)

SUMIF函数基本结构：SUMIF（条件区域，条件，求和区域）

5、多条件求和，运用求和函数：SUMIFS。

如图，计算销售一部1月份相机销售量。L2单元格：=SUMIFS($E$2:$E$18,$A$2:$A$18,"销售一部",D$2:D$18,"相机")

SUMIFS函数基本结构：SUMIF（求和区域，条件区域1，条件1，条件区域2，条件2...）

6、避开错误值求和。

如下图：计算1-5月份总销售量。C12单元格：=SUMIF(A2:E10,"<9.9E+307")

应用函数SUMIF设置条件完成，其中设置条件"<9.9E+307"，其含义是，9.9*10^307，即9.9乘10的307次方，9.9E+307是一个极大的数值，根据EXCEL的通过规则：数值<文本

7、通配符求和

如下图：计算1月份包含电脑的的总销量。G2单元格：=SUMIF(C2:C18,"*电脑",D2:D18)

应用函数SUMIF设置条件完成，通配符*代表任何字符或字符串，只要总字符不超过255个，设置条件"*电脑"，或“*电脑*”，在选定区域中查找包含“电脑”的所有商品，在计算区域求和。

8、快速累计求和

利用“$”对求和区域首个单元格进行绝对引用，马上就能对一列数值快速累计求和，如下图，C2单元格：=SUM($B$2:B2)，向下复制即可。

9、求和的快捷键："Alt + =",选中要求和的区域和拟计算结果的空白区域，一键即可在空白区域产生求和结果

高级篇

10、求和之王：SUMPRODUCT

SUMPRODUCT函数跟SUM函数的数组公式条件求和语法一样。

=SUMPRODUCT((条件区域=条件)*求和区域)

如上面案例，计算1月份冰箱的销售量。K2单元格：=SUMIF($D$2:$D$18,"冰箱",$E$2:$E$18)，也可以写成：=SUMPRODUCT((D2:D18="冰箱")*E2:E18)

如上面案例，计算销售一部1月份相机销售量。L2单元格：=SUMIFS($E$2:$E$18,$A$2:$A$18,"销售一部",D$2:D$18,"相机")，也可写成：=SUMPRODUCT((A2:A18="销售一部")*(D2:D18="相机")*E2:E18)

下面，举个复杂一点点的例子，昨天，世界杯开始，首场比赛，俄罗斯队5：0大胜沙特队，拟统计本次世界杯，各小组球队进、失球队总数。

以A组为例，第一场有真实比分，其余为模拟分。就可以用SUMPRODUCT计算，进球数：J2单元格：=SUMPRODUCT(($B$2:$B$7=$I3)*($C$2:$C$7))+SUMPRODUCT(($F$2:$F$7=$I3)*($E$2:$E$7))；失球数：K2单元格：=SUMPRODUCT(($B$2:$B$7=$I3)*($E$2:$E$7))+SUMPRODUCT(($F$2:$F$7=$I3)*($C$2:$C$7))

SUMPRODUCT与其他函数结合还可以解决你意想不到的求和需求，以后我们会专门进行分享。请关注后，期待好文。

每天学习一点点，每天进步一点点，积硅步，必能致千里，得大成。

使用Excel/WPS表格计算很方便，可有些时候连最简单的求和运算也会算错，就像下表，得出了“1.0+1.0=2.1”，别不相信你的眼睛！

是数值格式不对吗？是公式输入错了吗？

都不是啊！可结果却和期望相差了0.1、0.01、0.001！

很多做财务和会计的朋友会遇到这个问题。虽然结果看似相差不大，但是就像上面的表格，结账时相差0.1，这可是1000元啊。假如数字的单位变成了“百万”、“千万”，那可是不小的一笔钱啊。

细思极恐！

为什么求和会出错

既然单元格格式和公式都没有错，那我们有理由相信Excel没有计算错，错误只可能出现在原始数据和小数位数上。我们分别点击两个金额的单元格，在输入栏上可以看到原始的数据是“1.0345”、“1.0435”，虽然原始数据显示为小数点后保留一位，但Excel计算时还是用“1.0345+1.0435”，得到结果2.0780，保留一位小数点后得到2.1。

求和出错怎么办

终于找到了原因，我们可以用ROUND函数来处理。输入公式“=ROUND(C2,1)”\“=ROUND(C3,1)”，然后再用SUM函数求和就没有问题啦。

ROUND函数怎么用

语法：ROUND(数值，保留的小数位数）功能：按照指定的小数位数对数值进行四舍五入。

ROUND函数有两个参数，第一个表示要处理的数据，第二个表示要保留的数值位数/小数位数，它有3种情况。

第二个参数为正数，如2，表示小数点后保留两位数字，也就是对小数点后的第3位进行四舍五入。第二个参数为0，表示去掉小数点后所有的数字，结果取整，也就是对小数点后第1位数字进行四舍五入。第二个参数为负数，表示对小数点左边的数字进行四舍五入。如“=ROUND(15.5356,-1)”表示对小数点左侧第1位数字“5”四舍五入，得到20；“=ROUND(1.5356,-1)”表示对小数点左侧第1位数字“1”四舍五入，结果得到0。

每一个都要添加ROUND函数好麻烦怎么办

网上有些朋友给出了解决方案是：设置工作簿选项为“以显示精度为准”/“将精度设为所显示的精度”。

不过，这样做，会导致原始数据自动被四舍五入！原本的“1.0345”、“1.0435”都变成了“1.0”。

这等于丢失了原始数据！

所以还是建议使用ROUND函数。当数据很多时，可以先输入前面的几个公式，然后选中单元格，双击一下，即可批量输入公式。

如果表格中的数据很多，可以另外再做一个修正表，双击快速填充公式，还是很好用的。

相关阅读：《WPS Excel 日期变数字、变“ ”号怎么办》。

谢谢阅读，每天学一点，省下时间充实自己。欢迎点赞、评论、关注和点击头像。

有时候

当我们对一张表格中的

数据进行求和时

如果单元格中

某些数值是错误值

那么

直接使用SUM函数

是完全得不到正确结果的

那要怎么办呢？

有什么公式可以

把错误值忽略再进行求和吗？

答案肯定是有的

今天小编就教大家

如何在EXCEL表格中

忽略错误值求和

以下列这张表格为例

表格中出现了错误值#N/A

公式一

=SUMIF(B2:E2,"<9E+307")

SUMIF函数为条件求和函数

B2:E2为求和区域

<9E+307为求和判定条件

在EXCEL中计算机能处理的最大数为

9.999999999+307

在计算中一般用不到

所以将其作为条件

只要满足小于它的就参与计算

公式二

=SUMIF(B2:E2,"<1000000")

SUMIF函数为条件求和函数

B2:E2为求和区域

<1000000为求和判定条件

公式三

=SUMIF(B2:E2,">0")

SUMIF函数为条件求和函数

B2:E2为求和区域

>0为求和判定条件

公式四

=AGGREGATE(9,3,B2:E2)

AGGREGATE 函数返回列表或数据库中的合计

9指要使用的函数为SUM函数

3指在函数的计算区域内要忽略错误值

B2:E2为计算的区域

以上

就是在EXCEL中

忽略错误值

进行求和的方法

其实

前3个公式都是

应用了SUMIF函数

只是给定的判定条件不同

但结果都是一样的

那么这几个公式

你们都记住了

当你们不知道如何

进行求和时

看一下本篇文章就知道啦

关注

海生PPT

马上进入职场新境界

越专注 越幸运

心事留言，小编答你

Hi，大家好，我是胖斯基

周末闲暇，整理了下那铺满灰尘的书架。

透过尘埃，在故纸堆中发现这么一本连环画图册，脑海中瞬间回忆起那真假美猴王的剧幕，那一幕幕，完美的演绎了真亦假时假亦真，无为有处有还无……

其实，在Excel中，这种真真假假也同样存在，也一样带来了求和困扰！

求和，在Excel中很简单，相信小白都可以脱口而出，直接函数SUM即可，然后有时候，事实并非如此：

当采用最傻瓜的方式直接逐个相加时，发现结果正确；

但是当采用SUM求和时，结果却错误。

不明其中缘由的你，可能会非常困扰，明明就这几个数相加，怎么就不对了呢？

其源头就是“真假数据”，在Excel中的专业叫法是文本型数据（不参与直接运算）。

So，当这类“假数据”参与SUM时，自然不进行正确的求和运算。

1

那如何判定文本型的数值参与了运算？

技巧1：观察法

如果是文本型的数据，则在其单元格的左上角，会有一个三角符号提示

相信只要视力没问题，基本可以快速排查出所谓的“假数据”

当然，更BT的一种就是其单元格上没有小三角符合，那如何快速判定这一系列数据是否有问题呢？

依旧采用观察法：

选中这一列数据，然后观察Excel的右下方，会有文字提示：计数：6，数值计数：5，很明显，这其中有1个数字为“假数据”，So，找到Ta，解决Ta即可！

那如何从茫茫人海中找到这个“假数据”呢？

技巧2 ： 函数判断法

在Excel中，判断一个数字是否是真正的数值，有一个函数ISNUMBER，当其结果为TRUE的时候，其为真数字，当其结果为FALES时，其为假数字（文本型数字）

从函数检测结果来看，很容易就分辨出了那些数据有问题

发现问题很重要，解决问题更重要

2

如何解决文本型数值参与的计算？

技巧3 ： 文本转数值法

如果单元格里面的数值已经明确判定为文本型的“假数据”了，那可以采用文本转数值的模式，如下：

选中数据列，在右侧的提示框中选择转化为数值即可

技巧4 ： 公式计算法

当然，如果单元格里面的数据是从其他表，通过公式引入过来的，又该如何处理呢？

无论单元格里面公式是什么，在其后乘以1（*1）即可，通过数据运算让文本型转化为数值型数据

当然，也许发懒的你，什么都不想改，想直接在求和中自动计算，又该如何处理呢？

公式1：=SUM(1*(A2:A7)) ， 输入公式后，三键一起按（数组公式）

公式2：=SUMPRODUCT(1*(A2:A7))

其核心内涵，还是采用数据乘以1的方式，将文本转化为数值。

胖斯基|说

无论文本型数据也好，还是数值型数据也好，当掌握了上面4个小技巧时，真真假假，假假真真，便不那么重要了。