Excel表格的IF函数如何使用？

黑马说

又到了每周三的 Office 时刻，今天解决什么问题呢？录入成绩时，给定了分数怎么划定对应优良差的等级？根据销售额如何计算对应的提成？今天介绍的 IF 函数就可以一步解决。

图文说明01问题？

看到下面的图片，现在每个同学的成绩都录入进来了，等级的划分在右边也列出来了，但是每个同学对应的等级还未知。如果你一个一个的去看，然后手动输入进去，那也太麻烦了吧。

那么，今天的 IF 函数就可以完美的解决这个问题，一步就可以让 Excel 自动判定每个人的等级。

02IF 函数构成

看到下图，IF函数的语句除了「if」本身以外，其构成还包括三个部分：「判定条件」、「判定为真的输出」、「判定为假的输出」。其中，在判定的结果中（即「判定为真的输出」和「判定为假的输出」）我们还可以嵌套进其它的 if语句。这是 IF函数最大的特点，可以进行重复的、多层次的判断。

03输入语句

我们来输入语句，输入的时候我们注意三点：

1、if 语句中的内容必须用英文的括号括起来，输入的时候最好是一个括号整套进行输入，避免出错；

2、语句中的所有符号必须是英文的符号，否则无法识别；

3、语句中的三个部分是用英文的逗号隔开。

我们来看如何输入，首先输入「=if()」，然后在括号里输入判断的三个部分（上一步提到的）。第一部分是「判断条件」，即判断对应的单元格（即“B2”）的值小于60，输入“B2<60”；第二部分是「判断为真的输出」，即“B2”的值确实小于60显示什么，我们输入“ "E" ”，这里的 E 必须加上双引号，因为 E 是直接输出，双引号表示直接输出该内容；第三部分就是「判断为假的输出」，即“B2”的值大于60怎么办？因为大于60 还有四个等级需要判断，所以我们这里继续输入 if语句进行判断，此 if语句的构成与前面的一样。详细的过程请看视频的内容，讲得非常清楚。

应用

IF函数的应用非常广，也非常好用，只要是类似的、重复性的计算我们都可以用 IF函数来进行判断。比如我们在判定销售额对应的提成的时候，或者是计算个税的时候，我们就可以利用 IF函数来实现，只是与我们上文介绍的区别在于「判定条件」中增加了加减的运算。

在制作 Excel 表格过程中，有时需要用颜色标出满足一定条件的单元格，有时又需要标出满足一定条件的整行；它们可以用“条件格式”中的“使用公式确定要设置格式的单元格”加if条件实现。用这个方法不但可以标出满足一个条件的单元格或整行，并且可以标出满足多个条件的单元格或整行；另外，还可以自由选择用何种颜色标示。以下就是用条件格式加if标出满足一个条件或多条件的单元格或整行的具体操作方法，实例中操作所用版本均为 Excel 2016。

一、Excel条件格式怎么用if公式标出满足条件的单元格

1、假如要用绿色标出某班各科成绩平均分80分以上的学生姓名。框选所有学生成绩记录（即 A3:K30 这片区域），选择“开始”选项卡，单击“条件格式”，在弹出的菜单中选择“新建规则”，打开“新建格式规则”窗口，选择“使用公式确定要设置格式的单元格”，在“为符合此公式的值设置格式”下输入公式 =IF(K3>=80,B3)；单击“格式”，打开“设置单元格格式”窗口，选择“绿色”，单击“确定”，返回“新建格式规则”窗口，再单击“确定”，则用绿色标出所有平均分在80分以上的学生姓名，操作过程步骤，如图1所示：

2、注意：

A、不能框选表格的标题列，应该从表格记录行（即从 A3 单元格）开始框选，否则会发生错误，错误通常发生在标题行下的第一行，往往是不符合要求也用颜色标出。

B、要求用颜色标出第一列，但公式 =IF(K3>=80,B3) 中却不能写直接写 A3，因为 A3 这列不是数值，如果直接写 A3，将无法标出满条件的学生姓名，所以用数值列 B3 代替。

二、Excel条件格式怎么用if公式标出满足条件的整行

1、假如把某班学生成绩表中平均分在90分以上的整行用蓝色标出。按住 Alt，按一次 H，按一次 L，按一次 N，打开“新建格式规则”窗口，选择“使用公式确定要设置格式的单元格”，在“为符合此公式的值设置格式”下输入公式 =$K3>=90；单击“格式”，选择“填充”选项卡，选择“蓝色”，单击两次“确定”；再次按住 Alt，按一次 H，按一次 L，按一次 R，打开“条件格式规则管理器”窗口，选中“公式：=$K3>=90，在“应用于下”对应的输入框中把引用改为 =$3:$30；单击“编辑规则”，原来输入的公式发生了变化，把它改回原来的公式 =$K3>=90，单击两次“确定”，则用蓝色标出平均分在90分以上的学生，操作过程步骤，如图2所示：

2、在“条件格式规则管理器”窗口修改引用单元格后，原来输入的公式常常会发生变化，所以一定要返回检查，变化了则把它改回原来的公式。

3、=$3:$30 是对行的绝对引用，即绝对引用第三行到第30行，也就是只引用记录行，不要引用表格标题行，否则可能发生错误。

三、Excel怎么用多个if条件标出满足条件的单元格

1、假如要用橙色标出平均分在80分以上、C语言在90分以上的学生姓名。框选学生成绩表（即可选中 A3:K30 这片区域），按住 Alt，按一次 H，按一次 L，按一次 N，打开“新建格式规则”窗口，选择“使用公式确定要设置格式的单元格”，输入公式 =IF(K3>=80,IF(G3>=90,B3))，如图3所示：

2、单击“格式”，打开“设置单元格格式”窗口，选择“填充”选项卡，选择“标准色”下的“橙色”，如图4所示：

3、单击“确定”，返回“新建格式规则”窗口，再次单击“确定”，则用橙色标出所有平均分在80分以上、C语言在90分以上的学生姓名，如图5所示：

4、公式说明。公式 =IF(K3>=80,IF(G3>=90,B3)) 共有两个 IF，即 IF 中嵌套 IF；其中 K3>=80 是第一个 IF 的条件，如果 K3>=80 为真，则执行第二个 IF；如果为假，则什么了不返回；如果第二个 IF 为真，则返回 B3，否则什么也不返回。

经常使用函数的小伙伴们都知道excel if函数是我们工作中经常用到的函数，那么excel if函数怎么实现满足多个条件来使用呢?今天就为大家唠一下excel if函数多个条件的使用方法!希望可以帮助大家更有效的运用在工作当中!那么excel if函数的多个条件实现到底怎么用？我们首先要明白，满足多个条件也可以分两种情况：1)需要多个条件同时满足;2)或者一个、几个或多个条件。我们以下图的数据来举例说明。

首先，利用AND()函数来说明同时满足多个条件。举例：如果A列的文本是“A”并且B列的数据大于210，则在C列标注“Y”。

在C2输入公式：=IF(AND(A2=”A”,B2>210),”Y”,””)知识点说明：AND()函数语法是这样的，AND(条件1=标准1，条件2=标准2……)，每个条件和标准都去判断是否相等，如果等于返回TRUE，否则返回FALSE。只有所有的条件和判断均返回TRUE，也就是所有条件都满足时AND()函数才会返回TRUE。

然后，利用OR()函数来说明只要满足多个条件中的一个或一个以上条件。举例：如果A列的文本是“A”或者B列的数据大于150，则在C列标注“Y”。

在C2单元格输入公式：=IF(OR(A2=”A”,B2>150),”Y”,””)知识点说明：OR()函数语法是这样的：OR(条件1=标准1，条件2=标准2……)，和AND一样，每个条件和标准判断返回TRUE或者FALSE，但是只要所有判断中有一个返回TRUE，OR()函数即返回TRUE。

以上的方法是在单个单元格中进行判断，也可以写成数组公式形式在单个单元格中一次性完成在上述例子中若干个辅助单元格的判断，这样我们就可以随心所欲的对excel if函数的条件设置咱们需要的规则了！

好了，今天的excel if函数不知道各位小伙伴们有没有掌握到呢？如果你有更好的方法也可以在评论区和大家一起交流，谢谢

if函数是 Excel 中的条件判断函数，它由条件与两个返回结果组成，当条件成立时，返回真，否则返回假。if函数中的条件既可以单条件，也可以是多条件；多条件组合有三种方式，一种为多个 if 嵌套，第二种为用 And（或 *）组合多个条件，第三种为用 Or（或 +）组合多个条件。用 And（或 *）组合条件是“与”的关系，用 Or(或 +）组合条件是“或”的关系，它们的写法比 if 嵌套简单。以下就是它们的具体操作方法，实例中操作所用版本均为 Excel 2016。

一、Excel if函数语法

1、表达式：IF（logical_test,[value_if_true],[value_if_false])

中文表达式：如果（条件，条件为真时执行的操作，条件为假时执行的操作）

2、说明：[value_if_true] 和 [value_if_false] 表示可选项，即它们可以不写，如图1所示：

按回车，返回 False，因为 E2 为 435，F2 为 528，E2 > F2 不成立，如图2所示：

另外，=IF(3 > 2,)，返回 0，此处 0 表示假。

二、Excel if函数单条件使用方法

1、一个服装销量表中，价格为0的表示已下架，否则表示正在出售，假如要把它们分别用“下架”和“出售中”标识出来，操作过程步骤，如图3所示：

2、操作过程步骤说明：选中 H2 单元格，输入公式 =IF(E2<=0,"下架","出售中")，按回车，则返回“出售中”；把鼠标移到 H2 右下角的单元格填充柄上，按住左键并往下拖，则所经过单元格全填充为“出售中”，按 Ctrl + S 保存，则价格为 0 的单元格用“下架”填充，其它单元格用“出售中”填充。

3、公式说明：公式 =IF(E2<=0,"下架","出售中") 中，E2<=0 为条件，当条件为真时，返回“下架”，否同返回“出售中”。

三、Excel if函数嵌套多条件使用方法

1、假如要标出服装销量表中，“大类”为“女装”、“价格”大于等于 80 且“销量”大于 800 的服装，操作过程步骤，如图4所示：

2、操作过程步骤说明：选中 H2 单元格，把公式 =IF(C2="女装",IF(E2>=80,IF(F2>800,"满足条件","不满足条件"),"不满足条件"),"不满足条件") 复制到 H2，按回车，则返回“不满足条件”；再次选中 H2，把鼠标移到 H2 的单元格填充柄上，按住左键并往下拖，则所经过单元格用“不满足条件”填充，按 Ctrl + S 保存，同样 H3 用“满足条件”填充，其它单元格仍用“不满足条件”填充。

3、公式说明：

=IF(C2="女装",IF(E2>=80,IF(F2>800,"满足条件","不满足条件"),"不满足条件"),"不满足条件")

由三个 if 组成，即在一个 if 中嵌套了两个 if。第一个 if 的条件为 C2="女装"，如果条件为真，则执行 IF(E2>=80,IF(F2>800,"满足条件","不满足条件"),"不满足条件")；否则返回“不满足条件”。第二个 if 的条件为 E2>=80，如果条件为真，则执行 IF(F2>800,"满足条件","不满足条件")，否则返回“不满足条件”。第三个 if 的条件为 F2>800，如果条件为真，返回“满足条件”，否则返回“不满足条件”。

提示：if 最多只能嵌套 64 个 if，尽管如此，在写公式过程中，尽量少嵌套 if；一方面便于阅读与修改，另一方面执行效率也高一些。

四、Excel if函数用 And 与 OR 组合多个条件使用方法

（一）用 And 组合多个条件，为“与”的关系

1、把上例中的多 if 嵌套公式 =IF(C2="女装",IF(E2>=80,IF(F2>800,"满足条件","不满足条件"),"不满足条件"),"不满足条件") 改为用 And 组合，操作过程步骤，如图5所示：

2、操作过程步骤说明：选中 H2 单元格，把公式 =IF(AND(C2="女装",E2>=80,F2>800),"满足条件","不满足条件") 复制到 H2，按回车，则返回“不满足条件”；同样往下拖并保存，返回跟上例一样的结果，说明公式正确。

3、公式说明：

=IF(AND(C2="女装",E2>=80,F2>800),"满足条件","不满足条件")

公式用 And 函数组合了三个条件，分别为 C2="女装",E2>=80,F2>800，当同时满足三个条件时（即 AND(C2="女装",E2>=80,F2>800) 返回“真”），返回“满足条件”，否则返回“不满足条件”。

4、用 * 代替 And

A、把公式　　=IF(AND(C2="女装",E2>=80,F2>800),"满足条件","不满足条件")

用 * 代替 And 后变为：

=IF((C2="女装")*(E2>=80)*(F2>800),"满足条件","不满足条件")

如图6所示：

B、按回车，返回“不满足条件”，往下拖保存后，也是返回一样的结果。

（二）用 Or 组合多个条件，为“或”的关系

1、把上例中的 And 组合多个条件公式 =IF(AND(C2="女装",E2>=80,F2>800),"满足条件","不满足条件") 改为用 Or 组合，操作过程步骤，如图7所示：

2、操作过程步骤说明：选中 H2 单元格，把公式 =IF(OR(C2="女装",E2>=80,F2>800),"满足条件","不满足条件") 复制到 H2，按回车，则返回“满足条件”；同样往下拖并保存，全部返回“满足条件”。

3、公式说明：

=IF(OR(C2="女装",E2>=80,F2>800),"满足条件","不满足条件")

公式用 Or 函数组合了三个条件，分别为 C2="女装",E2>=80,F2>800，即 OR(C2="女装",E2>=80,F2>800)，意思是：只要满足一个条件，就返回“真”；一条件都不满足才返回“假”。演示中，每条记录都满足一个条件，所以全返回“满足条件”。

4、用 + 代替 Or

A、把公式

=IF(OR(C2="女装",E2>=80,F2>800),"满足条件","不满足条件")

用 + 代替 Or 后变为：

=IF((C2="女装")+(E2>=80)+(F2>800),"满足条件","不满足条件")

如图8所示：

B、按回车，返回“满足条件”，往下拖保存后，也是全部返回“满足条件”，说明公式正确。

IF函数是Excel的常用函数之一，它是根据指定的条件来判断其“真”（TRUE）、“假”（FALSE），根据逻辑计算的真假值，从而返回相应的内容的一个函数。

使用语法：=IF( logical_test , [value_if_true] , [value_if_false])

通俗理解：=IF(条件, 条件成立返回的值, 条件不成立返回的值)

1、实例：单条件判断，销售台数>=35台才完成任务，判断销售员是否完成任务。

G2单元格公式： =if(D2>=35,"完成","未完成"），往下填充即可

2、计算各部门销售总额

I2公式：={SUM(IF(C:C=H2,F:F)}

大括号表示数组公式，即输入公式=SUM(IF(C:C=H2,F:F)后，一定要按CTRL+SHIFT+ENTER三键结束，才可得出下图结果。

3、IF函数嵌套使用及多级嵌套变通办法

①根据给定的奖金评定标准的A级至E级标准的奖金数，计算出不同等级销售员应发奖金数。

②根据销售员等级计算出奖金等级。

说明1：如果IF函数嵌套太多，最好用VLOOKUP函数。

说明2：如果IF函数嵌套太多，又一定要用IF，对于数值而言可以用"+"，文本则用"&"来回避嵌套，看起来公式比较长，但比嵌套来说要简单一点。

嵌套公式：

F2单元格公式：

=IF(E3=$A$3,$B$3,IF(E3=$A$4,$B$4,IF(E3=$A$5,$B$5,IF(E3=$A$6,$B$6,$B$7))))

G2单元格公式

=IF(E3=$I$3,$J$3,IF(E3=$I$4,$J$4,IF(E3=$I$5,$J$5,IF(E3=$I$6,$J$6,$J$7))))

变通后公式（公式长度更长，但没那么容易出错）：

F2单元格公式：

=IF(E3=$A$3,$B$3,0)+IF(E3=$A$4,$B$4,0)+IF(E3=$A$5,$B$5,0)+IF(E3=$A$6,$B$6,0)+IF(E3=$A$7,$B$7,0)

G2单元格公式：=IF(E3=$I$3,$J$3,"")&IF(E3=$I$4,$J$4,"")&IF(E3=$I$5,$J$5,"")&IF(E3=$I$6,$J$6,"")&IF(E3=$I$7,$J$7,"")

4、IF函数与AND和OR混合使用

①对于60岁以上（含）的男性员工给予1000元奖金，两个条件同时满足用AND

C3单元格公式：=IF(AND(A3="男",B3>=60),1000,0)

②对于60岁以上或40岁以下的员工给予1000元奖金，两个条件满足其中一个即可，用OR

C10单元格公式：=IF(OR(B10>=60,B10<=40),1000,0)

③对于60岁以上的男员工或40岁以下的女员工给予1000元奖金，即有60岁以上和男员工要同时满足，40岁以下和女员工也要同时满足用AND，这两个大条件中间的或又要用到OR，有点复杂，逻辑一定要清楚。

C17单元格公式：＝if(or(and(A17="男"，B17>60),and(A17="女",B17<40)),1000,0)

温馨提示：

① 在使用IF多层嵌套时，函数执行的命令是从左向右执行的，要注意括号的对应关系，不要遗漏或增多括号。

② 2003及以下版本对嵌套有7层的限制，可用前面介绍的方法变通使用。

③ 嵌套太多建议改用VLOOKUP等其他函数。

我是EXCEL学习微课堂，分享EXCEL学习小技巧，小经验。如果分享的内容对您有帮助，欢迎点赞、收藏、评论、转发，更多的EXCEL技能，可以关注“EXCEL学习微课堂”。

今天遇到一个问题要大于等于85分的同学定为优秀，小于等于60为合格，小于60为需努力。原来计划是用筛选方法，后面想想这样不方便。到时成绩数据有变化还得更改。于是想到用IF函数来判断。

测试数据

结果

公式的优点

在上一篇文章excel关于函数if的巧妙运用中，我们通过三个实例介绍了函数if的基础应用。在上一篇文章中，我们介绍的if函数的应用实例结果都是二选一的，今天我们介绍的if函数的用法将在此基础上进一步深化，当然还是运用举例的做法向大家进行介绍。

今天主要介绍的内容是运用if函数在三种不同的结果中进行选择，也就是if函数与if函数自身的嵌套使用，光说不练恐怕会让各位读友看糊涂，咱们现在就直奔主题。

实例一：现在我们有这样一张excel工作表，表中有姓名、专业类和专业代号两种内容，现在姓名、专业类已知，专业类一共有三类：理科、文科、工程。

现在我们已知理工的专业代号是LG，文科的专业代号是WK，工程的专业代号是GC，也就是中文的首字母了，那么接下来我们要用if函数来为所有的专业类填上对应的专业代号，excel工作表具体如下图所示：

具体操作方法如下：在D2单元格输入“=IF(C2="理工","LG",IF(C2="文科","WK","GC"))”（ps:if函数中的标点符号在英文输入法状态下输入），按回车键，得到汪梅同学的专业代号，然后通过填充柄拖拽的方式向下拖拽，我们就能到其他同学的专业代号了。具体操作可参考下图：

实例二：现在我们要做一张成绩表，据有关部门规定，本地学生总分为基本成绩加30分，本省学生总分为基本成绩加20分，外省学生不加分，现在我的成绩表中的内容主要是姓名、性别、生源地、基本成绩、总成绩。姓名、性别、生源地、基本成绩四项内容已知，现在我们要用if函数来对各位学生的生源地进行判断，进而算出所有学生各自的总分。excel工作表具体如下图所示：

具体操作方法如下：在G7单元格输入“=IF(E7="本地",F7+30,IF(E7="本省",F7+20,F7))”，按回车键，得到丁一同学的总成绩，然后通过填充柄拖拽的方式向下拖拽，我们就能到其他同学的总成绩了。具体操作可参考下图：

实例三：实例三事实上是对实例二的深化，我们实例二的实例图表中增加了一项录取情况，现在我制作的成绩表中的内容就有姓名、性别、生源地、基本成绩、总成绩、录取情况六项内容了，其中姓名、性别、生源地、基本成绩、总成绩五项内容已知，现在我们要根据总成绩，运用if函数来判断各位同学的录取情况。

录取规则如下：如果考生总分大于或等于500分，录取情况显示为“一本”；考生总分小于500分且大于等于400分，录取情况显示为“二本”；考生总分小于400分，录取情况显示为“三本”。

具体操作方法如下：在H7单元格输入“=IF(G7>=500,"一本",IF(G7>=400,"二本","三本"))”或“=IF(G7>=500,"一本",IF(G7<400,"三本","二本"))”，按回车键，得到丁一同学的录取情况，然后通过填充柄拖拽的方式向下拖拽，我们就能到其他同学的录取情况了。具体操作可参考下图：

觉得对你们有用的小伙伴们请点赞关注吧！您的鼓励是我前进的动力，也希望擅长运用办公软件的小伙伴们能够不吝赐教，积极的留言，教会小编更多的excel运用的小技巧，欢迎一起来探讨学习！！

据许多调查显示，SUM、VLOOKUP、IF是使用量最大的三个函数，前两个函数我们都已经说过了，本次我们就一起来揭开IF函数的神秘面纱。

其实只要我们留心观察，生活中到处都充满了IF函数。

如果成绩大于60分，就能及格，否则就不及格；

如果明天下雨，我就不去露营；

如果有网，我就玩电脑，否则睡觉；

如果我是女生，我一定会嫁给他。

太多这样的例子，三天三夜都举不完。

如下是某个班级的学生成绩表，根据成绩等级评判标准，<60为不及格，60-70为及格，70-80为中等，80-90为良好，90-100为优秀，如何快速对学生进行成绩等级判定呢？

这时我们就要用到IF函数啦，先判断小于60分：=IF(C3<60,"不及格")。那60-70分的怎么判断呢？可能很多人都会想到按照数学上的方法为：=IF(C3<60,"不及格",IF(60≤C3<70,"及格"))

公式报错了。其实，在计算机中处理多条件时，和我们所学的数学的表达方式是有差别的。当条件为小于等于时，我们使用<=而不是使用≤，同理大于等于使用>=。

对于多条件，我们还需要使用到另外的两个函数AND和OR，AND表示并且的意思，只有当所有的条件都为真时，结果才为真，其余都为假；OR表示或者的意思，当条件中全部为假时，结果才为假，其余均为真。二者的语法如下：

=AND(条件1，条件2，条件n)

=OR(条件1，条件2，条件n)

则上述的公式可以更改为：

=IF(C2<60,"不及格",IF(AND(C2>=60,C2<70),"及格",IF(AND(C2>=70,C2<80),"中等",IF(AND(C2>=80,C2<90),"良好",IF(AND(C2>=90,C2<100),"优秀")))))，结果如下：

针对本例中的成绩判断，其实如果我们换一个思路，公式可以简化很多，也就不用使用AND函数。我们从高等级向低等级判断，如果大于等于90为优秀，如果不大于90但是大于等于80为优秀，只有当成绩不是优秀时，才会继续判断，所示此时第二个条件中没必要再判断是否小于90，如下：

=IF(C2>=90,"优秀",IF(C2>=80,"良好",IF(C2>=70,"中等",IF(C2>=60,"及格","不及格"))))。这样是不是简洁了许多？在

Excel函数和公式的运用中，有时候我们要多角度的考虑问题，这样才能写出更高效的公式！！！

IF函数家族起到的主要是辅助的作用，其实也不用学得太深，只要知道常用的方法就行了，如果大家学了数组函数之后，IF函数还会有一些更高级的用法，此处先不说。

IF函数是Excel中最常用到的函数之一。根据指定的条件来判断其“真”（TRUE）、“假”（FALSE），根据逻辑计算的真假值，从而返回相应的内容。

IF函数使用语法：=IF( logical_test , [value_if_true] , [value_if_false])

大白话解释 ：=IF(A,B,C)，表达式A，正确返回B，错误返回C

表达式运算符：

主要有=，<>，>，<，>=，<=等6个关系运算符。

不多说了，为大家准备几个案例看看吧！

1、成绩表及格和不及格表现出来。

如下图，将C列及格和不及格的表现出来。

公式很简单：

D2中填：=IF(C2>60,"及格","不及格")，然后往下拉得出结果如下图

2、求所有男生和女生成绩之和

公式：=SUM(IF(B2:B11="男",C2:C11))

下图表格左侧是数据源区域，其中包含学生的性别和分数信息，现在要对所有男生和女生的成绩求总和，在D2输入公式，如下图

注意：输完公式，一定要按组合键。不然结果算出来不对。

3、IF函数排除错误值求和

公式：=SUM(IF(ISERROR(C2:C11),0,C2:C11))

办公中经常遇到数据源有错误值的情况，如果直接使用SUM函数求和会出错，用IF、ISERROR、SUM函数组合成嵌套函数算可以避免错误。

如下图在D3输入公式，记得输入完了按组合键。

好了，今天就说到这里，IF函数的这三种拓展应用，在工作中经常碰到，用得好它会助你一臂之力。

今天花点心思写一下excel中if函数的用法，可能在数据小的时候大家用不到这些函数，但是如果表格数据量非常大的时候，那么excel中if函数的节省时间的效果出出来了。

在使用if函数之前，我先把数据准备好，以一个班级的语文成绩为例，依照不及格<60，60<良<80,优秀>80来划分成绩等级。

当然了三个判定条件大家一开始理解不了，可以先从及格不及格简单的判定开始了解if函数的用法。那么在C2中判定及格与不及格的if函数写法是=IF(B2>=60,"及格","不及格")。

我们先点击C2单元格，然后在上方的公式输入框中输入我们的if函数，按回车键运行一下函数就可以了，然后通过C2单元格右下角的下拉复制功能，将函数应用到C2下方的其它单元格中就可以了。

简单的使用if函数判定成绩及格与不及格就弄好了，接下来我们再讲下有三个条件的if函数的使用方法，具体要用的if函数公式如下。=IF(B2<60,"不及格",IF(B2<80,"良","优秀"))。

上面的公式很好理解，第一个if函数如果分数小于60，就输出不及格，否得花就进行第二个if函数的判定，如果分数小于80就输出良，大于80就输入优秀。在D2中输入完公式后按回车键运行公式结果。

接下来就是把D2的公式应用到下方的单元格中，记住不要用复制，一定要点击D2右下角按住鼠标不放下拉就可以了。这样excel中if函数的使用的简单方法就教给大家了。霸气走火就是我，我就是百度经验作者：ixlxt7Xzsl7，百度经验和百家号首发原创内容分享。