今天文章主题仍然是if函数，在上两篇文章excel关于函数if的巧妙运用excel关于if函数的嵌套使用中，第一篇文章，我们介绍了怎样运用if函数在两种不同结果之间进行判断计算的操作过程，第二篇文章中我们更近一步，函数if与函数if本身的嵌套使用，从而运用if函数解决了应对三种不同结果进行判断的解决方法。（今天这篇文章承接上面两篇文章的内容而来，感兴趣的朋友可以通过链接去看看）。

今天我们再更进一步，介绍一下面对三种以上情况结果下，函数if的运用方法。咱们外甥打灯笼，照旧按老规矩来，运用实例来说话。

今天我们的实例是这样的，我们已知业务员的等级分为A级、B级、C级、D级四个等级，分别对应的奖金为10000元、9000元、8000元和7000元，现在我们有四个业务员，分别是丁一、牛二、张三、李四，他们正好对应了A级、B级、C级、D级四个等级，这时就要求我们运用if函数根据四个业务员的等级来判断他们各自的奖金。excel工作表具体如下所示：

具体操作方法一（方法一继承了文章“excel关于if函数的嵌套使用”中的方法）：

在G4单元格输入“=IF(F4="A级",10000,IF(F4="B级",9000,IF(F4="C级",8000,7000)))”（ps:if函数中的标点符号在英文输入法状态下输入），按回车键，得到业务员丁一的应发奖金数，然后通过填充柄拖拽的方式向下拖拽，我们就能到其他业务员的应发奖金数了。具体操作可参考下图：

方法评价：运用if函数三层嵌套的方式成功解决了现有问题，但是一旦面对答案更多的情况，肯定会让人难以忍受，而且在excel中最多只能嵌套七层，所以这种方法限制太大了。

具体操作方法二（方法二继承了文章“excel关于函数if的巧妙运用”中的方法，使用函数if最简单的方式进行叠加运算）：

在G4单元格输入“=IF(F4="A级",10000,0)+IF(F4="B级",9000,0)+IF(F4="C级",8000,0)+IF(F4="D级",7000,0)”，按回车键，得到业务员丁一的应发奖金数，然后通过填充柄拖拽的方式向下拖拽，我们就能到其他业务员的应发奖金数了。具体操作可参考下图：

方法评价：使用函数if最简单的方式进行叠加运算的方法成功解决了现有问题，且该方法excel并没有进行限制，仅仅需要不断进行复制并修改相关数据的方式就能进行叠加运算，但是局限性也相当明显，一旦面对答案太多的情况，就不再适用了。

具体操作方法三：方法三是真正实用的方法，需要运用到函数vlookup。

在G4单元格输入“=VLOOKUP(F4,$B$4:$C$7,2,0)”，按回车键，得到业务员丁一的应发奖金数，然后通过填充柄拖拽的方式向下拖拽，我们就能到其他业务员的应发奖金数了。具体操作可参考下图：

方法评价：与函数if的两种方法相比，面对答案太多的情况，函数vlookup的局限性大大减小，堪称相对完美的方法了。

今天的分享也就到此结束了。觉得对你们有用的小伙伴们请点赞关注吧！您的鼓励是我前进的动力，也希望擅长运用办公软件的小伙伴们能够不吝赐教，积极的留言，教会小编更多的excel运用的小技巧，欢迎一起来探讨学习！！

在工作中，单个函数的运用往往达不到我们想要的结果，我们一般是一个或这几个函数嵌套使用，今天小编就跟常用的函数嵌套组合，熟悉使用这些嵌套函数，可以提高工作效率哦。

组合一：LEN+SUBSTITUTE 计算一个单元格内有几个项目。

如下图所示，要计算每个部门的人数。

这样的表格大家应该比较熟悉：

在一个单元格内有多个姓名而且每个姓名之间用顿号隔开

C2单元格的函数公式为： =LEN(B2)-LEN(SUBSTITUTE(B2,"、",))+1

函数公式解释：

先用LEN函数计算出B列单元格的字符长度，然后再用SUBSTITUTE函数将顿号全部替换掉之后，计算替换后的字符长度。用字符长度减去替换后的字符长度，就是单元格内顿号的个数。

接下来，加1即是实际的人数。

组合二：VLOOKUP+MATCH 用于不确定列数的数据查询。

如下图所示，要根据B13单元格的姓名，在数据表中查询对应的项目。

C13单元格的函数公式为： =VLOOKUP(B13,A1:G9,MATCH(C12,1:1,),0)

函数公式解释：

如果数据表的列数非常多，在使用VLOOKUP函数时，还需要掰手指头算算查询的项目在数据表中是第几列，真是麻烦的很。先用MATCH函数来查询项目所在是第几列，然后VLOOKUP函数就根据MATCH函数提供的情报，返回对应列的内容。

组合三：MIN+IF 用于计算指定条件的最小值。

如下图所示，要计算生产部的最低分数。

G3单元格可以使用数组公式： =MIN(IF(A2:A9=F3,D2:D9))

函数公式解释：

先用IF函数判断A列的部门是否等于F3指定的部门，如果条件成立，则返回D列对应的分数，否则返回逻辑值FALSE：

{FALSE;45;FALSE;FALSE;FALSE;66;FALSE;72}接下来再使用MIN函数计算出其中的最小值。

备注：由于执行了多项计算，所以在输入公式时，要按Shift+ctrl+Enter键

MIN函数有一个特性，就是可以自动忽略逻辑值，所以只会对数值部分计算，最终得到指定部门的最低分数。

大家学会了吗？有问题欢迎到评论区骚扰哦！后期不断更新软件学习技巧干货，保证一看就会！如果觉得有用可以转发一下，谢谢大家支持！

工作效率，一直是我们追求的目标。在Excel中，提高效率的方法很多，最常用的就是对各种技巧的熟练掌握。今天我们要学习的10个Excel实操技巧，对工作效率的提高，绝对不是一点点。

一、自适应调整列宽。

目的：极速调整列宽，显示单元格全部内容。

方法：

1、选定需要调整列宽的列。

2、移动鼠标至选定的任意两列分割线处，待鼠标变成左右双向箭头时，双击。

解读：

1、想要双击显示单元格的全部内容，必须取消“自动换行”。

2、如果没有取消“自动换行”，双击行标可以自动显示全部内容。

二、快速隐藏多列、多行。

目的：对不需要显示或保密的多列或多行内容快速隐藏。

方法：

1、选定目标行或列。

2、移动光标至选定的任意两行行标或列标中间，待鼠标变成双向箭头时，拖动鼠标。

解读：

1、拖动鼠标时如果拖动的幅度较小（小于当前行或列的宽度），则不会隐藏行或列，只是对行高或列宽进行调整。

2、拖动的幅度大于临近行或列的高度或宽度时，可以快速的实现隐藏功能。

三、快速取消隐藏行、列。

目的：对隐藏的多行、多列快速的进行显示。

方法：

1、选定需要取消隐藏的行或列。

2、移动鼠标，待鼠标变成双向箭头时，双击。

四、多单元格数据批量输入。

目的：批量输入演示数据或固定内容。

方法：

1、选定目标单元格。

2、输入公式：=RANDBETWEEN(10,100)或“Excel函数公式”。

3、Ctrl+Enter填充。

解读：

1、函数RANDBETWEEN的主要作用是生成指定两个数之间的随机数。

2、输入指定内容时，无需等号。

五、多工作表批量输入。

目的：在多个工作表中批量输入演示数据或指定内容。

方法：

1、选定任意表格的目标单元格。

2、按住Ctrl键，选定其它工作表。

3、输入公式:=RANDBETWEEN(10,100)或“Excel函数公式”。

3、Ctrl+Enter填充。

六、快速的输入：对号，错号。

目的：快速用对号或错号对数据进行标记。

方法：

1、选定目标单元格。

2、设置目标单元格的字体为：Wingdings 2。

3、输入大写R或S。

七、按月填充日期。

目的：对当前日期按月快速填充。

方法：

1、选定目标单元格并输入需要填充的日期。

2、拖动填充柄，并单击右下角的箭头，选择【按月填充】。

八、单元格内强制换行。

目的：调整内容显示，强制换行。

方法：

在目标内容后按Alt+Enter快捷键。

九、快速添加前缀。

目的：给序号添加前缀：函数公式。

方法：

1、选定目标单元格。

2、快捷键Ctrl+1打开设置单元格格式，选择【分类】中的【自定义】，在【类型】中输入：Excel函数-0。

3、【确定】。

十、快速输入有规律的长数字。

方法：

1、66万的后面有4个零，所以公式为：=66**4。

2、90亿，9的后面有9个零，所以公式为：=9**9。

结束语：

如果我们对实际操作中的技巧能够熟练掌握，相信对我们的工作效率提高的绝对不是一点点……欢迎大家在留言区讨论交流，同时别忘了点赞、转发哦！

Excel曾经一度出现了严重Bug，主要有两种比较悲催的情况，首先是这种：

更加悲催的是这种：

言归正传，今天和大家分享一组常用函数公式的使用方法：职场人士必须掌握的12个Excel函数，用心掌握这些函数，工作效率就会有质的提升。

建议收藏备用着，有时间多学习操练下。

目录：数字处理、判断公式、统计公式、求和公式、查找与引用公式、字符串处理公式、其他常用公式等

一、数字处理

01.取绝对值

=ABS(数字)

02.数字取整

=INT(数字)

03.数字四舍五入

=ROUND(数字,小数位数)

二、判断公式

04.把公式返回的错误值显示为空

公式：C2

=IFERROR(A2/B2,"")

说明：如果是错误值则显示为空，否则正常显示。

05.IF的多条件判断

公式：C2

=IF(AND(A2<500,B2="未到期"),"补款","")

说明：两个条件同时成立用AND,任一个成立用OR函数。

三、统计公式

06.统计两表重复

公式:B2

=COUNTIF(Sheet15!A:A,A2)

说明：如果返回值大于0说明在另一个表中存在，0则不存在。

07.统计年龄在30~40之间的员工个数

=FREQUENCY(D2:D8,{40,29})

08.统计不重复的总人数

公式：C2

=SUMPRODUCT(1/COUNTIF(A2:A8,A2:A8))

说明:用COUNTIF统计出每人的出现次数，用1除的方式把出现次数变成分母，然后相加。

09.按多条件统计平均值

F2公式

=AVERAGEIFS(D:D,B:B,"财务",C:C,"大专")

10.中国式排名公式

=SUMPRODUCT(($D$4:$D$9>=D4)*(1/COUNTIF(D$4:D$9,D$4:D$9)))

四、求和公式

11.隔列求和

公式：H3

=SUMIF($A$2:$G$2,H$2,A3:G3)

或

=SUMPRODUCT((MOD(COLUMN(B3:G3),2)=0)*B3:G3)

说明：如果标题行没有规则用第2个公式

12.单条件求和

公式：F2

=SUMIF(A:A,E2,C:C)

说明：SUMIF函数的基本用法

13.单条件模糊求和

公式：详见下图

说明：如果需要进行模糊求和，就需要掌握通配符的使用，其中星号是表示任意多个字符，如"*A*"就表示a前和后有任意多个字符，即包含A。

14.多条求模糊求和

公式：C11

=SUMIFS(C2:C7,A2:A7,A11&"*",B2:B7,B11)

说明：在sumifs中可以使用通配符*

15.多表相同位置求和

公式：b2

=SUM(Sheet1:Sheet19!B2)

说明：在表中间删除或添加表后，公式结果会自动更新。

16.按日期和产品求和

公式：F2

=SUMPRODUCT((MONTH($A$2:$A$25)=F$1)*($B$2:$B$25=$E2)*$C$2:$C$25)

说明：SUMPRODUCT可以完成多条件求和

五、查找与引用公式

17.单条件查找

公式1：C11

=VLOOKUP(B11,B3:F7,4,FALSE)

说明：查找是VLOOKUP最擅长的，基本用法

18.双向查找

公式：

=INDEX(C3:H7,MATCH(B10,B3:B7,0),MATCH(C10,C2:H2,0))

说明：利用MATCH函数查找位置，用INDEX函数取值

19.查找最后一个符合条件记录

公式：详见下图

说明：0/(条件)可以把不符合条件的变成错误值，而lookup可以忽略错误值

20.多条件查找

公式:详见下图

说明:公式原理同上一个公式

21.指定非空区域最后一个值查找

公式;详见下图

说明：略

22.区间取值

公式：详见下图

公式说明：VLOOKUP和LOOKUP函数都可以按区间取值，一定要注意，销售量列的数字一定要升序排列。

六、字符串处理公式

23.多单元格字符合并

公式：c2

=PHONETIC(A2:A7)

说明：Phonetic函数只能对字符型内容合并，数字不可以。

24.截取除后3位之外的部分

公式：

=LEFT(D1,LEN(D1)-3)

说明：LEN计算出总长度,LEFT从左边截总长度-3个

25.截取 - 之前的部分

公式:B2

=Left(A1,FIND("-",A1)-1)

说明：用FIND函数查找位置，用LEFT截取。

26.截取字符串中任一段

公式:B1

=TRIM(MID(SUBSTITUTE($A1," ",REPT(" ",20)),20,20))

说明:公式是利用强插N个空字符的方式进行截取

27.字符串查找

公式：B2

=IF(COUNT(FIND("河南",A2))=0,"否","是")

说明: FIND查找成功，返回字符的位置，否则返回错误值，而COUNT可以统计出数字的个数，这里可以用来判断查找是否成功。

28.字符串查找一对多

公式：B2

=IF(COUNT(FIND({"辽宁","黑龙江","吉林"},A2))=0,"其他","东北")

说明：设置FIND第一个参数为常量数组，用COUNT函数统计FIND查找结果

七、日期计算公式

29.两日期间隔的年、月、日计算

A1是开始日期（2011-12-1），B1是结束日期(2013-6-10)。计算：

相隔多少天？=datedif(A1,B1,"d") 结果：557

相隔多少月? =datedif(A1,B1,"m") 结果：18

相隔多少年? =datedif(A1,B1,"Y") 结果：1

不考虑年相隔多少月？=datedif(A1,B1,"Ym") 结果：6

不考虑年相隔多少天？=datedif(A1,B1,"YD") 结果：192

不考虑年月相隔多少天？=datedif(A1,B1,"MD") 结果：9

datedif函数第3个参数说明：

"Y" 时间段中的整年数。

"M" 时间段中的整月数。

"D" 时间段中的天数。

"MD" 天数的差。忽略日期中的月和年。

"YM" 月数的差。忽略日期中的日和年。

"YD" 天数的差。忽略日期中的年。

30.扣除周末的工作日天数

公式：C2

=NETWORKDAYS.INTL(IF(B2

说明：返回两个日期之间的所有工作日数，使用参数指示哪些天是周末，以及有多少天是周末。周末和任何指定为假期的日期不被视为工作日

八、其他常用公式

31.创建工作表目录的公式

把所有的工作表名称列出来，然后自动添加超链接，管理工作表就非常方便了。

使用方法：

第1步：在定义名称中输入公式：

=MID(GET.WORKBOOK(1),FIND("]",GET.WORKBOOK(1))+1,99)&T(NOW())

第2步、在工作表中输入公式并拖动，工作表列表和超链接已自动添加

=IFERROR(HYPERLINK("#'"&INDEX(Shname,ROW(A1))&"'!A1",INDEX(Shname,ROW(A1))),"")

32.中英文互译公式

=FILTERXML(WEBSERVICE("http://fanyi.youdao/translate?&i="&A2&"&doctype=xml&version"),"//translation")

excel中的函数公式千变万化，今天就整理这么多了。如果你能掌握一半，在工作中也基本上遇到不难题了。

建议收藏备用着，有时间多学习操练下。

很多人都和小编抱怨过，Excel太难学了。如果你想学，不管学的快还是学的慢，首先就是要开始学，如果你连开始的机会都不给，那怎么可能学会？

Excel是办公室自动化中非常重要的一款软件，很多巨型国际企业都是依靠Excel进行数据管理。它不仅仅能够方便的处理表格和进行图形分析.其更强大的功能体现在对数据的自动处理和计算，然而很多缺少理工科背景或是对Excel强大数据处理功能不了解的人却难以进一步深入。

很多人都怕Excel函数与公式，总是用不好。其实，这个真的不是你水平差，而是心理作用，越是怕越是学不好。

介绍给大家五个必须记住的Excel快捷键：

1. Ctrl+Shift+方向键 （快速选择数据区域）

当我们在excel中数据太多，想要快速选择数据区域的时候，我们可以使用快捷键Ctrl+Shift+方向键，首先鼠标放在A1单元格按快捷键Ctrl+Shift+↓ 可快速选择下面连续的数据区域，根据自己需求来更换方向键箭头。

2. Ctrl+A （全选）

在数据区域的任意单元格按快捷键Ctrl+A会快速选择连续的数据区域，在空白单元格按Ctrl+A会快速选择整个工作表。

3. Ctrl+- （删除单元格）

选择要删除的单元格区域，按Ctrl+-（减号）弹出要删除的选项，选择适合的选项确定即可。

4. Alt+= （快速求和）

选择要求和的数据区域，按快捷键Alt+= 可实现快速求和效果

5. F9 （查看公式运算结果）

当我们对输入的公式不理解的时候，可以选择公式按F9查看公式的运算结果

下面小编就结合例子来给大家讲解Excel的技巧

1

对省份进行判断，广东省的就属于省内，其他属于省外。

=IF(A2="广东省","省内","省外")

IF函数语法：

=IF(条件,满足的情况下返回值2,不满足的情况下返回值3)

A2="广东省"就是条件，如果单元格是广东省就返回第2参数也就是省内，否则就返回第3参数省外。

第3参数""这样又是什么意思呢？

=IF(A2="广东省","省内","")

""就是代表空白，什么都不显示的意思。假设让省外的显示空白，这样就会变得更加清晰，一目了然。

2

对省份进行判断，广东省和四川省有熟人，其他省份没有。

=IF(OR(A2="广东省",A2="四川省"),"有熟人","")

OR函数语法：

=OR(条件1,条件2,条件n)

只要其中一个条件成立，就是成立，否则就是不成立。举个简单的例子，通常情况下，电脑会分几个盘——C盘、D盘、E盘和F盘，我们在对电脑杀毒时，当杀毒软件发现任意一个盘中毒，就会立马提示电脑中毒了。

同理，满足单元格为广东省或者四川省就返回有熟人，否则返回空白。

OR函数也可以用+取代。

=IF((A2="广东省")+(A2="四川省"),"有熟人","")

跟OR函数类似的就是AND函数，语法一样。

AND函数就是需要满足所有条件才成立。举个最简单的例子，我每天早上发布文章，你每天早上看文章后留言，只有当这两个条件同时满足，才算读者与我们有了互动，假设任何一方没做到，就不叫互动。

=IF(AND(A1="会计情报局发文章",B1="读者留言"),"互动","")

AND函数也可以用四则运算的*代替。

=IF((A1="会计情报局发文章")*(B1="读者留言"),"互动","")

3

计算每一笔快递的邮费，广东省内消费满39元包邮，未满39元邮费8元；其他省份消费满79元包邮，未满79元邮费15元。

=IF(A2="广东省",IF(B2>=39,0,8),IF(B2>=79,0,15))

多个IF函数，看得头晕晕的有没有？

其实学函数就要懂得拆分，现在卢子手把手教你玩拆分。

=IF(A2="广东省",公式1,公式2)

单元格是广东省的，就返回公式1，否则就返回公式2。

公式1怎么来的呢？一起来看要求：消费满39元包邮，未满39元邮费8元。

=IF(B2>=39,0,8)

再来看公式2的要求：消费满79元包邮，未满79元邮费15元。

=IF(B2>=79,0,15)

将公式1和公式2分别放在单元格内。

通过拆分后，公式就变成这样：

=IF(A2="广东省",D2,E2)

公式没办法一口气写完的情况下都是写在单元格内的，理解起来会更简单。再将原来D2跟E2的公式替换进去就大功告成。

=IF(A2="广东省",IF(B2>=39,0,8),IF(B2>=79,0,15))

本文来源：Excel不加班

赠人玫瑰手有余香，这么实用的Excel教程不要私藏噢~快分享给朋友吧！

【免费领取】最全会计入门书籍合集，《会计入门全知道》、《三天学会纳税（你的第一本纳税书）》、《零基础学会计》、《跟着笨笨干会计》、《跟老会计学财务会计》

戳【了解更多】，赶紧领取！

Excel是大家知道一个办公软件，是办公人员特别是做会计的朋友离不开的优秀软件，一些专业人士肯定应用的比较自如，得心应手，但是一些刚接触的朋友就不怎么样了，今天为大家介绍Excel中的一些常用功能，方便大家的工作：

今天和大家分享的这些Excel函数都是最基本的，但应用面却非常广，学会基本Excel函数，也可以让工作事半功倍。

1、SUM函数

SUM函数的作用是求和。

统计一个单元格区域：

=sum(A1:A10)

统计多个单元格区域：

=sum(A1:A10,C1:C10)

2、AVERAGE函数

Average 的作用是计算平均数。

可以这样：

=AVERAGE(A1:A10)

也可以这样：

=AVERAGE(A1:A10,D1:D10)

3、COUNT函数

COUNT函数计算含有数字的单元格的个数。

COUNT函数参数可以是单元格、单元格引用，或者数字。

COUNT函数会忽略非数字的值。

如果A1:A10是COUNT函数的参数，其中只有两个单元格含有数字，那么COUNT函数返回的值是2。

也可以使用单元格区域作为参数，如：

=COUNT(A1:A10)

4、IF函数

IF函数的作用是判断一个条件，然后根据判断的结果返回指定值。

条件判断的结果必须返回一个或TRUE或FALSE的值，即“是”或是“不是”。

例如：

给出的条件是B2>C3，如果比较结果是TRUE，那么IF函数就返回第二个参数的值;如果是FALSE，则返回第三个参数的值。

IF函数的语法结构是：

=IF(逻辑判断,为TRUE时的结果,为FALSE时的结果)

5、NOW函数和TODAY函数

NOW函数返回日期和时间。TODAY函数则只返回日期。

假如说，要计算某项目到今天总共进行多少天了?

=TODAY()-开始日期

得出的数字就是项目进行的天数。

NOW函数和TODAY函数都没有参数，只用一对括号即可：

=NOW()

=TODAY()

6、VLOOKUP函数

VLOOKUP函数用来在表格中查找数据。

函数的语法公式是：

=VLOOKUP(查找值,区域,要返回第几列的内容,1近似匹配 0精确匹配)

7、ISNUMBER函数

ISNUMBER判断单元格中的值是否是数字，返回TRUE或FALSE。

语法结构是：

=ISNUMBER(value)

8、MIN函数和MAX函数

MIN和MAX是在单元格区域中找到最大和最小的数值。

可以这样：

=MAX(A1:A10)

也可以使用多个单元格区域：

=MAX(A1:A10, D1:D10)

9、SUMIF函数

SUMIF函数根据条件汇总，有三个参数：

=SUMIF(判断范围,判断要求,汇总的区域)

SUMIF的第三个参数可以忽略，第三个参数忽略的时候，第一个参数应用条件判断的单元格区域就会用来作为需要求和的区域。

10、COUNTIF函数

COUNTIF函数用来计算单元格区域内符合条件的单元格个数。

COUNTIF函数只有两个参数：

COUNTIF(单元格区域,计算的条件)

写在前面：洛阳亲友如相问，一片冰心在玉壶

也许在刚刚踏入陌生的一个世界中，你会发现有很多的人或者事情，你不熟悉。其实一路来走来，旅途的花开花落，情来情去情随缘，均有陌生人为你作伴相随。

不知你有木有发现我们的Excel其实也是有个很好的向导的，可以帮助我们更好的使用函数。

尤其当你不知道所需函数的名称，但不确定如何构建它，可以使用函数向导帮你完美解决。

我们举一个例子来说明一下：

选择单元格，然后转至“公式”>“插入函数”>在搜索函数框中键入 VLOOKUP，然后按“转到”。看到 VLOOKUP 突出显示时，在底部单击“确定”。如果选择列表中的函数，Excel 将显示其语法。

接下来，在其各自的文本框中输入函数参数。每输入一个参数，Excel 都会对其求值，并显示其结果，最终结果显示在底部。完成后请按“确定”，Excel 将为你输入公式。

我们在输入函数参数的时候，其实可以看到下面的解释，提示这个位置应该输入啥值。我们顺带简单提一下这个函数的使用方法哈！

VLOOKUP 是 Excel 中使用最广泛的函数之一（也是我们最喜欢的工具之一！）。使用 VLOOKUP，你可查找左侧列中的值，如果找到匹配项，则会在右侧的另一列中返回信息。

无一例外，你会遇到 VLOOKUP 找不到所需内容，并且返回错误 (#N/A) 的情况。有时是单纯的因为查找值不存在，或者因为引用单元格尚无任何值。

第一种情况，如果你知道查找值存在，但查找单元格为空，你希望隐藏错误，可以使用 IF 语句。在这种情况下，我们将如单元格 D43 所示嵌套现有 VLOOKUP 公式：

=IF(C43="","",VLOOKUP(C43,C37:D41,2,FALSE))

这表示如果单元格 C43 没有任何内容 ("")，则不返回任何结果，否则返回 VLOOKUP 的结果。请注意公式末尾的第二个右括号。这可关闭 IF 语句。

第二种情况，如果不确定查找值是否存在，但仍想抑制 #N/A 错误，可以在单元格 G43 中使用名为 IFERROR 的错误处理函数：=IFERROR(VLOOKUP(F43,F37:G41,2,FALSE),"")。IFERROR 表示，如果 VLOOKUP 返回有效结果，则显示该结果，否则不显示任何内容 ("")。此处我们没有显示任何内容 ("")，但还可以使用数字（0、1、2 等）或文本，如“公式不正确”。

PS:IFERROR 称为综合错误处理程序，意味着它将抑制公式可能引发的任何错误。如果 Excel 通知你公式有需要修复的合法错误，这可能导致问题。

经验法则是不要将错误处理程序添加到公式中，除非确定它们能工作正常。

有时，你会遇到含有错误的公式，Excel 显示为 #ErrorName。错误很有用，因为它们可指出某些内容未正确运行，但进行修复并非易事。所幸，有通过多种方式可帮助你查找错误来源，并进行修复。

1.错误检查 - 转到“公式”>“错误检查”。这将加载一个对话框，告知你特定错误的一般原因。在单元格 D9 内，引发 #N/A 错误的原因是没有匹配“苹 果”的值。可以修复此错误，方法是使用存在的值，使用 IFERROR 抑制错误，或知道在使用确实存在的值时错误会消失的情况下忽略它。

2.如果单击”关于此错误的帮助”，将打开特定于此错误消息的帮助主题。如果单击“显示计算步骤”，将加载“公式求值”对话框。

3.每次单击“求值”，Excel 都将逐步执行公式，一次一个部分。它不一定会告诉你出现错误的原因，但会指出位置。在这里，查看帮助主题，推导公式出问题的位置。

写在结尾：寒雨连江夜入吴，平明送客楚山孤。

以上就是今天要和大家分享的技巧，希望对大家有所帮助，欢迎大家帮忙转发，谢谢！

祝各位一天好心情！

Excel中每一个方法都有特定的用途，不是他们没有用处，只是你不了解或者暂时用不着，建议你收藏起来，万一哪天用着呢？

你还在因为不会使用Excel统计函数而烦恼吗？在我们操作插入表格函数的时候，时常因为“找不到对象”以及“不能插入对象”而烦恼。

那么今天就为你们介绍7个经常使用的表格统计公式，直接复制函数即可帮你解决问题。

一、计算数据合（注：函数里表格坐标，要按照实际表格坐标调整）

函数：=SUM(B2:F2)

二、计算表格总平均值（注：函数表格位置要按实际调整）

函数：=AVERAGE(G2:G7)

三、查找表格相同值（注：函数里表格坐标，要按照实际表格坐标调整）

函数：=IF(COUNTIF(A:A,A2)>1,"相同","")

四、计算表格不重复的个数（注：函数里表格坐标，要按照实际表格坐标调整）

函数：=IF(COUNTIF(A2:A99,A2)>1," 首次重复","")

五、计算出男生表格总平均成绩（注：函数里表格坐标，要按照实际表格坐标调整）

函数：=AVERAGEIF(B2:B7,"男",C2:C7)

六、计算出成绩排名（注：函数里表格坐标，要按照实际表格坐标调整）

函数：=SUMPRODUCT((B$2:B$7>B2)/COUNTIF(B$2:B$7,B$2:B$7))+1

以上就是今天为大家分享的所有Excel函数啦！，其实在我们统计表格中，还有很多函数，小编只是写了其中一些，如果大家知道一些实用性非常强的函数，欢迎在评论区积极分享。

其实无论是计算机考试中还是我们平时的工作中，都是需要用到查询函数，因为不仅是考试考点，学会使用它会使我们的工作简单许多。

vlookup函数通常用于在excel工作簿中搜索某个单元格区域的第一列，然后返回该区域相同行上任何单元格中的值。

当然在使用vlookup函数之前，我们必须对vlookup函数有基本的认识和了解，所以今天小编就来介绍一下vlookup函数的语法，大家可以跟着小编来学习一下。

函数的书写格式：

Vlookup（lookup|_value,table_array,col_index_num,range_lookup）

搜索表区域首列满足条件的元素，确定待检索单元格在区域中的行序号，再进一步返回选定单元格的值。默认情况下，表是以升序排序的。

vlookup函数参数说明如下：

lookup|_value：在表格或区域的第一列中要搜索的值。

table_array：包含数据的单元格区域，即要查找的范围。

col_index_num：参数中返回的搜寻值的列号。

range_lookup：逻辑值，指定希望Vlookup查找精确匹配值（0）还是近似值（1）。

我们已经对vlookup函数有了一个基本的认识，至少语法结构是没什么问题的，所以今天小编就要和大家说一说实际操作的步骤了。

我们今天就利用vlookup函数来查找公司员工信息，大家可以跟着小编来操作一下。 我们需要双击打开excel软件，随意选中一个空白单元格，在编辑框中输入 “=vlookup(”，单击函数栏左边的fX按钮。

在弹出的“函数参数”对话框中，我们想要查询北京主管的员工编号，在lookup_value栏中输入“北京”对应单元格。

在table_array栏中选中A4:C9单元格内容，在col_index_num栏中输入3（表示选取范围的第三列），在range_lookup栏中输入0（表示精确查找）。

单击确定按钮后，我们可以看到，已经查找到北京经理的员工编号了。

可能对于在用Excel的朋友来讲，平时使用的比较多的一个函数，那就是Vlookup函数，今天小编就来告诉大家一个Excel中最有用第一个函数，那就是Countif函数，这个函数的适用范围远远高于vlookup函数，所有把它列为最有用函数的NO.1也一点都不为过。下面我们就来学习一下这个函数。

今天教大家这个函数主要从以下6个场景来进行学习。

一对一对比两列数据多对多对比两列数据禁止重复输入输入时必须包含指定字符帮助Vlookup实现一对多查找统计不重复值的个数

:场景1：一对一核对两列数据

【例】如下图所示，要求对比A列和D列的姓名，在B和E列出哪些是相同的，哪些是不同的。

公式：

B2 =IF(COUNTIF(D:D,A2)>0,"相同","不同")

E2 =IF(COUNTIF(A:A,D2)>0,"相同","不同")

场景2：多对多核对两列数据

【例】如下面的两列数据，需要一对一的金额核对并用颜色标识出来。

步骤1 在两列数据旁添加公式，用Countif函数进行重复转化。

=COUNTIF(B$2:B2,B2)&B2

步骤2按ctrl键同时选取C和E列，开始 - 条件格式 - 突出显示单元格规则 - 重复值。

设置完成后后，红色的即为一一对应的金额，剩下的为未对应的。如下图所示

场景3：禁止重复录入

禁止在G列重复录入数据：

数据 - 有效性（2016版为数据验证） - 序列 - 输入公式

=COUNTIF(G:G,G1)=1

场景4：输入内容必须包括指定字符

【例】在列输入的内容，必须包含字母A。

=COUNTIF(H1,"*A*")=1

:如果输入不含A的字符就会警示并无法输入

场景5：帮助Vlookup函数实现一对多查找

【例】如下图所示左表为客户消费明细，要求在F:H列的蓝色区域根据F2的客户名称查找所有消费记录。

:步骤1 在左表前插入一列并设置公式，用countif函数统计客户的消费次数并用&连接成 客户名称+序号的形式。

A2: =COUNTIF(C$2:C2,C2)&C2

步骤2 在F5设置公式并复制即可得到F2单元格中客户的所有消费记录。

=IFERROR(VLOOKUP(ROW(A1)&$F$2,$A:$D,COLUMN(B1),0),"")

场景6：计算唯一值个数

【例】统计A列产品的个数

=SUMPRODUCT(1/COUNTIF(A2:A7,A2:A7))

总结：总的来讲Countif函数虽然只是单一条件的计数函数，但它在与其他函数搭配使用的时候，那他的作用将会变的无限大。所以说大家可以多去学习了解一下更多的函数嵌套的使用方法。