在 Excel 中，一共有两个替换字符的函数，一个是Substitute函数，另一个是Replace函数；前者是用新字符替换旧字符，后者是用新字符替换指定字符数。Substitute函数既可以替换源文本中所有指定字符，又可以替换某个指定字符，并且还能嵌套使用以实现一次替换多个不同字符。以下是 Excel Substitute函数的使用方法，共包含5个实例，实例操作所用版本均为 Excel 2016。

一、Substitute函数语法

1、表达式：SUBSTITUTE(Text, Old_Text, New_Text, [Instance_Num])

中文表达式：Substitute(文本, 被替换文本，替换文本，[被替换文本序号])

2、说明：

Instance_Num 为可选参数，用于指定替换第几个 Old_Text，如果省略，则替换所有 Old_Text。另外，Substitute函数不支持通配符，例如星号 "*" 不是代表任意个字符，只代表星号本身。

二、Substitute函数的使用方法及实例

(一）省略 Instance_Num 参数一次替换多个相同字符

1、假如要把“excel替换字母,数字,汉字”中的半角逗号（,)替换为全角逗号（，）。选中 B1 单元格，输入公式 =substitute(a1,",","，")，按回车，则“excel替换字母,数字,汉字”中所有半角逗号被替换为全角逗号；操作过程步骤，如图1所示：

2、公式说明：公式 =substitute(a1,",","，") 省略了 Instance_Num 参数，则会用 New_Text（即全角逗号） 替换文本中所有 Old_Text（即半角逗号）。

(二）指定 Instance_Num 参数一次仅替换一个字符

1、假如要替换 ExcEl 2016 中第二个大写 E 为小写。选中 B1 单元格，把公式 =SUBSTITUTE(A1,"E","e",2) 复制到 B1，按回车，返回 Excel 2016；操作过程步骤，如图2所示：

2、公式把 Instance_Num 参数设置为 2，即用小写 e 替换 ExcEl 2016 中的第二个大写 E。

（三）只替换单个数字

1、假如有一串数字 25,10,5,16,51，要把里面的单个 5 替换掉，不能替换其它数字中的 5。选中 B1 单元格，把公式 =SUBSTITUTE(A1,",5,",",") 复制到 B1，按回车，则 5 被替换掉，操作过程步骤，如图3所示：

2、公式说明：公式 =SUBSTITUTE(A1,",5,",",") 把 Old_Text 参数设置为 ",5,"，主要是为了区别其它数字（如 25）中的 5，以避免把 25 中的 5 也替换掉；把 New_Text 设置为 ","，用于替换掉 5 后把 5 的前后数字分隔。

（四）Substitute函数嵌套使用，同时替换多个不同字符

1、替换通配符星号 * 和井号 #

A、假如要替换 25,*,10,#,51 中的 * 和 #。 选中 B1 单元格，把公式 =SUBSTITUTE(SUBSTITUTE(A1,"*,", ""),"#,","") 复制到 B1，如图4所示：

B、按回车，则 25,*,10,#,51 中 * 和 # 被替换掉，如图5所示：

C、公式说明：公式 =SUBSTITUTE(SUBSTITUTE(A1,"*,", ""),"#,","") 由两个 Substitute函数嵌套组成；里面的 SUBSTITUTE(A1,"~*", ",") 用于替换 *；外面的 Substitute函数用于替换 #，它的 Text 参数是替换 * 后的结果，即 SUBSTITUTE(A1,"*,", "") 返回的结果。

2、替换双引号

A、假如要把数字串 “25”,“10”,“51” 中的双引号去掉。选中 B1 单元格，把公式 =SUBSTITUTE(SUBSTITUTE(A1,"“", ""),"”","") 复制到 B1，按回车，则数字串中的左右双引号全被去掉，操作过程步骤，如图6所示：

B、公式说明：公式 =SUBSTITUTE(SUBSTITUTE(A1,"“", ""),"”","") 也由两个 Substitute函数嵌套组成；里面的 SUBSTITUTE(A1,"“", "") 用于去掉左双引号，外面的 Substitute 用于去掉右边的双引号。

三、SubStitute函数与Replace函数的区别

SubStitute函数是用一个（或一串）字符替换另一个字符（或一串），而Replace函数是用一个（或一串）字符替换指定的字符数。如果要替换括号中的一串不确定有多少个的字符，由于SubStitute函数不支持通配符，因此无法实现替换，但用Replace函数却能替换，方法如下：

1、假如要替换文本“excel2016（kh@ei8#9kdfk8*ksdkjd）”中的括号及其中的字符串为“函数”。把公式 =REPLACE(A1,FIND("（",A1),FIND("）",A1)-FIND("（",A1)+1,"函数") 复制到 B1 单元格，如图7所示：

2、按回车，则源文本中的括号及其中的字符串被替换为“函数”，返回 excel2016函数，如图8所示：

3、公式说明：

1、公式 =REPLACE(A1,FIND("（",A1),FIND("）",A1)-FIND("（",A1)+1,"函数") 由Replace函数和Find函数组成，Find函数用于找出左右括号在文本中的位置，Replace函数用于替换。

2、第一个 FIND("（",A1) 用于找出左括号在文本中的位置作为 Replace 的“开始替换位置”；FIND("）",A1) 用于找出右括号在文本中的位置，然后用右括号的位置减左括号的位置再加 1 作为 Replace 的“要查找的字符数”。

在工作中，单个函数的运用往往达不到我们想要的结果，我们一般是一个或这几个函数嵌套使用，今天小编就跟常用的函数嵌套组合，熟悉使用这些嵌套函数，可以提高工作效率哦。

组合一：LEN+SUBSTITUTE 计算一个单元格内有几个项目。

如下图所示，要计算每个部门的人数。

这样的表格大家应该比较熟悉：

在一个单元格内有多个姓名而且每个姓名之间用顿号隔开

C2单元格的函数公式为： =LEN(B2)-LEN(SUBSTITUTE(B2,"、",))+1

函数公式解释：

先用LEN函数计算出B列单元格的字符长度，然后再用SUBSTITUTE函数将顿号全部替换掉之后，计算替换后的字符长度。用字符长度减去替换后的字符长度，就是单元格内顿号的个数。

接下来，加1即是实际的人数。

组合二：VLOOKUP+MATCH 用于不确定列数的数据查询。

如下图所示，要根据B13单元格的姓名，在数据表中查询对应的项目。

C13单元格的函数公式为： =VLOOKUP(B13,A1:G9,MATCH(C12,1:1,),0)

函数公式解释：

如果数据表的列数非常多，在使用VLOOKUP函数时，还需要掰手指头算算查询的项目在数据表中是第几列，真是麻烦的很。先用MATCH函数来查询项目所在是第几列，然后VLOOKUP函数就根据MATCH函数提供的情报，返回对应列的内容。

组合三：MIN+IF 用于计算指定条件的最小值。

如下图所示，要计算生产部的最低分数。

G3单元格可以使用数组公式： =MIN(IF(A2:A9=F3,D2:D9))

函数公式解释：

先用IF函数判断A列的部门是否等于F3指定的部门，如果条件成立，则返回D列对应的分数，否则返回逻辑值FALSE：

{FALSE;45;FALSE;FALSE;FALSE;66;FALSE;72}接下来再使用MIN函数计算出其中的最小值。

备注：由于执行了多项计算，所以在输入公式时，要按Shift+ctrl+Enter键

MIN函数有一个特性，就是可以自动忽略逻辑值，所以只会对数值部分计算，最终得到指定部门的最低分数。

大家学会了吗？有问题欢迎到评论区骚扰哦！后期不断更新软件学习技巧干货，保证一看就会！如果觉得有用可以转发一下，谢谢大家支持！

Excel函数是我们经常在工作中会使用的，但是关于一下的这些excel函数知识点击以及函数的使用方法你都知道吗？不知道的话就赶快随着小编一起来看一下吧。

一、知识讲解：什么是函数公式、函数嵌套

1、什么是函数公式？

=A1+A2+A3 不是函数公式,只是公式

=SUM(A1:A2)*100 是使用了SUM函数的函数公式。

函数是公式中可以实现特定数据处理功能的结构。它由函数名、双括号和参数组成。上述公式中：SUM是函数名称、A1:A2是SUM的参数。

也有的函数没有参数，如:

=Today() 获得当天日期

注：没有参数，双括号必须带上。

2、什么是函数嵌套？

所谓函数嵌套，就是函数的参数由另一个函数表达式构成。如：

统计大于平均值的数字个数公式：

=Countif(A:A,">" & Average(A:A))

上述公式中，Average函数计算出的平均值，连接上>构成Countif函数的参数。

再如：提取字符串中 - 左边的字符

=Left(A1,Find("-",A1)-1)

二、Excel函数

1、SUMIF进行判断数值大小求和

公式=SUMIF(B3:B11,">80",B3:B11)，在销售额里面B3:B11，找到大于80的值，进行求和，公式最后的求和区域和条件区域一致的时候，可以不输入。

2、SUMPRODUCT函数

计算所有商品的总计，如图示：

在单元格"B10"中输入公式"=SUMPRODUCT(B2:B9,C2:C9)"，然后按"Enter"键，即完成计算。结果如下图示：

注意事项：

①数组参数必须具有相同的维数，否则，函数SUMPRODUCT 将返回错误值#VALUE!；

②SUMPRODUCT函数将非数值型的数组元素作为0 处理；

③SUMPRODUCT函数不支持“*”和“？”等通配符。

三、学习方法

1、身边多备几套函数教程。可以有图书、视频教程等资料。平时看看即可，更重要的是需要了解某个函数时备查。

2、多看多练。在实际工作中或网络论坛上多找一些函数题目练习，只有在实战中才能熟悉和记住函数的用法。遇到不懂的就翻翻学习资料。

今天小编就分享到这里啦，欢迎随时进行补充喔。

迅捷PDF在线转换专注于各大文件之间的转换，喜欢的小伙伴就关注走一波呗。

The End

可能对于在用Excel的朋友来讲，平时使用的比较多的一个函数，那就是Vlookup函数，今天小编就来告诉大家一个Excel中最有用第一个函数，那就是Countif函数，这个函数的适用范围远远高于vlookup函数，所有把它列为最有用函数的NO.1也一点都不为过。下面我们就来学习一下这个函数。

今天教大家这个函数主要从以下6个场景来进行学习。

一对一对比两列数据多对多对比两列数据禁止重复输入输入时必须包含指定字符帮助Vlookup实现一对多查找统计不重复值的个数

:场景1：一对一核对两列数据

【例】如下图所示，要求对比A列和D列的姓名，在B和E列出哪些是相同的，哪些是不同的。

公式：

B2 =IF(COUNTIF(D:D,A2)>0,"相同","不同")

E2 =IF(COUNTIF(A:A,D2)>0,"相同","不同")

场景2：多对多核对两列数据

【例】如下面的两列数据，需要一对一的金额核对并用颜色标识出来。

步骤1 在两列数据旁添加公式，用Countif函数进行重复转化。

=COUNTIF(B$2:B2,B2)&B2

步骤2按ctrl键同时选取C和E列，开始 - 条件格式 - 突出显示单元格规则 - 重复值。

设置完成后后，红色的即为一一对应的金额，剩下的为未对应的。如下图所示

场景3：禁止重复录入

禁止在G列重复录入数据：

数据 - 有效性（2016版为数据验证） - 序列 - 输入公式

=COUNTIF(G:G,G1)=1

场景4：输入内容必须包括指定字符

【例】在列输入的内容，必须包含字母A。

=COUNTIF(H1,"*A*")=1

:如果输入不含A的字符就会警示并无法输入

场景5：帮助Vlookup函数实现一对多查找

【例】如下图所示左表为客户消费明细，要求在F:H列的蓝色区域根据F2的客户名称查找所有消费记录。

:步骤1 在左表前插入一列并设置公式，用countif函数统计客户的消费次数并用&连接成 客户名称+序号的形式。

A2: =COUNTIF(C$2:C2,C2)&C2

步骤2 在F5设置公式并复制即可得到F2单元格中客户的所有消费记录。

=IFERROR(VLOOKUP(ROW(A1)&$F$2,$A:$D,COLUMN(B1),0),"")

场景6：计算唯一值个数

【例】统计A列产品的个数

=SUMPRODUCT(1/COUNTIF(A2:A7,A2:A7))

总结：总的来讲Countif函数虽然只是单一条件的计数函数，但它在与其他函数搭配使用的时候，那他的作用将会变的无限大。所以说大家可以多去学习了解一下更多的函数嵌套的使用方法。

前面几节课，我们简单介绍了IF、OR、AND的用法，IF 单独使用的情况较多，但是OR、AND一般嵌入IF的函数中使用的概率较高，今天我们趁热打铁，讲讲这三者的使用方式~~

01 视频讲解

02 文字详解

案例：2项都在90分及以上值为"优秀"，有1项目90分及以上"良好"，否则"一般"。

公式使用：IF(AND(B4>=90,C4>=90),"优秀",IF(OR(B4>=90,C4>=90),"良好","一般"))

鼠标放置D4单元格右下角，变为黑色十字，双击往下自动填充公式

结果：

以上就是IF、OR、AND嵌套使用方法，有什么不明白的地方欢迎在下方留言，我们将及时给你答复~~

这一篇我将从IF函数的基本用法说起，接着介绍多条件IF函数嵌套是怎么理解的，怎样写函数嵌套公式。

IF函数基础

IF函数是我们处理表格最常用的函数之一，是每个人都必须掌握的，它的公式和流程如下：

IF函数共有3个参数，第一个是判断条件，第二个是条件成立时能得到的结果，第三个是条件不成立时得到的结果。

如图，我们输入在B2单元格输入公式“=IF(B2>=60,"及格","不及格")”，由于76大于60，所以得到结果“及格”。

IF函数嵌套

IF函数就像是在抛硬币，硬币落地时要么正面朝上，要么反面朝上，只有这两个结果，IF函数的结果要么是第二个参数，要么是第三个参数。可有时候希望得到三个结果，如考试成绩分为“优秀”、“及格”和“不及格”，怎么办呢？

这就要用到IF函数嵌套。函数嵌套的意思就是一个公式中有两个以上的函数，包括两个相同的函数。

有些朋友看到函数嵌套就头晕，其实你可以先写一个简单的公式“IF(条件，真值，假值)”，再把其中的“真值”或“假值”替换成另一个IF函数即可。

如果对自己写的函数嵌套公式没有把握，不妨画出它的流程图。

除了两层的IF函数嵌套，还可以用三层嵌套，方法也是一样，先写简单的，再慢慢替换。就像我们人为判断一个学生的成绩属于什么水平，会先看他是否及格了，及格了之后看他是否是良或优秀。

IF函数和其他逻辑函数嵌套

IF函数除了在真值部分嵌套IF函数之外，也可以在假值部分嵌套函数，还可以和其他函数嵌套，常见的有求和函数SUM、计数函数COUNT/COUNTIF、逻辑函数AND/OR/NOT。

一个学生有多门课程，当需要综合评价他的成绩时，我们就会用到下图中的公式了。

写一个嵌套函数是很容易出错，另外它看起来总是不那么好理解，因此，不宜嵌套太多层，虽然IF函数最多能支持7层函数嵌套，但我建议不要使用超过4层的函数嵌套，条件过多时，可以寻找其他的替代函数如lookup/round等。

谢谢阅读，每天学一点，省下时间充实自己。欢迎点赞、评论、关注和点击头像。

if 函数针对一定的条件做真假判断并返回不同的结果，可以说是EXCLE中最常用到的函数之一，下面就通过多例子让大家掌握这一函数的使用方法。IF 函数是根据对指定的条件计算结果为 TRUE 或 FALSE，返回不同的结果，语法IF(logical_test,value_if_true,value_if_false)。也就是 IF(条件判断是真或是假，条件为真时的值，条件为假时的值）,下面来通过一个例子说明。

当成绩在0-59之间的时候为不及格，60-89之间为良好，90-100之间为优秀。把下面的公式：=IF(C2<60,"不及格",IF(C2<90,"良好","优秀"))输入到D2单元格，注意“”输入的时候是在英文状态下，把公式下拉完成了程序的设定。

本文所有图片、文字均为原创，以上教程截图来自EXCEL2016，其他版本的EXCEL设置方法类似，如果你感觉本文对你有帮助，记着关注“EXCEL交流学习”哦，每天一个小技能，让你快速成为高手！

实际的数据处理，远远的比我们想象的复杂的多，如果有多个层次的数据，需要根据不同的层次进行计算，你首先想到的计算方法是什么？IF函数嵌套？那如果有几万条数据，你该怎么办了？

一、示例数据。

例如：某公司的提成机制如下图所示：

从图表中我们可以看出，当销售额大于等于2000时，提成5%，每增加2000，提成增加0.5%。

二、实际问题：

如果让你去计算销售员的提成金额，你会怎样去做？

可能会用IF函数嵌套使用来完成，如果数据量较少，当然也是可以的，但是如果有几万、几十万条数据，IF函数嵌套几十万次吗？

正确解决办法：使用VLOOKUP函数查询法。

方法：

在目标单元格中输入公式：=VLOOKUP(F3,$B$3:$C$10,2,1)。

解析：

1、输入公式之后快速的查询出了提成比例。而且符合实际情况。

2、利用VLOOKUP函数的模糊查找法（最后一个参数为1时为模糊查找，为0时为精准查找）在区域B3:C10中查找对应的销售金额。如果查找的金额在对应的范围中没有找到，则会返回比当前查找值小且最接近该值的值，例如：查找9800时，返回的值为6.5%。

3、此方法不管有多少条数据，都能轻松的应对，更贴近我们的目的。

在上一篇文章excel关于函数if的巧妙运用中，我们通过三个实例介绍了函数if的基础应用。在上一篇文章中，我们介绍的if函数的应用实例结果都是二选一的，今天我们介绍的if函数的用法将在此基础上进一步深化，当然还是运用举例的做法向大家进行介绍。

今天主要介绍的内容是运用if函数在三种不同的结果中进行选择，也就是if函数与if函数自身的嵌套使用，光说不练恐怕会让各位读友看糊涂，咱们现在就直奔主题。

实例一：现在我们有这样一张excel工作表，表中有姓名、专业类和专业代号两种内容，现在姓名、专业类已知，专业类一共有三类：理科、文科、工程。

现在我们已知理工的专业代号是LG，文科的专业代号是WK，工程的专业代号是GC，也就是中文的首字母了，那么接下来我们要用if函数来为所有的专业类填上对应的专业代号，excel工作表具体如下图所示：

具体操作方法如下：在D2单元格输入“=IF(C2="理工","LG",IF(C2="文科","WK","GC"))”（ps:if函数中的标点符号在英文输入法状态下输入），按回车键，得到汪梅同学的专业代号，然后通过填充柄拖拽的方式向下拖拽，我们就能到其他同学的专业代号了。具体操作可参考下图：

实例二：现在我们要做一张成绩表，据有关部门规定，本地学生总分为基本成绩加30分，本省学生总分为基本成绩加20分，外省学生不加分，现在我的成绩表中的内容主要是姓名、性别、生源地、基本成绩、总成绩。姓名、性别、生源地、基本成绩四项内容已知，现在我们要用if函数来对各位学生的生源地进行判断，进而算出所有学生各自的总分。excel工作表具体如下图所示：

具体操作方法如下：在G7单元格输入“=IF(E7="本地",F7+30,IF(E7="本省",F7+20,F7))”，按回车键，得到丁一同学的总成绩，然后通过填充柄拖拽的方式向下拖拽，我们就能到其他同学的总成绩了。具体操作可参考下图：

实例三：实例三事实上是对实例二的深化，我们实例二的实例图表中增加了一项录取情况，现在我制作的成绩表中的内容就有姓名、性别、生源地、基本成绩、总成绩、录取情况六项内容了，其中姓名、性别、生源地、基本成绩、总成绩五项内容已知，现在我们要根据总成绩，运用if函数来判断各位同学的录取情况。

录取规则如下：如果考生总分大于或等于500分，录取情况显示为“一本”；考生总分小于500分且大于等于400分，录取情况显示为“二本”；考生总分小于400分，录取情况显示为“三本”。

具体操作方法如下：在H7单元格输入“=IF(G7>=500,"一本",IF(G7>=400,"二本","三本"))”或“=IF(G7>=500,"一本",IF(G7<400,"三本","二本"))”，按回车键，得到丁一同学的录取情况，然后通过填充柄拖拽的方式向下拖拽，我们就能到其他同学的录取情况了。具体操作可参考下图：

觉得对你们有用的小伙伴们请点赞关注吧！您的鼓励是我前进的动力，也希望擅长运用办公软件的小伙伴们能够不吝赐教，积极的留言，教会小编更多的excel运用的小技巧，欢迎一起来探讨学习！！

if函数是 Excel 中的条件判断函数，它由条件与两个返回结果组成，当条件成立时，返回真，否则返回假。if函数中的条件既可以单条件，也可以是多条件；多条件组合有三种方式，一种为多个 if 嵌套，第二种为用 And（或 *）组合多个条件，第三种为用 Or（或 +）组合多个条件。用 And（或 *）组合条件是“与”的关系，用 Or(或 +）组合条件是“或”的关系，它们的写法比 if 嵌套简单。以下就是它们的具体操作方法，实例中操作所用版本均为 Excel 2016。

一、Excel if函数语法

1、表达式：IF（logical_test,[value_if_true],[value_if_false])

中文表达式：如果（条件，条件为真时执行的操作，条件为假时执行的操作）

2、说明：[value_if_true] 和 [value_if_false] 表示可选项，即它们可以不写，如图1所示：

按回车，返回 False，因为 E2 为 435，F2 为 528，E2 > F2 不成立，如图2所示：

另外，=IF(3 > 2,)，返回 0，此处 0 表示假。

二、Excel if函数单条件使用方法

1、一个服装销量表中，价格为0的表示已下架，否则表示正在出售，假如要把它们分别用“下架”和“出售中”标识出来，操作过程步骤，如图3所示：

2、操作过程步骤说明：选中 H2 单元格，输入公式 =IF(E2<=0,"下架","出售中")，按回车，则返回“出售中”；把鼠标移到 H2 右下角的单元格填充柄上，按住左键并往下拖，则所经过单元格全填充为“出售中”，按 Ctrl + S 保存，则价格为 0 的单元格用“下架”填充，其它单元格用“出售中”填充。

3、公式说明：公式 =IF(E2<=0,"下架","出售中") 中，E2<=0 为条件，当条件为真时，返回“下架”，否同返回“出售中”。

三、Excel if函数嵌套多条件使用方法

1、假如要标出服装销量表中，“大类”为“女装”、“价格”大于等于 80 且“销量”大于 800 的服装，操作过程步骤，如图4所示：

2、操作过程步骤说明：选中 H2 单元格，把公式 =IF(C2="女装",IF(E2>=80,IF(F2>800,"满足条件","不满足条件"),"不满足条件"),"不满足条件") 复制到 H2，按回车，则返回“不满足条件”；再次选中 H2，把鼠标移到 H2 的单元格填充柄上，按住左键并往下拖，则所经过单元格用“不满足条件”填充，按 Ctrl + S 保存，同样 H3 用“满足条件”填充，其它单元格仍用“不满足条件”填充。

3、公式说明：

=IF(C2="女装",IF(E2>=80,IF(F2>800,"满足条件","不满足条件"),"不满足条件"),"不满足条件")

由三个 if 组成，即在一个 if 中嵌套了两个 if。第一个 if 的条件为 C2="女装"，如果条件为真，则执行 IF(E2>=80,IF(F2>800,"满足条件","不满足条件"),"不满足条件")；否则返回“不满足条件”。第二个 if 的条件为 E2>=80，如果条件为真，则执行 IF(F2>800,"满足条件","不满足条件")，否则返回“不满足条件”。第三个 if 的条件为 F2>800，如果条件为真，返回“满足条件”，否则返回“不满足条件”。

提示：if 最多只能嵌套 64 个 if，尽管如此，在写公式过程中，尽量少嵌套 if；一方面便于阅读与修改，另一方面执行效率也高一些。

四、Excel if函数用 And 与 OR 组合多个条件使用方法

（一）用 And 组合多个条件，为“与”的关系

1、把上例中的多 if 嵌套公式 =IF(C2="女装",IF(E2>=80,IF(F2>800,"满足条件","不满足条件"),"不满足条件"),"不满足条件") 改为用 And 组合，操作过程步骤，如图5所示：

2、操作过程步骤说明：选中 H2 单元格，把公式 =IF(AND(C2="女装",E2>=80,F2>800),"满足条件","不满足条件") 复制到 H2，按回车，则返回“不满足条件”；同样往下拖并保存，返回跟上例一样的结果，说明公式正确。

3、公式说明：

=IF(AND(C2="女装",E2>=80,F2>800),"满足条件","不满足条件")

公式用 And 函数组合了三个条件，分别为 C2="女装",E2>=80,F2>800，当同时满足三个条件时（即 AND(C2="女装",E2>=80,F2>800) 返回“真”），返回“满足条件”，否则返回“不满足条件”。

4、用 * 代替 And

A、把公式　　=IF(AND(C2="女装",E2>=80,F2>800),"满足条件","不满足条件")

用 * 代替 And 后变为：

=IF((C2="女装")*(E2>=80)*(F2>800),"满足条件","不满足条件")

如图6所示：

B、按回车，返回“不满足条件”，往下拖保存后，也是返回一样的结果。

（二）用 Or 组合多个条件，为“或”的关系

1、把上例中的 And 组合多个条件公式 =IF(AND(C2="女装",E2>=80,F2>800),"满足条件","不满足条件") 改为用 Or 组合，操作过程步骤，如图7所示：

2、操作过程步骤说明：选中 H2 单元格，把公式 =IF(OR(C2="女装",E2>=80,F2>800),"满足条件","不满足条件") 复制到 H2，按回车，则返回“满足条件”；同样往下拖并保存，全部返回“满足条件”。

3、公式说明：

=IF(OR(C2="女装",E2>=80,F2>800),"满足条件","不满足条件")

公式用 Or 函数组合了三个条件，分别为 C2="女装",E2>=80,F2>800，即 OR(C2="女装",E2>=80,F2>800)，意思是：只要满足一个条件，就返回“真”；一条件都不满足才返回“假”。演示中，每条记录都满足一个条件，所以全返回“满足条件”。

4、用 + 代替 Or

A、把公式

=IF(OR(C2="女装",E2>=80,F2>800),"满足条件","不满足条件")

用 + 代替 Or 后变为：

=IF((C2="女装")+(E2>=80)+(F2>800),"满足条件","不满足条件")

如图8所示：

B、按回车，返回“满足条件”，往下拖保存后，也是全部返回“满足条件”，说明公式正确。