点击上方「 韩老师讲office 」可快速关注

敬请阅读与分享，让更多学习者一起进步！

函数解释

SUMPRODUCT 函数是 Excel 中的数学函数，将给定的几个数组间对应元素相乘，并返回乘积之和。

其基本语法为：

SUMPRODUCT(array1,[array2], [array3], ...)

SUMPRODUCT 函数语法具有下列参数：

Array1 ：必需。其相应元素需要进行相乘并求和的第一个数组参数。

Array2, array3,... ：可选。 2 到 255 个数组参数，其相应元素需要进行相乘并求和。

特别注意：

数组参数必须具有 相同的维数 。 否则，函数 SUMPRODUCT 将返回 #VALUE! 错误值 #REF! 。

基本用法

SUMPRODUCT 函数最基本的用法是：

数组间对应的元素相乘，并返回乘积之和。

如下图：

公式：=SUMPRODUCT(B2:B9,C2:C9)

该公式的含义是：

B2*C2+B3*C3+B4*C4+B5*C5+B6*C6+B7*C7+B8*C8+B9*C9

单条件求和

如下图，计算女员工业绩得分和：

公式：

=SUMPRODUCT((B2:B11="女")*C2:C11)

其中：

B2:B11="女"：

将B2:B11内每个单元格值与“女”比较，凡是性别为“女”的是TRUE，否则是FALSE，结果返回一组逻辑值：

{FALSE;TRUE;FALSE;TRUE;FALSE;TRUE;FALSE;TRUE;FALSE;TRUE;}

(B2:B11="女")*C2:C11

将上述逻辑数组内的值与对应的C2:C11的数值相乘。

多条件求和

员工业绩得分高于15的得分和：

=SUMPRODUCT((B2:B11="女")*(C2:C11>15),C2:C11)

多条件求和的通用写法是：

=SUMPRODUCT((条件一)*(条件二)*……*(条件N),求和范围)

模糊条件求和

销售 部门 女

销售部门不止一个，要查找所有的销售部门，就要按照关键字“销售”查找，就属于模糊查找。

=SUMPRODUCT(ISNUMBER(FIND("销售",A2:A11))*(C2:C11="女"),D2:D11)

FIND("销售",A2:A11)

在A2:A11各单元格值中查找"销售"，如果能查到，返回"销售"在单元格值中位置，如果差不到，返回错误值#VALUE!。

本部分的结果是：

{#VALUE!;1;1;1;#VALUE!;1;#VALUE!;#VALUE!;1;#VALUE! }

ISNUMBER(FIND("销售",A2:A11)) ：

判断上述数值中各值是不是数字，如果是，返回TRUE，否则返回FALSE,所以，本部分公式的结果是：

{FALSE;TRUE;TRUE;TRUE;FALSE;TRUE;FALSE;FALSE;TRUE;FALSE}

SUMPRODUCT相关知识回顾

Excel | SUMPRODUCT函数注意事项：乘号与逗号有区别

Excel | RANK.EQ（RANK）总排名、SUMPRODUCT分类排名

Excel | SUMPRODUCT计算指定年份与月份的销售总额

Excel | 领导不喜欢看“间断”的排名，RANK换成SUMPRODUCT!

Excel | DGET、SUMIFS、SUMPRODUCT、LOOKUP、OFFSET、VLOOKUP多条件查询

喜欢、有用就点点关注

▲

一、函数语法解析

1、函数定义：对满足条件的单元格求和。

2、函数语法格式

range：根据条件进行计算的单元格的区域。每个区域中的单元格必须是数字或名称、数组或包含数字的引用。空值和文本值将被忽略。所选区域可以包含标准 Excel 格式的日期。criteria：用于确定对哪些单元格求和的条件，其形式可以为数字、表达式、单元格引用、文本或函数。sum_range：实际求和区域，需要求和的单元格、区域或引用。

二、函数应用实例

1、经典用法

输入公式：=SUMIF(C3:C8,">=8000",C3:C8)或者=SUMIF(C3:C8,">=8000")当条件区域和求和区域相同时可以省略第三参数。第三参数省略时，默认条件区域就是求和区域。

2、求性别为“女”的销售额之和

输入公式：=SUMIF(B12：B17,"女",C12:C17)

3、通配符的使用

公式：F21=SUMIF(A21:A26,"*"&6&"*",C21:C26)F24=SUMIF(A21:A26,"???",C21:C26)星号*匹配任意一串字符，问号?匹配任意单个字符。

4、超过15个字符出错

当我们在单元格F30输入公式：=SUMIF(B$30:B$35,E30,C$30:C$35)，很明显得到的结果是错误的，那该怎么办呢？

正确公式是：=SUMIF(B$30:B$35,E30&"*",C$30:C$35)，向下填充。

5、查找功能

通常我们查找时都会用LOOKUP、VLOOKUP等函数查找，下面这题我们将用SUMIF来代替VLOOKUP查找。

公式：G39=SUMIF($A$39:$A$44,$F39,B$39:B$44),向右向下填充。

使用查询注意事项：

①条件区域的数据必须是唯一的；②查询的结果必须是数字。

6、求销售额在[5000,8000]的和

初看这题时，如果用SUMIF函数来解，是不是觉得只能是这样解呢：F48=SUMIF(C48:C53,">=5000")-SUMIF(C48:C53,">8000")其实也可以用我们前面学到的函数SUM：F49=SUM(SUMIF(C48:C53,{">=5000",">8000"})*{1,-1})或者F50=SUM(SUMIF(C48:C53,ROW(5000:8000)))，三键结束。

7、隔行求和

公式：D57=SUMIF(A56:A63,"*",A57:A63)

8、隔列求和

公式：I67=SUMIF(A67:F72,"L-L-X",B67)

9、排错求和

公式：D77=SUMIF(A75:A82,"

10、求最后一次销售日期

下表为2016年10月10日-18日的销售量：

公式：K86 =SUMIF(A86:J86,"",B$85:J$85)-SUMIF(B86:J86,"",B$85:J$85)-1，向下填充。

三、函数总结

①、使用SUMIF函数匹配超过255个字符的字符串或字符串#VALUE! 时，将返回不正确的结果。②、第二参数支持使用通配符，包括问号（?）和星号（*）。问号匹配任意单个字符；星号匹配任意一串字符。如果要查找实际的问号或星号，请在该字符前键入波形符（~）。③、第二参数中指定的条件必须用双引号括起来,如 "④、当第三参数省略时，则条件区域就是实际求和区域。⑤、sum_range 参数与range参数的大小和形状可以不同。求和的实际单元格通过以下方法确定：使用sum_range参数中左上角的单元格作为起始单元格，然后包括与range参数大小和形状相对应的单元格。⑥、SUMIF函数本身不是易失性函数，但是，当SUMIF函数中的range和sum_range参数不包含相同的单元格个数时，它将具备易失性，工作表重新计算需要的时间可能比预期的长。

爱上Excel合伙人2017出品

我们一直秉承简洁、优雅、高效的为读者分享工作中遇到的每一个Excel问题，不论是Excel技巧、函数、图表、VBA，甚至是有关于Excel的开发，只要你能提出来问题，我们总能给你一个满意的答案！

每天准时来一篇Excel在职场中的案例。

求和，是我们日常工作中必不可少的部分，但是如何正确、高效或附带条件的求和，使不少同学都犯难的问题，今天，我们就针对单条件求和做详细的讲解。

一、功能及语法结构。

功能：对满足条件的单元格求和。

语法：=Sumif(条件范围，条件，求和范围)。

当条件范围和求和范围相同时，求和范围可以省略。

示例：

目的：求男、女销售员的销售和。

方法：

在目标单元格中输入公式：=SUMIF(C3:C9,H3,D3:D9)。

解读：

1、C3:C9为条件范围，H3为条件，D3:D9为求和范围。

二、单字段单条件求和。

目的：求销量大于等于60的销量和。

方法：

在目标单元格中输入公式：=SUMIF(D3:D9,">=60")。

解读：

因为条件范围和求和范围同为D3:D9,所以可以省略求和范围。

三、单字段多条件求和。

目的：计算“王东”、“小南”、“小李”的销量之和。

方法：

在目标单元格中输入公式：=SUM(SUMIF(B3:B9,{"王东","小南","小李"},D3:D9))。

解读：

1、利用Sumif函数分别求和“王东”、“小南”、“小李”的销量，其实再次充当更像是Vlookup或Lookup函数的功能。

2、利用Sum函数计算“王东”、“小南”、“小李”的销量和。

四、统计前X名销量之和。

目的：统计前5名销量之和。

方法：

在目标单元格中输入公式：=SUMIF(D3:D9,">"&LARGE(D3:D9,6))。

解读：

1、函数Large作用为：返回数据中第K个最大值，语法结构为：=Large(数据范围，返回最大值的位数）。公式=LARGE(D3:D9,6)返回的值为第6个最大值，暨33。

2、公式=SUMIF(D3:D9,">"&LARGE(D3:D9,6))可以理解为：=SUMIF(D3:D9,">33")。

五、模糊求和。

目的：求“王”姓销售员的销量和。

方法：

在目标单元格中输入公式：=SUMIF(B3:B9,"王*",D3:D9)。

解读：

1、条件“王*”中的*（星号）为通配符，可以匹配任意长度的字符。意思为只要是以“王”开头的所有销售员都是符合条件的。

六、隔列分类统计。

目的：计算出“计划”和“实际”的总和。

方法：

在目标单元格中输入公式：=SUMIF($C$3:$J$3,K$3,$C4:$J4)。

解读：

1、此公式的重点在于理解相对引用和绝对引用。

2、条件范围不变，所以采用绝对引用的形式，而条件分别“计划”和实际，由于在两列同一行，所以列标相对引用而行标绝对引用，求和范围中列不变，行变化，所以列标绝对引用，行相对应用哦！

七、查找引用。

目的：查询销售员对应的销售额。

方法：

在目标单元格中输入公式：=SUMIF(B3:B9,K3,C3:H9)。

解读：

由于每个月对应的销量是单一的，所以求和的同时完成了查询的功能。

结束语：

本文主要讲解了单条件求和函数Sumif的实际应用，通过示例的方式进行了演示，相信大家对于单条件求和Sumif的用法有了进一步的了解。如果有不懂的地方可以在留言区留言讨论哦！

求和，一直是Excel中最普通的话题，但是对于求和，大家真的了解吗，尤其是多条件求和？今天我们要掌握的是SUMIF函数和SUMPRODUCT函数多条件求和的技巧。

目的：统计出销售到【上海】地区的【联想】和【华硕】的数量。

方法一：

方法：

在目标单元格中输入公式：=SUM(SUMIFS(D3:D9,B3:B9,"上海",C3:C9,{"联想","华硕"}))。

备注：

SUMIFS(D3:D9,B3:B9,"上海",C3:C9,{"联想","华硕"})对“联想”和“华硕”分别进行统计，然后用SUM函数来求和。

方法二：

方法：

在目标单元格输入公式：=SUMPRODUCT((B3:B9="上海")*(C3:C9={"联想","华硕"})*D3:D9)。

方法三：

方法：

在目标单元中输入公式：=SUMPRODUCT((B3:B9="上海")*((C3:C9="联想")+(C3:C9="华硕")),D3:D9)。

1，条件求和 - 精确值求和。

示例中求微信类类型“订阅号”用户数量的总和。

2，条件求和 - 范围值求和。

示例中求出大于500的用户数量的总和。

SUMIF省略第三个参数时，会对第一个参数进行求和。

3，含错误值求和。

示例中求出F列用户数量的总和。其中F列含有错误值。

4，模糊条件求和。

示例中求出微信号中含有“office"的用户数量总和。

* 代表通配符。

5，多条件模糊求和。

示例中求出微信号中含有“office" & "buy"的用户数量总和。

6，多条件求和。

示例中求出微信号中officeGif/Goalbuy/Echat458这三个微信号的用户数量总和。

7，根据等级计算总分值。

8，跨列提取编号。

请点击此处输入图片描述

施老师：

在Excel中普通的求和SUM函数大家都知道，而且，之前也有给大家详细介绍过。不过，在大多情况下，我们可能还需要进行多条件求和等。今天，施老师就来给各位分享一下在工作中常用的多条件求和函数公式。

SUMIF函数

SUMIF（条件判断区域,条件，求和区域）

注意：SUMIF函数只能带一个条件，其格式为判断区域，条件，求和区域。

解释：条件判断区域：就是所以求和的条件域；条件：求和条件；求和区域：所示求和的引用单元格区域。

如下图：我们想要计算出格力空调的单价总和。

那么我们可以这样做，在右边品牌格力求和的一栏中输入公式：=SUMIF(A2:A10,"格力",C2:C10)

其中A2:A10是品牌区域，“格力”代表计算的是“格力”空调的总和，C2：C10代表的单价区域，这样就轻松的计算出了格力空调的单价之和。

各位朋友们，你们也试一下吧，点我头像关注我，有不懂的在文章下方的评论区留言问我，我会跟大家一起探讨。本文欢迎转发，转发请注明出处。

应用场景：

1、有时候单纯的求和公式SUM不能满足我们所有的要求，单一的条件求和SUMIF无法满足多条件求和的需求，这样SUMIFS这个多条件求和函数就应运而生啦！只要学会这个函数，再多条件的求和都不是问题。

函数解析:SUMIFS的参数可分为两类，一类为求和范围参数，另一类为条件参数。

如上图所示，参数1为求和范围参数，参数2,3为条件参数1（需要成组出现，包含条件范围和条件），参数4,5为条件参数2（需要成组出现），如果有更多条件，需要把条件范围和条件成组列明。

案例说明:

案例1：根据下图的销售明细表分别计算出各销售部门1月20日之前的销售总额。

案例条件要求同时满足下面的两个条件：

①按部门划分求和

②销售时间早于1月20日

操作步骤：

1、列出所有需要求和的部门，如下图所示：

2、在I2单元格录入公式：=SUMIFS(F:F,C:C,$H2,A:A,"<2018-1-20")

求和范围：F列销售总额

条件范围1：C列销售部门

条件1：销售一科

条件范围2：A列销售时间

条件2：小于2017-1-20，如果条件不是单元格引用，需要给条件加双引号。

3、下拉填充公式计算其他部门1月20日之前的销售总额。

4、验证：D2和F2单元格我们用SUBTOTAL函数对筛选条件下的数据求和，通过筛选统计销售一科2018年1月20日之前的销售总额数据，检验出我们的函数计算正确。

动态演示：

案例2：根据下图产品销售情况表分别计算出各销售部门销售各种产品（打印机、笔记本、台式机）的总数。

求和范围：E列销售台数

条件范围1：C列销售部门

条件1：销售一科

条件范围2：D列销售产品

条件2：包含H1到J1的产品

思考：案例中同一种销售产品有很多种型号，怎样将同一种产品的不同型号进行求和呢？

其实可以用通配符“*”，它可以代表任意多个字条。

操作步骤：

1、先将需要求和的部门和产品列出，如下图所示：

2、在H2 单元格录入公式：=SUMIFS($E:$E,$C:$C,$G2,$D:$D,H$1&"*")

由于要向右向下拖拉公式，所以求和区域，条件区域都要用绝对引用，而部门条件因为都在G列，所在条件1要锁定G列，而产品条件都在第1行，所以条件2要锁定第1行。

3、向右向下填充公式即可。

动态演示：

温馨提示：

① *为通配符，可以代表任意多个字符。

② 因为要向右向下填充，一定要注意相对引用和绝对引用的问题。

我是EXCEL学习微课堂，分享EXCEL学习的小技巧，小经验。如果分享的内容对您有用，欢迎点赞、收藏、评论、转发，更多的EXCEL技能，可以关注“EXCEL学习微课堂”。

Excel求和函数，除了Sum、Sumif和Sumifs以外，你还用过其它的函数吗？今天分享一个简单实用又高效的数据库函数DSUM，它集「查找」和「求和」功能为一身，能多条件求和，还能跨表多条件求和，让你一看到就会爱上它！

一、函数解析

DSUM函数：将数据库中符合条件记录的字段列中的数字求和。使用它可以对数据进行多条件累加，这种方式可以很方便地修改求和的条件。

DSUM有3个参数：Dsum(数据区域，求和的列数,条件区域)

① 数据区域：一组数据列表，即需要对该组数据列表中的某些数据进行计算。

② 列数：需要求和数据所在列数（也可以是列标题）比如：如果该参数为“3”，则表示需要计算的数据在参数①第3列中，如果该参数为“销量”，则表示需要计算的数据是参数①中的“销量”那一列。

③ 条件区域：由标题行和条件构成的多行区域（条件为公式时，若使用函数标题应为空）。

二、多条件求和案例

如下图所示，计算侯采和马来军的总销量。

在F2单元格中，输入公式：=DSUM(A1:E13,E1,G1:G3)

其中A1:E13是数据区域，E1是统计列“销售量“，G1:G3是条件区域，即计算侯采和马来军2人的销售量。

三、模糊统计案例

统计销售一科以打印机开头的所有产品销量和销售二科的台式机销售之和。

在I2单元格输入公式=DSUM(A1:E13,E1,G1:H3)

DSUM()函数中的判定条件，支持使用通配符 “*” 和 “？”，如下图所示，H2在单元格中使用了通配符“*“表示包含以打印机开头的A、B型号，但不包括D13的激光打印机，如果要包括则前面要加通配符。案例中，同一行的，销售二科和台式机必须同时满足，即并条件，而不同行的销售一科的打印机和销售二科的台式机是或条件，写在不同的行。

四、符合时间条件的求和案例

统计销售日期在2018-1-7至2018-1-14之间的销售量。

I2单元格输入公式：=DSUM(A1:E13,E1,G1:H2)，销售日期是一个区间，可以在一行用两个销售日期的条件。一个是大于2018-1-6，另一个是小于2018-1-15。

五、条件为公式时，函数标题应为空

统计销售一科销量小于平均销量人员的销量总和，销量小于平均销量必须用到公式=E2

H2单元格输入公式=E2

I2单元格输入公式=DSUM(A1:E13,E1,G1:H2)

六、多数据批量汇总案例

分别计算销售一科、销售二科和销售三科的销量。

H2单元格输入公式=DSUM($A$1:$E$13,$E$1,$G$1:G2)-SUM($H$1:H1)

1、由于公式要往下填充，所以数据区域和列都用了绝对引用

2、条件区域是一个从G1开始的活动区域，所以G1是绝对引用，但G2是相对引用

3、因为不同的行是“或条件”所以在统计销售二科销售总量时，结果会包含销售一科的销售总量，需要减去销售一科的销量，同样的道理，统计销售三科销量时要减去销售一科和销售二科的销售和。

七、跨工作表统计案例

如下图所示，有表1、表2和表3三个工作表，要统计三个表中，张1、张2、张3的销量和。

C2单元格输入公式=

SUM(DSUM(INDIRECT({"表1";"表2";"表3"}&"!A1:D11"),4,A$1:B2))-SUM(C$1:C1)

1、数据区域，跨表引用了3个工作表，所以用工作表引用函数INDIRECT。

2、列数，第4列“销量”。

3、条件区域是从A1开始的活动区域，所以A1是绝对引用，但B2是相对引用。

4、由于是的跨表引用，因此dsum返回的是数组，不是单值，因此要外套sum。

5、因为不同的行是“或条件”所以在统计张2第一周的销量时，结果会包含张1第一周的销量，需要减去张1第一周销量，同样的道理，统计张3第一周的销售时要减去张1和张2第一周的销售和。

温馨提示：

1、条件区域列标题内容要与数据区域一致，比如数据区域列标题是“销售产品”，那你要统计某一产品时，条件列标题也要是“销售产品”如果你改为产品，统计会出错

2、切记“并条件”需要横着写，即写在同一行，“或条件”需要竖着写，即写在不同行。

3、条件为公式时，若使用函数标题应为空。

我是EXCEL学习微课堂，如果我的分享对您有帮助，欢迎点赞、收藏、评论、转发！更多的EXCEL技能，可以关注百家号“EXCEL学习微课堂”。

在日常工作当中，对数据求和时，函数sum经常会用到，但是对求和结果赋予几个条件之后你还会用函数公式解决吗？今天就给大家介绍一下多条件求和函数sumifs的应用技巧，首先我们先通过一张图片来认识一下这个函数；

上图中sum-range是指实际求和区域；criteria-range1是指条件区域1；criteria是指条件。

在具体介绍sumifs的具体应用技巧之前，我们先引入一组数据源，如下图所示：

针对上图的数据源，给出的求和条件是计算每日单据类型为收款单的金额合计数；公式展开如下图；

公式讲解：实际求和区域为金额，所以是D列；条件1为日期，故条件区域为B列，条件二为单据类型，故条件区域2为C列。给单元格赋予公式之后计算结果也就完成了，输出结果见下图：

以上就是多条件求和函数sumifs的操作技巧，这里只是用了一个简单的案列来讲解了一下，实际工作中可能赋予的求和条件会更多，但操作逻辑是一样的，对这个函数感兴趣的朋友们可以试着操作一下。多学一个函数的使用技巧对将来的职场生活还是有很大助益的。今天的讲解到此结束，喜欢的朋友欢迎关注、分享 谢谢！

语录分享：生活包含着更广阔的意义，而不在于我们实际得到了什么；关键是我们的心灵是否充实。

End

SumIfs函数是 Excel 中多个求和函数之一，它主要用于统计指定区域满足单个或多个条件的和。SumIfs函数可以有多个参数，除第一个参数“求和区域”外，其它的参数都成组出现，每组由“条件区域和条件”组成，可以有 N 组这样的参数。SumIfs函数的多条件用数组表示，数组中的每个元素就是一个条件；当用数组组合多个条件时，SumIfs函数通常要与Sum函数结合才能统计出满足多个条件的和。以下就是Sumifs函数多字段多条件求和使用实例，实例中操作所用版本均为 Excel 2016。

一、Excel Sumifs 语法

1、表达式：SUMIFS(sum_range, criteria_range1, criteria1, [criteria_range2, criteria2], ...)

中文表达式：SUMIFS(求和区域，条件区域1，条件1，[条件区域2，条件2]，...)

2、说明：

A、表达式中，前三个参数是必需的，括号（[]）中的参数是可选的，省略号（...）表示继续构建[条件区域3，条件3]、[条件区域4，条件4]、...、[条件区域n，条件n]。

B、可以在条件中使用通配符“问号 (?) 和星号 (*)”，问号匹配任意单个字符，星号匹配任意一个或一串字符；果要找“? 和 *”，需要在它们前面加转义字符 ~，例如要查找 ?，需要这样写 ~?。

C、如果在条件中使用文本条件、含有逻辑或数学符号的条件都必须用双引号 (") 括起来；例如使用大于号，应该这样写：">50" 或 ">"&50。

D、SumIfs 只对数值求和，文本则忽略，如果选中的求和区域全为文本，则返回 0；如果既有文本又有数值，则只取数值求和。

二、Excel Sumifs函数的使用方法举例

（一）单条件

1、假如要统计在广州销售的所有服装的销量之和。选中 H2 单元格，把公式 =SUMIFS(F2:F10,D2:D10,"广州") 复制到 H2，按回车，则返回在广州销售的所有服装销量之和，如图1所示：

2、公式说明

公式 =SUMIFS(F2:F10,D2:D10,"广州") 中，F2:F10 是求和区域，D2:D10 是条件区域，“广州”是条件。

（二）多条件

1、双条件

A、假如要统计在广州销售的且为“衬衫”的所有服装销量之和。把公式 =SUMIFS(F2:F10,D2:D10,"广州",C2:C10,"衬衫") 复制到 H2 单元格，按回车，则统计出所有满足条件销量之和，操作过程步骤，如图2所示：

B、公式说明

公式 =SUMIFS(F2:F10,D2:D10,"广州",C2:C10,"衬衫") 的求和区域为 F2:F10；条件区域1为 D2:D10，条件1为“广州”；条件区域2为 C2：C10，条件2为“衬衫”。

2、数组条件且与Sum函数结合

A、假如要统计在广州和深圳销售的衬衫销量之和。选中 H2 单元格，把公式 =SUM(SUMIFS(F2:F10,D2:D10,{"广州","深圳"},C2:C10,"衬衫")) 复制到 H2，按回车，则统计出满足的衬衫销量之和，操作过程步骤，如图3所示：

B、公式说明

公式 =SUM(SUMIFS(F2:F10,D2:D10,{"广州","深圳"},C2:C10,"衬衫")) 由 Sum 和 SumIfs 两个函数组成，其中 SumIfs 函数用来分别统计在“广州”和“深圳”销售的“衬衫”销量之和，Sum函数用来把 SumIfs 求出的在“广州”和“深圳”销售的“衬衫”销量之和加起来。SumIfs 的条件1“{"广州","深圳"}”为数组，数组中只有两个条件，如果还要加条件，可以在后面添加。

提示：如果不用 Sum 函数，仅统计“广州”的“衬衫”销量。

3、多数组条件

A、假如要统计在广州和杭州销售的价格为 86、80 或 65 元的服装销量之和。把公式 =SUM(SUMIFS(F2:F10,D2:D10,{"广州","杭州"},E2:E10,{86;80;65})) 复制到 H2 单元格，如图4所示：

B、按回车，则统计出满足条件的服装销量之和，如图5所示：

注意：条件2 {86;80;65} 中数字之间用半角分号（;），如果用半角逗号（,），只会返回第一条满足条件的销量；结果返回 329，它正是第一条记录“长袖白衬衫”的销量，如图6所示：

（三）用通配符组合条件

1、假如要统计产品名称为四个字、销售地区含有“州”字、价格大于60元的全部服装销量之和。把公式 =SUM(SUMIFS(F2:F10,B2:B10,"????",D2:D10,"*州*",E2:E10,">60")) 复制到 H2 单元格，按回车，则统计所有满足条件的服装销量之和，如图7所示：

2、公式说明

公式 =SUM(SUMIFS(F2:F10,B2:B10,"????",D2:D10,"*州*",E2:E10,">60")) 中的 SumIfs 由三组“条件区域和条件”组成；第一组（B2:B10,"????"）是从 B2:B10 中找出名称为四个字的服装；第二组（D2:D10,"*州*"）是从 D2:D10 中找出含有“州”字的服装；第三组（E2:E10,">60"）是从 E2：E10 中找出“价格”大于 60 元的服装。最后把三组统计出的服装销量用 Sum 求和。