平时在设计表格的时候，为了减少数据冗余。经常会进行数据单元格的合并。数据以合并以后，一些统计运算就变得有些复杂了，本文将结合案例。给大家介绍一些套路。以实现对合并单元格的按条件统计，因为涉及到的公式较为复杂，大家仔细看好了。有任何疑问都可以在文章底部给勇哥留言，勇哥定会知无不言言无不尽。更多Excel学习和问题请加群：289393114、570064677

如下图所示，A列的姓名合并了单元格。我们需要按照员工对B列进行求和运算。

众所周知，由于合并了单元格。在合并区域只有第一行只有内容，剩下的被合并的内容都是空值，这样会导致无法进行数据统计。那有没有办法对合并单元格的数据进行按条件求和呢？答案是肯定的，也许你要说我直接吧合并的单元格补齐，不就可以求和了。确实这么操作可以这么处理，勇哥将另辟蹊径。给大家介绍一种方法，通过介绍这种方法。您能够掌握更多的Excel公式。是不是很期待，心动了吧。那就跟着勇哥，慢慢往下看吧。

实现思路

1.按照姓名查找到对应的区域，然后使用sum进行求和

2.关键问题就转化为如何找到姓名对应的区域？

3.使用Match函数找到姓名第一次出现的行

4.在使用lookup从当前的下一行开始找到不为空的数据出现的行数。（为了保证能够获取到靓颖的数据。勇哥决定在数据的下一行敲入一些空格，记住一定要敲哦）

5.有了第3,4步的结果使用求和函数即可计算出相应的结果

为了讲解清楚这个公式，勇哥决定把公式分解开。这样既可以方便定位问题，也便于大家理解公式。勇哥决定拆分成如下的表格，依次计算出每个姓名对应的开始位置，结束位置。有了开始、结束位置。比较容易求和统计结果了。

开始位置

MATCH(E2,A:A,0)

结束位置

开始位置 + {MATCH(TRUE,OFFSET($A$1,G2+1,0,1000,1)<>"",0)}

MATCH(TRUE,OFFSET($A$1,G2+1,0,1000,1)<>"",0)

这个公式是从开始位置的下一行开始找不为空的数据出现的位置，这是个讨论。建议大家记住

通过比较构造一个true false的数组。然后采用match函数匹配到第一个不为空数据出现位置

OFFSET($A$1,G2+1,0,1000,1)

构造一个从开始位置下一行开始的一个1000行1列的数据区域，当然这里写成了1000是为了扩大区域。你也可以将1000 修改为函数，以自动计算数据的个数。

提示：因为是数组公式，这里一定要按三键哦

统计结果

sum(indirect("B" & 开始位置 &":B" & 结束位置))

indirect 可以获取到对应的单元格区域

在实际工作中，我们会遇到跨表求和的情况，需要汇总连续多个表中相同区域的数据 (所有的表结构相同，项目不存在重复情况)，如何跨表快速汇总呢？

如下所示：在1~12月每个工作表中都存在相同的表格形式，现在需要在汇总表中计算1~12月所有品牌手机的销售数量和金额

方法其实很简单的，我们先看销量计算的公式，销售额同理

方法一：

输入公式=sum('*'！E6)

技能get: * 为通配符，代表任意多个字符的意思，在这里代表除了汇总表之外的其他所有表，！表示工作表的意思，输入此公式后会自动转化为=sum('1月：12月'!E6）

方法二：

先输入=sum( , 然后鼠标点住1月工作表标签，按住shift,再点击最后一个工作表标签（12月），然后鼠标选择E6单元格，按enter结束公式输入，公式显示结果=sum('1月:12月'!E6)

什么情况下用这种方式呢，如果工作簿中除了需要汇总的表格之外，还有其他的不需要汇总的表格，为了防止使用通配符造成不需要汇总的表格也参与汇总，可以使用这种方式

需要注意的是以上两种方法针对的表格的结构上的要求：所有需要汇总的表结构相同，项目不存在重复情况，小伙伴们，如果你学会了，现在就尝试一下吧

求和的解法在Excel中是千变万化的，也有很多种方法，但是有一种问题，不知道各位小伙伴们有没有注意到，这也是一位朋友在工作中遇到的一个例子。

下面就给大家举例说明一下这个题目，如何用公式来完成。

问题：求下面三个型号的数量的合计。

关于以上题目的做法，很多朋友也说出了一些基本操作的方法，但是好像都不能奏效。

小A说：可以用透视表的作法。小编在这里拉了一个透视表，但是只出现了大写的型号的合计，而小写的也没有出现。并且在统计的金额上也出现了错误。

如下图所示：

小B说：可以用合并计算的方法。但是好像也没有起到作用，合并计算出来的结果与透视表的结果是一样的，当你去逐一验证的时候又是不对，也没有出现小写的型号。

小C说：再不行的话就用筛选的方法进行原始的合并计算。小编验证了一下，好像也是不行的。

小D说：那就是用sumif的基本用法进行条件求和。小编同样满足了他的要求，但是求和的结果也同上面的是一样的。

上面的众多的方法都尝试过了，但都不是最好的办法，那么说没有好的方法了吗？

并不是的，条条大路通罗马嘛，方法还是有的哈，听小编给大家一一讲来。

大家都知道，Sum、Sumif、Sumifs、Sumproduct在单独使用的时候是不区分英文字母的大小写的，包括之前讲过的Vookup也是一样的。所以大家在使用的时候一定要注意一些单独的字符或者字符串在查找或者求值的过程中要注意区分大小写。在Excel中，基本区分大小写的函数有Find、Exact、Substitute等函数。

下面，我们就使用这些函数进行求和。

方法一：Sum/Sumproduct+Exact组合法

在G5单元格中输入以下的公式：

=SUM(EXACT(F5,$A$2:$A$21)*($B$2:$B$21))

并按组合键确定并填充。

此处也可以将Sum替换成Ssumproduct，直接按Enter键即可。

解析：Exact可以区分大小写。先用此函数将目标查找值与查找区域进行对比，确定符合条件的区域值，EXACT(F5,$A$2:$A$21)返回值为：

{TRUE;FALSE;FALSE;FALSE;FALSE;FALSE;FALSE;FALSE;FALSE;FALSE;FALSE;FALSE;FALSE;FALSE;FALSE;TRUE;FALSE;FALSE;FALSE;FALSE}，在前几期中过，逻辑值是可民认参与运算的，此处就转换为了0，1的值，然后再将数量区域乘上，产生

=SUM({TRUE;FALSE;FALSE;FALSE;FALSE;FALSE;FALSE;FALSE;FALSE;FALSE;FALSE;FALSE;FALSE;FALSE;FALSE;TRUE;FALSE;FALSE;FALSE;FALSE}*{85;37;35;24;72;80;21;43;6;24;73;62;50;13;61;52;47;53;80;8})，然后再用sum函数将以上的相乘的值进行相加。

方法二：Sum/Sumproduct+Substitute组合法

=SUM((SUBSTITUTE($A$2:$A$21,F5,"")="")*($B$2:$B$21))

此处也可以将Sum替换成Sumproduct，直接按Enter键即可。

解析：Substitute是替换函数，此处使用该函数将要查找的目标值替换为空白，然后以此为条件进行逻辑值运算，从面得出结果。SUBSTITUTE($A$2:$A$21,F5,"")的执行结果为：

{"";"AB002";"AB003";"AB004";"AB005";"AB006";"AB007";"Ab001";"Ab002";"Ab003";"Ab004";"Ab005";"Ab006";"Ab007";"ab001";"";"ab003";"ab004";"ab005";"ab006"}，然后再将“=“” ”得出逻辑值为：

{TRUE;FALSE;FALSE;FALSE;FALSE;FALSE;FALSE;FALSE;FALSE;FALSE;FALSE;FALSE;FALSE;FALSE;FALSE;TRUE;FALSE;FALSE;FALSE;FALSE},然后同以上方法中的运算一样，进行求积求和运算即可。

遗留问题：关于在筛选状态下、合并计算求和、透视表求和会出现错误的结果？

以上问题供各位小伙伴自己去解决，这里不再做过多的阐述。

End.

来自：Excel学堂

今天和新手们分享有关条件求和的内容，高手请忽略。

先来看一组销售数据，是某商场不同品牌电视机的三天销售记录：

现在需要根据G列的品牌，计算其三天的销售总和。

想必有表亲已经想到办法了，既然是按条件求和，就用SUMIF呗：

=SUMIF(B:B,G2,C:C)+SUMIF(B:B,G2,D:D)+SUMIF(B:B,G2,E:E)

公式分别对C、D、E列条件求和，最后相加。

这样看是没有问题的，可是如果需要对30列数据条件求和，那岂不是太费劲了哦。

嗯，还有一种简便一点的公式：

这里用到了数组公式：

=SUM(IF(B$2:B$72=G2,C$2:E$72))

首先用IF函数进行处理，如果B2:B72中等于G2单元格指定的品牌，就返回C2:E72单元格区域中对应行的数值，否则返回逻辑值FLASE，最后使用SUM函数求和。

这里因为执行了数组运算，所以公式编辑完成后，要单击编辑栏，再按住Shift+Ctrl不放，按回车。注意公式两侧的花括号是自动生成的，手工敲入是无效的哦。

这个公式比较简短，但是需要按三键才能输入，有些新人朋友可能一时还找不到感觉，耐心点，多试几次吧。

还有一个不需要按三键输入的公式：

=SUMPRODUCT((B$2:B$72=G2)*C$2:E$72)

首先使用B$2:B$72=G2判断B列是否等于指定的品牌，得到逻辑值TRUE或是FLASE，再用逻辑值与C2:E72的数值相乘，最后使用SUMPRODUCT计算出乘积之和。

本例中，除了使用以上公式之外，如果使用数据透视表汇总，将会更加便捷方便，你会使用吗？

作者：Hoa小熊猫 图文整理：祝洪忠

ExcelHome，微软技术社区联盟成员

我们肯定知道按单条件、多条件，多表求和，唯独有一种求和我们很少听说过，那就是：按—颜—色—求—和。是的没看错，就是an颜色求和，

【例】如下图所示，要求按颜色进行求和。

Excel中还没提供按颜色求和的函数，但我们可以借用宏表函数（老版本遗留的一种函数，只能在定义名称中使用）获取单元格的颜色值，然后再用sumif函数求和来解决我们的问题。

一、定义名称，为提取颜色值做准备

公式 - 定义名称 ，在定义名称窗口中输入名称 mycolor（可以自定义），然后在下面引用来源中输入公式：=GET.CELL(63,Sheet2!B2)&T(NOW())

公式说明：

Get.cell(63,单元格) 可以获取单元格填充颜色值&T(NOW()) 实现表格在更新时定义名称取值也可以更新

二、获取颜色值

在C列和F列分别输入公式 =mycolor，即可获取B列和D列的单元格填充色。

三、剩下的交给sumif函数吧

单元格内输入 =SUMIF(C:C,E2,B:B)

按颜色求和对高手并不难，但对于新手可能还要用多了才能记住，所以建议大家先收藏起来备用吧。

求和，是最常见的统计工作，但花样繁多的求和要求和条件，常常让不少人限入苦思冥想不得其解的困惑之中，今天运用EXCEL函数与公式，总结从初级到高级的10个求和技巧，与大家一起学习和交流。

初级篇

1、运用“=”、“+”来计算

这是最基础的求和方法，适合无规律或指定单元格求和。如下图：计算1、3、5月份的销售量。J2单元格：=E2+G2+I2，然后，向下复制

2、运用函数SUM求和

这是基础求和函数，适合连续区域求和，高级应用多为与其他函数结合形成SUM数组公式。说明一点，SUM函数的参数，可以是单元格区间，也可以是单个单元格。如下图：计算1、3、5月份的销售量。J2单元格：=SUM(E2,G2,I2)，然后，向下复制

中级篇

3、忽略文本跨列求和

如下图，计算全部销售人员的销售额。C10单元格：=SUM(A2:I7)

利用Excel中sum函数本身对文本类型数值自动忽略的规定，所以，可以用来直接对跨列的数值型数据求和。

4、单条件求和，运用求和函数：SUMIF。

如图，计算1月份冰箱的销售量。K2单元格：=SUMIF($D$2:$D$18,"冰箱",$E$2:$E$18)

SUMIF函数基本结构：SUMIF（条件区域，条件，求和区域）

5、多条件求和，运用求和函数：SUMIFS。

如图，计算销售一部1月份相机销售量。L2单元格：=SUMIFS($E$2:$E$18,$A$2:$A$18,"销售一部",D$2:D$18,"相机")

SUMIFS函数基本结构：SUMIF（求和区域，条件区域1，条件1，条件区域2，条件2...）

6、避开错误值求和。

如下图：计算1-5月份总销售量。C12单元格：=SUMIF(A2:E10,"<9.9E+307")

应用函数SUMIF设置条件完成，其中设置条件"<9.9E+307"，其含义是，9.9*10^307，即9.9乘10的307次方，9.9E+307是一个极大的数值，根据EXCEL的通过规则：数值<文本

7、通配符求和

如下图：计算1月份包含电脑的的总销量。G2单元格：=SUMIF(C2:C18,"*电脑",D2:D18)

应用函数SUMIF设置条件完成，通配符*代表任何字符或字符串，只要总字符不超过255个，设置条件"*电脑"，或“*电脑*”，在选定区域中查找包含“电脑”的所有商品，在计算区域求和。

8、快速累计求和

利用“$”对求和区域首个单元格进行绝对引用，马上就能对一列数值快速累计求和，如下图，C2单元格：=SUM($B$2:B2)，向下复制即可。

9、求和的快捷键："Alt + =",选中要求和的区域和拟计算结果的空白区域，一键即可在空白区域产生求和结果

高级篇

10、求和之王：SUMPRODUCT

SUMPRODUCT函数跟SUM函数的数组公式条件求和语法一样。

=SUMPRODUCT((条件区域=条件)*求和区域)

如上面案例，计算1月份冰箱的销售量。K2单元格：=SUMIF($D$2:$D$18,"冰箱",$E$2:$E$18)，也可以写成：=SUMPRODUCT((D2:D18="冰箱")*E2:E18)

如上面案例，计算销售一部1月份相机销售量。L2单元格：=SUMIFS($E$2:$E$18,$A$2:$A$18,"销售一部",D$2:D$18,"相机")，也可写成：=SUMPRODUCT((A2:A18="销售一部")*(D2:D18="相机")*E2:E18)

下面，举个复杂一点点的例子，昨天，世界杯开始，首场比赛，俄罗斯队5：0大胜沙特队，拟统计本次世界杯，各小组球队进、失球队总数。

以A组为例，第一场有真实比分，其余为模拟分。就可以用SUMPRODUCT计算，进球数：J2单元格：=SUMPRODUCT(($B$2:$B$7=$I3)*($C$2:$C$7))+SUMPRODUCT(($F$2:$F$7=$I3)*($E$2:$E$7))；失球数：K2单元格：=SUMPRODUCT(($B$2:$B$7=$I3)*($E$2:$E$7))+SUMPRODUCT(($F$2:$F$7=$I3)*($C$2:$C$7))

SUMPRODUCT与其他函数结合还可以解决你意想不到的求和需求，以后我们会专门进行分享。请关注后，期待好文。

每天学习一点点，每天进步一点点，积硅步，必能致千里，得大成。

日常我们工作中经常会需要汇总不同地区发来的表格，或者是需要把不同小组发来的数值叠加到一块计算一个汇总值，除了拿计算器一个一个敲之外，下面分享两种方法：

一、直接用华中B2+华南B2+。。。然后左右拖拉即可。

此方法适用于表格相对较少，简单好记不需要技巧

excel

二、运用函数

=SUM(华东:华北！B2)，其中华东是第一个sheet，华北是最后一个sheet，然后向右向下拖动即可。

此方法适合于sheet较多的情况，直接一个公式就行了，不用一个一个去加还容易遗漏某个sheet，但是就是需要去记住此公式了。

Excel的公式真的太多了，长期不用就忘了，用的时候又想不起来了，小编的办法就是收藏起来说不定哪天就用到了(#^.^#)

excel求和很简单，我们大家都会。但是excel求和仅仅是同工作表求和，如果我们需要跨工作表求和，又该怎么实现呢？这时候就需要我们运用到公式。下面我就给大家一步一步慢慢解说，看过之后，你一定也会觉得非常简单。

为了方便大家学习本经验，我特地制作了几个简单的表，这个表总共是有四个工作表：一个是汇总表，另外三个是单独的个人表。

通过上面几个工作表我们可以看到，张三、李四、王五的成绩都是已知的，而汇总表却是空白的，那么，我们应该怎么将他们的成绩汇总到汇总表内呢。

首先，我们先来填汇总表中所有人第一学期的语文成绩

这里需要一个公式，就是跨工作表的公式：

=（sheet1！X1+sheet2！X1+sheet3！X1）

我给大家解说一下这个公式--sheet代表工作表；X代表工作表内纵坐标的英文字母；1则代表工作表内横坐标的数字。

我们现在将公式带入：

很简单的，我们得到了第一个数值，也就是汇总表内所有人的第一学期的语文成绩

用同样的方法，我们可以得到第一学期所有人的各科成绩。

那么合计又怎么填呢？没错，用求和。之前也写过关于求和的经验，有不明白的大家也可以参考一下噢

总计也是用同样的方法~

就这样，我们填完了所有汇总表的格子啦。是不是很容易呢~

Excel求和函数，除了Sum、Sumif和Sumifs以外，你还用过其它的函数吗？今天分享一个简单实用又高效的数据库函数DSUM，它集「查找」和「求和」功能为一身，能多条件求和，还能跨表多条件求和，让你一看到就会爱上它！

一、函数解析

DSUM函数：将数据库中符合条件记录的字段列中的数字求和。使用它可以对数据进行多条件累加，这种方式可以很方便地修改求和的条件。

DSUM有3个参数：Dsum(数据区域，求和的列数,条件区域)

① 数据区域：一组数据列表，即需要对该组数据列表中的某些数据进行计算。

② 列数：需要求和数据所在列数（也可以是列标题）比如：如果该参数为“3”，则表示需要计算的数据在参数①第3列中，如果该参数为“销量”，则表示需要计算的数据是参数①中的“销量”那一列。

③ 条件区域：由标题行和条件构成的多行区域（条件为公式时，若使用函数标题应为空）。

二、多条件求和案例

如下图所示，计算侯采和马来军的总销量。

在F2单元格中，输入公式：=DSUM(A1:E13,E1,G1:G3)

其中A1:E13是数据区域，E1是统计列“销售量“，G1:G3是条件区域，即计算侯采和马来军2人的销售量。

三、模糊统计案例

统计销售一科以打印机开头的所有产品销量和销售二科的台式机销售之和。

在I2单元格输入公式=DSUM(A1:E13,E1,G1:H3)

DSUM()函数中的判定条件，支持使用通配符 “*” 和 “？”，如下图所示，H2在单元格中使用了通配符“*“表示包含以打印机开头的A、B型号，但不包括D13的激光打印机，如果要包括则前面要加通配符。案例中，同一行的，销售二科和台式机必须同时满足，即并条件，而不同行的销售一科的打印机和销售二科的台式机是或条件，写在不同的行。

四、符合时间条件的求和案例

统计销售日期在2018-1-7至2018-1-14之间的销售量。

I2单元格输入公式：=DSUM(A1:E13,E1,G1:H2)，销售日期是一个区间，可以在一行用两个销售日期的条件。一个是大于2018-1-6，另一个是小于2018-1-15。

五、条件为公式时，函数标题应为空

统计销售一科销量小于平均销量人员的销量总和，销量小于平均销量必须用到公式=E2

H2单元格输入公式=E2

I2单元格输入公式=DSUM(A1:E13,E1,G1:H2)

六、多数据批量汇总案例

分别计算销售一科、销售二科和销售三科的销量。

H2单元格输入公式=DSUM($A$1:$E$13,$E$1,$G$1:G2)-SUM($H$1:H1)

1、由于公式要往下填充，所以数据区域和列都用了绝对引用

2、条件区域是一个从G1开始的活动区域，所以G1是绝对引用，但G2是相对引用

3、因为不同的行是“或条件”所以在统计销售二科销售总量时，结果会包含销售一科的销售总量，需要减去销售一科的销量，同样的道理，统计销售三科销量时要减去销售一科和销售二科的销售和。

七、跨工作表统计案例

如下图所示，有表1、表2和表3三个工作表，要统计三个表中，张1、张2、张3的销量和。

C2单元格输入公式=

SUM(DSUM(INDIRECT({"表1";"表2";"表3"}&"!A1:D11"),4,A$1:B2))-SUM(C$1:C1)

1、数据区域，跨表引用了3个工作表，所以用工作表引用函数INDIRECT。

2、列数，第4列“销量”。

3、条件区域是从A1开始的活动区域，所以A1是绝对引用，但B2是相对引用。

4、由于是的跨表引用，因此dsum返回的是数组，不是单值，因此要外套sum。

5、因为不同的行是“或条件”所以在统计张2第一周的销量时，结果会包含张1第一周的销量，需要减去张1第一周销量，同样的道理，统计张3第一周的销售时要减去张1和张2第一周的销售和。

温馨提示：

1、条件区域列标题内容要与数据区域一致，比如数据区域列标题是“销售产品”，那你要统计某一产品时，条件列标题也要是“销售产品”如果你改为产品，统计会出错

2、切记“并条件”需要横着写，即写在同一行，“或条件”需要竖着写，即写在不同行。

3、条件为公式时，若使用函数标题应为空。

我是EXCEL学习微课堂，如果我的分享对您有帮助，欢迎点赞、收藏、评论、转发！更多的EXCEL技能，可以关注百家号“EXCEL学习微课堂”。

在 Excel 中，除在同一工作表求和外，还可以在不同工作表与不同 Excel 文档的工作之间求和；如果只在不同的工作表求和，只需标明工作表名称，如果在不同 Excel 文档之间求和，还要标明文档名称。另外，还可以跨行与跨列求和，它们可以用SUMPRODUCT函数。以下就是Excel跨工作表、跨行与跨列求和的具体操作方法，实例中操作所用版本均为 Excel 2016。

一、Excel跨表求和

1、假如要求一个服装表中 1月、2月和3月的销量之和。选中 E2 单元格，把公式 =SUM('1月'!D2:D6,'2月'!D2:D6,'3月'!D2:D6) 复制到 E2，按回车，则求出一件服装的 1 至 3 月销量之和；把鼠标移到 E2 右下角的单元格填充柄上，按住左键并往下拖，则求出其它服装的 1 至 3 月的销量之和；操作过程步骤，如图1所示：

2、公式说明。公式中 '1月' 是工作表（即 Sheet）的名称，工作表与单元格之间用感叹号 ! 隔开，“2月和3月”的求和单元格的引用方法也一样。

3、跨文档求和。

A、如果待求和的单元格分布在两个或多个 Excel 文档中，则还需要在表格名称的前面加上文档名称。假如要对“服装销量1.xlsx”和“服装销量2.xlsx”两个文档的“1月”工作表的服装销量求和，操作过程步骤，如图2所示：

B、操作过程步骤说明：在“服装销量1”窗口，在 E2 单元格输入公式 =SUM()，把光标定位在括号中，单击一下工作表“1月”，框选 D2:D6，公式变为 =SUM('1月'!D2:D6)，在 D6 后输入逗号（,）；切换到“服装销量2”窗口，单击一下工作表“1月”，同样框选 D2:D6，切换回“服装销量1”窗口，公式变为 =SUM('[服装销量1.xlsx]1月'!D2:D6,'[服装销量2.xlsx]1月'!D2:D6)，即在“服装销量2”文档中选择的单元格自动填到了公式中；按回车，则计算出一件服装的销量之和，同样用往下拖的方法求出其它服装的销量之和。

C、如果要求“服装销量1.xlsx”和“服装销量2.xlsx”1月与2月的服装销量之和，公式可以这样写：=SUM('1月'!D2:D6,'2月'!D2:D6,'[服装销量2.xlsx]1月'!$D$2:$D$6,'[服装销量2.xlsx]2月'!$D$2:$D$6)，如图3所示：

按回车，则求出两个文档的“1月和2月”的服装销量之和，如图4所示：

二、Excel跨行求和

1、假如要求偶数行的和。把公式 =SUMPRODUCT((MOD(ROW($2:$10),2)+1=ROW(A1))*F$2:F$10) 复制到 F11 单元格，按回车，则求出第 2、4、6、8 和 10 行的和，操作过程步骤，如图5所示：

2、公式说明：

A、选中公式所在单元格 F11，按住 Alt 键，按一次 M，按一次 V，打开“公式求值”窗口，单击“求值”一直到求出最终的结果，如图6所示：

B、公式中 ROW($2:$10) 返回一个 2 到 10 的数组，即{2;3;4;5;6;7;8;9;10}；MOD(ROW($2:$10),2) 是把数组中的每个元素与 2 求模；然后再把求得的数组每个元素都加 1；再判断数组的每个元素是否等于 ROW(A1)（即 1，ROW(A1) 是取 A1 行号），如果等于，返回 True，否则返回 False。

C、经过上述计算，求得数组{True;False;True;False;True;False;True;False;True}，数组中为 True 的用 F 列中的数字代替，为 False 的用 0 代替，即得数组{329;0;874;0;982;0;897;0;563}，最后用 SUMPRODUCT函数求出和。

3、如果要求第 3、6、9 行的求，公式可以这样写：=SUMPRODUCT((MOD(ROW($3:$9),3)+1=ROW(A1))*F$3:F$9)，如图7所示：

按回车，计算结果，如图8所示：

三、Excel跨列求和

1、假如要求偶数列的和。把公式 =SUMPRODUCT((MOD(COLUMN($B:$H),2)+1=COLUMN(A1))*$B2:$H2) 复制到 I2 单元格，按回车，则求出第2行指定列的和，同样用往下拖的方法求出其它行指定列的和，操作过程步骤，如图9所示：

2、公式说明：公式与求偶数行的和一样，要注意的是：把对行的绝对引用改为对列的绝对引用，即把 F$3:F$9 改为 $B2:$H2，$ 由在数字前改为在字母前。