今天要跟大家介绍的是曾被誉为Excel函数界迂回大师的INDIRECT函数。

INDIRECT函数的作用是返回由文本字符串指定的引用，它的语法结构为：

=INDIRECT(单元格的引用, [引用类型])，第一个参数也可以是代表引用的文本字符串。

下面我们通过4个案例来了解一下INDIRECT函数的妙用。

1、设置二级下拉菜单

首先进行定义名称设置：选中部门和岗位明细数据区域--公式--根据所选内容创建--勾选“首行”；接着利用数据有效性设置部门的一级下拉菜单：选中B1单元格--数据--数据验证--序列--来源输入：=$E$1:$H$1；最后设置二级下拉菜单：选中B2单元格--数据--数据验证--序列--来源输入：=INDIRECT(B1)

2、创建开始部分始终固定的区域引用

如下图所示，我们在B、C两列中分别进行业绩求和，在B6单元格中输入公式：=SUM(B2:B5) ，C6单元格中输入公式：=SUM(INDIRECT("C2"):C5)。之后在标题行下插入空白行，添加新销售员的业绩，可以发现，B列的业绩总计不变，而C列出现了变化，把新加入的销售员业绩也进行了统计。

这是因为在C列求和公式中，INDIRECT函数参数为"C2 "，返回的是C2中的内容，即固定了开始单元格为C2，不管开头增加多少数据，该公式引用区域的开始单元格始终不受影响。

3、实现一列转多列

比如我们要把表格中的一列数据转为四列，这里可以在C2单元格中输入公式：

=INDIRECT("A"&4*ROW(A1)-3+COLUMN(A1))&""

解析：

4*ROW(A1)-3+COLUMN(A1)：返回结果为2，公式往下填充时，计算结果为6、10、14……，即生成差为4的自然数序列。公式向右填充时，计算结果为3、4、5……，即生成公差为1的自然数序列；INDIRECT("A"&4*ROW(A1)-3+COLUMN(A1))：和字符A结合形成一个单元格地址，用INDIRECT函数返回文本字符串指定的引用；最后加上&""，目的是规避在行列转换时出现的0值。4、实现多表数据汇总

如下图所示，需要把这6个相同结构表格中的商品销量进行汇总，这里我们框选空白区域，输入公式：=INDIRECT(B$1&"!B"&ROW())，按Ctrl+Enter组合键输入。

解析：B$1&"!B"&ROW()：B$1用于返回不同的月份，在公式向左复制时分别为C$1、D$1、E$1，即对应返回的值依次为1月、2月……6月；连接符&接"!B"，!是表格和单元格的分界标志，这里加引号用文本表示，表示固定部分；最后ROW()返回行号，公式向下填充到哪一行就返回哪一行的行号。比如公式如果在B2单元格，这部分返回的值为1月!B2。

看完以上几个例子，相信你也明白为什么INDIRECT函数如此受高手们欢迎了，它的实际应用其实还有很多，欢迎大家在留言补充分享~

各位朋友大家好，图文版的officer帮帮忙又和大家见面啦，今天帮帮给大家推荐一个小技巧，希望能够在工作上帮到您哦！

大家请看范例表格，这是一张从其他系统中导出的表格，里面的地址按行政区域进行了保存，如图一

图一

现在我想将他们放到同一个单元格里面，我们应该怎么做呢？有的朋友也许会说，我可以在I列用=B2&C2.....&H2就可以啦（如图二）

图二

但是这样做应付一些列比较少的表还可以，如果遇到几十列的表格或者你需要在中间插入一列加入新的内容又要去修改公式，是不是非常麻烦呢，您这样做容易出错并且也会累死啦！，下面帮帮给大家介绍一个函数可以轻松搞定，大家请看图三

图三

图三结果

对了，就是PHONETIC函数，是不是又简短又简单，而且还不会出错呢，下面我给大家详细讲解一下这个函数的功能和一些注意事项：

1、PHONETIC函数可以将多个单元格中的字符串连接成一个字符串，只要在函数中填写需要合并单元格的范围比如图三中的B2:H2，就能合并该范围单元格中的所有内容，并且是可以跨行引用。

2、PHONETIC函数在使用中一定要注意，被统计的单元格范围必须相邻，也就是说不能隔行或者隔列引用，否则会出现错误

3、PHONETIC函数只能合并文本哦，如果单元格内容是数值或公式需要将单元格格式转换为文本才能合并

Excel曾经一度出现了严重Bug，主要有两种比较悲催的情况，首先是这种：

更加悲催的是这种：

言归正传，今天和大家分享一组常用函数公式的使用方法：职场人士必须掌握的12个Excel函数，用心掌握这些函数，工作效率就会有质的提升。

建议收藏备用着，有时间多学习操练下。

目录：数字处理、判断公式、统计公式、求和公式、查找与引用公式、字符串处理公式、其他常用公式等

一、数字处理

01.取绝对值

=ABS(数字)

02.数字取整

=INT(数字)

03.数字四舍五入

=ROUND(数字,小数位数)

二、判断公式

04.把公式返回的错误值显示为空

公式：C2

=IFERROR(A2/B2,"")

说明：如果是错误值则显示为空，否则正常显示。

05.IF的多条件判断

公式：C2

=IF(AND(A2<500,B2="未到期"),"补款","")

说明：两个条件同时成立用AND,任一个成立用OR函数。

三、统计公式

06.统计两表重复

公式:B2

=COUNTIF(Sheet15!A:A,A2)

说明：如果返回值大于0说明在另一个表中存在，0则不存在。

07.统计年龄在30~40之间的员工个数

=FREQUENCY(D2:D8,{40,29})

08.统计不重复的总人数

公式：C2

=SUMPRODUCT(1/COUNTIF(A2:A8,A2:A8))

说明:用COUNTIF统计出每人的出现次数，用1除的方式把出现次数变成分母，然后相加。

09.按多条件统计平均值

F2公式

=AVERAGEIFS(D:D,B:B,"财务",C:C,"大专")

10.中国式排名公式

=SUMPRODUCT(($D$4:$D$9>=D4)*(1/COUNTIF(D$4:D$9,D$4:D$9)))

四、求和公式

11.隔列求和

公式：H3

=SUMIF($A$2:$G$2,H$2,A3:G3)

或

=SUMPRODUCT((MOD(COLUMN(B3:G3),2)=0)*B3:G3)

说明：如果标题行没有规则用第2个公式

12.单条件求和

公式：F2

=SUMIF(A:A,E2,C:C)

说明：SUMIF函数的基本用法

13.单条件模糊求和

公式：详见下图

说明：如果需要进行模糊求和，就需要掌握通配符的使用，其中星号是表示任意多个字符，如"*A*"就表示a前和后有任意多个字符，即包含A。

14.多条求模糊求和

公式：C11

=SUMIFS(C2:C7,A2:A7,A11&"*",B2:B7,B11)

说明：在sumifs中可以使用通配符*

15.多表相同位置求和

公式：b2

=SUM(Sheet1:Sheet19!B2)

说明：在表中间删除或添加表后，公式结果会自动更新。

16.按日期和产品求和

公式：F2

=SUMPRODUCT((MONTH($A$2:$A$25)=F$1)*($B$2:$B$25=$E2)*$C$2:$C$25)

说明：SUMPRODUCT可以完成多条件求和

五、查找与引用公式

17.单条件查找

公式1：C11

=VLOOKUP(B11,B3:F7,4,FALSE)

说明：查找是VLOOKUP最擅长的，基本用法

18.双向查找

公式：

=INDEX(C3:H7,MATCH(B10,B3:B7,0),MATCH(C10,C2:H2,0))

说明：利用MATCH函数查找位置，用INDEX函数取值

19.查找最后一个符合条件记录

公式：详见下图

说明：0/(条件)可以把不符合条件的变成错误值，而lookup可以忽略错误值

20.多条件查找

公式:详见下图

说明:公式原理同上一个公式

21.指定非空区域最后一个值查找

公式;详见下图

说明：略

22.区间取值

公式：详见下图

公式说明：VLOOKUP和LOOKUP函数都可以按区间取值，一定要注意，销售量列的数字一定要升序排列。

六、字符串处理公式

23.多单元格字符合并

公式：c2

=PHONETIC(A2:A7)

说明：Phonetic函数只能对字符型内容合并，数字不可以。

24.截取除后3位之外的部分

公式：

=LEFT(D1,LEN(D1)-3)

说明：LEN计算出总长度,LEFT从左边截总长度-3个

25.截取 - 之前的部分

公式:B2

=Left(A1,FIND("-",A1)-1)

说明：用FIND函数查找位置，用LEFT截取。

26.截取字符串中任一段

公式:B1

=TRIM(MID(SUBSTITUTE($A1," ",REPT(" ",20)),20,20))

说明:公式是利用强插N个空字符的方式进行截取

27.字符串查找

公式：B2

=IF(COUNT(FIND("河南",A2))=0,"否","是")

说明: FIND查找成功，返回字符的位置，否则返回错误值，而COUNT可以统计出数字的个数，这里可以用来判断查找是否成功。

28.字符串查找一对多

公式：B2

=IF(COUNT(FIND({"辽宁","黑龙江","吉林"},A2))=0,"其他","东北")

说明：设置FIND第一个参数为常量数组，用COUNT函数统计FIND查找结果

七、日期计算公式

29.两日期间隔的年、月、日计算

A1是开始日期（2011-12-1），B1是结束日期(2013-6-10)。计算：

相隔多少天？=datedif(A1,B1,"d") 结果：557

相隔多少月? =datedif(A1,B1,"m") 结果：18

相隔多少年? =datedif(A1,B1,"Y") 结果：1

不考虑年相隔多少月？=datedif(A1,B1,"Ym") 结果：6

不考虑年相隔多少天？=datedif(A1,B1,"YD") 结果：192

不考虑年月相隔多少天？=datedif(A1,B1,"MD") 结果：9

datedif函数第3个参数说明：

"Y" 时间段中的整年数。

"M" 时间段中的整月数。

"D" 时间段中的天数。

"MD" 天数的差。忽略日期中的月和年。

"YM" 月数的差。忽略日期中的日和年。

"YD" 天数的差。忽略日期中的年。

30.扣除周末的工作日天数

公式：C2

=NETWORKDAYS.INTL(IF(B2

说明：返回两个日期之间的所有工作日数，使用参数指示哪些天是周末，以及有多少天是周末。周末和任何指定为假期的日期不被视为工作日

八、其他常用公式

31.创建工作表目录的公式

把所有的工作表名称列出来，然后自动添加超链接，管理工作表就非常方便了。

使用方法：

第1步：在定义名称中输入公式：

=MID(GET.WORKBOOK(1),FIND("]",GET.WORKBOOK(1))+1,99)&T(NOW())

第2步、在工作表中输入公式并拖动，工作表列表和超链接已自动添加

=IFERROR(HYPERLINK("#'"&INDEX(Shname,ROW(A1))&"'!A1",INDEX(Shname,ROW(A1))),"")

32.中英文互译公式

=FILTERXML(WEBSERVICE("http://fanyi.youdao/translate?&i="&A2&"&doctype=xml&version"),"//translation")

excel中的函数公式千变万化，今天就整理这么多了。如果你能掌握一半，在工作中也基本上遇到不难题了。

建议收藏备用着，有时间多学习操练下。

Excel的函数使用是很多Excel使用者的难点，由于Excel主要是用于各种统计、计算，所以有三个函数：VLookup/countif/sumif 非常重要，掌握这三个就可以大胆闯天下了。

其中VLOOKUP又是其中的函数之王，今天我们擒贼先擒王，说说这个vlookup函数。

Vlookup匹配一切，连接一切。说到查找函数，大部分人都会想到它。

这里以Excel2016版本为例。

1

函数语法

=VLOOKUP(lookup_value,table_array,col_index_num,[range_lookup])

lookup_value：要查找的值，也被称为查阅值。

table_array：查阅值所在的区域。请记住，查阅值应该始终位于所在区域的第一列，这样VLOOKUP 才能正常工作。例如，如果查阅值位于单元格C2 内，那么区域应该以C 开头。

col_index_num区域中包含返回值的列号。例如，如果指定 B2：D11 作为区域，那么应该将B 算作第一列，C作为第二列，以此类推。

[range_lookup]（可选）如果需要返回值的近似匹配，可以指定TRUE；如果需要返回值的精确匹配，则指定FALSE。如果没有指定任何内容，默认值将始终为TRUE 或近似匹配。

2

精确查找

一份销售业绩表，根据姓名来查找对应的销售量，一个人只对应一个值，即为精确查找。

第一步：点击I2单元格，然后选择【公式】-【查找与引用】，找到点击VLOOKUP。

第二步：在查阅值中选择H2单元格，所选区域选择A2:C11，销售量在所选区域的第三列，所以此处填3，最后的参数中输入0表示精确匹配。

3

模糊查找

有时候我们所需要的数据不是唯一对应的，一个范围区间内的多个查阅值对应一个值。比如查找销售量对应的销售等级，需要使用模糊查找。

第一步：和上述方法一致在【销售等级】下方选中单元格后点击VLOOKUP函数公式

第二步：在查阅值处选中C2单元格，查阅区域选择右侧事先制定好的等级规则，选中后，再将所选区域H2:I4选中，按F4锁定（注意这里的区域一定要用【$】锁定，即选中后按F4），下方由于等级为所选区域第二列，故填2，最后查找为近似值，故填1。

最后双击填充，将这一列等级填充完毕。

4

空值显示为空白

很多时候我们的数据表中会出现空值的单元格，我们利用VLOOKUP查找时显示为0，以下方法可以让显示0的单元格变为空白单元格。

保持原公式不变的情况下，在公式后添加【$】符号，和英文状态下的双引号（该符号在英文输入法下输入）。

你还在因为不会使用Excel统计函数而烦恼吗？在我们操作插入表格函数的时候，时常因为“找不到对象”以及“不能插入对象”而烦恼。

那么今天就为你们介绍7个经常使用的表格统计公式，直接复制函数即可帮你解决问题。

一、计算数据合（注：函数里表格坐标，要按照实际表格坐标调整）

函数：=SUM(B2:F2)

二、计算表格总平均值（注：函数表格位置要按实际调整）

函数：=AVERAGE(G2:G7)

三、查找表格相同值（注：函数里表格坐标，要按照实际表格坐标调整）

函数：=IF(COUNTIF(A:A,A2)>1,"相同","")

四、计算表格不重复的个数（注：函数里表格坐标，要按照实际表格坐标调整）

函数：=IF(COUNTIF(A2:A99,A2)>1," 首次重复","")

五、计算出男生表格总平均成绩（注：函数里表格坐标，要按照实际表格坐标调整）

函数：=AVERAGEIF(B2:B7,"男",C2:C7)

六、计算出成绩排名（注：函数里表格坐标，要按照实际表格坐标调整）

函数：=SUMPRODUCT((B$2:B$7>B2)/COUNTIF(B$2:B$7,B$2:B$7))+1

以上就是今天为大家分享的所有Excel函数啦！，其实在我们统计表格中，还有很多函数，小编只是写了其中一些，如果大家知道一些实用性非常强的函数，欢迎在评论区积极分享。

Excel或者Wps表格中连接单元格日期数据的一个小方法

大家好，我是头条号@爱玩电脑，不会IT高科技，只讲电脑小知识。今天给大家讲讲在Excel中将两个单元格中的日期数据连接起来，合并到一个单元格中显示的办法，Wps表格中操作一致。

应用场景如下：一个单元格保存的是开工日期，一个单元格保存的是完工日期，现在老板叫你在一列中显示起止日期。普通的文本如果要合并，比较简单，不会的可以参考我写的另外一篇文章（点右边--->）：excel或者wps表格中多个单元格数据快速合并的两个方法，但日期格式相对特殊一些，按照上述方法处理的结果是错误的。

概述：系统windows7，软件Excel2007，需要处理的表格如下：

题目

我需要在E列把C、D列的数据合并显示，主要是利用Text函数。

TEXT函数主要有两个参数，第一个是需要转换的值，第二个是转换后的格式。其官方说明如下：

TEXT官方说明

具体方法就二步：

第一步：用Text函数将日期转换为文本。

第二步：将两个文本连接起来。

具体来说就是在E2单元格输入公式：=TEXT(C2,"yyyy-mm-dd")&"至"&TEXT(D2,"yyyy-mm-dd")，回车后向下填充，就成功了。效果如下：

成功了

你也可以修改下数字格式：=TEXT(C2,"yyyy/mm/dd")&"至"&TEXT(D2,"yyyy/mm/dd")，效果就是这样的了：

也成功了

更多的格式就需要大家自行探索了。

好了，Excel中日期格式单元格数据合并的方法就讲到这里，在Wps表格中的操作方法是一致的。文章由头条号@爱玩电脑首发于今日头条，转载请注明出处。

我们在数据匹配查找的过程中经常会碰到按照条件一对多进行数据查询，比如说根据姓名查询当天所有的记录。经常我们用到的方法就是vlookup函数和其他函数搭配使用，还有就是使用VBA代码进行自定义查找。今天我们就来讲一个99%的人都没有见过的一个函数，那就是textjoin函数怎么轻松实现数据的一对多查询。

一、textjoin函数详解

1. 函数解释

①简单来说它就是一个连接文本的函数；

②通过分隔符的，连接所有符合条件的单元格内容和区域。

2. 函数语法结构

公式=TEXTJOIN(分隔符,TRUE,需要合并的字符串区域或列表)

①第一参数分隔符代表我们可以任意设置任何符号来连接数据；

②第二参数TRUE代表忽略空值，也就是不存在的值会自动忽略，等同于1；

③第三参数代表对应的数据区域。

实现的效果图如下：

二、实际案例操作

如上图我们需要根据A列A1A2A3三个条件值，对应查找出B列的所有值。运用TEXTJOIN函数就会显得非常简单。

函数=TEXTJOIN(",",TRUE,IF(D2=$A$2:$A$10,$B$2:$B$10,""))，结果等于B1，C1，D1，E1。

函数解析：

1、第一参数为“，”：代表每个值中间用逗号，连接；

2、第二参数默认为TRUE，如果有空值可以不做计算；

3、第三参数为函数IF(D2=$A$2:$A$10,$B$2:$B$10,"")，这个函数代表的意思是当D2单元格条件A1，在A列中存在的时候，提取出对应的B列的所有值。我们选择这段函数按F9，就会显示出以下对应的内容，如下图：

A1对应的值B1C1D1E1都会被提取出来。

④输入上面的完整函数之后，光标选择全部函TEXTJOIN(",",TRUE,IF(D2=$A$2:$A$10,$B$2:$B$10,""))，按Ctrl+Shift+Enter，以三键数组的方式即可用连接符提取出我们条件值对应的所有数据。

现在你学会了这个不一样的一对多查询方法了吗？

注意：这个函数仅限于Office 365版本支持。

前言：我们成长的速度好像永远也追不上我们曾经逝去的

你是否经常需要在Excel中对数据进行整理，这其中包括处理数字、字符等类型处理。

我们今天来说一下如何对其中的字符串连接文本。也许提到文本连接，你肯定会想到连接符("&")，但是我们今天说的猪角是PHONETIC函数。

这是一个连接文本的函数。

一、PHONETIC 函数帮助文件： 语法 PHONETIC(reference) 为文本字符串或对单个单元格文本字符串的单元格区域的引用。

注解的2个点，可是非常重要的哦！ 如果 reference 为单元格区域，则返回区域左上角单元格中的文本字符串。 如果 reference 为不相邻单元格的区域，将返回错误值 #N/A。不支持数字、日期、时间、逻辑值、错误值等我们还是看几个例子，来说明这个函数的用法吧！

如下图所示，为源数据区域1。

公式=+PHONETIC(D26:I27) 结果：世间所有相遇都是久别重逢

这个函数可以将除纯数据(数字、日期、时间)、公式结果（包括错误信息）外的所有字符进行连接。 连接顺序：按先行后列，从左向右，由上到下的顺序连接。

如下图所示，为源数据区域2。这个函数可以嵌套其他的函数进行使用。

这个公式其实就是我们常见的查询组合啦！

这个函数还可以嵌套我最近新学的一个函数，INDIRECT函数。我们下篇文章将讲解这个函数的具体用法。

数组公式={+PHONETIC(INDIRECT("d26:i"&{27;27}))}

那么是不是所有的文本型数字均能用该函数连接呢？答案是否定的，而且这个函数还不支持任何公式生成的值，也就是说你使用公式查找过来的值，他并不能操作。

写在最后，这个函数的几个缺点让实用性大打折扣

不支持非单元格（数组），要是像vba中的join函数就完美了。

2.只支持文本格式也略显不足。

PS:学习的苦难需要我们主动面对,生活的苦难你躺着它自己主动就过来啦!与君共勉!!!

以上就是今天要和大家分享的技巧，希望对大家有所帮助，祝各位一天好心情！

唯有不断学习，才能不被淘汰！

Excel中每一个方法都有特定的用途，不是他们没有用处，只是你不了解或者暂时用不着，建议你收藏起来，万一哪天用着呢？

大家好，我是超爱高效率的秋小叶~

最近有一位同学求助，他需要在 Excel 文件里加很多超链接，可他只会一个个加，感觉太麻烦了。

那可不，身为超爱高效率的我，今天就教大家一个一键搞定超链接添加的函数！

先来看看这位同学的具体问题：

有一张 Excel 汇总表，其中一列是合同编号，每个合同编号都有个对应的 Excel 文件。现在需要实现：点击总表中的合同编号时能自动跳转到对应的明细表。可我只会一个个加链接，好慢啊！

原始表格长这样，我给它打了个码。

乍一看这个问题很特殊，好像自己不会碰到。

但要解决的问题本质上是：如何批量创建超链接到其他工作表。

只要会这一个函数，就能轻松搞定，这个函数就是Hyperlink(超级链接函数)。

链接到其它工作表

下面以一个简单的表格作为示例，在 B2:B6 区域创建可以跳转到对应工作表的链接：

操作过程很简单：

用 Hyperlink 这个函数，你需要告诉 Excel 跳转的目的地在哪，也就是链接地址，还有显示出来的超链接名称是什么。

你也可以用链接地址的形式显示：hyperlink(链接地址,显示名称)

上面这个案例，链接的目标是当前 Excel 文件的其他工作表，有一个固定结构，就是前面必须有一个 # 号：

= hyperlink("#"&工作表名&"!A1",显示名称)

这个公式结构的含义是：创建一个超链接，跳转到指定工作表中的 A1 单元格。

用 Hyperlink 函数还可以实现很多好玩的效果。

跳转到指定网址

例如，要创建一个跳转到百度页面的超链接时，可以这样写：

= hyperlink("https://baidu","百度一下")

点击展示搜索结果

要创建一个自动搜索关键词的链接，比如用百度搜索「秋叶」的结果页面。可以把具体的网址替换掉链接地址这个参数：

= hyperlink("https://baidu/s?wd=秋叶","百度秋叶")

点击搜索相应关键词

想要根据单元格里的数据进行搜索？那就利用 & 连字符，拼接单元格，构建出一个可以生成完整链接地址的公式结构。

这样就能向下填充，得到自动搜索对应关键词的按钮。

= hyperlink("https://baidu/s?wd="&A2,"点击搜索")

打开某个文件夹下的文件

同样的，在自己电脑上的文件，也可以通过超链接的形式点击就打开。

我们需要的是提取出文件名，用 & 构建出一个链接地址，然后用 Hyperlink 函数批量生成跳转链接。

例如，在 D 盘下有一个相片集的文件夹，包含很多照片：

我们可以通过 Hyperlink 函数批量添加超链接，在 Excel 表中就可以直接打开对应的照片文件。

例如张三的照片，完整路径应该是 D:\相片集\张三.jpg，张三这个名字直接引用 A2 单元格的内容，于是写成公式就是：

= hyperlink("D:\相片集\"&A2&".jpg","查看照片")

看吧，函数其实并不可怕，只要搞懂它的语法结构，告诉 Excel 怎么按部就班的处理数据，它就会乖乖听话，帮你搞定大量的重复操作。

重点

“超链接”这个名词相信大家不会陌生吧，在之前的课堂上呢，主要和大家分享了我们如何通过超链接命令去操作执行我们文档的跳转和页面的跳转，今天呢，和大家谈谈我们Excel中的HYPERLINK超链接函数。

HYPERLINK超链接函数的参数和语法

HYPERLINK(link_location,friendly_name)

①hyperlink函数第一参数是表示超级链接的文件的路径和文件名，或者是要跳转的单元格地址。

②hyperlink函数第二参数是随意指定的字符串或某一单元格的值，是在超链接单元格中显示的内容。

看这个例子大家应该就明白了。

案例一：某公司的员工很多，使得员工信息表的行数就增加了，这个员工信息表的阅读带来了一定的不便。

要求：现在要求在员工信息表的最后一行建立一个链接，以便在阅读信息表之后可以直接返回工作表首行。

这个的话很简单：只需要在我们的单元格里面输入=HYPERLINK("#A1","返回首行")

简单的分析一下吧，"#A1"代表的是这个单元格的A1单元格地址，"返回首行"就是指的我们超链接单元格所显示的内容。

案例一说明：

①HYPERLINK参数，第一个参数必选，为跳转地址，第二个参数可选择填写，如果省略，则显示第一个参数。

②参数的第一个参数是有要求的。比如本例中的“#”，表示当前工作薄。是不能够省略的，

案例二：使用HYPERLINK函数建立的超链接可以打开指定的网址，如实现百度搜索。

只需要在单元格输入=HYPERLINK("https://baidu/baidu?word="&B2,"搜索")

点击后结果如下：

案例二说明：

①在利用超链接函数的时候，我们的链接地址一定要完整，不能少写。

HYPERLINK函数可以实现很多功能，比如选择符合条件的单元格、打开当前计算机指定的位置文件或文件夹，注意的是跳转当前工作薄的位置是，需要在地址文本前加“#”。