函数中最受欢迎的有三大家族，一个是以SUM函数为首的求和家族，一个是以VLOOKUP函数为首的查找引用家族，另外一个就是以IF函数为首的逻辑函数家族。根据二八定律，学好这三大家族的函数，就能完成80%的工作。

现在一起来学习VLOOKUP函数，让关于查找的烦恼一次全解决！

1、根据番号精确查找俗称。

=VLOOKUP(D2,A:B,2,0)

VLOOKUP函数语法：

=VLOOKUP(查找值,查找区域,返回查找区域第N列,查找模式)

VLOOKUP函数示意图。

2、屏蔽错误值错误值查找。

=VLOOKUP(D2,A:B,2,0)

VLOOKUP函数如果查找不到对应值会显示错误值#N/A，这个看起来很不美观。这时可以在外面加个容错函数IFERROR，如果是2013版本那就更好，可以用IFNA函数，这个是专门处理#N/A这种错误值。

=IFERROR(VLOOKUP(D2,A:B,2,0),"")=IFNA(VLOOKUP(D2,A:B,2,0),"")

函数语法：

=IFERROR(表达式,错误值要显示的结果)

说白了就是将错误值显示成你想要的结果，不是错误值就返回原来的值。IFNA函数的作用也是一样，只是IFERROR函数是针对所有错误值，而IFNA函数只针对#N/A。

3、按顺序返回多列对应值。

通过上面的例子，我们知道可以通过更改第3参数，返回各项对应值如：

=VLOOKUP($A13,$A$1:$F$10,2,0)=VLOOKUP($A13,$A$1:$F$10,3,0)

如果项目少，更改几次参数也没什么，但项目多时，肯定不方便。如图 5103所示，可以通过ROW、COLUMN产生行列号，从而得到1，2，……，n的值。

=VLOOKUP($A13,$A$1:$F$10,COLUMN(B1),0)

因为这里是同一行产生序号，所以用COLUMN函数。

4、按不同顺序返回对应值。

这回看来只能手动更改第3参数了，COLUMN完全派不上用场。

NO！每当你觉得操作繁琐时，就要停下来思考，也许Excel本身存在这个功能，只是自己一时想不到或者不知道而已。列号不管千变万化，在数据源的位置始终不变，利用这个特点可以去搜索一下看看有什么函数可以解决。

在“搜索函数”文本框输入：位置，单击“转到”按钮，就会出现跟位置有关的函数，查看每个函数的说明，找到我们需要的，如MATCH函数，返回符合特定值特定顺序的项在数组中的相应位置，单击“确定”按钮。

在弹出的“函数参数对话框”中尝试填写相应的参数，每个参数的作用下面都有相关说明，填写后会出现计算结果3，也就是订单数在区域中是第3列。尝试下更改第1参数为C12（俗称），计算结果是2，也就是区域中第2列。经过尝试，知道这个函数是我们要找的那个函数，单击“取消”按钮，返回工作表。

在单元格再做最后一次验证。

到这一步已经十拿九稳了，将公式设置为：

=VLOOKUP($A13,$A$1:$F$10,MATCH(B$12,$A$1:$F$1,0),0)

5、根据番号逆序俗称。

帮助提到VLOOKUP函数只能按首列查找，不能逆向查找，既然如此，那就得想办法将非首列的区域转换成首列。怎么转换区域呢，这时IF函数就派上用场。一步步来了解IF函数的转换。

看看好友传递如何趣聊IF函数，吃货的福音。

IF函数其实只有一个条件来判断是否符合条件，返回FALSE和TRUE两种结果。

当菜只有分甜的或咸的2种口味时，甜味是红烧肉，咸味是酱油肉。

盲人吃饭时，看不到是什么菜。当别人问盲人：“你现在吃的什么菜？ 是咸的吗？如果是咸的，就是酱油肉，如果不是咸的就是红烧肉。”（给定判断条件：咸味）盲人刚好在吃红烧肉，于是就咂吧着嘴说：“恩，好吃，不是咸的！是红烧肉”（根据提问的要求，不符合咸的）假如要是盲人当时是在吃酱油肉呢,一定回答；“是的，咸的，是酱油肉”（条件为真，是！TRUE）。盲人根据口感，结合提问者说的条件，就知道自己吃的是红烧肉还是酱油肉了。

把这段话用公式来写：

=IF(A1="咸的",A2,B2)

翻译：是咸的吗？要是（TRUE），就是酱油肉，要是不是咸的（FALSE），就是甜的红烧肉。

A1="咸的"这个条件也可以直接换成TRUE或者FALSE。

=IF(TRUE,A2,B2)

因为满足条件，所以返回A2的对应值酱油肉。

=IF(FALSE,A2,B2)

因为不满足条件，所以返回B2的对应值红烧肉。

其实TRUE=1，FALSE=0，所以可以直接用1跟0表示。

=IF(1,A2,B2)=IF(0,A2,B2)

IF函数不止可以返回1个单元格的值，也可以返回多个单元格的值。

=IF({1,0},A2,B2)=IF({0,1},A2,B2)

选择两个单元格输入，按Ctrl+Shift+Enter三键结束。条件为{1,0}，返回A2:B2的对应值顺序不变；条件为{0,1}，返回A2:B2的对应值，顺序对换。也就是说通过改变1跟0的位置，可以调换两单元格的前后位置。

看到这里，知道IF函数通过改变1,0可以调换单元格的顺序，如果要改变区域的顺序也是可以实现的。

用IF函数重新构造的新区域，是多单元格数组公式，记得按Ctrl+Shift+Enter三键结束，否则出错。

新区域：

=IF({1,0},B2:B10,A2:A10)

所以公式可以变成：

=VLOOKUP(A13,新区域,2,0)

两个公式合并，大功告成。

=VLOOKUP(A13,IF({1,0},$B$2:$B$10,$A$2:$A$10),2,0)

6、根据俗称跟订单号两个条件查询完成情况。

正常情况下VLOOKUP函数是不能多条件查询，通过IF函数的学习，我们知道IF函数可以重新构造区域，这里就再次用IF构成一个区域。

新区域：

=IF({1,0},A2:A9&C2:C9,E2:E9)

所以公式可以变成：

=VLOOKUP(A12&B12,新区域,2,0)

两个公式合并，大功告成，记得按Ctrl+Shift+Enter三键结束。

=VLOOKUP(A12&B12,IF({1,0},$A$2:$A$9&$C$2:$C$9,$E$2:$E$9),2,0)

7、根据俗称的第一个字符查找番号。

=VLOOKUP(D2&"*",A:B,2,0)

星号（*）是通配符，代表所有字符，问号（?）代表一个字符。D2&"*"就是开头包含D2的意思。

8、根据区域判断成绩的等级。

借助辅助列的话，很容易查询等级，只需将VLOOKUP函数的第四参数设置为1或者省略即可。

=VLOOKUP(E2,A:C,3)

如果不用辅助列，估计很多人看到这条公式就得哭了，得结合前面所有函数知识才能完成，有兴趣的朋友可以自己去研究。

=VLOOKUP(E2,IF({1,0},--LEFT(B$2:B$5,FIND("-",B$2:B$5)-1),C$2:C$5),2)

前阵子无意间发现了IMREAL函数，所以不用辅助列的数组公式可以稍微简单一点。

=VLOOKUP(E2,IF({1,0},IMREAL(B$2:B$5&"i"),C$2:C$5),2)

IMREAL函数是计算复数的实部系数的函数，作用就是提取区间的下限。

通过这8个疑难，基本上的查询问题都能够解决。

开心吗？一下搞定8大疑难！

在Excel中，我们如何将一个表中的数据直接引用到另一个表中使用呢？如下图：我们要将【身份证号】表中的身份证号直接在【sheet5】表中直接调用

在这里我们要用到VLOOKUP函数

公式：VLOOKUP（lookup_value,table_array,col_index_num,range_lookup）

lookup_value：需要在数据表中搜索的值，在这里我们搜索的是A列单元格，则选中A列，如下：

table_array:需要在其中搜索数据的数据表，在这里，我们选择【身份证号】表，然后拖动A到B列（B列是我们想要引用的数据，所以只拖动到我们需要引用的那一列数据即可）如下：

col_index_num：满足条件的单元格在数组区域table_array中的序列号，首列号为1。在这里我们只有两列切第二列是我们要引用的，所以为2，如下：

range_lookup：指定在查找时是要求精确匹配，还是大致匹配。即false为大致匹配，true为精确匹配。（0代表大致匹配，不填或者写入大于0的整数则精确匹配）我们在这里输入0，大致匹配，如下：

单后单击确定。引用数据成功

有一天，老板忽然给了小金一份名单，让他找出名单中10个人的电脑号码。已有的客户备忘录中有几百条记录，请问小金应该怎样快速查找出这些人的电话？

用查找快捷键“Ctrl + F”，一个一个查找吗？10个人当然可以这样，可是如果要查找的是几十个人的电话号码呢？

正确而又高效的应该是用VLOOKUP函数，如图，几秒就搞定了老板的要求。

VLOOKUP函数怎么用呢？

VLOOKUP的公式是“=VLOOKUP(查找值,数据表,序列数,匹配条件[0,1])”，通俗地讲，就是4个问题，“找谁？”、“去哪里找？”、“找到后要什么？”、“找个相似的还是找个一模一样的”。

只要你回答了这4个问题，并且用单元格引用作为回答，就可以正确写出VLOOKUP函数。

在单元格中输入函数有两种办法。

办法1

熟悉VLOOKUP用法的，可以直接在单元格中输入“=VLOOKUP(”，然后用鼠标拖动选择查找值所在的单元格，接着用鼠标选取查找范围单元格，最后输入第三和第四个参数。

输入时有两个小技巧，第一，先点击一个单元格，按“Ctrl +Shift + ↓”可以快速选中该单元格及之后的同一列的数据，按“Ctrl +Shift + →”可以快速选中单元格及右侧的单元格；第二，按F4键可以快速切换绝对引用和相对引用。

办法2

不熟悉公式的朋友，可以使用公式引导。如图，点击输入栏上的“fx”，接着输入VLOOKUP，然后就会看到函数参数窗口，该窗口中包含了参数解释，使用前述的两个小技巧，逐一设置每个参数的值。

注意

我们在使用VLOOKUP函数前，最好给数据排序；VLOOKUP的第二个参数表示查找范围，一般这个范围都是固定的，因此需要使用绝对引用（也就是$符号），否则极容易出错。

谢谢阅读，欢迎点赞、评论、关注和点击头像。

大家好，我是婶婶，希望接下来的分享能够对大家有些许帮助，也希望大家多多支持鼓励，收藏、分享、评论多多益善啦，如果对胃口记得关注哦！

犹记得我在大二的时候参加数学建模比赛，比赛期间，我们需要处理并提取大量的数据，什么引用、匹配什么的层出不穷，当时我就傻了，可是到了指导老师手里，各种函数几秒钟解决问题，其中常用的一个函数就是今天的主角-----VLOOKUP函数！

工作以后，我们每次论订单时，同时也会时不时地用VLOOKUP函数，简直就亮瞎了我的钛合金狗眼啊；于是乎，这段时间苦学，将自己的所得分享给大家；一共分为4小段，分别为：入门篇、初级篇、进阶篇和高级篇，本篇则为入门篇。

1、名词解释

函数定义：在表格的首列查找指定的数据，并返回指定的数据所在行中的指定列处的数据。

说白了，或者说用婶婶的话讲就是-----“VLOOKUP是一个查找函数，如果给定一个查找的目标，它就能从指定的查找区域中查找返回想要查找到的值。”。

2、语法解答

它的基本语法为：

VLOOKUP（查找目标，查找范围，返回值的列数，精确OR模糊查找)

下面以一个实例来介绍一下这四个参数的使用：

例1：根据图表中所给出的数据，用公式快速匹配迪丽热巴的魅力值；如下图所示：

公式=VLOOKUP(E3,A2:C10,3,0)，公式讲解如下：

查找目标：地址E3所包含内容——迪丽热巴；

查找范围：原始数据库A2:C10；

返回值的列数：我们想要得到魅力值，魅力值在上述查找范围中属于第三列，这里就是3；

查找方式：0代表精确查找。

3、案例详解

咱们爱打篮球的都知道，NBA张伯伦有一个外号——张两万（20000）；江湖言传其与20000个女性发生过关系。

我们现在假设这20000人中，有0.5%是中国人，也就是100人；而这100人中，又有10人让其印象深刻；我们现在有100人的姓名和联系方式，张大帅现在想联系这10人，又只记得这10人的名字，如何快速找出并匹配10人的电话，就得用到我们的VLOOKUP函数了！

具体操作如下图：

输入公式=VLOOKUP(B4,F:G,2,0)；

4、语法详读及注意事项

1）查找目标（lookup_value）

这个比较好理解，就是指我们要找的对象;但是有两点需要注意；

【注意】

（1）查找目标不要和返回值搞混了：上面例子中查找目标是姓名而不是魅力值，案例详解中查找目标是姓名而不是电话；（后者是你想要返回的值）

（2）查找目标与查找区域的第一列的格式要保持一致，否则容易出错。

2） 查找范围（table_array）

所谓查找范围，也就是说在哪里查找我所需要的数据，本来这个没有什么解释的；但是VLOOKUP函数，和别的函数不一样，其查找范围的第一列必须要包含查找目标，其也就是为了很好地成为基点，为后面的参数做好标杆而设置的！

我们看下图：我们同样还是查找迪丽热巴的魅力值，我们并不是从第一列开始作为查找范围，而是从包含姓名的第二列开始；即F:G，而非E:F；后面参数是2，而非3！

3 ）返回值的列数（col_index_num）

我想通过查找范围的讲解，应该知道为什么是2，而非3了；这里就不赘述了。

只需要其数字是查找范围的第几列即可，不要管其在整个表格中是第几列。

4） 精确OR模糊查找（ range_lookup）

最后一个参数是决定函数精确和模糊查找的关键。精确即完全一样，用0或FALSE表示；模糊即包含的意思，用1或TRUE表示。

5）总结

1）Vlookup函数看似是查找的功能，实际是匹配——查找到的数值只是中间过程，返回的匹配值才是我们想要的。

2）几个注意事项：一是数据格式统一；二是查找目标在第一列；三是查找范围包含返回值。

今天就到此为止了，明天我们将会将初级篇，都会有什么呢？！大家可以找找，提前学习学习哦！

怎么样，大家理解了么，如果有问题，可以在评论里交流或者私信我哦！

喜欢的朋友，或者说觉得对自己有点用处，抑或是对身边的朋友有点用处，感谢点个“赞”哦，关注我的头条号和转发我的文章，非常感谢大家的支持，明天见！

在平时用Excel进行各类数据处理的时候，很多朋友都会碰到的一个问题就是数据查询，说到查询函数大家可能也会说到的就是Vlookup函数。其实在Excel中还有其他更加实用的数据查找函数公式，今天我们就来完整的学习一遍Excel中12种查询方式。

场景1：正常情况下数据查找

案例：查找出对应人员的语文成绩

函数=VLOOKUP(F5,B:C,2,0)

场景2：向左数据查找

案例：根据学号查询出对应姓名

函数=INDEX(B:B,MATCH(G5,C:C,0))

场景3：多函数条件交叉查询

案例：求出赵二第三周考试成绩

函数=VLOOKUP(I6,B:G,MATCH(J6,B$2:G$2,0),0)

场景4：LOOKUP多条件查询

案例：求出B产品在京东平台的销量

函数=LOOKUP(1,0/(B:B=F6)*(C:C=G6),D:D)

场景5：数据等级区间查询

案例：求出销售额对应的提成比例

函数=LOOKUP(F5,$B$3:$C$6)

场景6：横向纵向区间数据查询

案例：根据当月销售额及完成比例求出对应提成

函数=INDEX(C3:F9,MATCH(I4,B3:B9),MATCH(I5,C2:F2))

场景7：根据规律自动提取数值对应系数

案例：按照规律根据我们需要的数值提取出对应的系数

函数=TREND(OFFSET(B1,MATCH(D3,A2:A6,1),,2,1),OFFSET(A1,MATCH(D3,A2:A6,1),,2,1),D3)

场景8：查找符合条件的最后一个数

案例：查找出王五最后一天的销售额

函数=LOOKUP(1,0/(B:B=J4),F:F)

场景9：通配符模糊查找

案例：查找出姓王的人的销售额

函数=VLOOKUP(G5&"*",C:D,2,0)

场景10：高级匹配查找

案例：从对应完整地址中提取所在城市的提成点数

=lookup(9^9.find(A$3:A$6,A10),B$3:B$6)

场景11：查找最后一个非空的单元格内容

案例：求出对应人员最近一次缴纳社保的月份

函数=LOOKUP(1,0/(E4:E10<>""),$A$4:$A$10)

场景12：轻松实现一对多查询

案例：轻松提取部门人员全天的门禁记录

函数=IFERROR(VLOOKUP(ROW(A1),A:D,4,0),"")，首先需要在A列做辅助列，函数=COUNTIF(B$2:B2,G$2)

现在Excel关于数据查询你学会了吗？

VLOOKUP函数是Excel里面经常会使用到的一个函数。下面来讲解一下具体的含义和使用规则。

VLOOKUP=vertical lookup，意思就是在一部分选中区域内，按照要查找的值在选定区域内垂直进行对比筛选，查找到需要的信息并且进行返回。

以下为理论部分：

=VLOOKUP(lookup_value,table_array,col_index_num,range_lookup)

释义：

lookup_value：要查找的值，包括数字，文本等

table_array：要查找的值以及预期返回的内容所在的区域

col_index_num：查找的区域的列数，选中区域的第一列为1，依次顺延，而不是根据工作表给定的ABC列来算

range_lookup：近似匹配（1 / TRUE）或完全匹配（0 / FALSE）

以下为实际使用：

表格中为学生及语文科目的成绩。

现在要在另一个单元格内返回王五的成绩，可以使用VLOOKUP函数来进行。公式表达为：

=VLOOKUP(A4,A1:C5,3,FALSE)

或

=VLOOKUP("王五",A1:C5,3,FALSE)

lookup_value：这里指王五，就是单元格A4，当然也可以使用”王五”来替代，但是要注意使用英文引号。

table_array：这里需要选择A1:C5这个区域，因为王五在A列，需要得到的成绩在C列，都要包括进去。

col_index_num：这里需填写3，因为第一列为明细，成绩所在的列为第三列。

range_lookup：要查找王五的成绩，必然是需要完全匹配的，这里写false或者0都可。

于是公式会在第一列里面垂直从上往下查找，找到王五以后，返回的结果就是王五的成绩，与原表格的数据也能对应上。

有几个注意点：

第一，当要查找的值在这一列里面重复出现，公式会返回第一个出现的匹配值。如图所示，公式会返回第一次出现王五时的成绩B，因为查找的时候是垂直从上往下查找，找到第一个即返回结果。

第二，使用模糊匹配。在使用公式中，精确匹配用到的会比较多，但是模糊匹配也会有一些实际的应用，通常可以通过关键字进行模糊匹配查找。例如，图中为很多人的名字与身份证信息。

这时要查找一个叫做“五五”的人的身份证号码，想不起来姓什么，但是明确只有一个人叫五五，就可以通过模糊匹配来查找。

=VLOOKUP("五五",A1:B6,2,1)

这里引号内直接输入五五，然后选择模糊匹配，就可以返回相应的结果。如果这里选择了完全匹配，公式返回值会显示错误。用这个方法就可以快速找到想要的结果了。

数据核对，一直是Excel中比较常见的工作之一，如果一行，一个字母，一个数字的去核对，费时费力而且还容易出错。那么，有没有办法进行高效率的数据核对呢？

一、原数据的准备。

1、账面库存。

2、盘点库存。

目的：核对上面的账面数据和库存数据。

二、将“账面数据”引用到“库存数据”当中。

方法：

1、添加辅助列。

2、选定目标单元格。

3、输入公式:：=VLOOKUP(B3,账面库存!B:C,2,0)。

4、Ctrl+Enter填充。

解读：

VLOOKUP函数不仅可以实现本表内数据的查询，还可以实现跨表查询，其语法结构为：=VLOOKUP（查询的值，查询的表名!查询范围，返回的列数，匹配模式）。

三、核对“账面数据”和“库存数据”。

方法：

1、插叙新的入住列。

2、选定目标单元格。

3、输入公式：=IFERROR(IF(C3<>D3,"错误",""),"无数据")。

4、Ctrl+Enter填充。

解读：

1、用IF(C3<>D3,"错误","")判断C3和D3的值是否不相等，如果相等，返回“错误”两个字，如果相等，返回空。

2、用IFERROR函数来判断单元格是否存在错误形式，如果存在，则返回“无数据”。

其实无论是计算机考试中还是我们平时的工作中，都是需要用到查询函数，因为不仅是考试考点，学会使用它会使我们的工作简单许多。

vlookup函数通常用于在excel工作簿中搜索某个单元格区域的第一列，然后返回该区域相同行上任何单元格中的值。

当然在使用vlookup函数之前，我们必须对vlookup函数有基本的认识和了解，所以今天小编就来介绍一下vlookup函数的语法，大家可以跟着小编来学习一下。

函数的书写格式：

Vlookup（lookup|_value,table_array,col_index_num,range_lookup）

搜索表区域首列满足条件的元素，确定待检索单元格在区域中的行序号，再进一步返回选定单元格的值。默认情况下，表是以升序排序的。

vlookup函数参数说明如下：

lookup|_value：在表格或区域的第一列中要搜索的值。

table_array：包含数据的单元格区域，即要查找的范围。

col_index_num：参数中返回的搜寻值的列号。

range_lookup：逻辑值，指定希望Vlookup查找精确匹配值（0）还是近似值（1）。

我们已经对vlookup函数有了一个基本的认识，至少语法结构是没什么问题的，所以今天小编就要和大家说一说实际操作的步骤了。

我们今天就利用vlookup函数来查找公司员工信息，大家可以跟着小编来操作一下。 我们需要双击打开excel软件，随意选中一个空白单元格，在编辑框中输入 “=vlookup(”，单击函数栏左边的fX按钮。

在弹出的“函数参数”对话框中，我们想要查询北京主管的员工编号，在lookup_value栏中输入“北京”对应单元格。

在table_array栏中选中A4:C9单元格内容，在col_index_num栏中输入3（表示选取范围的第三列），在range_lookup栏中输入0（表示精确查找）。

单击确定按钮后，我们可以看到，已经查找到北京经理的员工编号了。

《粉红女郎》要重拍，里面的万人迷令人记忆犹新，她风情万种，美丽妖娆，是个不折不扣的感情专家，可以一语中的地找到你的情感真相！

在Excel中，也有个著名的万人迷，它就是VLookup，只要是找东西，大家首先想到的就是它。

先来个最基本的查找当开胃菜：

Vlookup语法：

Vlookup(根据什么找,到哪里找,找哪个,怎么找)

注意：

1、“根据什么找”中的“什么”一定要位于“到哪里找”区域的第1列！

2、若从“到哪里找”区域中找到多个“什么”，则仅返回第1个找到的“什么”对应的东西；

3、“找哪个”不是实际列号，而是“到哪里找”区域中的第几列，其中，“什么”位于第1列，以此类推；

4、“怎么找”包含0（精确查找）、1或省略（模糊查找），其中，模糊查找时，首列必须升序排列；

公式分析：

= VLOOKUP(G3,C3:E12,2,0)

根据G3单元格的查找客户（第1参数），到C3:E12单元格区域中找（第2参数），其中第1列是客户名称列，即查找依据所在的列，要查找第2列的数据值（第3参数），即查找客户的付款金额，按精确查找的方式进行查找（第4参数），即客户名称与查找客户要完全相同；

再看以下数据，要根据订单号，查找该订单的所有资料，你怎么做？

在I、J、K、L列分别输入VLOOKUP公式，当然可以，但要是数据列较多，就比较麻烦了，告诉你一个公式就能搞定：

公式分析：

=VLOOKUP($H$3,$B$3:$F$12,COLUMN(B1),0)

1、需要在“客户名称”列返回查找区域第2列的值，在“付款金额”列返回查找区域第3列的值……，以此类推，为了实现一个公式就能在不同的列返回对应的数据，我们需要让VLookup的第3参数，即“找哪个”变成动态的，在I3单元格第3参数为2，在J3单元格第3参数为3，那么，COLUMN函数就能帮上忙了：

2、COLUMN函数可以返回指定单元格的列号，COLUMN(B1)返回B1单元格的列号2，由于使用的是单元格相对引用，随着公式向右复制，J3单元格会变成COLUMN(C1)，即返回C1单元格的列号3；

3、再以COLUMN函数的结果作为VLookup函数的第3参数，就能实现让“找哪个”变成动态的了，刚好满足了我们的要求。

想根据条件找到多个符合的数据，VLookup可以做到吗？比如：一个订单号记录了订购的多款产品，想根据订单号查找该订单下的所有产品，怎么做呢？

第1步：首先我们要构造一个辅助序号列，在A3单元格输入公式，并下拉复制到A12单元格：

=(B3=$G$3)+A2

公式分析：

l B3=$G$3：判断B3单元格的销售订单号是否等于G3单元格的查找订单号，若相同，则返回true，否则返回false；

l 逻辑值再与A2相加，true相当于1，false和空相当于0，得到截止当前行，查询订单号出现的总次数；

第2步：在H3单元格输入公式：

=VLOOKUP(ROW(A1),$A$3:$C$12,3,0)

公式分析：

1、为了查找订单号对应的多个产品，根据下图可以看出，只要查找到1~10（10为查询数据总行数，为某订单可能包含的最多产品数）在A列中出现的行位置，再找到相应的第3列即C列的订单产品，就搞定了。

2、我们需要将查找到的第1个产品放入H3列，第2个产品放入H4列，依次向下，直至填完查找订单号包含的所有订单产品；

3、于是，我们在H3单元格查找A列的序号1，即查询订单号第1次出现的位置，并返回该订单下的第1个产品，H4单元格查找序号2……

4、而ROW函数恰好可以满足以上要求，在H3单元格使用ROW(A1)作为VLookup的查找条件，ROW(A1)可以返回指定单元格A1对应的行号1，随着公式向下复制，由于A1为相对引用，到H4单元格将变为以ROW(A2)即2作为查询条件；

第3步：为H列处理错误值，修改H3单元格的公式，并下拉复制到H12：

=IFERROR(VLOOKUP(ROW(A1),$A$3:$C$12,3,0),"")

公式分析：

1、我们并不确定每个查询订单号下到底有多少个产品，因此，我们将上一步的公式从H3单元格一直复制填充到H12，共10格，即查询数据区域的总行数，意思是，某个订单号下，最多最多可能包含的产品个数；

2、但一般来说，某个查询订单号下，不会有这么多个产品的，于是上一步的公式就出现了下面的情况：

3、这些“#N/A”就是没找到第n个产品时出现的错误值，IFERROR函数的作用就是屏蔽掉它们：若VLookup的结果出现错误值，则显示空值””。

好了，这回的VLookup详解就先到这里，今后一定还会跟大家分享更多，相信你已经get到它的要点了，那就找个机会用起来吧！

本文章由丹丹老师编撰，版权归Excel.live所有！

vlookup函数是excel表格中高级的用法，通过vlookup函数我们可以调用符合条件的数据，在大量调用时可以节省我们查找复制excel数据的时间，今天我就教下大家vlookup函数的使用方法吧。

vlookup函数的使用方法

如图我准备了一张员工入职时间表，员工有非常多，如果我要在这里面一一找出张三李四王五等人的入职时间的话，可以通过查找黏贴的方式，但是这样的效率就很低了，特别是要找的人多的话，那使用vlookup函数是最简单的方法。

接下来我们就需要根据vlookup函数的公式来做调整，使vlookup函数的基本公式变成我们excel表格需要的公式，vlookup函数的语法结构是VLOOKUP(lookup_value,table_array, col_index_num, [range_lookup])。

如我们的表格，我们要查找的是人名，那么对应的lookup_value就是D2张三，而table_array查找区域就是A2到B14这个区域，那么table_array就写$A$2:$B$14。

接下来我们再看col_index_num，这个就是返回值代表在查找区域中返回哪一列的数据，而入职时间在第二列，所以这里就填写2就可以了。而[range_lookup]代表精确查找，我们输入0就可以了。

这样子我们就限定了E2是取A2到B14这个区域的入职时间，那么我们输入完公式后，直接按回车键运行一下，就可以取到姓名为张三的入职时间了。

取完一个正确的数据后，我们要把公式应用到下方的单元格中，只需要将鼠标移动到E2单元格的右下角，鼠标符号变成十字加号后按住鼠标左键往下拉就可以了。

这样vlookup函数的使用方法就教大家了，是不是觉得很简单，只要记好vlookup函数的公式，大家都能成为excel高手。

霸气走火就是我，我就是百度经验作者：ixlxt7Xzsl7，百度经验和百家号首发原创内容分享。