本文将为大家讲解 Microsoft Excel 试算表中的 COUNT 函数及应用，兼容 Google Sheets。这里我们拿一个名为「Everything Zone」的新闻网站作举例，尝试把这个新闻网站的记者的每周工作记录，储入了 Excel 试算表；表格内的数字为员工在每天的交稿数量。如果这个新闻网站的董事，想知道是否所有员工都乖乖每天填上交稿量，你可以用 COUNT 函数轻易找出答案。

COUNT 函数

功能：找出资料格范围内，有多少个资料格含有数字或日期。 语法：COUNT（资料格范围, [资料格范围]）

在这公式里，第一个「资料格范围」是必须填上，以计算这个范围内，共有多少个资料格是含有数字或日期。第二个「[资料格范围]」是 optional 的，例如你只想 COUNT 单数的行列，不要双数的行列，你就要用第二个「[资料格范围]」，而且可以不断增加至最多 255 个。

示例

在资料格 C12 输入 =COUNT(C3:C9)，得出答案是 7；即可找出该栏员工（勤爷）在 6 月 1 日至 6 月 7 日（本周）内，7 天都有填上交稿记录。

如果在 C12 输入 =COUNT(C2:C10)，得出答案仍然是 7；因为 C2 是文字（勤爷），C10 是 blank 空白格，均不被计算在 COUNT 公式里。

如果在 C12 输入 =COUNT(B2:C3)，答案是 2；皆因只有 B3（日期）和 C3（数字）被计算，B2（空白格）与 C2（文字）是不被计算的。

如果在 C12 输入 =COUNT(C3:C9,E3:E9,G3:G9)，答案是 19，为甚么？不是 21 才对吗？原来，员工「脑细」在 6 月 2 日和 6 月 6 日，不但没有交稿，更没有填写 Everything Zone 工作统计表，因此该两格变成了 Blank 空白格，不被 COUNT 计算在内，可恶！

你可能会说，用上述方法，只 COUNT 出答案是 19 而非 21，却不知道没有填上两个 Blank 空白格的员工是谁。那么，我们可以在 C12 输入 =COUNT(C3:C9)后，将它从 C12 向横复制公式至 I12（黄色列），脑细是不是和其他人员的工作量不一样了呢？是不是一目了然就可以轻松的统计出每个人的工作量了？

好了，如果大家有认真的一步一步的都看懂，那么在以后的再去做统计工作量的时候你会非常轻松并且非常快速完成自己的统计工作，今天的教程大家喜欢吗？喜欢的话别忘了点击关注就可以查看更多往期精彩内容！如果您觉得本文非常有帮助就伸出您的大拇指点个赞吧！感谢每天有您的陪伴，我们每天一起快乐学习快乐提高！

朋友们

今天

我们来谈谈COUNTIF函数

接触过EXCEL的朋友

肯定都知道

COUNTIF函数

它是统计

某个单元格区域中

符合指定条件的单元格数目

比如以下这个例子

要统计出A1至B13单元格区域中

分数为95的人数

我们在D2单元格中输入公式

=COUNTIF(B2:B13,95)

结果就出来了

上面的例子

统计的是一个数据

在一个区域中的个数

那如果我们要统计的是

单元格颜色呢

如下图

我们还能使用

COUNTIF函数吗

其实

要统计每个颜色

在单元格中的个数

单单用COUNTIF函数是实现不了的

但是我们可以使用

自定义函数

具体操作如下

首先

选中A1单元格

点击【公式】—【定义名称】

在对话框中

名称设置为【颜色】

引用位置输入为

【=GET.CELL(38,Sheet1!A1)】

（38表示单元格颜色）

并点击确定

公式说明：

GET.CELL函数可返回引用单元格的信息

即返回A1单元格中的颜色的名称

接着

在A列中输入【=颜色】

并向下填充

选择【不带格式填充】

即可得出每个颜色的代码

最后

在B列中输入公式

=IF(COUNTIF($A$1:A1,A1)=1,COUNTIF($A$1:$A$11,A1),"")

即可得到我们最终需要的结果

公式说明：

=COUNTIF($A$1:A1,A1)

指在$A$1:A1区域中A1单元格中的颜色第几次出现

如果A1单元格中的颜色是第一次出现

则返回=COUNTIF($A$1:$A$11,A1)

即A1单元格中颜色出现的总次数

否则返回空值

好了

我们的COUNTIF函数

就讲到这了

今天我们讲的主要内容

就是由COUNTIF函数的

应用中延伸出的问题

所以

看了今天的内容

你们是不是

对COUNTIF函数的了解更深了

对如何统计单元格中颜色的个数也清楚了

如果是的话

就给小编点个赞哟

心事留言，小编答你

excel数据太多，如何批量、快速的判断并进行统计呢？

举个例子，假如公司需要进行优秀员工数量统计，我们现在有这样一些excel数据:

我们需要统计的excel数据

我们现在的要求是，计算excel里完成力、执行力、创新力任意一项大于98，就算优秀员工，有人说，这个不是很简单吗？我们来数一数，张三执完成力96、执行力65、创新力78，不满足，李四完成力73、执行力83、创新力83，不满足，以此类推，当然，数量少是没有问题的，不过要是员工人数几千或者上万呢，我的天呐，要累死人啦！

那么，excel里有快速的办法吗？有的！

excel，需要显示优秀员工的单元格输入=IF(OR(B2>=95,C2>=95,D2>=95),"优秀员工","")，向下填充，在需要统计人数的单元格输入=COUNTIF(E2:E9,"优秀员工")，哇，瞬间得到结果，何惧几千上万呢？

excel瞬间完成的计算

excel需要的单元格输入函数

这是什么意思呢？if函数就是假如的意思，or就是或者，意思就是假如引用单元格1大于等于98，或者引用单元格2大于等于98，或者引用单元格3大于等于98，假如有1个条件满足，就是优秀员工，否则的话就为空。

COUNTIF自然就是计算满足条件的单元格个数啦。

怎么样，很简单吧，你学会了吗？快去试试吧！非常感谢您观看文本，如果你有更好的方法适用这个情况，请您留言分享！分享好玩、有趣、实用的手机和电脑技巧，您的支持就是我的最大动力！

搞定Office每周三更新

「搞定Office」是黑马公社全新的七大版块之一，每周三更新，教授Office等办公软件的各种应用技巧。

◆◆◆

Excel中利用Countifs函数进行查询和统计

黑马说：黑马之前介绍过条件求和函数SUMIFS，今天介绍一个特定条件统计函数，COUNTIFS，根据我们特定的条件统计该条件下包含的项目总和，Excel必备函数之一。

By：Andy

◆◆◆

图文说明

固定条件统计

我们来求和员工中工资大于5000（含）小于10000的人数，输入函数「=COUNTIFS(E3:E13,">=5000",E3:E13,"<10000")」。E3:E13 表示第一个条件的判断区域；">=5000" 和 "<10000" 表示判断条件，要大于等于5000，和小于10000，需要用双引号引起来；输入完成后回车就好了。

我们再来看一个例子，我们要求开发部员工中工资大于7000的总人数，输入函数「=COUNTIFS(C3:C13,C6,E3:E13,">7000")」。C3:C13 表示第一个条件的判断区域，C6 表示第一个条件要符合C6这个单元格的值；E3:E13 表示第二个条件的判断区域，">7000" 表示第二个条件要大于7000。

动态条件

有些时候我们的判断条件可能会有变化，如何设置让我们统计结果根据条件实时变化呢？只需要将条件的判定设定为单元格就好了。比如这里的上限和下限。

我们输入函数「=COUNTIFS(E3:E13,">"&J3,E3:E13,"<"&K3)」。E3:E13 表示判断区域，">"&J3 表示判定条件，但是判定条件要设定为特定的单元格，所以这里有一些不同，我们先输入判断符号 >，用双引号引起来，然后用 & 连接特定的单元格 J3。同理就可以得出后面的一个条件的输入方法了。

单一条件

还有单一条件的设定和统计，这个就很简单了，方法都是一样的，只是使用的是「COUNTIF」函数，没有「S」。例如这里的统计各部门的员工数，我们就可以输入「=COUNTIF(C3:C13,G12)」。下面的统计就只需要填充就可以了。

然后看到多条件的填充，我们首先输入函数「=COUNTIFS(C3:C13,G12,E3:E13,">"&$J$3)」。输入条件和上面的方法都是一致的，只是最后一个需要固定在对应的单元格上，固定单元格的方式就是在单元格的符号中加入两个美元符号，例如「J3」单元格，那么就改成「$J$3」就好了。

如果你对我们的新版块有什么建议，快快在下方评论吧！

一份学生成绩单，需要分别统计出60分以下、60-69、70-79、80-89、90-100各阶段成绩的学生数量。下面分别介绍4种方法来统计符合要求的学生数量。

1、利用FREQUENCY函数

FREQUENCY函数为：计算数值在某个区域内的出现频率（个数）。函数语法为：

FREQUENCY(data_array, bins_array)：

Data_array 必需。 要对其频率进行计数的一组数值或对这组数值的引用。 如果 data_array 中不包含任何数值，则 FREQUENCY 返回一个零数组。Bins_array 必需。 要将 data_array 中的值插入到的间隔数组或对间隔的引用。 如果 bins_array 中不包含任何数值，则 FREQUENCY 返回 data_array 中的元素个数。使用FREQUENCY函数难点为函数返回的是一个数组，所以它必须以数组公式的形式输入。C2:C26 为学生成绩，E2：E6为成绩分数区间分割点，对应的分别在F2：F6统计数量。

1）选中F2：F6单元格区域（由于是数组函数，必须选中F2：F6单元格区域），选定后在F2输入公式：

=FREQUENCY(C2:C26,E2:E6)。

2）公式输入完后同时按Shift+Ctrl+Enter键，会在F2:F6中分别返回满足条件的成绩个数。

2、使用COUNTIFS函数

COUNTIFS函数为：统计满足某个条件的单元格的数量（个数）。函数语法为：

=COUNTIF(要检查哪些区域? 要查找哪些内容?)

这里将学生成绩按成绩范围各自计数，E2:F6为成绩范围，在G2输入公式：

=COUNTIFS($C$2:$C$26,">="&E2,$C$2:$C$26,"<="&F2)，然后向下拖动复制到G6即可。注意C2:C26为绝对引用，按F4加"$"符号。

3、利用数据透视表

数据透视表处理大量数据时比较常用的方法，而且比较直观。

4、利用分析工具库

首先加载分析工具库。打开Excel选项，点击加载项，在管理下拉列表选择excel加载项，点击转到，勾选分析工具库。在excel数据工具栏下会加载数据分析选项。

1）点击工具栏数据—数据分析，在数据分析对话框中选择直方图，确定。

2）在直方图对话框输入区域和接收区域分别输入数据区域，在输出区域选择一个空单元格，下面柏拉图、累积百分率、直方图3个选项任选一个，我这里选直方图，确定。

“使用Excel函数统计各分数段的人数”的操作步骤是：

1、打开Excel工作表；

2、由已知条件可知，需要将B2:B34单元格的分数，按照分数段统计出相应的个数，在Excel中可通过SUMPRODUCT、SUM、COUNTIF、FREQUENCY等函数来实现。

3、方法一：SUMPRODUCT函数

在E2单元格输入以下公式，然后向下填充公式

=SUMPRODUCT((B$2:B$34>=--LEFT(D2,FIND("-",D2)-1))*(B$2:B$34<--RIGHT(D2,LEN(D2)-FIND("-",D2))))

公式表示：将B2:B34单元格中同时满足大于等于D2连接符左侧数据且小于D2连接符右侧数据的个数统计出来。

    方法二：SUM函数

在E2单元格输入以下公式数组，按Ctrl+Shift+Enter组合键结束，然后向下填充公式

=SUM((B$2:B$34>=--LEFT(D2,FIND("-",D2)-1))*(B$2:B$34<--RIGHT(D2,LEN(D2)-FIND("-",D2))))

    方法三：COUNTIF函数

在E2单元格输入以下公式数组，按Ctrl+Shift+Enter组合键结束，然后向下填充公式

=COUNTIF(B$2:B$34,">="&--LEFT(D2,FIND("-",D2)-1))-COUNTIF(B$2:B$34,">="&--RIGHT(D2,LEN(D2)-FIND("-",D2)))

公式表示：从B2:B34数据区域，统计大于等于D2连接符左侧条件的个数，再减去大于D2连接符右侧条件的个数，得到分数段的个数。

    方法四：FREQUENCY函数

在D8:D10单元格输入分数段的上限70,80,90，作为分数段的分界点，然后选择E7:E10单元格，输入以下数组公式，按Ctrl+Shift+Enter组合键结束；

=FREQUENCY(B$2:B$34,D$8:D$10)

公式结果与上面的分数段结果有所不同，这是因为计数规则的差别，也即70、80、90计入哪个分数段的规则的差异，不同的计数规则会有不同的结果。

（本文内容由百度知道网友AHYNLWY贡献）

excel数据量太多，如何进行快速、批量的判断并统计数量呢？

假如你是一个教师，你们学校的所有学生成绩都归你统计，哈哈，这个时候你开心了吧，一个学校好几千个学生，别人给了你这样的excel成绩表：

excel成绩表

领导让你统计一年级优秀学生人数是多少？条件是分数大于等于95。这个时候有人会说了，这个不是很简单吗？我们一个一个去查，一年级，张三96，一个优秀，二年级李四98,2个优秀，依此类推，我的天哪，数量少当然没问题，但是学校好几千个人呐，这是要累死的节奏吗？当然不会。

你这样，在excel里需要统计优秀学生的单元格输入=COUNTIFS(A2:A9,"一年级",C2:C9,">=95")，一瞬间，哇哦，结果出来了，几千也不怕：

excel瞬间得到优秀学生结果

其他年级excel也是一样的瞬间得到结果

哎呀，这是个什么意思呢？为什么excel会这么神奇呢？COUNTIFS是条件计数，A2:A9是引用范围，我们这里的范围是一年级，所以自然是引用年级这列，"一年级"自然是条件啦，还有另一个条件就是分数大于等于95，所以我们写上C2:C9,">=95"，一样的C2:C9是范围，">=95"是条件。

怎么样，很简单吧，你学会了吗？快去试试吧！非常感谢您观看文本，如果你有更好的方法适用这个情况，请您留言分享！分享好玩、有趣、实用的手机和电脑技巧，您的支持就是我的最大动力！

如下图：

依据每条线路的名单，如何统计人数？

公式：

在C2单元格输入公式：

=LEN(B2)-LEN(SUBSTITUTE(B2,"、",""))+1，

向下填充，即得各条线路的人数。

公式详解

SUBSTITUTE(B2,"、","")：

将B2单元格内的"、"全部替换掉；

LEN(SUBSTITUTE(B2,"、",""))：

替换掉“、”以后的字符串长度；

LEN(B2)：

替换前B2单元格字符的长度；

LEN(B2)-LEN(SUBSTITUTE(B2,"、",""))+1：

由于"、"的数量比姓名数量少1，所以人数为：替换"、"前的字符串长度—替换后的长度+1。

LEN函数

功能：LEN 返回文本字符串中的字符数。

语法：LEN(text)

SUBSTITUTE函数功能

在某一文本字符串中替换指定的文本。

语法

SUBSTITUTE(text, old_text, new_text, [instance_num])

SUBSTITUTE 函数语法具有下列参数：

文本 必需。 需要替换其中字符的文本，或对含有文本（需要替换其中字符）的单元格的引用。

old_text 必需。 需要替换的文本。

new_text 必需。 用于替换 old_text 的文本。

Instance_num 可选。 指定要用 new_text 替换 old_text 的事件。 如果指定了 instance_num，则只有满足要求的 old_text 被替换。 否则，文本中出现的所有 old_text 都会更改为 new_text。

特点

1、区分大小写和全角半角：当text中没有包含 old_text指定的字符串时，函数结果与text相同；

2、当第三个参数为空文本或是省略，而只保留参数前的逗号时，相当于将 old_text替换；

3、当第四个参数省略，text中与 old_text相同的文本将被替换；

4、如果第四个参数有指定，比如“2”，则只有第二次出现的old_text被替换。

以上四个特点举例如下：

用countif函数可统计符合条件的人数。

示例：已知成绩，统计不及格（60分以下）、及格（60-74）、良（75-84）、优（85以上）各多少人。

D2单元格公式：=COUNTIF($B:$B,"<60")

E2单元格公式：=COUNTIF($B:$B,">=60")-COUNTIF($B:$B,">=75")

F2单元格公式：=COUNTIF($B:$B,">=75")-COUNTIF($B:$B,">=85")

G2单元格公式：=COUNTIF($B:$B,">=85")

（本文内容由百度知道网友slai_枫贡献）

EXCLE中用于统计人数的常有COUNT、COUNTIF函数。

COUNT 函数计算包含数字的单元格以及参数列表中数字的个数。 使用 COUNT 函数获取数字区域或数组中的数字字段中的项目数。

其语法为COUNT(value1, [value2], ...)

COUNT 函数语法具有下列参数：

value1    必需。 要计算其中数字的个数的第一项、单元格引用或区域。

value2, ...    可选。 要计算其中数字的个数的其他项、单元格引用或区域，最多可包含 255 个。

【注意】   这些参数可以包含或引用各种类型的数据，但只有数字类型的数据才被计算在内。

 例如，可以输入“=COUNT(A1:A15)”公式（引号里面的为公式）计算区域 A1:A15 中包含数字的单元格的个数。

可以输入“=COUNT(A1:A15,2)”公式计算单元格区域A1到A15中包含数字和值2的单元格的个数

COUNTIF 是一个统计函数，用于统计满足某个条件的单元格的数量；例如，统计特定城市在客户列表中出现的次数。

其语法为COUNTIF(range, criteria) 

range   （必需）要统计数量的单元格的组。 Range 可以包含数字、数组或包含数字的引用。 将忽略空白和文本值。

criteria   （必需）用于决定要统计哪些单元格的数量的数字、表达式、单元格引用或文本字符串。

【注意】COUNTIF 仅使用一个条件。 如果要使用多个条件，请使用 COUNTIFS。或者几个COUNTIF函数相加。

例如输入“=COUNTIF（D2:D16，F2）”公式统计单元格D2到D16中包含“优秀”（使用 F2中的条件）的单元格的数量。 结果为“1”。（如果条件直接选择优秀，要使用英语中的引号，且不方便拖动下拉填充，而且根据情况，有的范围要绝对引用）

（本文内容由百度知道网友贡献）