大家好，今天和大家分享“提取数字前面的字母你会几种方法？”，首先大家不要看我的解法，自己想想看，你可以用几种解法解出这个题，要求如下图，字母连续且在左边，数字在右边。我用6种解法分享给大家，记得全是数组公式。

一、解法1：Find找第一个数字出现的位置|更多Excel学习和问题请加群：289393114、570064677

1、公式截图

2、公式

=LEFT(A2,MIN(FIND(ROW($1:$10)-1,A2&5/19))-1)

3、公式解释

用find函数找到第1个数字出现的位置，然后减掉1，得到字母的个数，再从左边提取字母

为什么A2后面要连接一个5/19，目的是防止找不到报错

ROW($1:$10)-1指10个阿拉伯数字

min提取的第一个数字出现的位置

二、解法2：Count统计字母的个数

=LEFT(A2,COUNT(0/(MID(A2,ROW($1:$19),1)>="A")))

MID(A2,ROW($1:$19),1)>="A" 用mid函数分隔每个字符，然后判断是否大于等于A，注意不区分大小写的，得到一个维数组，由True,False构建的

0/true返回0，0/False返回报错

用Count统计0的个数，就是得到字母的个数，最后用Left函数提取字母出来

三、解法3：Match找第一个数字出现的位置

=LEFT(A2,MATCH(,MID(A2,ROW($1:$19),1)*0,)-1)

用函数mid把每一个字母分隔，然后乘0，也就是所有的分隔出来的数全变成了0

MATCH(,MID(A2,ROW($1:$19),1)*0,)-1用Match函数找到第1个0出现的位置，也就是第一个数字出现的位置，所以也要减掉1

然后用Left函数从左边提取

四、解法4：Match找最后一个字母出现的位置

=LEFT(A2,MATCH(1,0/(MID(A2,ROW($1:$19),1)>"9")))

0/(MID(A2,ROW($1:$19),1)>"9")用Mid分隔每个字符，然后判断是否大于9，记得9要加双引号，所以的字母都大于“9”，也就是说所有字母在的位置都返回true,我们找最后一个true的位置，其实就是最后一个字母的位置，用0除，目的让所有的True返回0，所有的False报错

MATCH(1,0/(MID(A2,ROW($1:$19),1)>"9"))用match找最后一个0的位置

最后用lfeft从左边提取

五、解法5：字母的个数=总字符数-数字的个数

=LEFT(A2,LEN(A2)-COUNT(--RIGHT(A2,ROW($1:$19))))

COUNT(--RIGHT(A2,ROW($1:$19)))统计数字的个数

LEN(A2)-COUNT(--RIGHT(A2,ROW($1:$19)))总的字符数减掉数字的个数，得到字母的个数

六、解法6：巧用Match第2参数

=LEFT(A2,COUNT(MATCH(MID(A2,ROW($1:$19),1),CHAR(ROW($65:$90)),)))

用mid把每个字符都分隔出来作match函数第1参数，这里很巧妙用26个字母作match函数的第2参数，也就是说单元格里每一个字符都会返回一个数字位置，这些数字的个数就是字母的总个数，然后用Count函数去统计

CHAR(ROW($65:$90))返回26个大写字母

另注意，Match函数查找字母时，不区分大小写字母

Hi，大家好，我是胖斯基

又是一个突如其来的周三傍晚，风雨交夹，狂风相随……

想想那许久未更新的公众号，再摸摸那胸前的一整块腹肌，愧色依旧，还是码字减肥吧！

如何在Excel中巧妙的提取你需要的数据？

举个例子：

由于从财务系统导出的数据中，会计科目是一种全级显示，用””来展示层级的划分，但是实际在数据统计或应用的时候，需要用到末级科目，故：如何在批量数据中，快速提取末级科目的名称？

也许猴急如你，一上来就想着函数或VBA，可行是可行，但是这种霸王硬上弓的模式，往往因用力过猛而不能快速得到预期效果……

聪明人，应该懂得循序渐进！

1

查找替换法

曾经有那么一个快捷键，它可以在茫茫人海中帮你寻觅“对象”，活好话不多，Ta就是Ctrl+F。

如果你想起了Ta，那这个问题便迎刃而解，效果如下：

注意这里查找的时候，用到的查询内容是 【*\】，查找内容替换为空，过程进度的处理基本上是秒级。

说明：由于要获取的是末级科目名称，故希望在科目信息中，保留的内容是最后一个【\】后面的内容，所以这里查找的时候采用了通配符【*】，组合起来就是【*\】，故：凡是最后一个【\】前的内容都查询出来，并替换为空

想想，这种温柔的方式，是不是比直接上函数和VBA的来的更和谐？

2

快速填充法

当然条条大路通罗马，何必单恋一种法？

曾经也有那么一个智能填充工具，Ta有那么一点人工智能的特效，能够想你所想，取你所需……

Ta就是在Excel2013版及之后推出的一个快速填充工具（Ctrl+E）。如果你想起Ta，那基本也就是万花丛中笑春风般的效果，如下：

注意：这里手工输入了2条记录（目的在于给Excel更多判断的选择），然后手工拖拽，选择快速填充后，所有末级科目数据自动呈现出来，怎么样？处理进度上是不是也是秒级？

So，循序渐进是不是很重要？

慢慢来，你会发现不一样的精彩

3

函数法

这种方法呢不是特别提倡，毕竟不是人人都能上手就来函数，当然，你要是Excel大神，无妨，怎么开心怎么来。

函数1：=TRIM(RIGHT(SUBSTITUTE(B3,"",REPT(" ",200)),200))

函数2：=MID(B3,COUNT(,FIND("",B3,ROW($1:$99))),20)

函数3：=VLOOKUP("*",RIGHT(B3,ROW($3:$24)-{0,1}),2,)

具体函数逻辑就不在重复累赘说明了

胖斯基|说

在Excel中提取有效的数据，是一项频率极高的操作，其处理逻辑基本都已成为套路，学会灵活应用就好。

当然，依旧要敲黑板说明的是：观察Ta，循序渐进，温柔对待，也许灵巧的技巧，能解决你很大的问题……

更多精彩，敬请关注Excel老斯基

施老师：相信许多人经常会遇到一些不懂Excel的同事和老板，将一份好好的资料在Excel中填写的是乱七八糟，甚至有时在一个单元格中弄了N多个信息，又是中文，又是英文，又是数据。如果数据少的话可以手动一个一个的拎出来，如果数据多的话就麻烦了。今天就由宁双学好网施老师给大家分享一个不错的VBA，可以将单元格中混合数据包含中文、英文、数据信息单独提取出来。

混合数据预览

先看看混乱的数据吧！也许你的数据比这更乱，不过也没关系，我们可以轻松提取我们想要的中文或英文或数据。

开始提取

一、首先是【开发工具】-【查看代码】-【Visual Basic】；

二、在弹出的界面中点击【插入】-【模块】；

三、将下列代码复制到模块中。

Function MyGet(Srg As String, Optional n As Integer = False)

Dim i As Integer

Dim s, MyString As String

Dim Bol As Boolean

For i = 1 To Len(Srg)

s = Mid(Srg, i, 1)

If n = 1 Then

Bol = Asc(s) < 0

ElseIf n = 2 Then

Bol = s Like "[a-z,A-Z]"

ElseIf n = 0 Then

Bol = s Like "#"

End If

If Bol Then MyString = MyString & s

Next

MyGet = IIf(n = 1 Or n = 2, MyString, Val(MyString))

End Function

四、返回Excel界面，然后在需要提取单元格中录入公式

【=myget(A2,1)】是提取所有中文

【=myget(A2,2)】是提取所有英文

【=myget(A2)】是提取所有的数据

五、最后鼠标相应的往下拉就行。

喜欢施老师的干货文章请点赞，关注，分享，大家碰到中英文和数字混到一个单元格中，是怎样分离的，请在下方评论区留言写下你的看法，和施老师一起探讨。

假设A列有500个数据，如何选出这一列里的第5、10、15、20、25个数据，以此类推。

=INDEX($A:$A,ROW(1:1)*5+1)

INDEX函数有2种语法结构。这里介绍她的第一种结构：

INDEX(要取数的目标区域，行号，列号)，其中列号可以省略。如果列号省略，则目标区域必须为单列。

在实际的办公中，时长需要提取指定的数字、文本等数据，这时我们就要用到LEFT、RIGHT、MID等函数了。

一、LEFT:提取左侧字段。

方法：

1、选定目标单元格。

2、输入公式：=LEFT(B3,2)。

3、Ctrl+Enter填充。

4、在联系方式处输入第一个人的联系电话。

6、选定给所有目标单元格（包括输入电话的单元格）。

7、Ctrl+E填充。

二、RIGHT：右侧提取。

方法：

1、选定目标单元格。

2、输入公式：=RIGHT(B3,11)。

3、Ctrl+Enter填充。

三、LEFT+LEN:不规则字段中数字或文本的提取。

方法：

1、选定目标单元格。

2、输入公式：=LEFT(B3,2*LEN(B3)-LENB(B3))或=RIGHT(B3,LENB(B3)-LEN(B3))。

3、Ctrl+Enter填充。

四、MID：中间提取。

方法：

1、选定目标单元格。

2、输入公式：=TEXT(MID(C3,7,8),"00-00-00")。

3、Ctrl+Enter填充。

五、FIND：返回指定值左右的字符。

方法：

1、选定目标单元格。

2、输入公式：=LEFT(B3,FIND("-",B3)-1)或=RIGHT(B3,LEN(B3)-FIND("-",B3))。

3、Ctrl+Enter填充。

今天都教大家一些简单的，常用的小技巧！

顺便回答下，有的同学问我：

问：你怎么懂得那么多？

回答：呜呜呜，大神我就是单位那个经常加班做表的人，呜呜呜！

问：那你是从哪里学会的呢？

答：第一，网上，不会了就去查，就记住了，第二，看书，家里好几本关于EXCEL的书！

下面进入教学，这些技能都非常适用于各个单位做表的同志们！

1、取绝对值（这个不好解释，请学习初中数学课本或直接看下图）

函数格式：=ABS(数字)

2、取整（取至小数点）

函数格式：=INT(数字)

3、四舍五入（这个好理解）

函数格式：=ROUND(数字,保留小数位数)

4、以绝对值减小或增大的方向，按指定位数舍入数字（这个请看下图，就更好理解）

函数公式：ROUNDDOWN(数字，保留小数位数)

图示a

函数公式：ROUNDUP(数字，保留小数位数)

图示b

特别注意事项：ROUNDUP是就高原则保留，如：图示b，而ROUNDDOWN刚好相反，是就低原则保留，如图示a。

END……

使用公式提取单元格内的数字，要根据具体的数据结构找到某种规律从而设计出对应的公式。

例一 数字在左侧，且数字位数固定。

直接用公式：=left(A2,2)

第一个参数是要提取数字的单元格，第二个参数是要提取几位（从左边算起）。对于例一的这一类数据，使用的时候根据数字的长度修改第二参数即可。

例二：数字在左侧，数字位数不固定，但是有明显的分隔符号。

见下面的例子：

1、利用公式=FIND("-",A2,1)可以确定"-"的位置。

2、find函数有三个参数，第一个参数是要找什么内容，第二个参数是从哪里找，第三个参数是从第几个字开始找（从左边算起）。

=FIND("-",A2,1) 意思是在A2单元格找“-”，从开始位置找（左边第一位）。公式的结果是数字，代表“-”在单元格的位置（第几个字符），此时我们需要提取的数字长度就是find的结果减1，因此方法就有了：=LEFT(A2,FIND("-",A2,1)-1)

应用场景：工作中，常常需要从单元格数据中截取一部分进行统计、计算，或者从不同系统导出的数据中提取中文、数字和英文等，如何快速提取需要的数据呢？介绍4种常用方法。

第一种方法，用文本截取函数三剑客（LEFT/RIGH/MID函数）和文本长度度量函数（LEN /LENB）来提取

1、LEFT函数和RIGHT函数

参数：

LEFT (①要截取的文本或字符串,②要截取的字符个数)

RIGHT (①要截取的文本或字符串,②要截取的字符个数)

2、MID函数

参数：

MID（①要截取的文本或字符串，②从哪个位置开始截取，③要截取的字符个数）

3、LEN和LENB函数

LEN()& LENB()函数的参数很简单，只有一个，就是您要测量长度的文本，LEN()函数和LENB()函数的区别就是前者测量字符数，后者测量字节数，只有在文本字符串中包含汉字时才会有区别。

4、案例

案例1：从身份证号中截取省市区代码、出生年月和顺序及校验码

省区代码：从左边取6位。C2公式：Left(B2,6)

出生年月：从第7位数据开始取，要取出8位数。D2公式：Mid(B2,7,8)

顺序号和校验码：从右边4位数。E2公式：Right（B2,4）

案例2： 将单元格中的中英文分开

提取英文：

①在B2单元格录入公式：=LEFT(A2,LEN(A2)*2-LENB(A2))

②下拉填充公式。

公式解析：

LEN(A2)*2得出的结果是：12 （效果相当于：love爱love爱）

LENB(A2)得出的结果是：8 （效果相当于： love爱爱）

LEN(A2)*2-LENB(A2)得出的结果是：12-8=4（效果相当于：love爱love爱- love爱爱=love）

最后用LEFT函数从左取相对应的英文字母数即可提取英文单词。

提取中文：

①在C2单元格录入公式：=RIGHT(A2,LENB(A2)-LEN(A2))

②下拉填充公式。

公式解析：

LENB(A2)得出的结果是：8 （效果相当于：love爱爱）

LEN(A2)得出的结果是：6（效果相当于：love爱）

LENB(A2)-LEN(A2)得出的结果是8-6=2 （love爱爱- love爱=爱）

最后用RIGHT函数从右取相对应的汉字字符数即可提取中文。

第二种方法：用EXCEL快速填充功能提取

快速填充是EXCEL2013以上版本的一个新功能，她能模拟、识别你的操作，推测你内心的想法，然后按照你的想法进行数据填充。

运用快速填充时，首先直接输入一组到三组数据，让Excel自动识别你的意图，再进行快速填充，快速填充的快捷键为Ctrl+E，也可以单击“数据”选项卡 > 在“数据工具”组中 >单击“快速填充”或选中示例单元格，拖动填充柄往下填充，然后在“自动填充”选项中选择“快速填充”来实现。（详细教程可见“EXCELl学习微课堂分享的《EXCEL快速填充功能如此牛逼，你知道吗？》）

案例动态演示：

第三种方法：用自定义函数myget

函数有两参数，=myget(①从哪提取，②提取什么)

=myget(字符串,0) 取出数字

=myget(字符串,1) 取出中文字符

=myget(字符串,2) 取出英文字母

=myget(字符串,3) 取出特殊字符

=myget(字符串,4) 取出取第一个数字的位置

=myget(字符串,5) 取出取最后一个数字的位置

方法步骤：

首先导入自定义函数的模板文件，点开发工具→VBA或都按ALT+F11 调出VBA 编辑器 →在工程窗口右键选择【导入文件】→选择VBA 模块文件（提取中文、英文和数字自定义函数myget.bas）→关闭VBA 编辑器。然后再输入公式即可。

动态演示：

第四种方法：用【数据】→【分列】的方法

案例步骤：

1、【选中需分列的列】→【数据】→【分列】，在弹出的文本分列向导设置窗口中，根据实际情况选择分隔符号或固定宽度，案例中都是用/分隔的，所以选【分隔符号】→【下一步】

2、选择分隔符号为其他符号【/】→【下一步】

3、选列区域的格式，案例中选择默认的常规格式即可，目标区域选择$B$1（即分列的结果放在哪）点【完成】数据按要求进行了分类提取到3列。

动态演示：

小伙伴们，EXCEL快速提取方法都齐了，大家可根据需要选取不同的方法！

我是EXCEL学习微课堂，分享EXCEL学习小技巧，小经验。如果分享的内容对您有帮助，欢迎点赞、收藏、评论、转发，更多的EXCEL技能，可以关注“EXCEL学习微课堂”。如需自定义函数myget代码文件，可私信联系我！

前言：

之前发过一篇文章：EXCEL中如何实现中文与数字的快速分离？教你一招快速处理！

教了大家如何用LEFT和SUBSTITUTE函数实现将中文左边和右边的数字进行分离的方法，但这个方法不适用数字在中文里面的情况 。

故有同学在后台留言询问：数字在中间及还有小数点的情况下如何处理呢？

今天我就教大家两个方法实现数字快速提取！

需提取中文中的数字

方法1：利用两端对齐提取数字

复制A列的字符到B列，然后把B列的列宽调整为一个汉字大小的宽度

开始选项卡 － 编辑 － 填充 － 两端对齐

从B列的第一个数字向下选取全部，打开提示下拉，点转换为数字。

选取B列，打开定位窗口 - 定位条件 － 文本。执行这一步会选取所有非数字的单元格，然后右键中点删除文本就行了。

方法2：编写自定义函数提取数字

虽然EXCEL软件并没有提供从中文中提取数字的专门函数，但我们可以自已编写一个自定义函数mygetnumber实现这一功能。将以下代码放入任一模块中，即可在工作表中使用这个函数。

Function mygetnumber(cel As Range)

With CreateObject("vbscript.regexp") ‘利用正则表达式实现数字提取

.Pattern = "[^\d.-]+"

.Global = True

mygetnumber = .Replace(cel, " ")

End With

End Function

编写自定义函数提取数字

结语：excel软件实际上是非常强大的，只有想不到，没有做不到。小伙伴们，你学会了吗？快快动手试试看吧！

处理复杂的Excel表格时候，如何把单元格里面复杂的数字给提取出来呢?是将单元格里面的数字复制粘贴出来吗?NO不是!在这里教大家几个函数轻松帮你将单元格里面的数字给全部提取出来，完全不费吹灰之力!

1、如何提取单元格文本中数字

代入函数公式：

=MIDB(A2,SEARCHB("?",A2),2*LEN(A2)-LENB(A2))

将函数代入到指定的单元格，即可提取A2单元格数字，前提要将函数的坐标对应好单元格呦!

2、如何提取文本左右数字

(左侧)代入函数公式：

=LEFT(A2,2*LEN(A2)-LENB(A2))

(右侧)代入函数公式：

=RIGHT(A2,2*LEN(A2)-LENB(A2))

同理直接将函数代入到单元格里面，就可以快速提取数字，下面我演示下提取文本左侧数字。

3、如何提取混合在一起的数字

代入函数公式：

=SUM(MID(0&A2,LARGE(ISNUMBER(--MID(A2,ROW($1:$1024),1))* ROW($1:$1024),ROW($1:$308))+1,1)*10^ROW($1:$308)/10)

在复制函数到单元格的同时要按住Shift+Ctrl+Enter键，就可以提取混合在一起的数字了!