前面的课程我们讲了vlookup函数的基础用法，以及函数的向左和向右查询。今天我们讲一下这个函数的一个高级用法，那就是多条件匹配查询，不要走开。

场景解析

当我查询的数据需要同时满足两个或者以上的条件时候，这个时候我们单纯用单一的条件值去查询就做不到了，因为多条件的使用在vlookup函数中会牵涉到数组的运用。请看下面的实际操作。

案例解析：

函数等于：

{=VLOOKUP(G2&H2,IF({1,0},A:A&B:B,C:C),2,0)}

{=VLOOKUP(G2&H2,IF({1,0},A:A&B:B,D:D),2,0)}

1、多条件查询值时，同样需要用到if函数进行判断处理，思路同上一节课；

2、用&符号将两个条件进行连接起来；

3、函数写完后需要用到ctrl+shift+enter 三键结束，因为多条件查询的情况下，实际查询的内容以数组的形式展示。

有没有学到这个呀~喜欢的话关注一下呗~

昨天我给大家分享了一些人事和财务的日常常用的函数，很多朋友留言说很受用，这令小编感到十分的欣慰，今天我再和大家分享一些关于我们在日常工作中经常遇到的汇总函数。

一说到汇总数据，很多同学立马就想到要用sum、sumif、sumifs、countif、countifs等函数。这非常的不错哈。但是也有不少的同学经常会把这些个函数的语法整混，特别是sumifs、countifs这两个函数，他们的语法结构有点相似。

我们先看简单的汇总数据如何来处理，比如根据考核的成绩单，判断员工此次的考核结果。我们可以直接用if函数来进行汇总。对条件进行判断并返回指定内容。不少同学就在疑惑，if函数不是逻辑判断函数，怎么可以用来进行汇总呢？你仔细慢慢看完你就了解了。

1、IF函数:对条件进行判断并返回指定内容。

用法：

=IF(判断条件,符合条件时返回真的值,不符合条件时返回假的值)

=IF(B2>=60,"及格","不及格")

如图所示，使用IF函数来判断同事的成绩是否合格。

用通俗的话描述就是：

如果B2>=60，就返回“及格”，否则就返回“不及格”。

2、SUMIF函数:按指定条件求和。

用法：

=SUMIF(条件区域,指定的求和条件,求和的区域)

如下图所示，使用SUMIF函数计算一班的总成绩：

=SUMIF(B2:B12,E2,C2:C12)

用通俗的话描述就是：

如果B2:B12区域的班级等于E2单元格的“一班”，就对C2:C12单元格对应的区域求和。

扩展用法：

如果使用下面这种写法，就是对条件区域求和：

=SUMIF(条件区域,指定的求和条件)

如下图所示，使用SUMIF函数计算C2:C12单元格区域大于60的成绩总和。

=SUMIF(C2:C12,">60")

这里省略SUMIF函数第三参数，表示对C2:C12单元格区域大于60的数值求和。

3、COUNTIF函数：统计符合条件的个数。

用法：=COUNTIF(条件区域,指定的条件)

如下图所示，使用COUNTIF函数计算C2:C12单元格区域大于60的个数。

=COUNTIF(C2:C12,">60")

4、SUMIFS函数：完成多个指定条件的求和计算。

用法：

=SUMIFS(求和区域,条件区域1,求和条件1,条件区域2,求和条件2……)

注意哦，求和区域可是要写在最开始的位置。

如下图所示，使用SUMIFS函数计算一班、女生的总成绩。

=SUMIFS(D2:D12,B2:B12,"女",C2:C12,"一班")

B2:B12,"女" 和 C2:C12,"一班"是两个条件对，如果两个条件同时满足，就对D2:D12单元格对应的数值进行求和。

5、COUNTIFS函数：用于统计符合多个条件的个数。

用法：

=COUNTIFS(条件区域1,指定条件1,条件区域2,指定条件2……)

如下图所示，使用COUTNIFS函数计算一班、女性的人数。

=COUNTIFS(B2:B12,"女",C2:C12,"一班")

这里的参数设置和SUMIFS函数的参数设置是不是很相似啊，仅仅是少了一个求和区域，也就是只统计符合多个条件的个数了。

6、AVERAGEIF函数和AVERAGEIFS函数

AVERAGEIF，作用是根据指定的条件计算平均数。

AVERAGEIFS，作用是根据指定的多个条件计算平均数。

两个函数的用法与SUMIF、SUMIFS的用法相同。

如下图所示，计算一班的平均分。

=AVERAGEIF(C2:C12,"一班",D2:D12)

这里的参数设置，和SUMIF函数的参数是一模一样的。

如果C2:C12单元格区域等于“一班”，就计算D2:D125区域中，与之对应的算术平均值。

同样，如果要计算一班男性的平均分，可以使用AVERAGEIFS函数：

=AVERAGEIFS(D2:D12,C2:C12,"一班",B2:B12,"女")

这里的参数设置，就是和SUMIFS函数一样的，计算平均值的区域在第一个参数位置，后面就是成对的“区域/条件”。

好了我们今天分享就到这里，各位亲有这方面的需求，不妨好好收藏一下，仔细研读一下。

CountIfs函数在 Excel 中用于组合多个条件区域/条件对，以弥补CountIf函数只能组合一个条件区域/条件对的不足。如果要统计同时满足两个条件的某种产品个数，用 CountIf 需要用数组组合条件，比较麻烦，而用 CountIfs 组合两个条件区域/条件对即可，比较简单明了。CountIfs 与 CountIf 一样，条件中可以用逻辑值与通配符（问号和星号）。以下就是 Excel CountIfs函数的使用方法及实例，包括不为空和多个条件的实例的具体操作方法，实例中操作所用版本均为 Excel 2016。

一、CountIfs函数语法

1、表达式：COUNTIFS(Criteria_Range1, Criteria1, [Criteria_Range2, Criteria2], …)

中文表达式：COUNTIFS(条件区域1, 条件1, [条件区域2, 条件2], …)

2、说明：

A、条件区域和条件组成一个条件区域/条件对，至少包含一个条件区域/条件对，最多只能有 127 个条件区域/条件对。

B、如果有多个条件区域，每个条件区域必须有相同的行数和列数，它们可以不相邻。

C、如果单元格为空，CountIfs 将它的值视为 0。

D、在条件中可以使用通配符问号（?）和星号（*），问号表示任意一个字符，星号表示一个或一串字符；如果要查找问号或星号，需要在它们前面加转义字符~，例如查找问号，表达式可以这样写 ~?。

二、CountIfs函数的使用方法及实例

(一）只有一个条件区域/条件对

1、假如要统计“销售地区”为“广州”的个数。选中 D13 单元格，输入公式 =COUNTIFS(D2:D12,"广州")，按回车，返回统计结果 4；操作过程步骤，如图1所示：

2、公式说明：公式 =COUNTIFS(D2:D12,"广州") 只有一个条件区域/条件对，条件区域为 D2:D12，条件为“广州”，是用文字作条件，并且可以在文字前面加等号，即 =COUNTIFS(D2:D12,"=广州")；另外，仅数值也可以作条件。

（二）有两个条件区域/条件对

1、假如要统计“销售地区”为“广州”且销量大于等于 500 的服装件数。把公式 =COUNTIFS(D2:D12,"广州",F2:F12,">=500") 复制到 F13 单元格，按回车，返回统计结果为 3，操作过程步骤，如图2所示：

2、公式中第一个条件区域/条件对为 D2:D12,"广州"，第二个条件区域/条件对为 F2:F12,">=500"，即先统计 D2:D12 中为“广州”的个数，再统计 F2:F12 中销量大于等于 500 的个数；条件2 ">=500" 也可以用 ">="&500。

（三）用通配符问号与星号组合条件

1、假如要统计以“T恤”结尾、以“白”字开头、仅有三个字的服装件数；把公式 =COUNTIFS(B2:B12,"*T恤",B2:B12,"白*",B2:B12,"???") 复制到 B13 单元格，如图3所示：

2、按回车，返回结果 1，如图4所示：

3、如果要统计以一个指定字（或词）开头且以另一个指定字（或词）结果的服装件数，例如统计以“粉”字开头且以“衬衫”结尾的服装件数，公式可以这样写：=COUNTIFS(B2:B12,"粉*衬衫")。

（四）条件为空、不为空和不等于

1、假如要统计“分类”不等于“衬衫”且“销量”为空的服装件数。把公式 =COUNTIFS(C2:C12,"<>衬衫",F2:F12,"") 复制到 F13 单元格，按回车，返回统计结果 2，操作过程步骤，如图5所示：

2、如果要统计“分类”不等于“衬衫”且“销量”不为空的服装件数，则公式可以这样写：=COUNTIFS(C2:C12,"<>衬衫",F2:F12,"<>"&"")，如图6所示：

（五）CountIfs 与 Average 组合使用

1、假如要统计“分类”为“T恤”、销售地区为“杭州”且大于平均销量的服装件数。把公式 =COUNTIFS(C2:C12,"T恤",D2:D12,"杭州",F2:F12,">"&AVERAGE(F2:F12)) 复制到 F13 单元格，按回车，返回结果 2，操作过程步骤，如图7所示：

2、在条件中，只需用 & 连接 > 与求平均值的函数 Average，如果要用其它函数也是一样的连接方法。

三、CountIfs函数与CountIf函数用多条件的比较

1、CountIfs函数可轻松组合多个条件，而CountIf函数需要用数组才能组合多个条件。假如要统计销量大于等于 500 且小于等于 800 的服装件数。用 CountIfs函数公式可这样写：=COUNTIFS(F2:F12,">=500",F2:F12,"<=800")，而用 CountIf函数，公式需要这样写：=SUM(COUNTIF(F2:F12,{">=500",">800"})*{1,-1})，两个公式统计结果都为 4；操作过程步骤，如图8所示：

2、用CountIfs函数写要简单得多，且它们的计算顺序是一样的，都先统计满足第一个条件的个数，再统计满足第二个条件的件数，因此遇到多个条件的情况，可以先选用CountIfs函数。

施老师：

有时我们需要求出不同品牌商品的数量。如果数据区域小，我们可以手动的去计算，如果数据区域很大。那手动就太麻烦了。今天施老师给大家教一招，用多条件统计数量函数去计算。非常的方便实用。

如下图：

我们需要统计销售部有多少个人工资是6000的

我们可以在H2里输入函数：=COUNTIFS(B2:B9,"销售部",D2:D9,"6000")

这样就算出销售部拿6000元的工资人数是2人。

大家看一下，这个函数是不是非常的方便啊

各位朋友们，你们也试一下吧，点我头像关注我，有不懂的在文章下方的评论区留言问我，我会跟大家一起探讨。本文欢迎转发，转发请注明出处。

　　if套用问题，可能关系二方面，一是公式怎么写，二是数据处理中怎么判断，

公式写法：=if(判断对错，对时显示结果，错时显示结果），如:=if(a1>1,1,0);后两个结果分别可以换成if()公式。如：=if(a1>1,if(a1>10,3,1),0)=if(a1>1,1,if(a1>0,0,-5))计算机计算时，是从最外层if开始计算的，就是先判断最左边，第一个if（），所以如果判断较多时，可以只用大于号>,或小于号，如下题。例如：某工厂计件奖励，完成率低于70%无奖金，大于等于70%一件扣0.5元，大于等于86%的一件扣0.3元，100%的奖1000元，多于100%的一件奖1元。数据在A2，完成率在B2，任务数量在E2，公式：=IF(B2>1,1000+A2-$E$2,IF(B2=1,1000,IF(B2>=0.86,-($E$2-A2)*0.3+1000,IF(B2>=0.7,-($E$2-A2)*0.5+1000,0))))

（本文内容由百度知道网友贡献）

统计成绩的时候，统计成下图这种方式：

COUNTIFS函数介绍：

语法：COUNTIFS(criteria_range1, criteria1, [criteria_range2, criteria2],…)

中文语法：COUNTIFS(区域1, 条件1, [区域2, 条件2],[区域3, 条件3],…)

最多允许 127 个区域/条件对。

在本示例中：

在F2单元格输入公式：“=COUNTIFS($A$2:$A$135,G$1,$C$2:$C$135,">="&$F2)”

函数解读：

函数在向右与向下填充的过程中，一定要注意“所有班级区域”与“所有分数区域”的绝对引用、“要统计的班级”与“要统计的分数段”单元格的相对引用。

经常使用Excel函数的小伙伴们都知道，在Excel中使用频率最高的还是那些比较简单的函数，其中IF函数就是高频率函数之一，那么，能不能用IF函数来进行多条件运算呢？

一、IF+AND：同时满足多个条件

目的：将“上海”地区的“男”通知标识为“Y”。

方法：

在目标单元格中输入公式：=IF(AND(D3="男",E3="上海"),"Y","")。

解读：

1、AND函数的语法：AND(条件1,=标准1，条件2=标准2……条件N=标准N）。如果每个条件和标准都相等，则返回TRUE，否则返回FALSE 。

2、用IF函数判断AND函数的返回结果，如果为TRUE，则返回“Y”，否则返回""。

二、IF+OR:满足多个条件中的一个即可。

目的：将性别为“男”或地区为“上海”的标记为“Y”。

方法：

在目标单元格中输入公式：=IF(OR(D3="男",E3="上海"),"Y","")。

解读：

1、OR函数的语法结构为：(条件1,=标准1，条件2=标准2……条件N=标准N）。如果任意参数的值为TRUE，则返回TRUE ,当所有条件为FALSE时，才返回FALSE。

2、用IF函数判断OR函数的返回结果，如果为TRUE,则返回“Y”，否则返回""。

if函数是 Excel 中的条件判断函数，它由条件与两个返回结果组成，当条件成立时，返回真，否则返回假。if函数中的条件既可以单条件，也可以是多条件；多条件组合有三种方式，一种为多个 if 嵌套，第二种为用 And（或 *）组合多个条件，第三种为用 Or（或 +）组合多个条件。用 And（或 *）组合条件是“与”的关系，用 Or(或 +）组合条件是“或”的关系，它们的写法比 if 嵌套简单。以下就是它们的具体操作方法，实例中操作所用版本均为 Excel 2016。

一、Excel if函数语法

1、表达式：IF（logical_test,[value_if_true],[value_if_false])

中文表达式：如果（条件，条件为真时执行的操作，条件为假时执行的操作）

2、说明：[value_if_true] 和 [value_if_false] 表示可选项，即它们可以不写，如图1所示：

按回车，返回 False，因为 E2 为 435，F2 为 528，E2 > F2 不成立，如图2所示：

另外，=IF(3 > 2,)，返回 0，此处 0 表示假。

二、Excel if函数单条件使用方法

1、一个服装销量表中，价格为0的表示已下架，否则表示正在出售，假如要把它们分别用“下架”和“出售中”标识出来，操作过程步骤，如图3所示：

2、操作过程步骤说明：选中 H2 单元格，输入公式 =IF(E2<=0,"下架","出售中")，按回车，则返回“出售中”；把鼠标移到 H2 右下角的单元格填充柄上，按住左键并往下拖，则所经过单元格全填充为“出售中”，按 Ctrl + S 保存，则价格为 0 的单元格用“下架”填充，其它单元格用“出售中”填充。

3、公式说明：公式 =IF(E2<=0,"下架","出售中") 中，E2<=0 为条件，当条件为真时，返回“下架”，否同返回“出售中”。

三、Excel if函数嵌套多条件使用方法

1、假如要标出服装销量表中，“大类”为“女装”、“价格”大于等于 80 且“销量”大于 800 的服装，操作过程步骤，如图4所示：

2、操作过程步骤说明：选中 H2 单元格，把公式 =IF(C2="女装",IF(E2>=80,IF(F2>800,"满足条件","不满足条件"),"不满足条件"),"不满足条件") 复制到 H2，按回车，则返回“不满足条件”；再次选中 H2，把鼠标移到 H2 的单元格填充柄上，按住左键并往下拖，则所经过单元格用“不满足条件”填充，按 Ctrl + S 保存，同样 H3 用“满足条件”填充，其它单元格仍用“不满足条件”填充。

3、公式说明：

=IF(C2="女装",IF(E2>=80,IF(F2>800,"满足条件","不满足条件"),"不满足条件"),"不满足条件")

由三个 if 组成，即在一个 if 中嵌套了两个 if。第一个 if 的条件为 C2="女装"，如果条件为真，则执行 IF(E2>=80,IF(F2>800,"满足条件","不满足条件"),"不满足条件")；否则返回“不满足条件”。第二个 if 的条件为 E2>=80，如果条件为真，则执行 IF(F2>800,"满足条件","不满足条件")，否则返回“不满足条件”。第三个 if 的条件为 F2>800，如果条件为真，返回“满足条件”，否则返回“不满足条件”。

提示：if 最多只能嵌套 64 个 if，尽管如此，在写公式过程中，尽量少嵌套 if；一方面便于阅读与修改，另一方面执行效率也高一些。

四、Excel if函数用 And 与 OR 组合多个条件使用方法

（一）用 And 组合多个条件，为“与”的关系

1、把上例中的多 if 嵌套公式 =IF(C2="女装",IF(E2>=80,IF(F2>800,"满足条件","不满足条件"),"不满足条件"),"不满足条件") 改为用 And 组合，操作过程步骤，如图5所示：

2、操作过程步骤说明：选中 H2 单元格，把公式 =IF(AND(C2="女装",E2>=80,F2>800),"满足条件","不满足条件") 复制到 H2，按回车，则返回“不满足条件”；同样往下拖并保存，返回跟上例一样的结果，说明公式正确。

3、公式说明：

=IF(AND(C2="女装",E2>=80,F2>800),"满足条件","不满足条件")

公式用 And 函数组合了三个条件，分别为 C2="女装",E2>=80,F2>800，当同时满足三个条件时（即 AND(C2="女装",E2>=80,F2>800) 返回“真”），返回“满足条件”，否则返回“不满足条件”。

4、用 * 代替 And

A、把公式　　=IF(AND(C2="女装",E2>=80,F2>800),"满足条件","不满足条件")

用 * 代替 And 后变为：

=IF((C2="女装")*(E2>=80)*(F2>800),"满足条件","不满足条件")

如图6所示：

B、按回车，返回“不满足条件”，往下拖保存后，也是返回一样的结果。

（二）用 Or 组合多个条件，为“或”的关系

1、把上例中的 And 组合多个条件公式 =IF(AND(C2="女装",E2>=80,F2>800),"满足条件","不满足条件") 改为用 Or 组合，操作过程步骤，如图7所示：

2、操作过程步骤说明：选中 H2 单元格，把公式 =IF(OR(C2="女装",E2>=80,F2>800),"满足条件","不满足条件") 复制到 H2，按回车，则返回“满足条件”；同样往下拖并保存，全部返回“满足条件”。

3、公式说明：

=IF(OR(C2="女装",E2>=80,F2>800),"满足条件","不满足条件")

公式用 Or 函数组合了三个条件，分别为 C2="女装",E2>=80,F2>800，即 OR(C2="女装",E2>=80,F2>800)，意思是：只要满足一个条件，就返回“真”；一条件都不满足才返回“假”。演示中，每条记录都满足一个条件，所以全返回“满足条件”。

4、用 + 代替 Or

A、把公式

=IF(OR(C2="女装",E2>=80,F2>800),"满足条件","不满足条件")

用 + 代替 Or 后变为：

=IF((C2="女装")+(E2>=80)+(F2>800),"满足条件","不满足条件")

如图8所示：

B、按回车，返回“满足条件”，往下拖保存后，也是全部返回“满足条件”，说明公式正确。

在进行数据统计时，有时需要挑选出同时满足多个条件的数据。例如在进行三好学生、优秀学生等评选时，有时会需要挑选出各学科考试成绩都大于某个数值的学生，作为参评的条件之一。例如要挑选出各学科成绩都大于80的学生。这时在班级里学生较多的情况下，如果采用逐个查看每个学生各科成绩来进行挑选的方法将会花费一定的时间，还有可能因为马虎而出现疏漏，这样不但影响工作效率，还可能影响最终结果的准确性。这种情况可以考虑用Excel来帮助我们较轻松和准确的完成这个任务，这里以Excel2007为例介绍如何操作，以供参考。

在Excel中挑选出同时满足多个条件的数据可以考虑采用“AND”函数，其语法为：AND(logical1,logical2, ...)，括号内的“logical1,logical2, ...”为各种条件的表达式，如果各种条件的表达式都成立，Excel就会返回“TRUE” 否则返回“FALSE”。

但如果表格中只显示英文的“TRUE”和“FALSE”，会显得不太美观，也不够明了。这时可以组合使用其他的函数，如“IF”函数，让Excel显示我们自定义的字符。IF”函数的语法为：IF(logical_test,value_if_true,value_if_false)，括号中的“Logical_test”为表达式（例如可以用上述的“AND”函数作为表达式），“value_if_true”为表达式结果为TRUE”时Excel返回的结果，“value_if_false”为表达式结果为“FALSE”时Excel返回的结果。

例如要从下图表格中挑选出各科成绩都大于80的学生：

●统计时可先在表格右侧添加一个显示统计结果的列，然后点击选中该列的列首单元格。

●选中单元格后，在编辑栏中输入“=AND(C4>=80,D4>=80,E4>=80,F4>=80)”，其中的C4、D4、E4、F4为该行中的学生各科考试成绩所在的单元格，>=80为判断条件，即要求考试成绩大于等于80分。如果AND后面的括号中各判断条件都成立，即各科成绩都大于等于80分，则Excel会返回“TRUE” 否则如果有一科或者多科成绩不大于等于80，Excel会返回“FALSE”。

●输入上述函数公式后，按键盘回车键或者点击编辑栏左侧的对号，该单元格中就会显示出计算结果。

●再用下拉填充柄或者选择性粘贴公式的方法在该列的其他单元格中快速填充公式，就会显示出所有学生的判断结果，其中结果为“TRUE”的表示该学生的各科成绩都大于等于80，结果为“FALSE”的表示该学生至少有一科成绩不大于等于80。但这种显示结果不太美观和明了，最好再组合IF函数来显示中文或者其他符号的判断结果。

●我们可以把列首单元格中的公式改成=IF(AND(C4>=80,D4>=80,E4>=80,F4>=80),"是","否")，即如果公式"AND(C4>=80,D4>=80,E4>=80,F4>=80)"的判断结果为“TRUE”，则Excel会显示字符“是”；反之如果判断结果为“FALSE”则Excel会显示字符“否”，这样看起来比英文的“TRUE”和“FALSE”要明了一些。

●这样再下拉填充或者选择性粘贴公式后，该列其他单元格中就都显示出中文的判断结果了。

●我们还可以用对号来表示符合条件，用空白来表示不符合条件。即把上述公式修改为=IF(AND(C4>=80,D4>=80,E4>=80,F4>=80),"√","")。

●这样，符合条件的学生就都会显示对号，不符合条件的学生会显示空白，感觉更加一目了然。

上述例子介绍的只是AND函数和IF函数相组合的一种应用方法，熟练掌握这两种函数的用法后，可以给数据统计带来更多的方便。

经常使用函数的小伙伴们都知道excel if函数是我们工作中经常用到的函数，那么excel if函数怎么实现满足多个条件来使用呢?今天就为大家唠一下excel if函数多个条件的使用方法!希望可以帮助大家更有效的运用在工作当中!那么excel if函数的多个条件实现到底怎么用？我们首先要明白，满足多个条件也可以分两种情况：1)需要多个条件同时满足;2)或者一个、几个或多个条件。我们以下图的数据来举例说明。

首先，利用AND()函数来说明同时满足多个条件。举例：如果A列的文本是“A”并且B列的数据大于210，则在C列标注“Y”。

在C2输入公式：=IF(AND(A2=”A”,B2>210),”Y”,””)知识点说明：AND()函数语法是这样的，AND(条件1=标准1，条件2=标准2……)，每个条件和标准都去判断是否相等，如果等于返回TRUE，否则返回FALSE。只有所有的条件和判断均返回TRUE，也就是所有条件都满足时AND()函数才会返回TRUE。

然后，利用OR()函数来说明只要满足多个条件中的一个或一个以上条件。举例：如果A列的文本是“A”或者B列的数据大于150，则在C列标注“Y”。

在C2单元格输入公式：=IF(OR(A2=”A”,B2>150),”Y”,””)知识点说明：OR()函数语法是这样的：OR(条件1=标准1，条件2=标准2……)，和AND一样，每个条件和标准判断返回TRUE或者FALSE，但是只要所有判断中有一个返回TRUE，OR()函数即返回TRUE。

以上的方法是在单个单元格中进行判断，也可以写成数组公式形式在单个单元格中一次性完成在上述例子中若干个辅助单元格的判断，这样我们就可以随心所欲的对excel if函数的条件设置咱们需要的规则了！

好了，今天的excel if函数不知道各位小伙伴们有没有掌握到呢？如果你有更好的方法也可以在评论区和大家一起交流，谢谢