一、万行数据的自动求和我只用30秒,你要用多久时间呢？

Sum函数即求和函数，是Excel当中最为常用最为简单的统计还是之一。此函数返回某几个单元格，或者单元格区域中所有数字之和，对于非数字类型的单元格包括文本、逻辑值、空值等自动忽略，对于错误值类型单元格则会报错，如下图所示：

图文：傲看今朝

此函数虽然使用非常简单，几乎人人都可以会用，然而很多人使用起来效率并不高。

下面我给大家介绍一个快捷输入sum函数的小技巧。请看下面的案例：将表格中所有的总计行快速求和。

操作步骤：

单击列序号A，拖拽至列序号M，既选中了A:M;

按下Ctrl+G组合键，打开定位对话框,单击定位条件，打开定位条件对话框，选择空值，单击确定；

这时候总计栏里所有的空单元格都被选中了，按下Alt+=组合键,完成表格所有总计行单元格的求和。

下面能看一下动画演示，到底有多快吧！

这样的操作一定不会超过30秒,如果你一列一列去自动求和五分钟都不止

二、Sumif函数：极其实用简单的条件求和函数

sum函数的确非常实用简单，然而这个函数的功能却极其有限，比如说他对下面的需求就无能为力：小胡，请统计一下咱们公司这个月男女员工各发出去了多少钱工资？

当然这个需求的话，sum函数也能做，只是写起公式比较复杂（我自信，大多数读者不会写），因此接下来我会给大家带来另外一个实用的函数：sumif函数，专门解决这个问题。

sumif，由两个单词构成，一个是sum(求和)，另外一个是if（条件）。字面意思就是：满足某个条件，就加起来，否则，就自动忽略。因此使用这个函数，我们需要告诉Excel，我们的条件是什么？以及我们要对什么区域进行求和。

因此这个函数应该是长成这样：

=sumif(条件,求和区域)

这跟我们实际见到的sumif函数不太一样，实际是这样的：

=sumif(条件区域,条件,求和区域)

但我们简单分析一下，这个跟我预想的公式本质上的意思却是完全一致（虽然多了一个参数）：条件区域及条件，这两个参数不就是要让我们告诉excel我们设定的条件是什么嘛。

1.我就拿刚刚提到的例子做个实例：男员工工资发出去了多少钱？

分析：条件为男员工（条件区域为性别列，条件为“男”。），求和区域工资所在的列。

因此公式应该写为：

=SUMIF(B:B,"男",D:D)

条件可以采取引用单元的方式，因此这个公式也可以写成：

=SUMIF(B:B,$B$2,D:D)

这到底对不对呢？请看动画演示：结果完全正确

2.我们刚刚举的例子是非常简单的。现在我们来看一个工作中比较常见实用的案例：统计一下各个花费科目分别都花出去了多少钱？如下图所示：

一次性搞定各个科目的发生额统计

使用sumif函数来完成这个统计我们需要知道，条件区域是什么？条件是什么？以及求和区域是什么？

我们的条件是统计各个科目下产生的费用，因此：

条件区域：即是左边表格的第三列C列；

条件：各个科目，分别就是邮寄费、独子费、过桥路费以及手机电话费了；

求和区域：理所当然是D列了。

因此我们公式应该写为：

=SUMIF(C:C,F3,D:D)

由于我们需要分别算出邮寄费、独子费、过桥路费以及手机电话费各项的总费用，因此公式需要向下复制，因此中间的参数F3应该为相对引用。

下面请看动画演示：

动画演示

3.我们前面给出的条件都是相对来说比较简单的，现在我们来看一看，如果是数字类的条件，我们如何输写呢？比方说：大于或者等于200的发生额总计有多少？如下图所示：

条件写法有变化

分析：

条件区域：发生额所在的列即D列

条件：">=200",除了单元格引用、函数或者是数字外，其他的条件都要加上英文引号。

求和区域：发生额所在的列即D列

=sumif(D:D,">=200",D:D)

这里要提到Sumif函数的一个特性:当求和区域和条件区域完全一致时，求和区域这个参数可以省略。

因此此公式可以简化为：=sumif(D:D,">=200")

三、案例：Sumif函数巧妙取代Vlookup函数

如下图所示，我们需要快速查询几个员工的工资，通常有点Excel使用经验的同学首先想到的应该是Vlookup函数，这个函数的确非常好用，然而这样的统计Sumif照样也可以干得挺好。

不止有vlookup函数，sumif函数更简洁

条件区域：A列；

条件：李明、王华、郭磊等；

求和区域：实发数即B列。

=sumif(A:A,E3,B:B)

比用Vlookup函数简单一些，不是吗？请看下图操作。

比vlookup写起来简单多了

说明

SUM函数将对参数的所有数字求和。 其中每个参数都可以是单元格区域、单元格引用、数组、常数公式或另一函数的结果。

例如，SUM(A1:A5)将对单元格 A1 到 A5（区域）中的所有数字求和。

再如，SUM(A1, A3, A5)将对单元格 A1、A3 和 A5中的数字求和。

语法

SUM(number1,[number2],...])SUM 函数语法具有下列参数：

number1 必需， 想要相加的第一个数值参数。number2,,... 可选， 想要相加的 2 到 255 个数值参数。说明

如果参数是一个数组或引用，则只计算其中的数字。 数组或引用中的空白单元格、逻辑值或文本将被忽略。如果任意参数为错误值或为不能转换为数字的文本，Excel 将会显示错误。示例1：

因为SUM函数使用的频率实在太高，所以我们可以在【开始】-【自动求和】，也可以在【公式】-【自动求和】，如果我们点击上面的自动求和，excel会将与此单元格相邻的，带有数字的单元格，自动列入我们参数框内，我们只需要根据自己需要调整参数范围，然后确认即可。

sum-例1

示例2：

除了采用菜单中输入的方式以外，我们还可以采用快捷键，这样来得更加暴力，更加快速，比如说还是上面的数据表，我们需要统计每位员工的工资合计，以及部分工资的统计，我们就可以选中需要列出求和单元格的区域，然后使用快捷键“ALT+=”，一步搞定：

sum-例2

求和函数是我们平时使用的比较多的函数，前面两篇已经介绍了SUM及SUMIF函数的使用，本篇文章我们将继续介绍求和函数SUMPRODUCT。

一、SUMPRODUCT基本语法

功能：返回相应的区域或数组乘积的和。

基本格式：=SUMPRODUCT（array1，array 2，……，array 255），各个数组必须是相同的大小，否则会返回#VALUE！错误。

计算原理：两个数组的所有元素对应相乘，然后把乘积相加，例如：

SUMPRODUCT(a2:a5,b2:b5)的计算过程为=a2*b2+a3*b3+a4*b4+a5*b5=2*4+5*2+3*3+6*2=39。

二、SUMPRODUCT使用示例

示例一：根据绩效考核系数和各项评分求员工综合得分

某公司的员工综合考评得分由勤奋态度、业务工作、管理监督、指导协调、工作效果五项组成，每项的系数分别为0.1、0.35、0.15、0.15、0.25，请根据以下员工的各项评分计算出员工的综合得分。

根据以上对SUMPRODUCT函数的介绍，可以知道我们可以使用该函数比较简便的计算出总得分。公式如下：

=SUMPRODUCT($B$3:$F$3,B4:F4)

计算后的结果如下：

示例二：根据多条件求教师的课时总数

根据以下的教师课时安排表统计出性别为男且职称为中一的教师的总课时数。

该计算案例比上面的一个案例相对就要复杂很多，这里涉及到一个判断的问题。这里需要回顾我们之前介绍过的逻辑值的相关问题。然后再根据逻辑值的相关运算，就可以组成一个新的数组，将这个新的数组作为第一个数组条件。公示如下：

=SUMPRODUCT((B2:B16="男")*(C2:C16="中一"),D2:D16)。

这里对第一个条件进行一下运算的解释：

B2:B16="男"：结果为{true,true,false,false,true,true,false,false,false,true,false,false,true,false,false}

C2:C16="中一"：结果为{false,false,true,true,true,false,true,false,true,false,true,true,true,true,false}

(B2:B16="男")*(C2:C16="中一")：运算结果为{false,false,false,false,true,false,false,false,false,false,false,false,true,false,false}。

这个可能稍微有点复杂，大家好好的理解一下，这样对理解逻辑运算及该函数都会有很大的帮助。

三、SUMPRODUCT可能出现的错误

①编辑公式时，引用的数据区域大小不一致导致计算错误，返回值为#VALUE！。

②数据区域中有错误值时，计算出现错误值。

③数据区域引用不能整列引用，否则返回错误值#NUM！。

④数据区域有文本，计算中系统默认文本值为0。

四、拓展训练

大家思考一下，通过使用SUM函数的数组公式形式能不能实现上面的两个示例的计算？如果你已经想出计算方法，请评论发出来，如果你不知道怎么计算，请继续关注下篇文章，我将给大家讲解如何通过SUM数组函数进行计算。

转载自百家号作者：EXCEL学习微课堂

最实用Excel求和函数公式大全，小伙伴快来收藏备用！

一、快速求和：快捷键【ALT+=】快速求和

选取整个区域（B2:G14），点按快捷键【ALT+=】

二、含小计行的总计求和公式

如下图所示，要求在单元格设置累计求和公式，等于各小计之和。

B12=SUM(B2:B11)/2

三、隔列求和

隔列求和，如下图所示的计划与实际对比的表中，要计算全年的计划和实际完成情况，可以直接用sumif求和。

F3单元格公式为：=SUMIF($B$2:$E$2,F$2,$B3:$E3)

四、合并单元格求和

如下图所示，要求在D列对A列的类别求和。

D3=SUM(C3:C10)-SUM(D4:D10)

注：公式输入方法，选取D3：D10,在编辑栏中输入公式后按Ctrl+Enter完成输入。

五、含文本型数字求和

含文本型数字的求和，用sum得不到正确的结果，可以用Sumproduct函数进行求和，如下图所示，用Sum求和得到的结果明显不对。

六、忽略错误值求和

如下图所示，如果一个区域中含有错误值，那么在用sum求和时，结果也会显示错误。如果要忽略错误值求和，可用sumif函数解决。

=SUMIF(G2:C12,"<9E+307")或者=SUMIF(G2:G12,">0")

公式解析：

9E+307是接近最大的数字，一种约定俗成的写法。在excel中，错误值比最大的数字大，因此"<9E+307"就是对小于最大值的数字求和，就实现了我们的目标：忽略错误值只对数字求和。反过来，excel忽略错误值求和，我们也可以这样写公式：=SUMIF(G2:G12,">0")

七、多条件求和

根据条件对数据分类求和也是常遇到的求和方式，如果是单条件用SUMIF函数，如果是多条件就用SUMIFS函数。

如下图，根据销售情况表，求出各销售部门2018年1月20日之前的销售总额

I2单元格公式为：=SUMIFS(F:F,C:C,H2,A:A,"<2018-1-20")

八、模糊条件求和

如果需要进行模糊求和，就需要掌握通配符的使用，其中星号是表示任意多个字符。

如下图，根据销售情况表分别计算出各销售部门销售各种产品（打印机、笔记本、台式机）的总数。H2=SUMIFS($E:$E,$C:$C,$G2,$D:$D,H$1&"*")，由于打印机、笔记本和台式机有多个型号，所有要用通配符“*”。

九、多个表格同一位置求和

1月至12月的12个工作表如果格式完全相同，可以用sum函数的多表求和功能。

如下图所示，要求在汇总表里设置合计公式，汇总12个月员工各产品的销售情况。

B2单元格公式为： =SUM('1月:12月'!B2)

十、多个表格多条件求和

多表多条件求和可以用SUM函数和DSUM函数嵌套使用。

如下图所示，有表1、表2和表3三个工作表，要统计三个表中，张1、张2、张3的销量和。

C2单元格输入公式=

SUM(DSUM(INDIRECT({"表1";"表2";"表3"}&"!A1:D11"),4,A$1:B2))-SUM(C$1:C1)

公式解析：

1、数据区域，跨表引用了3个工作表，所以用工作表引用函数INDIRECT。

2、列数，第4列“销量”。

3、条件区域是从A1开始的活动区域，所以A1是绝对引用，但B2是相对引用。

4、由于是跨表引用，因此DSUM返回的是数组，不是单值，因此要外套sum。

5、因为不同的行是“或条件”所以在统计张2第一周的销量时，结果会包含张1第一周的销量，需要减去张1第一周销量，同样的道理，统计张3第一周的销售时要减去张1和张2第一周的销售和。

十一、按颜色求和

excel中还没提供按颜色求和的函数，需要借用宏表函数获取单元格的颜色值，然后再用sumif函数求和。

1、定义名称：公式 - 定义名称 ，在定义名称窗口中输入名称【颜色】，也可以自定义其它名称），然后在下面引用来源中输入公式：=GET.CELL(63,1月!B2)&T(NOW())

公式解析：

①Get.cell(63,单元格) 可以获取单元格填充颜色值

② &T(NOW) 实现表格在更新时定义名称取值也可以更新

2、获取颜色值：在C列和F列分别输入公式 =颜色，即可获取B列和D列的单元格填充色。

3、通过sumif函数求和。在F3单元格输入公式=SUMIF(C:C,E3,B:B)

我是EXCEL学习微课堂，百家号教育视频原创作者，如果我的分享对您有帮助，欢迎点赞、收藏、评论和转发！更多的EXCEL技能，可以关注百家号“EXCEL学习微课堂”。

与本教程有关的往期分享教程有：

1、Excel秒杀一切的求和函数SUMIFS, 多条件求和就靠它了！

2、EXCEL多条件求和、跨表多条件求和函数DSUM，让你求和效率更高！

本文由“EXCEL学习微课堂”原创，欢迎关注，带你一起长知识！

很多做数据统计的

都听说过数据区域，一般不放汉字，因为无法运算，

那么现在，可以放了

案例：

C列中，既有汉字，还有文本型的数字，那么如何用公式，直接进行求和呢

公式：

在E1单元格，直接输入公式=SUM(IFERROR(VALUE(C2:C11),0))，而后键盘上按ctrl+shift+enter键，将公式转化为数组，即可得出正确的结果。

有兴趣的亲们，欢迎评论+转发

公式解释

因为有文本型的数字，首先用value函数，将文本型的，转换为可以参与运算的数值型，而后鼠标选中VALUE(C2:C11)这部分，按F9键，得到的结果如下

2，处理文本型数值之后，就是汉字，我们可以看到运算中有错误，就是汉字造成的，这个时候，就用到iferror函数，用这个函数，我们将所有的汉字，转换为0，参与运算，就没有了错误，而后鼠标选中后，按F9，可以看到结果

3，上图，我们可以看到，sum函数里面，都是数字，而且是有大括号的，因为公式是数组公式，我们只要将公式，转化为数组，即可正常得出结果

Hi，大家好，我是胖斯基

数据求和，在Excel的使用中可谓是频率极高的一种，无论是初入新手，还是E场老斯基，其应用范围面都有所涉及。

那就数据求和而言，最常见的有以下几种：

1

快速求和系列

快捷键：AL+= , 选中求和区域，快捷键一下即可

2

快速累计求和系列

Excel中锁定符号[$]的应用，使得结果逐行累加，更多应用请见《技巧 | 隐藏在Excel中的定海神针》

3

忽略文本跨列求和系列

Excel中sum函数本身对文本类型数据自动忽略，故用来对跨列的数值型数据求和

4

单条件求和系列

Excel中SUMIF，单条件求和的万能公式

5

多条件求和系列

Excel中SUMIFS，多条件求和的万能公式

6

单条件多区域求和系列

例3和例4的综合应用

7

避开错误值求和系列

依旧采用SUMIF函数的应用，其中条件"<9.9E+307"，其含义是9.9E+307是一个极大的数值，故通过规则：数值<文本

8

通配符求和系列

通配符*代表多个字符，故*茶*的含义就是只要涵盖了[茶]这个字，即符合调价，纳入条件求和范围

So，常见的8种求和方式如上所述，你知道几种？

Hi，大家好，我是胖斯基

周末闲暇，整理了下那铺满灰尘的书架。

透过尘埃，在故纸堆中发现这么一本连环画图册，脑海中瞬间回忆起那真假美猴王的剧幕，那一幕幕，完美的演绎了真亦假时假亦真，无为有处有还无……

其实，在Excel中，这种真真假假也同样存在，也一样带来了求和困扰！

求和，在Excel中很简单，相信小白都可以脱口而出，直接函数SUM即可，然后有时候，事实并非如此：

当采用最傻瓜的方式直接逐个相加时，发现结果正确；

但是当采用SUM求和时，结果却错误。

不明其中缘由的你，可能会非常困扰，明明就这几个数相加，怎么就不对了呢？

其源头就是“真假数据”，在Excel中的专业叫法是文本型数据（不参与直接运算）。

So，当这类“假数据”参与SUM时，自然不进行正确的求和运算。

1

那如何判定文本型的数值参与了运算？

技巧1：观察法

如果是文本型的数据，则在其单元格的左上角，会有一个三角符号提示

相信只要视力没问题，基本可以快速排查出所谓的“假数据”

当然，更BT的一种就是其单元格上没有小三角符合，那如何快速判定这一系列数据是否有问题呢？

依旧采用观察法：

选中这一列数据，然后观察Excel的右下方，会有文字提示：计数：6，数值计数：5，很明显，这其中有1个数字为“假数据”，So，找到Ta，解决Ta即可！

那如何从茫茫人海中找到这个“假数据”呢？

技巧2 ： 函数判断法

在Excel中，判断一个数字是否是真正的数值，有一个函数ISNUMBER，当其结果为TRUE的时候，其为真数字，当其结果为FALES时，其为假数字（文本型数字）

从函数检测结果来看，很容易就分辨出了那些数据有问题

发现问题很重要，解决问题更重要

2

如何解决文本型数值参与的计算？

技巧3 ： 文本转数值法

如果单元格里面的数值已经明确判定为文本型的“假数据”了，那可以采用文本转数值的模式，如下：

选中数据列，在右侧的提示框中选择转化为数值即可

技巧4 ： 公式计算法

当然，如果单元格里面的数据是从其他表，通过公式引入过来的，又该如何处理呢？

无论单元格里面公式是什么，在其后乘以1（*1）即可，通过数据运算让文本型转化为数值型数据

当然，也许发懒的你，什么都不想改，想直接在求和中自动计算，又该如何处理呢？

公式1：=SUM(1*(A2:A7)) ， 输入公式后，三键一起按（数组公式）

公式2：=SUMPRODUCT(1*(A2:A7))

其核心内涵，还是采用数据乘以1的方式，将文本转化为数值。

胖斯基|说

无论文本型数据也好，还是数值型数据也好，当掌握了上面4个小技巧时，真真假假，假假真真，便不那么重要了。

Excel中最常用的功能莫过于求和，但是我们时长对求和的结果并不满意，甚至部分求和的结果明显是错误的，遇到类似的情况该如何去解决了？

一、示例。

方法：

1、在目标单元格中输入公式：=SUM(C3:C9)。

2、在目标单元格中输入公式：=C3+C4+C5+C6+C7+C8+C9。

解析：

1、从输入公式的目的来看是对C3:C9单元格区域的值进行求和计算。但是计算的结果不同。

2、检查公式：两个公式都没有错误。我们通过观测发现通过累加单元格方式计算的结果反而是正确的，那用SUM函数计算导致错误的原因是什么了？

3、其实观测数据源，我们不难发现，数据中除了数据类型的数据外，还有文本类型的数据。

如果将SUM函数的计算结果：298+57=355。正好是全部销量之和。

二、解决办法。

1、观察法。

如果数值的数据类型为文本，则在其单元格的左上角，有一个倒立的三角形，也就是“绿帽子”。

解决办法：

修改器数据类型为数据或常规类型即可。

2、函数判断法。

目的：判断数据是否为数值类型。

方法：

1、增加辅助列。

2、选定目标单元格并输入公式：=ISNUMBER(C3)。

3、查看结果，如果为TRUE，则为数值类型，否则为非数值类型。

4、根据判断结果修改类型。

3、SUM公式计算法。

目的：利用公式快速的对目标区域求和。

方法：

1、在目标单元格中输入公式：=SUM(1*(C3:C9))。

2、Ctrl+Shift+Enter填充。

4、SUMPRODUCT公式计算法。

目的：利用公式快速的对目标区域求和。

方法：

1、在目标单元格中输入公式：=SUMPRODUCT(1*(C3:C9))。

2、Ctrl+Shift+Enter填充。

excel求和，有汉字怎么办？好烦人啊，有解决的办法吗？有！

很多用excel计算的朋友，会经常遇到这样的情况：

我们得到的excel数据

有人说这个不是很简单吗？我们在后面的单元格输入=B2*C2，往下一拉不就行了吗，来吧我们试试看：

excel出现的结果竟然是这样的：

简单的求和，excel出错了

那应该怎么办呢？假如我们想要的是，待定，未定，这些忽略，目前确定的数量是多少，我们在需要求和的单元格输入=SUMPRODUCT(B2:B6,C2:C6)，哇，竟然没出错，太神奇了！

excel在有汉字的情况下，完美的计算出了结果

这是什么意思呢？我们需要的结果是单价和数量乘积之和，而SUMPRODUCT是专门解决这个问题的函数，函数 SUMPRODUCT 将非数值型的数组元素作为 0 处理，所以汉字就被excel视为0。

怎么样，很简单吧，你学会了吗？快去试试吧！非常感谢您观看文本，如果你有更好的方法适用这个情况，请您留言分享！分享好玩、有趣、实用的手机和电脑技巧，您的支持就是我的最大动力！

求和，是最常见的统计工作，但花样繁多的求和要求和条件，常常让不少人限入苦思冥想不得其解的困惑之中，今天运用EXCEL函数与公式，总结从初级到高级的10个求和技巧，与大家一起学习和交流。

初级篇

1、运用“=”、“+”来计算

这是最基础的求和方法，适合无规律或指定单元格求和。如下图：计算1、3、5月份的销售量。J2单元格：=E2+G2+I2，然后，向下复制

2、运用函数SUM求和

这是基础求和函数，适合连续区域求和，高级应用多为与其他函数结合形成SUM数组公式。说明一点，SUM函数的参数，可以是单元格区间，也可以是单个单元格。如下图：计算1、3、5月份的销售量。J2单元格：=SUM(E2,G2,I2)，然后，向下复制

中级篇

3、忽略文本跨列求和

如下图，计算全部销售人员的销售额。C10单元格：=SUM(A2:I7)

利用Excel中sum函数本身对文本类型数值自动忽略的规定，所以，可以用来直接对跨列的数值型数据求和。

4、单条件求和，运用求和函数：SUMIF。

如图，计算1月份冰箱的销售量。K2单元格：=SUMIF($D$2:$D$18,"冰箱",$E$2:$E$18)

SUMIF函数基本结构：SUMIF（条件区域，条件，求和区域）

5、多条件求和，运用求和函数：SUMIFS。

如图，计算销售一部1月份相机销售量。L2单元格：=SUMIFS($E$2:$E$18,$A$2:$A$18,"销售一部",D$2:D$18,"相机")

SUMIFS函数基本结构：SUMIF（求和区域，条件区域1，条件1，条件区域2，条件2...）

6、避开错误值求和。

如下图：计算1-5月份总销售量。C12单元格：=SUMIF(A2:E10,"<9.9E+307")

应用函数SUMIF设置条件完成，其中设置条件"<9.9E+307"，其含义是，9.9*10^307，即9.9乘10的307次方，9.9E+307是一个极大的数值，根据EXCEL的通过规则：数值<文本

7、通配符求和

如下图：计算1月份包含电脑的的总销量。G2单元格：=SUMIF(C2:C18,"*电脑",D2:D18)

应用函数SUMIF设置条件完成，通配符*代表任何字符或字符串，只要总字符不超过255个，设置条件"*电脑"，或“*电脑*”，在选定区域中查找包含“电脑”的所有商品，在计算区域求和。

8、快速累计求和

利用“$”对求和区域首个单元格进行绝对引用，马上就能对一列数值快速累计求和，如下图，C2单元格：=SUM($B$2:B2)，向下复制即可。

9、求和的快捷键："Alt + =",选中要求和的区域和拟计算结果的空白区域，一键即可在空白区域产生求和结果

高级篇

10、求和之王：SUMPRODUCT

SUMPRODUCT函数跟SUM函数的数组公式条件求和语法一样。

=SUMPRODUCT((条件区域=条件)*求和区域)

如上面案例，计算1月份冰箱的销售量。K2单元格：=SUMIF($D$2:$D$18,"冰箱",$E$2:$E$18)，也可以写成：=SUMPRODUCT((D2:D18="冰箱")*E2:E18)

如上面案例，计算销售一部1月份相机销售量。L2单元格：=SUMIFS($E$2:$E$18,$A$2:$A$18,"销售一部",D$2:D$18,"相机")，也可写成：=SUMPRODUCT((A2:A18="销售一部")*(D2:D18="相机")*E2:E18)

下面，举个复杂一点点的例子，昨天，世界杯开始，首场比赛，俄罗斯队5：0大胜沙特队，拟统计本次世界杯，各小组球队进、失球队总数。

以A组为例，第一场有真实比分，其余为模拟分。就可以用SUMPRODUCT计算，进球数：J2单元格：=SUMPRODUCT(($B$2:$B$7=$I3)*($C$2:$C$7))+SUMPRODUCT(($F$2:$F$7=$I3)*($E$2:$E$7))；失球数：K2单元格：=SUMPRODUCT(($B$2:$B$7=$I3)*($E$2:$E$7))+SUMPRODUCT(($F$2:$F$7=$I3)*($C$2:$C$7))

SUMPRODUCT与其他函数结合还可以解决你意想不到的求和需求，以后我们会专门进行分享。请关注后，期待好文。

每天学习一点点，每天进步一点点，积硅步，必能致千里，得大成。