你还在因为不会使用Excel统计函数而烦恼吗？在我们操作插入表格函数的时候，时常因为“找不到对象”以及“不能插入对象”而烦恼。

那么今天就为你们介绍7个经常使用的表格统计公式，直接复制函数即可帮你解决问题。

一、计算数据合（注：函数里表格坐标，要按照实际表格坐标调整）

函数：=SUM(B2:F2)

二、计算表格总平均值（注：函数表格位置要按实际调整）

函数：=AVERAGE(G2:G7)

三、查找表格相同值（注：函数里表格坐标，要按照实际表格坐标调整）

函数：=IF(COUNTIF(A:A,A2)>1,"相同","")

四、计算表格不重复的个数（注：函数里表格坐标，要按照实际表格坐标调整）

函数：=IF(COUNTIF(A2:A99,A2)>1," 首次重复","")

五、计算出男生表格总平均成绩（注：函数里表格坐标，要按照实际表格坐标调整）

函数：=AVERAGEIF(B2:B7,"男",C2:C7)

六、计算出成绩排名（注：函数里表格坐标，要按照实际表格坐标调整）

函数：=SUMPRODUCT((B$2:B$7>B2)/COUNTIF(B$2:B$7,B$2:B$7))+1

以上就是今天为大家分享的所有Excel函数啦！，其实在我们统计表格中，还有很多函数，小编只是写了其中一些，如果大家知道一些实用性非常强的函数，欢迎在评论区积极分享。

Excel曾经一度出现了严重Bug，主要有两种比较悲催的情况，首先是这种：

更加悲催的是这种：

言归正传，今天和大家分享一组常用函数公式的使用方法：职场人士必须掌握的12个Excel函数，用心掌握这些函数，工作效率就会有质的提升。

建议收藏备用着，有时间多学习操练下。

目录：数字处理、判断公式、统计公式、求和公式、查找与引用公式、字符串处理公式、其他常用公式等

一、数字处理

01.取绝对值

=ABS(数字)

02.数字取整

=INT(数字)

03.数字四舍五入

=ROUND(数字,小数位数)

二、判断公式

04.把公式返回的错误值显示为空

公式：C2

=IFERROR(A2/B2,"")

说明：如果是错误值则显示为空，否则正常显示。

05.IF的多条件判断

公式：C2

=IF(AND(A2<500,B2="未到期"),"补款","")

说明：两个条件同时成立用AND,任一个成立用OR函数。

三、统计公式

06.统计两表重复

公式:B2

=COUNTIF(Sheet15!A:A,A2)

说明：如果返回值大于0说明在另一个表中存在，0则不存在。

07.统计年龄在30~40之间的员工个数

=FREQUENCY(D2:D8,{40,29})

08.统计不重复的总人数

公式：C2

=SUMPRODUCT(1/COUNTIF(A2:A8,A2:A8))

说明:用COUNTIF统计出每人的出现次数，用1除的方式把出现次数变成分母，然后相加。

09.按多条件统计平均值

F2公式

=AVERAGEIFS(D:D,B:B,"财务",C:C,"大专")

10.中国式排名公式

=SUMPRODUCT(($D$4:$D$9>=D4)*(1/COUNTIF(D$4:D$9,D$4:D$9)))

四、求和公式

11.隔列求和

公式：H3

=SUMIF($A$2:$G$2,H$2,A3:G3)

或

=SUMPRODUCT((MOD(COLUMN(B3:G3),2)=0)*B3:G3)

说明：如果标题行没有规则用第2个公式

12.单条件求和

公式：F2

=SUMIF(A:A,E2,C:C)

说明：SUMIF函数的基本用法

13.单条件模糊求和

公式：详见下图

说明：如果需要进行模糊求和，就需要掌握通配符的使用，其中星号是表示任意多个字符，如"*A*"就表示a前和后有任意多个字符，即包含A。

14.多条求模糊求和

公式：C11

=SUMIFS(C2:C7,A2:A7,A11&"*",B2:B7,B11)

说明：在sumifs中可以使用通配符*

15.多表相同位置求和

公式：b2

=SUM(Sheet1:Sheet19!B2)

说明：在表中间删除或添加表后，公式结果会自动更新。

16.按日期和产品求和

公式：F2

=SUMPRODUCT((MONTH($A$2:$A$25)=F$1)*($B$2:$B$25=$E2)*$C$2:$C$25)

说明：SUMPRODUCT可以完成多条件求和

五、查找与引用公式

17.单条件查找

公式1：C11

=VLOOKUP(B11,B3:F7,4,FALSE)

说明：查找是VLOOKUP最擅长的，基本用法

18.双向查找

公式：

=INDEX(C3:H7,MATCH(B10,B3:B7,0),MATCH(C10,C2:H2,0))

说明：利用MATCH函数查找位置，用INDEX函数取值

19.查找最后一个符合条件记录

公式：详见下图

说明：0/(条件)可以把不符合条件的变成错误值，而lookup可以忽略错误值

20.多条件查找

公式:详见下图

说明:公式原理同上一个公式

21.指定非空区域最后一个值查找

公式;详见下图

说明：略

22.区间取值

公式：详见下图

公式说明：VLOOKUP和LOOKUP函数都可以按区间取值，一定要注意，销售量列的数字一定要升序排列。

六、字符串处理公式

23.多单元格字符合并

公式：c2

=PHONETIC(A2:A7)

说明：Phonetic函数只能对字符型内容合并，数字不可以。

24.截取除后3位之外的部分

公式：

=LEFT(D1,LEN(D1)-3)

说明：LEN计算出总长度,LEFT从左边截总长度-3个

25.截取 - 之前的部分

公式:B2

=Left(A1,FIND("-",A1)-1)

说明：用FIND函数查找位置，用LEFT截取。

26.截取字符串中任一段

公式:B1

=TRIM(MID(SUBSTITUTE($A1," ",REPT(" ",20)),20,20))

说明:公式是利用强插N个空字符的方式进行截取

27.字符串查找

公式：B2

=IF(COUNT(FIND("河南",A2))=0,"否","是")

说明: FIND查找成功，返回字符的位置，否则返回错误值，而COUNT可以统计出数字的个数，这里可以用来判断查找是否成功。

28.字符串查找一对多

公式：B2

=IF(COUNT(FIND({"辽宁","黑龙江","吉林"},A2))=0,"其他","东北")

说明：设置FIND第一个参数为常量数组，用COUNT函数统计FIND查找结果

七、日期计算公式

29.两日期间隔的年、月、日计算

A1是开始日期（2011-12-1），B1是结束日期(2013-6-10)。计算：

相隔多少天？=datedif(A1,B1,"d") 结果：557

相隔多少月? =datedif(A1,B1,"m") 结果：18

相隔多少年? =datedif(A1,B1,"Y") 结果：1

不考虑年相隔多少月？=datedif(A1,B1,"Ym") 结果：6

不考虑年相隔多少天？=datedif(A1,B1,"YD") 结果：192

不考虑年月相隔多少天？=datedif(A1,B1,"MD") 结果：9

datedif函数第3个参数说明：

"Y" 时间段中的整年数。

"M" 时间段中的整月数。

"D" 时间段中的天数。

"MD" 天数的差。忽略日期中的月和年。

"YM" 月数的差。忽略日期中的日和年。

"YD" 天数的差。忽略日期中的年。

30.扣除周末的工作日天数

公式：C2

=NETWORKDAYS.INTL(IF(B2

说明：返回两个日期之间的所有工作日数，使用参数指示哪些天是周末，以及有多少天是周末。周末和任何指定为假期的日期不被视为工作日

八、其他常用公式

31.创建工作表目录的公式

把所有的工作表名称列出来，然后自动添加超链接，管理工作表就非常方便了。

使用方法：

第1步：在定义名称中输入公式：

=MID(GET.WORKBOOK(1),FIND("]",GET.WORKBOOK(1))+1,99)&T(NOW())

第2步、在工作表中输入公式并拖动，工作表列表和超链接已自动添加

=IFERROR(HYPERLINK("#'"&INDEX(Shname,ROW(A1))&"'!A1",INDEX(Shname,ROW(A1))),"")

32.中英文互译公式

=FILTERXML(WEBSERVICE("http://fanyi.youdao/translate?&i="&A2&"&doctype=xml&version"),"//translation")

excel中的函数公式千变万化，今天就整理这么多了。如果你能掌握一半，在工作中也基本上遇到不难题了。

建议收藏备用着，有时间多学习操练下。

施老师：

有时办公室人事做员工信息表时，需要填写性别，如果一个一个地去点，太麻烦了，数据少些还尚可，如果碰到大批量的员工信息。那就实在是太麻烦了。这里讲一个自动用函数识别身份证号的中男女性别的方法。

首先，我们要了解身份证的号码的规则才行。众所周知，身份证第17位数字表示性别：奇数表示男性，偶数表示女性。知道这一规则后，我们就知道应该从何下手了。

方法一直接在B2单元格，输入公式：【=IF(MOD(MID(当前单元格,17,1),2),"男","女")】即可。剩下的单元格可以直接将当前单元格按住“+”往下拉即可。MID(当前单元格,17,1)说明：截取当前单元格中第17位数；MOD(MID(A2,17,1),2说明：MOD求余函数，MOD(MID(A2,17,1),2表示中间截取的这个数除以2后是不是奇数；IF：若为奇数，则为男，否则为女。

方法二直接在C2单元格，输入公式：【=IF(MOD(RIGHT(LEFT(当前单元格,17)),2),"男","女")】。LEFT说明：取当前单元格单元格的左边17位；RIGHT：取上一步结果的右边1位；MOD：取上一步结果除以2的余数；IF：判断结果是奇数是男，否则是女；

大家平时用EXCEL去录入员工信息时，是一个一个的去输入，还是用下拉框，还是用直接用函数计算呢？欢迎在下方评论区留言，写下你的看法，和施老师一起探讨！

实际的工作中，我们常用的函数公式其实都是最基本的，对于一些高大上的功能，一般情况下我们用到的很少，所以，对一般函数公式的掌握非常的重要。

一、文本提取。

目的：从指定的字符串中提取年份，部门，编号。

方法：

1、在目标单元格中分别输入：=LEFT(B3,4)、=MID(B3,6,3)、=RIGHT(B3,3)。

2、Ctrl+Enter填充。

二、生成随机数。

目的：生成0-99之间的随机数。

方法：

1、在目标单元格中输入公式：=RANDBETWEEN(1,99)。

2、F9刷新。

三、四舍五入保留2位小数。

目的：对销售额进行规范处理。

方法：

在目标单元格中输入公式：=ROUND(C3,2)。

四、不显示公式错误值。

目的：对数据中未知的错误进行有效的处理。

方法：

在目标单元格中输入公式：=IFERROR(D3/C3,"")。

五、条件判断。

目的：对得分情况进行判断，如果大于等于95分，则“晋升”。

方法：

在目标单元格中输入公式：=IF(C3>=95,"晋升","")。

六、首字母大写。

方法：

在目标单元格中输入公式：=PROPER(B3)。

七、统计排名。

方法：

在目标单元格中输入公式：=RANK(C3,C$3:C$9,0)。

八、计数统计。

目的：统计销售笔数。

方法：

在目标单元格中输入公式：=COUNTIF(B3:B9,H3)。

九、多表求和。

目的：对1、2、3、的销售额及销售笔数进行汇总。

方法：

在目标单元格中输入公式：=SUM('1:3'!D3)、=SUM('1:3'!I3)。

十、按次数重复数据。

目的：将姓名重复3次。

方法：

在目标单元格中输入公式：=REPT(B3,3)。

实际的工作中，我们用到的函数公式并不多，相对于那些高大上的函数公式，我们更多用到的是一些常见的，相对比较简单的函数公式。例如IF函数、SUMIF函数、COUNTIF函数等……

一、IF函数：条件判断。

目的：判断相应的分数，划分类别。

方法：

在目标单元格中输入公式：=IF(C3=100,"满分",IF(C3>=95,"优秀",IF(C3>=80,"良好",IF(C3>=60,"及格","不及格"))))。

解读：

IF函数不仅可以单独进行条件判断，还可以嵌套进行使用。

二、SUMIF函数：单条件求和。

目的：计算出男生或女生的成绩总和。

方法：

在目标单元格中输入公式：=SUMIF(D3:D9,G3,C3:C9)。

解读：

SUMIF函数的语法结构是：=SUMIF(条件范围，条件，求和范围）。其中求和范围可以省略，如果省略，默认和条件范围一致。主要作用是对符合条件的数进行求和。

三、COUNTIF函数：单条件计数。

目的：按性别统计人数。

方法：在目标单元格中输入公式：=COUNTIF(D3:D9,G3)。

解读：COUNTIF函数的语法结构是：=COUNTIF（条件范围，条件）。主要作用是统计符合条件的数。

四、LOOKUP函数：单条件或多条件查询。

目的：查询学生的考试成绩档次。

方法：

在目标单元格中输入公式：=LOOKUP(1,0/(B3:B9=$G$3),E3:E9)。

解读：

此方法是LOOKUP函数的变异用法，查询值为1，而0/(B3:B9=$G$3)的判断结果是党B3:B9范围中的值等于G3单元格中的值时，返回TRUE，0/TRUE等于0，如果不等于G3单元格中的值时，返回FALSE ,0/FALSE,返回FALSE ,然后用查询值对0/(B3:B9=$G$3)返回的结果进行对比分析，返回最接近查询值的对应位置上的值。

五、LOOKUP函数：逆向查询。

目的：根据分数查询出对应的姓名。

方法：

在目标单元格中输入公式：=LOOKUP(1,0/(C3:C9=$G$3),B3:B9)。

六、INDEX+MATCH：查询号搭档。

目的：查询对应人的所有信息。

方法：

在目标单元格中输入公式：=INDEX($B$2:$E$9,MATCH($G$3,$B$2:$B$9,0),MATCH(H$2,$B$2:$E$2,0))。

七、DATEDIF函数：计算年龄。

目的：计算销售员的年龄。

方法：

在目标单元格中输入公式：=DATEDIF(D3,TODAY(),"y")。

解读：

DATEDIF函数是系统的隐藏函数，其主要作用是计算两个时间段之间的差异，可以是年、月、日任意一种需求。

八、TEXT+MID：提取出生年月。

目的：根据身份证号提取出生年月。

方法：

在目标单元格中输入公式：=TEXT(MID(C3,7,8),"0-00-00")。

九、SUMPRODUCT:中国式排名。

目的：对成绩进行排名。

方法：在目标单元格中输入公式：

=SUMPRODUCT(($D$3:$D$9>D3)/COUNTIF($D$3:$D$9,$D$3:$D$9))+1或=SUMPRODUCT((D3>$D$3:$D$9)/COUNTIF($D$3:$D$9,$D$3:$D$9))+1。

解读：

1、=SUMPRODUCT(($D$3:$D$9>D3)/COUNTIF($D$3:$D$9,$D$3:$D$9))+1为降序排序。

2、=SUMPRODUCT((D3>$D$3:$D$9)/COUNTIF($D$3:$D$9,$D$3:$D$9))+1为升序排序。

工作效率，一直是我们追求的目标。在Excel中，提高效率的方法很多，最常用的就是对各种技巧的熟练掌握。今天我们要学习的10个Excel实操技巧，对工作效率的提高，绝对不是一点点。

一、自适应调整列宽。

目的：极速调整列宽，显示单元格全部内容。

方法：

1、选定需要调整列宽的列。

2、移动鼠标至选定的任意两列分割线处，待鼠标变成左右双向箭头时，双击。

解读：

1、想要双击显示单元格的全部内容，必须取消“自动换行”。

2、如果没有取消“自动换行”，双击行标可以自动显示全部内容。

二、快速隐藏多列、多行。

目的：对不需要显示或保密的多列或多行内容快速隐藏。

方法：

1、选定目标行或列。

2、移动光标至选定的任意两行行标或列标中间，待鼠标变成双向箭头时，拖动鼠标。

解读：

1、拖动鼠标时如果拖动的幅度较小（小于当前行或列的宽度），则不会隐藏行或列，只是对行高或列宽进行调整。

2、拖动的幅度大于临近行或列的高度或宽度时，可以快速的实现隐藏功能。

三、快速取消隐藏行、列。

目的：对隐藏的多行、多列快速的进行显示。

方法：

1、选定需要取消隐藏的行或列。

2、移动鼠标，待鼠标变成双向箭头时，双击。

四、多单元格数据批量输入。

目的：批量输入演示数据或固定内容。

方法：

1、选定目标单元格。

2、输入公式：=RANDBETWEEN(10,100)或“Excel函数公式”。

3、Ctrl+Enter填充。

解读：

1、函数RANDBETWEEN的主要作用是生成指定两个数之间的随机数。

2、输入指定内容时，无需等号。

五、多工作表批量输入。

目的：在多个工作表中批量输入演示数据或指定内容。

方法：

1、选定任意表格的目标单元格。

2、按住Ctrl键，选定其它工作表。

3、输入公式:=RANDBETWEEN(10,100)或“Excel函数公式”。

3、Ctrl+Enter填充。

六、快速的输入：对号，错号。

目的：快速用对号或错号对数据进行标记。

方法：

1、选定目标单元格。

2、设置目标单元格的字体为：Wingdings 2。

3、输入大写R或S。

七、按月填充日期。

目的：对当前日期按月快速填充。

方法：

1、选定目标单元格并输入需要填充的日期。

2、拖动填充柄，并单击右下角的箭头，选择【按月填充】。

八、单元格内强制换行。

目的：调整内容显示，强制换行。

方法：

在目标内容后按Alt+Enter快捷键。

九、快速添加前缀。

目的：给序号添加前缀：函数公式。

方法：

1、选定目标单元格。

2、快捷键Ctrl+1打开设置单元格格式，选择【分类】中的【自定义】，在【类型】中输入：Excel函数-0。

3、【确定】。

十、快速输入有规律的长数字。

方法：

1、66万的后面有4个零，所以公式为：=66**4。

2、90亿，9的后面有9个零，所以公式为：=9**9。

结束语：

如果我们对实际操作中的技巧能够熟练掌握，相信对我们的工作效率提高的绝对不是一点点……欢迎大家在留言区讨论交流，同时别忘了点赞、转发哦！

写在前面：洛阳亲友如相问，一片冰心在玉壶

也许在刚刚踏入陌生的一个世界中，你会发现有很多的人或者事情，你不熟悉。其实一路来走来，旅途的花开花落，情来情去情随缘，均有陌生人为你作伴相随。

不知你有木有发现我们的Excel其实也是有个很好的向导的，可以帮助我们更好的使用函数。

尤其当你不知道所需函数的名称，但不确定如何构建它，可以使用函数向导帮你完美解决。

我们举一个例子来说明一下：

选择单元格，然后转至“公式”>“插入函数”>在搜索函数框中键入 VLOOKUP，然后按“转到”。看到 VLOOKUP 突出显示时，在底部单击“确定”。如果选择列表中的函数，Excel 将显示其语法。

接下来，在其各自的文本框中输入函数参数。每输入一个参数，Excel 都会对其求值，并显示其结果，最终结果显示在底部。完成后请按“确定”，Excel 将为你输入公式。

我们在输入函数参数的时候，其实可以看到下面的解释，提示这个位置应该输入啥值。我们顺带简单提一下这个函数的使用方法哈！

VLOOKUP 是 Excel 中使用最广泛的函数之一（也是我们最喜欢的工具之一！）。使用 VLOOKUP，你可查找左侧列中的值，如果找到匹配项，则会在右侧的另一列中返回信息。

无一例外，你会遇到 VLOOKUP 找不到所需内容，并且返回错误 (#N/A) 的情况。有时是单纯的因为查找值不存在，或者因为引用单元格尚无任何值。

第一种情况，如果你知道查找值存在，但查找单元格为空，你希望隐藏错误，可以使用 IF 语句。在这种情况下，我们将如单元格 D43 所示嵌套现有 VLOOKUP 公式：

=IF(C43="","",VLOOKUP(C43,C37:D41,2,FALSE))

这表示如果单元格 C43 没有任何内容 ("")，则不返回任何结果，否则返回 VLOOKUP 的结果。请注意公式末尾的第二个右括号。这可关闭 IF 语句。

第二种情况，如果不确定查找值是否存在，但仍想抑制 #N/A 错误，可以在单元格 G43 中使用名为 IFERROR 的错误处理函数：=IFERROR(VLOOKUP(F43,F37:G41,2,FALSE),"")。IFERROR 表示，如果 VLOOKUP 返回有效结果，则显示该结果，否则不显示任何内容 ("")。此处我们没有显示任何内容 ("")，但还可以使用数字（0、1、2 等）或文本，如“公式不正确”。

PS:IFERROR 称为综合错误处理程序，意味着它将抑制公式可能引发的任何错误。如果 Excel 通知你公式有需要修复的合法错误，这可能导致问题。

经验法则是不要将错误处理程序添加到公式中，除非确定它们能工作正常。

有时，你会遇到含有错误的公式，Excel 显示为 #ErrorName。错误很有用，因为它们可指出某些内容未正确运行，但进行修复并非易事。所幸，有通过多种方式可帮助你查找错误来源，并进行修复。

1.错误检查 - 转到“公式”>“错误检查”。这将加载一个对话框，告知你特定错误的一般原因。在单元格 D9 内，引发 #N/A 错误的原因是没有匹配“苹 果”的值。可以修复此错误，方法是使用存在的值，使用 IFERROR 抑制错误，或知道在使用确实存在的值时错误会消失的情况下忽略它。

2.如果单击”关于此错误的帮助”，将打开特定于此错误消息的帮助主题。如果单击“显示计算步骤”，将加载“公式求值”对话框。

3.每次单击“求值”，Excel 都将逐步执行公式，一次一个部分。它不一定会告诉你出现错误的原因，但会指出位置。在这里，查看帮助主题，推导公式出问题的位置。

写在结尾：寒雨连江夜入吴，平明送客楚山孤。

以上就是今天要和大家分享的技巧，希望对大家有所帮助，欢迎大家帮忙转发，谢谢！

祝各位一天好心情！

Excel中每一个方法都有特定的用途，不是他们没有用处，只是你不了解或者暂时用不着，建议你收藏起来，万一哪天用着呢？

Excel是大家知道一个办公软件，是办公人员特别是做会计的朋友离不开的优秀软件，一些专业人士肯定应用的比较自如，得心应手，但是一些刚接触的朋友就不怎么样了，今天为大家介绍Excel中的一些常用功能，方便大家的工作：

今天和大家分享的这些Excel函数都是最基本的，但应用面却非常广，学会基本Excel函数，也可以让工作事半功倍。

1、SUM函数

SUM函数的作用是求和。

统计一个单元格区域：

=sum(A1:A10)

统计多个单元格区域：

=sum(A1:A10,C1:C10)

2、AVERAGE函数

Average 的作用是计算平均数。

可以这样：

=AVERAGE(A1:A10)

也可以这样：

=AVERAGE(A1:A10,D1:D10)

3、COUNT函数

COUNT函数计算含有数字的单元格的个数。

COUNT函数参数可以是单元格、单元格引用，或者数字。

COUNT函数会忽略非数字的值。

如果A1:A10是COUNT函数的参数，其中只有两个单元格含有数字，那么COUNT函数返回的值是2。

也可以使用单元格区域作为参数，如：

=COUNT(A1:A10)

4、IF函数

IF函数的作用是判断一个条件，然后根据判断的结果返回指定值。

条件判断的结果必须返回一个或TRUE或FALSE的值，即“是”或是“不是”。

例如：

给出的条件是B2>C3，如果比较结果是TRUE，那么IF函数就返回第二个参数的值;如果是FALSE，则返回第三个参数的值。

IF函数的语法结构是：

=IF(逻辑判断,为TRUE时的结果,为FALSE时的结果)

5、NOW函数和TODAY函数

NOW函数返回日期和时间。TODAY函数则只返回日期。

假如说，要计算某项目到今天总共进行多少天了?

=TODAY()-开始日期

得出的数字就是项目进行的天数。

NOW函数和TODAY函数都没有参数，只用一对括号即可：

=NOW()

=TODAY()

6、VLOOKUP函数

VLOOKUP函数用来在表格中查找数据。

函数的语法公式是：

=VLOOKUP(查找值,区域,要返回第几列的内容,1近似匹配 0精确匹配)

7、ISNUMBER函数

ISNUMBER判断单元格中的值是否是数字，返回TRUE或FALSE。

语法结构是：

=ISNUMBER(value)

8、MIN函数和MAX函数

MIN和MAX是在单元格区域中找到最大和最小的数值。

可以这样：

=MAX(A1:A10)

也可以使用多个单元格区域：

=MAX(A1:A10, D1:D10)

9、SUMIF函数

SUMIF函数根据条件汇总，有三个参数：

=SUMIF(判断范围,判断要求,汇总的区域)

SUMIF的第三个参数可以忽略，第三个参数忽略的时候，第一个参数应用条件判断的单元格区域就会用来作为需要求和的区域。

10、COUNTIF函数

COUNTIF函数用来计算单元格区域内符合条件的单元格个数。

COUNTIF函数只有两个参数：

COUNTIF(单元格区域,计算的条件)

信息，在现在社会及生活中是非常重要的，这个词的英文是“information”，有的语言称之为情报或者是资讯，它包含的内容十分之广泛。有我们熟悉的内容，也有我们不熟悉的内容，今日重点讲在EXCEL函数中，能作为提供信息的函数有哪些，这些函数都可以提供什么信息。

一.CELL函数

用途：返回某一引用区域的左上角单元格的格式、位置或内容等信息，该函数主要用于保持与其它电子表格程序的兼容性。

语法：CELL(info_type，reference)

参数：Info_type 为一个文本值，指明所需要的单元格信息的类型。Reference 表示要获取其有关信息的单元格。如果忽略，则在info_type 中所指定的信息将返回给最后更改的单元格。

下面的列表显示了几个常见的info_type 的可能值及相应的结果。

“col”返回：reference 中单元格的列号。

“color” 返回：如果单元格中的负值以不同颜色显示，则为值1；否则返回0（零）。

“contents” 返回：reference 中左上角单元格的值；不是公式。

“filename” 返回：包含 reference 的文件名（包括全部路径）， 文本格式。如果包含 reference 的工作表尚未保存， 则返回空文本("")。

“row” 返回：reference 中单元格的行号。

“type” 返回：与单元格中数据类型对应的文本值。如果单元格为空，则返回“b”；

“width” 返回：取整后的单元格列宽。列宽以默认字号的一个字符宽度为单位。

2.ERROR.TYPE函数

用途：返回对应于某一错误类型的数字，如果没有错误则返回#N/A。在IF 函数中可以使用ERROR.TYPE 检测错误值，并返回文字串(如“发生错误”)来取代错误值。

语法：ERROR.TYPE(error_val)

参数：Error_val为需要得到其数字代码的一个错误类型。尽管error_val 可以是实际的错误值，但它通常为一个单元格引用，而此单元格中包含需要检测的公式。

注意：ERROR.TYPE 函数返回的错误代码是：#NULL!返回1， #p/0!返回2， #VALUE!返回3， #REF!返回4， #NAME?返回5， #NUM!返回6，#N/A 返回7，其他错误则返回#N/A。

实例：如果A1=316/0，则公式“=ERROR.TYPE(A1)”返回2。表示除数不为零。

3.INFO函数

用途：返回有关当前操作环境的的信息。

语法：INFO(type_text)

参数：Type_text是一文本，指明所要返回的信息类型。下面的参数为常见的几种参数类型。

其中"directory"返回当前目录或文件夹的路径，

"memavail"返回可用的内存空间(以字节为单位)，

"numfile"返回当前所有打开的工作表的数目，

"osversion"返回当前操作系统的版本号(文本)，

"recalc"返回当前的重计算方式(“自动”或“人工”)，

"release"返回Excel 的版本号(文本)，

"system"返回操作系统名称(Macintosh="mac"，Windows="pcdos")，

注意：INFO函数中的文本参数必须用西文引号引起来。

当然，如果从广义的角度讲，信息函数还有其他的种类，如IS函数也可以提供信息，但比起上面的几个信息函数而言，有着明显的不同，这里不归于此类。

今日内容回向：

1 如何得知系统是32位还是64位的系统？

2 在打开的EXCEL中如何知道文件的位置？

分享成果，随喜正能量

可能对于在用Excel的朋友来讲，平时使用的比较多的一个函数，那就是Vlookup函数，今天小编就来告诉大家一个Excel中最有用第一个函数，那就是Countif函数，这个函数的适用范围远远高于vlookup函数，所有把它列为最有用函数的NO.1也一点都不为过。下面我们就来学习一下这个函数。

今天教大家这个函数主要从以下6个场景来进行学习。

一对一对比两列数据多对多对比两列数据禁止重复输入输入时必须包含指定字符帮助Vlookup实现一对多查找统计不重复值的个数

:场景1：一对一核对两列数据

【例】如下图所示，要求对比A列和D列的姓名，在B和E列出哪些是相同的，哪些是不同的。

公式：

B2 =IF(COUNTIF(D:D,A2)>0,"相同","不同")

E2 =IF(COUNTIF(A:A,D2)>0,"相同","不同")

场景2：多对多核对两列数据

【例】如下面的两列数据，需要一对一的金额核对并用颜色标识出来。

步骤1 在两列数据旁添加公式，用Countif函数进行重复转化。

=COUNTIF(B$2:B2,B2)&B2

步骤2按ctrl键同时选取C和E列，开始 - 条件格式 - 突出显示单元格规则 - 重复值。

设置完成后后，红色的即为一一对应的金额，剩下的为未对应的。如下图所示

场景3：禁止重复录入

禁止在G列重复录入数据：

数据 - 有效性（2016版为数据验证） - 序列 - 输入公式

=COUNTIF(G:G,G1)=1

场景4：输入内容必须包括指定字符

【例】在列输入的内容，必须包含字母A。

=COUNTIF(H1,"*A*")=1

:如果输入不含A的字符就会警示并无法输入

场景5：帮助Vlookup函数实现一对多查找

【例】如下图所示左表为客户消费明细，要求在F:H列的蓝色区域根据F2的客户名称查找所有消费记录。

:步骤1 在左表前插入一列并设置公式，用countif函数统计客户的消费次数并用&连接成 客户名称+序号的形式。

A2: =COUNTIF(C$2:C2,C2)&C2

步骤2 在F5设置公式并复制即可得到F2单元格中客户的所有消费记录。

=IFERROR(VLOOKUP(ROW(A1)&$F$2,$A:$D,COLUMN(B1),0),"")

场景6：计算唯一值个数

【例】统计A列产品的个数

=SUMPRODUCT(1/COUNTIF(A2:A7,A2:A7))

总结：总的来讲Countif函数虽然只是单一条件的计数函数，但它在与其他函数搭配使用的时候，那他的作用将会变的无限大。所以说大家可以多去学习了解一下更多的函数嵌套的使用方法。