Left函数是指从一个文本字符串的左边第一个字符开始返回指定个数的字符。其公式是LEFT(text,num_chars)。其中text表示我们要截取的那个内容，num_chars表示要截取多少内容。

举例说明：

一、使用方法

1、要提取下表中班级学生的姓氏

2、按照中国的传统习俗，姓氏应该放在左边第一位，因此采用left方法，在H2中输入公式=left（A2,1)，由于姓氏是排在第一位的，因此后面的数字就是1。

3、点击“Enter”，就会得到班级学生的姓氏

二、注意事项

1、left(text,num_chars)，其中num_chars的值必须大于等于0.小于0时直接报错，等于0时为空值。

num_chars的值小于0

num_chars的值等于0

2、如果num_chars大于文本长度，则返回所有文本。很明显，A2：A13中每个单元格的字符都不超过3，所以当后面的数字超过3了，使用LEFT函数得到的结果还是原来的文本

（Right函数恰恰相反，小编在此就不给大家演示了，感谢大家阅读我的文章，欢迎大家批评指正）

CountIfs函数在 Excel 中用于组合多个条件区域/条件对，以弥补CountIf函数只能组合一个条件区域/条件对的不足。如果要统计同时满足两个条件的某种产品个数，用 CountIf 需要用数组组合条件，比较麻烦，而用 CountIfs 组合两个条件区域/条件对即可，比较简单明了。CountIfs 与 CountIf 一样，条件中可以用逻辑值与通配符（问号和星号）。以下就是 Excel CountIfs函数的使用方法及实例，包括不为空和多个条件的实例的具体操作方法，实例中操作所用版本均为 Excel 2016。

一、CountIfs函数语法

1、表达式：COUNTIFS(Criteria_Range1, Criteria1, [Criteria_Range2, Criteria2], …)

中文表达式：COUNTIFS(条件区域1, 条件1, [条件区域2, 条件2], …)

2、说明：

A、条件区域和条件组成一个条件区域/条件对，至少包含一个条件区域/条件对，最多只能有 127 个条件区域/条件对。

B、如果有多个条件区域，每个条件区域必须有相同的行数和列数，它们可以不相邻。

C、如果单元格为空，CountIfs 将它的值视为 0。

D、在条件中可以使用通配符问号（?）和星号（*），问号表示任意一个字符，星号表示一个或一串字符；如果要查找问号或星号，需要在它们前面加转义字符~，例如查找问号，表达式可以这样写 ~?。

二、CountIfs函数的使用方法及实例

(一）只有一个条件区域/条件对

1、假如要统计“销售地区”为“广州”的个数。选中 D13 单元格，输入公式 =COUNTIFS(D2:D12,"广州")，按回车，返回统计结果 4；操作过程步骤，如图1所示：

2、公式说明：公式 =COUNTIFS(D2:D12,"广州") 只有一个条件区域/条件对，条件区域为 D2:D12，条件为“广州”，是用文字作条件，并且可以在文字前面加等号，即 =COUNTIFS(D2:D12,"=广州")；另外，仅数值也可以作条件。

（二）有两个条件区域/条件对

1、假如要统计“销售地区”为“广州”且销量大于等于 500 的服装件数。把公式 =COUNTIFS(D2:D12,"广州",F2:F12,">=500") 复制到 F13 单元格，按回车，返回统计结果为 3，操作过程步骤，如图2所示：

2、公式中第一个条件区域/条件对为 D2:D12,"广州"，第二个条件区域/条件对为 F2:F12,">=500"，即先统计 D2:D12 中为“广州”的个数，再统计 F2:F12 中销量大于等于 500 的个数；条件2 ">=500" 也可以用 ">="&500。

（三）用通配符问号与星号组合条件

1、假如要统计以“T恤”结尾、以“白”字开头、仅有三个字的服装件数；把公式 =COUNTIFS(B2:B12,"*T恤",B2:B12,"白*",B2:B12,"???") 复制到 B13 单元格，如图3所示：

2、按回车，返回结果 1，如图4所示：

3、如果要统计以一个指定字（或词）开头且以另一个指定字（或词）结果的服装件数，例如统计以“粉”字开头且以“衬衫”结尾的服装件数，公式可以这样写：=COUNTIFS(B2:B12,"粉*衬衫")。

（四）条件为空、不为空和不等于

1、假如要统计“分类”不等于“衬衫”且“销量”为空的服装件数。把公式 =COUNTIFS(C2:C12,"<>衬衫",F2:F12,"") 复制到 F13 单元格，按回车，返回统计结果 2，操作过程步骤，如图5所示：

2、如果要统计“分类”不等于“衬衫”且“销量”不为空的服装件数，则公式可以这样写：=COUNTIFS(C2:C12,"<>衬衫",F2:F12,"<>"&"")，如图6所示：

（五）CountIfs 与 Average 组合使用

1、假如要统计“分类”为“T恤”、销售地区为“杭州”且大于平均销量的服装件数。把公式 =COUNTIFS(C2:C12,"T恤",D2:D12,"杭州",F2:F12,">"&AVERAGE(F2:F12)) 复制到 F13 单元格，按回车，返回结果 2，操作过程步骤，如图7所示：

2、在条件中，只需用 & 连接 > 与求平均值的函数 Average，如果要用其它函数也是一样的连接方法。

三、CountIfs函数与CountIf函数用多条件的比较

1、CountIfs函数可轻松组合多个条件，而CountIf函数需要用数组才能组合多个条件。假如要统计销量大于等于 500 且小于等于 800 的服装件数。用 CountIfs函数公式可这样写：=COUNTIFS(F2:F12,">=500",F2:F12,"<=800")，而用 CountIf函数，公式需要这样写：=SUM(COUNTIF(F2:F12,{">=500",">800"})*{1,-1})，两个公式统计结果都为 4；操作过程步骤，如图8所示：

2、用CountIfs函数写要简单得多，且它们的计算顺序是一样的，都先统计满足第一个条件的个数，再统计满足第二个条件的件数，因此遇到多个条件的情况，可以先选用CountIfs函数。

Excel曾经一度出现了严重Bug，主要有两种比较悲催的情况，首先是这种：

更加悲催的是这种：

言归正传，今天和大家分享一组常用函数公式的使用方法：职场人士必须掌握的12个Excel函数，用心掌握这些函数，工作效率就会有质的提升。

建议收藏备用着，有时间多学习操练下。

目录：数字处理、判断公式、统计公式、求和公式、查找与引用公式、字符串处理公式、其他常用公式等

一、数字处理

01.取绝对值

=ABS(数字)

02.数字取整

=INT(数字)

03.数字四舍五入

=ROUND(数字,小数位数)

二、判断公式

04.把公式返回的错误值显示为空

公式：C2

=IFERROR(A2/B2,"")

说明：如果是错误值则显示为空，否则正常显示。

05.IF的多条件判断

公式：C2

=IF(AND(A2<500,B2="未到期"),"补款","")

说明：两个条件同时成立用AND,任一个成立用OR函数。

三、统计公式

06.统计两表重复

公式:B2

=COUNTIF(Sheet15!A:A,A2)

说明：如果返回值大于0说明在另一个表中存在，0则不存在。

07.统计年龄在30~40之间的员工个数

=FREQUENCY(D2:D8,{40,29})

08.统计不重复的总人数

公式：C2

=SUMPRODUCT(1/COUNTIF(A2:A8,A2:A8))

说明:用COUNTIF统计出每人的出现次数，用1除的方式把出现次数变成分母，然后相加。

09.按多条件统计平均值

F2公式

=AVERAGEIFS(D:D,B:B,"财务",C:C,"大专")

10.中国式排名公式

=SUMPRODUCT(($D$4:$D$9>=D4)*(1/COUNTIF(D$4:D$9,D$4:D$9)))

四、求和公式

11.隔列求和

公式：H3

=SUMIF($A$2:$G$2,H$2,A3:G3)

或

=SUMPRODUCT((MOD(COLUMN(B3:G3),2)=0)*B3:G3)

说明：如果标题行没有规则用第2个公式

12.单条件求和

公式：F2

=SUMIF(A:A,E2,C:C)

说明：SUMIF函数的基本用法

13.单条件模糊求和

公式：详见下图

说明：如果需要进行模糊求和，就需要掌握通配符的使用，其中星号是表示任意多个字符，如"*A*"就表示a前和后有任意多个字符，即包含A。

14.多条求模糊求和

公式：C11

=SUMIFS(C2:C7,A2:A7,A11&"*",B2:B7,B11)

说明：在sumifs中可以使用通配符*

15.多表相同位置求和

公式：b2

=SUM(Sheet1:Sheet19!B2)

说明：在表中间删除或添加表后，公式结果会自动更新。

16.按日期和产品求和

公式：F2

=SUMPRODUCT((MONTH($A$2:$A$25)=F$1)*($B$2:$B$25=$E2)*$C$2:$C$25)

说明：SUMPRODUCT可以完成多条件求和

五、查找与引用公式

17.单条件查找

公式1：C11

=VLOOKUP(B11,B3:F7,4,FALSE)

说明：查找是VLOOKUP最擅长的，基本用法

18.双向查找

公式：

=INDEX(C3:H7,MATCH(B10,B3:B7,0),MATCH(C10,C2:H2,0))

说明：利用MATCH函数查找位置，用INDEX函数取值

19.查找最后一个符合条件记录

公式：详见下图

说明：0/(条件)可以把不符合条件的变成错误值，而lookup可以忽略错误值

20.多条件查找

公式:详见下图

说明:公式原理同上一个公式

21.指定非空区域最后一个值查找

公式;详见下图

说明：略

22.区间取值

公式：详见下图

公式说明：VLOOKUP和LOOKUP函数都可以按区间取值，一定要注意，销售量列的数字一定要升序排列。

六、字符串处理公式

23.多单元格字符合并

公式：c2

=PHONETIC(A2:A7)

说明：Phonetic函数只能对字符型内容合并，数字不可以。

24.截取除后3位之外的部分

公式：

=LEFT(D1,LEN(D1)-3)

说明：LEN计算出总长度,LEFT从左边截总长度-3个

25.截取 - 之前的部分

公式:B2

=Left(A1,FIND("-",A1)-1)

说明：用FIND函数查找位置，用LEFT截取。

26.截取字符串中任一段

公式:B1

=TRIM(MID(SUBSTITUTE($A1," ",REPT(" ",20)),20,20))

说明:公式是利用强插N个空字符的方式进行截取

27.字符串查找

公式：B2

=IF(COUNT(FIND("河南",A2))=0,"否","是")

说明: FIND查找成功，返回字符的位置，否则返回错误值，而COUNT可以统计出数字的个数，这里可以用来判断查找是否成功。

28.字符串查找一对多

公式：B2

=IF(COUNT(FIND({"辽宁","黑龙江","吉林"},A2))=0,"其他","东北")

说明：设置FIND第一个参数为常量数组，用COUNT函数统计FIND查找结果

七、日期计算公式

29.两日期间隔的年、月、日计算

A1是开始日期（2011-12-1），B1是结束日期(2013-6-10)。计算：

相隔多少天？=datedif(A1,B1,"d") 结果：557

相隔多少月? =datedif(A1,B1,"m") 结果：18

相隔多少年? =datedif(A1,B1,"Y") 结果：1

不考虑年相隔多少月？=datedif(A1,B1,"Ym") 结果：6

不考虑年相隔多少天？=datedif(A1,B1,"YD") 结果：192

不考虑年月相隔多少天？=datedif(A1,B1,"MD") 结果：9

datedif函数第3个参数说明：

"Y" 时间段中的整年数。

"M" 时间段中的整月数。

"D" 时间段中的天数。

"MD" 天数的差。忽略日期中的月和年。

"YM" 月数的差。忽略日期中的日和年。

"YD" 天数的差。忽略日期中的年。

30.扣除周末的工作日天数

公式：C2

=NETWORKDAYS.INTL(IF(B2

说明：返回两个日期之间的所有工作日数，使用参数指示哪些天是周末，以及有多少天是周末。周末和任何指定为假期的日期不被视为工作日

八、其他常用公式

31.创建工作表目录的公式

把所有的工作表名称列出来，然后自动添加超链接，管理工作表就非常方便了。

使用方法：

第1步：在定义名称中输入公式：

=MID(GET.WORKBOOK(1),FIND("]",GET.WORKBOOK(1))+1,99)&T(NOW())

第2步、在工作表中输入公式并拖动，工作表列表和超链接已自动添加

=IFERROR(HYPERLINK("#'"&INDEX(Shname,ROW(A1))&"'!A1",INDEX(Shname,ROW(A1))),"")

32.中英文互译公式

=FILTERXML(WEBSERVICE("http://fanyi.youdao/translate?&i="&A2&"&doctype=xml&version"),"//translation")

excel中的函数公式千变万化，今天就整理这么多了。如果你能掌握一半，在工作中也基本上遇到不难题了。

建议收藏备用着，有时间多学习操练下。

CountIf函数是 Excel 中根据条件统计个数的函数，它只有两个参数，一个是统计范围，另一个是统计条件。一般情况下，只用一个统计条件，但也可以用数组组合多重条件。在条件中，既可以用小于等于大于号，又可以通配符问号和星号，还可以用其它函数。以下就是 Excel CountIf函数的使用方法，分为一个条件基本使用方法和用数组组合多重条件使用实例的具体操作方法，实例中操作所用版本均为 Excel 2016。

一、CountIf函数语法

1、表达式：COUNTIF(Range, Criteria)

中文表达式：COUNTIF(统计范围, 条件)

2、说明：

A、条件不能超过 255 个字符，否则会返回错误。

B、统计文本个数时，不能包含前导空格与尾部空格，也不能出现直引号与弯引号不一致和非打印字符；否则，可能返回不可预期的值。

C、在条件中可以使用通配符问号（?）和星号（*），问号表示任意一个字符，星号表示一个或一串字符；如果要查找问号或星号，需要在它们前面加转义字符~，例如查找问号，表达式应该这样写 ~?。

二、Countif函数的使用方法

(一）统计指定文字个数

1、假如要统计“小类”中“T恤”的个数。选中 C13 单元格，输入公式 =COUNTIF(C2:C12,"T恤")，按回车，返回统计结果 4；操作过程步骤，如图1所示：

2、公式说明：公式 =COUNTIF(C2:C12,"T恤") 中“统计范围”为 C2:C12，条件为“T恤”，也就是说单文字也可以作为条件。

（二）用 >= 或 < 组合条件

1、假如要统计价格大于等于 90 的服装件数。把公式 =COUNTIF(E2:E12,">=90") 复制到 E13 单元格，按回车，返回统计结果为 6，操作过程步骤，如图2所示：

2、公式中的条件 ">=90" 也可以这样写：">="&90。如果要统计价格小于等于 90 的服装件数，公式可以这样写：=COUNTIF(E2:E12,"<="&90)，如图3所示：

按回车，统计结果返回 5，如图4所示：

如果要统计价格不等于 90 的服装件数，只需把公式 =COUNTIF(E2:E12,">=90") 条件中的 >= 改为 <>，则公式变为 =COUNTIF(E2:E12,"<>90")。

（三）用通配符问号与星号组合条件

假如要统计以“衬衫”结尾的服装件数；把公式 =COUNTIF(B2:B12,"*衬衫") 复制到 B13 单元格，按回车，返回结果 5。假如要统计以“粉红”开头的服装件数，把公式 =COUNTIF(B2:B12,"粉红*") 复制到 B13 单元格，按回车，返回统计结果 2。假如要统计名称为四个字的服装件数，把公式 =COUNTIF(B2:B12,"????") 复制到 B13，按回车，返回统计结果 8。假如要统计“前面四个字 + T恤”组合的服装名称，把公式 =COUNTIF(B2:B12,"????T恤") 复制到 B13，按回车，返回统计结果 1；操作过程步骤，如图5所示：

（四）CountIf 与 Average 组合使用

1、假如要统计大于平均销量的服装件数。把公式 =COUNTIF(F2:F12,">"&AVERAGE(F2:F12)) 复制到 F13 单元格，如图6所示：

2、按回车，返回结果 5。

3、公式说明：公式 =COUNTIF(F2:F12,">"&AVERAGE(F2:F12)) 中条件为 ">"&AVERAGE(F2:F12)，AVERAGE 是求平均值函数，条件的意思是：求大于服装销量的平均值。

三、CountIf函数用数组组合多重条件的使用实例

1、假如要统计销量大于等于 350 且小于等于 750 的服装件数。把公式 =SUM(COUNTIF(F2:F12,{">=350",">750"})*{1,-1}) 复制到 F13 单元格，按回车，则返回统计结果 4；操作过程步骤，如图7所示：

2、公式说明：CountIf 中的条件 {">=350",">750"} 是一个数组，数组中包含两个条件，一个是 ">=350"，另一个是 ">750"，这里要求的是<= 750，为何第二个条件是 >750？这决定于 CountIF 的计算顺序，它先统计 F2:F12 中满足第一个条件（>=350）的服装件数（结果为 8），再统计满足第二个条件（>750）服装件数（结果为 4），然后再把两个结果加起来，这样结果为 12，显然不对，因此后面再加 *{1,-1}，这样用第一个条件的统计结果 8 * 1，用第二个条件的统计结果 4 * -1，再把两个结果相加，即 8-4，最终等于 4；公式求值过程，如图8所示：

3、其它数组组合条件分别如下：

A、大于 350 且小于 750：=SUM(COUNTIF(F2:F12,{">350",">=750"})*{1,-1})

B、大于等于 350 且小于 750：=SUM(COUNTIF(F2:F12,{">=350",">=750"})*{1,-1}) 或 =SUM(COUNTIF(F2:F12,">="&{350,750})*{1,-1})

C、大于 350 且小于等于 750：=SUM(COUNTIF(F2:F12,{">350",">750"})*{1,-1}) 或 =COUNTIF(F2:F12,">350"）- COUNTIF(F2:F12,">750"）

在Excel中，offset函数是一个引用函数，表示引用某一个单元格或者区域。由于在日常做一些组合函数中经常用到，需要熟练掌握。

offset函数通过上下左右偏移得到新的区域的引用，返回的引用可以是一个单元格也可以是一个区域，并且可以引用指定行列数的区域。

它的语法形式是 OFFSET(reference,rows,cols,height,width)，reference是指初始引用单元格或区域参考、rows,cols分别是偏移行数和列数、height,width是指偏移后新的单元格或区域的大小。

下面就以一个实例应用做解释 。

一、以A1单元格作为参考系，向下移动2行，向右移动2列，我们可以直接找到引用的单元格是 C3，结果是97。

在E3单元格输入公式=OFFSET(A1,2,2,1,1)，其中A1是参考系，接着的2,2分别表示下，右移动的行数和列数，同样向上，左则是负数。最后面的1,1表示引用的区域大小是一行一列，也就是一个单元格。当然函数公式中最后面的1,1可以省略=OFFSET(A1,2,2,1,1)和=OFFSET(A1,2,2)效果一样。

二、以区域做参考系

还是这个例子，我们以A1到B2的区域作为参考系，来引用下移2行，右移动1列的2行2列的区域。

在E3输入公式=OFFSET(A1:B2,2,1,2,2)，其表示的意思与上面以单元格为参考系的基本一致，然后同时按下CTRL、SHIFT和ENTER三个键（因引用的是数组区域），组合键按下后E3的公式变成了｛=OFFSET(A1:B2,2,1,2,2)｝。这个时候E3单元格中显示的是引用到区域中第一行第一列的单元格，此时将鼠标放在该单元格右下角出现十字的时候点住，右拉到2列，再接着点住下拉到2行，那么此时所有引用的区域就出现了。如下图所示。

今天文章主题仍然是if函数，在上两篇文章excel关于函数if的巧妙运用excel关于if函数的嵌套使用中，第一篇文章，我们介绍了怎样运用if函数在两种不同结果之间进行判断计算的操作过程，第二篇文章中我们更近一步，函数if与函数if本身的嵌套使用，从而运用if函数解决了应对三种不同结果进行判断的解决方法。（今天这篇文章承接上面两篇文章的内容而来，感兴趣的朋友可以通过链接去看看）。

今天我们再更进一步，介绍一下面对三种以上情况结果下，函数if的运用方法。咱们外甥打灯笼，照旧按老规矩来，运用实例来说话。

今天我们的实例是这样的，我们已知业务员的等级分为A级、B级、C级、D级四个等级，分别对应的奖金为10000元、9000元、8000元和7000元，现在我们有四个业务员，分别是丁一、牛二、张三、李四，他们正好对应了A级、B级、C级、D级四个等级，这时就要求我们运用if函数根据四个业务员的等级来判断他们各自的奖金。excel工作表具体如下所示：

具体操作方法一（方法一继承了文章“excel关于if函数的嵌套使用”中的方法）：

在G4单元格输入“=IF(F4="A级",10000,IF(F4="B级",9000,IF(F4="C级",8000,7000)))”（ps:if函数中的标点符号在英文输入法状态下输入），按回车键，得到业务员丁一的应发奖金数，然后通过填充柄拖拽的方式向下拖拽，我们就能到其他业务员的应发奖金数了。具体操作可参考下图：

方法评价：运用if函数三层嵌套的方式成功解决了现有问题，但是一旦面对答案更多的情况，肯定会让人难以忍受，而且在excel中最多只能嵌套七层，所以这种方法限制太大了。

具体操作方法二（方法二继承了文章“excel关于函数if的巧妙运用”中的方法，使用函数if最简单的方式进行叠加运算）：

在G4单元格输入“=IF(F4="A级",10000,0)+IF(F4="B级",9000,0)+IF(F4="C级",8000,0)+IF(F4="D级",7000,0)”，按回车键，得到业务员丁一的应发奖金数，然后通过填充柄拖拽的方式向下拖拽，我们就能到其他业务员的应发奖金数了。具体操作可参考下图：

方法评价：使用函数if最简单的方式进行叠加运算的方法成功解决了现有问题，且该方法excel并没有进行限制，仅仅需要不断进行复制并修改相关数据的方式就能进行叠加运算，但是局限性也相当明显，一旦面对答案太多的情况，就不再适用了。

具体操作方法三：方法三是真正实用的方法，需要运用到函数vlookup。

在G4单元格输入“=VLOOKUP(F4,$B$4:$C$7,2,0)”，按回车键，得到业务员丁一的应发奖金数，然后通过填充柄拖拽的方式向下拖拽，我们就能到其他业务员的应发奖金数了。具体操作可参考下图：

方法评价：与函数if的两种方法相比，面对答案太多的情况，函数vlookup的局限性大大减小，堪称相对完美的方法了。

今天的分享也就到此结束了。觉得对你们有用的小伙伴们请点赞关注吧！您的鼓励是我前进的动力，也希望擅长运用办公软件的小伙伴们能够不吝赐教，积极的留言，教会小编更多的excel运用的小技巧，欢迎一起来探讨学习！！

Offset函数是 Excel 中用于返回距指定单元格或单元格区指定行数和列数区域的引用；它共有五个参数，前三个为必选项，后两个为可选项；其中第一个参数为引用单元格或单元格区域；第二、三个参数分别为行数和列数，它们不能超过表格范围，否则会返回错误；另外，行数和列数还有正负之分，取值不同，引用区域也不同。Offset函数可与Sum函数、Match函数组合使用，例如与Sum函数组合求一片选定区域的和。以下就是 Excel Offset函数的使用方法及与Sum函数组合的具体操作实例，实例中操作所用版本均为 Excel 2016。

一、Excel Offset函数语法

1、表达式：OFFSET(Reference, Rows, Cols, [Height], [Width])

中文表达示：OFFSET(引用单元格, 行数, 列数, [返回引用高度], [返回引用宽度])

2、说明：

A、Reference 是对单元格或相邻单元格的引用，否则会返回 #VALUE 错误。

B、Rows 距引用单元格左右上角或下角的行数；当 Rows 为正数时，表示距引用单元格左下角的行数；当 Rows 为负时，表示距引用单元格左上角的行数；如果指定的 Rows 超出表格范围，将返回 #REF! 错误。

C、Cols 距引用单元格左边或右边的行数；当 Cols 为正时，表示距引用单元格右边的行数；当 Cols 为负时，表示距引用单元格左边的行数。如果指定的 Cols 超出表格范围，也返回 #REF! 错误。

D、Height 和 Width 为可选项，Height 表示返回引用的高度；Width 表示返回引用的宽度；当引用一个单元格时，Height 和 Width 都为1；当引用多个单元格时，Height 和 Width 可以都指定与引用单元格同样的高度和宽度，也可指定为大于引用单元格的高度和宽度。如果省略 Height 和 Width，将返回与引用单元格同等大小的区域。

二、Excel Offset函数的使用方法及实例

（一）引用一个单元格

1、返回引用单元格左下角的指定值

A、把公式 =OFFSET(D5,2,-2,1,1) 复制到 H2 单元格，按回车，则返回“黑色T恤”，操作过程步骤，如图1所示：

B、公式说明：引用单元格为 D5；行数为 2，列数为 -2，高度和宽度都为 1，公式的意思是：返回 D5 左下角距 D5 2 行与两列的单元格的引用；符合 Rows 为正时，返回引用单元格左下角的值；Cols 为负时，返回引用单元格左边的值。返回一个单元格的值，把高度和宽度都设置为 1 或省略，否会发生错误。

2、返回引用单元格左上角的指定值

A、把上面公式 =OFFSET(D5,2,-2,1,1) 中的 2 改为 -2，就可以返回引用单元格左上角的指定值，操作过程步骤，如图2所示：

B、说明：公式改为 =OFFSET(D5,-2,-2,1,1) 后，按回车，返回“长袖白衬衫”，正是 D5 左上角单元格的值，且距 D5 2 行 2 列。

3、返回引用单元格右下角的指定值

A、把上面公式 =OFFSET(D5,2,-2,1,1) 中的 -2 改为 2，则公式变为 =OFFSET(D5,2,2,1,1)，如图3所示：

B、按回车，返回 872，正是在 D5 右下角的值且距 D5 2 行 2 列，如图4所示：

（二）对多个单元格的引用并求和

1、把公式 =SUM(OFFSET(D5:E6,2,2,2,2)) 复制到 H2 单元格，按回车，返回结果 8021，操作过程步骤，如图5所示：

2、公式说明：

A、公式先用 OFFSET(D5:E6,2,2,2,2) 选定一片单元格区域，所选定的区域为在 D5:E6 右下角且距 D5:E6 左上角的顶点 2 行 2 列，也就是 F7:G8 这四个单元格，如图6所示：

B、为什么是 F7:G8 这四个单元格？因为高度和宽度都为 2。选定单元格后，再用 Sum 求它们的和，所以结果为 8021。

3、把高度和宽度都改为 3，则公式变为 =SUM(OFFSET(D5:E6,2,2,3,3))，此时，OFFSET(D5:E6,2,2,3,3) 选中的单元格区域为 F7:H9，如图7所示：

按回车，返回结果为 10546，如图8所示：

由此可知：返回的高度和宽度不必与引用单元格 D5:E6 一致。

4、把高度和宽度都改为 -3，则公式变为 =SUM(OFFSET(D5:E6,2,2,-3,-3))，此时，OFFSET(D5:E6,2,2,-3,-3) 选中的单元格区域为 D5:F7，如图9所示：

按回车，返回结果为 5398，如图10所示：

由此可知：当高度和宽度都变为负数时，返回的单元格区域会向左移。

前期我们讲了

满足某个条件下求出所需值的if；

两个条件及以上只要满足其中1个条件即可求出所需值的or；

今天，给大家介绍的是同时满足两个及以上的条件求出所需值的and

视频讲解

文字详解

案例：每门课程都在80分及以上值为"TRUE"，反之"FALSE"。

公式使用：AND(B3>=80,C3>=80)

鼠标放置D3单元格右下角，变为黑色十字，双击往下自动填充公式

结果：

以上就是and函数的用法，有什么不明白的地方欢迎在下方留言，我们将及时给你答复~~

下期你最想学习哪个函数

也欢迎在底下给我们留言

在 Excel 中，Match函数用于返回查找值在数组的位置，它共有三个参数，分别为 lookup_value、lookup_array 和 match_type；其中 match_type 有三个参数，即 1、0、-1，当取不同值时返回不同的结果，其中取 0 时，可用通配符问号（?）和星号（*）进行模糊查找。Match函数除单独使用外，还常常与Index函数一起使用。以下就是Match函数的使用方法及与Index组合使用实例的具体操作方法，实例中操作所用版本均为 Excel 2016。

一、Excel Match函数语法

1、表达式：MATCH(lookup_value, lookup_array, [match_type])

中文表达式：MATCH(查找值, 查找数组, [查找类型])

2、说明：

A、Match函数用于返回 lookup_value 在数组中的位置；lookup_value 和 lookup_array 是必选项，match_type 是可选项；如果省略 match_type，则默认值为 1。

B、match_type 的取值说明：取 1 表示查找小于或等于查找值 lookup_value 的最大值，返回该值在数组中的位置，要求数组按升序排序；取 0 表示查找等于 lookup_value 的第一个值，返回该值在数组中的位置，不要求数组按升序或降序排序；取 -1 表示查找大于或等于 lookup_value 的最小值，返回该值在数组中的位置，要求数组按降序排序。

C、当 match_type 为 0 且 lookup_value 是文本，可在 lookup_value 中使用通配符“问号 (?) 和星号 (*)”；问号表示任意一个字符，星号表示任意一个或一串字符；如果要查找问号或星号，需要在它们前加转义波形符（~）。

二、Excel Match函数的使用方法

（一）match_type 取 1（或省略）的使用实例

1、假如要查找服装销量表中价格为 80 与 95 元在 E 列中的位置。首先把 E 列按升序排序，框选 E2:E12，选择“数据”选项卡，单击“升序”，在弹出的“排序提醒”窗口中，选择“扩展选定区域”，单击“确定”，则表格记录按价格升序排序；在 G2 中输入公式 =MATCH(80,E2:E12)，按回车，则返回 80 在 E2:E12 中的位置 2；再在 G3 中输入公式 =MATCH(95,E2:E12,1)，按回车，则返回 5，操作过程步骤，如图1所示：

2、说明：公式 =MATCH(80,E2:E12) 和 =MATCH(95,E2:E12,1)，一个省略 1，另一个未省略，都表示查找小于或等于 lookup_value 的最大值；80 在 E2:E12 中有，因此返回它所在的位置 2，95 在 E2:E12 中没有，所以返回小于它的最大值 89 所在位置，E2:E12 中有两个 89，返回的是第二个 89 的位置。

（二）match_type 取 0 的使用实例

1、查找数值

A、假如要查找价格为 89 元在 E 列中的位置。把公式 =MATCH(89,E2:E12,0) 复制到 G2 单元格，按回车，返回结果为 4，正是 89 在 E2:E12 中位置，操作过程步骤，如图2所示：

B、当 match_type 取 0 时，数组不用排序。如果查找数组中没有的值，则会返回 #N/A 错误，例如查找 87，如图3所示：

按回车后，返回 #N/A 错误，如图4所示：

2、用通配符问号（?）与星号（*）

A、假如要查找以“T恤”结尾的服装在 B 列中的位置。把公式 =MATCH("*T恤",B2:B12,0) 复制到 G2 单元格，按回车，返回结果 2，正是“绿色T恤”在 B2:B12 中的位置（返回的是第一个以“T恤”结束的服装在 B2:B12 中的位置），操作过程步骤，如图5所示：

B、假如要查找只有三个字的服装在 B 列中的位置。把公式 =MATCH("???",B2:B12,0) 复制到 G2 单元格，如图6所示：

按回车，返回结果 10，正是“白衬衫”在 B2:B12 中的位置，如图7所示：

（三）match_type 取 -1 的使用实例

1、假如要查找销量为 681 与 750 在 E 列中的位置。框选 F2:F12，选择“数据”选项卡，单击“降序”，在打开“排序提醒”窗口中，选择“扩展选项区域”，单击“确定”，将记录按销量降序排列；把公式 =MATCH(681,F2:F12,-1) 复制到 G2 单元格，按回车，返回结果为 5，正是 681 在 F:F12 中位置；把 681 改为 750，公式变为 =MATCH(750,F2:F12,-1)，按回车，结果为 4，操作过程步骤，如图8所示：

B、说明：第二个公式 =MATCH(750,F2:F12,-1) 要查找 750，由于 F2:F12 中没有这个值，因此返回大于或等于 750 的最大值 874 在 F2:F12 中的位置，所以结果为 4。

三、Excel Index 与 Match 组合使用实例

1、假如要查找价格为 65 元的服装的编号。把公式 =INDEX(A:A,MATCH(65,E1:E12,0)) 复制到 G2 单元格，按回车，返回结果为 WS-585，正是价格为 65 元的服装编号；操作过程步骤，如图9所示：

B、公式说明：

公式 =INDEX(A:A,MATCH(65,E1:E12,0)) 先用 MATCH(65,E1:E12,0) 返回价格为 65 元的服装在 E 列中的位置，结果为 8；再用Index函数返回行号为 8 的服装编号。

index函数的表达式为：INDEX(array, row_num, [column_num])，第一个参数为数组，第二个参数为行号，第三个参数为列号（可选）；示例中省略了列号，因此只返行号为的服装编号。如果既有行号又有列号，则返回行号与列号对应的值。

vlookup函数是excel表格中高级的用法，通过vlookup函数我们可以调用符合条件的数据，在大量调用时可以节省我们查找复制excel数据的时间，今天我就教下大家vlookup函数的使用方法吧。

vlookup函数的使用方法

如图我准备了一张员工入职时间表，员工有非常多，如果我要在这里面一一找出张三李四王五等人的入职时间的话，可以通过查找黏贴的方式，但是这样的效率就很低了，特别是要找的人多的话，那使用vlookup函数是最简单的方法。

接下来我们就需要根据vlookup函数的公式来做调整，使vlookup函数的基本公式变成我们excel表格需要的公式，vlookup函数的语法结构是VLOOKUP(lookup_value,table_array, col_index_num, [range_lookup])。

如我们的表格，我们要查找的是人名，那么对应的lookup_value就是D2张三，而table_array查找区域就是A2到B14这个区域，那么table_array就写$A$2:$B$14。

接下来我们再看col_index_num，这个就是返回值代表在查找区域中返回哪一列的数据，而入职时间在第二列，所以这里就填写2就可以了。而[range_lookup]代表精确查找，我们输入0就可以了。

这样子我们就限定了E2是取A2到B14这个区域的入职时间，那么我们输入完公式后，直接按回车键运行一下，就可以取到姓名为张三的入职时间了。

取完一个正确的数据后，我们要把公式应用到下方的单元格中，只需要将鼠标移动到E2单元格的右下角，鼠标符号变成十字加号后按住鼠标左键往下拉就可以了。

这样vlookup函数的使用方法就教大家了，是不是觉得很简单，只要记好vlookup函数的公式，大家都能成为excel高手。

霸气走火就是我，我就是百度经验作者：ixlxt7Xzsl7，百度经验和百家号首发原创内容分享。