饼图、百分比堆积图都可以很好的表现出数据的百分比，不过使用时略有不同。制作步骤非常类似：选中数据，插入图表，选择合适的图表，图表就生成了，接下来就是修改图表的样式和外观了。

百分比堆积柱形图

如图，百分比堆积图上不仅显示了员工已完成的数量和待完成的数量，还可以很清楚地两者之间的百分比。

百分比堆积条形图

和百分比堆积柱形图几乎没有区别，一个横向，一个纵向。当类系列名称较长时，条形图就比较适合了，柱形图上的系列名称（横坐标数据）会倾斜，甚至显示不完整。

组合图（柱形图+堆积面积图）

如图，使用堆积面积图来表示百分比，整个图表最大值是100%，有颜色填充的部分是员工已经完成的数据，可以非常清楚地看到每个人的完成率和整体的完成情况。

排列图

排列图会自动对数据进行排序，一般用于表示质量问题，可以让人一眼就找出问题的严重性和问题最多的系列。

饼图

饼图也许是用得最多的百分比图表了。百分比堆积柱形图上显示的百分比一般属于同一事物或同一个人（如已完成和未完成的比例），而普通的饼图则表示的是一个团队中每个人的贡献比例。如果要同时表现出每个人的贡献和每个人的完成情况，可以使用饼图的变体——圆环图。

图表虽多，表达出来的意义有所不同，使用哪一个，还要看自己的需要。想学习图表的制作和修改的朋友，请阅读我的文章《WPS Excel入门：图表制作方法和图表元素》。

谢谢阅读，每天学一点，省下时间充实自己其他能力。欢迎点赞、评论、关注和点击头像。

工作中，统计是无处不在的，有时是非常笼统的，有时附加有很多条件，那么我们如何去应对这些情况了？

一、COUNT函数：统计范围之内的数据类型的个数。

语法结构：COUNT(value1, [value2], ...)。

理解成：COUNT(统计范围）。

参数说明：

value1 必需。 要计算其中数字的个数的第一项、单元格引用或区域。value2, ... 可选。 要计算其中数字的个数的其他项、单元格引用或区域，最多可包含 255 个。

注意事项:

这些参数可以包含或引用各种类型的数据，但只有数字类型的数据才被计算在内。

示例：

方法：

在目标单元格中输入公式：=COUNT(C:C)。

备注：

从演示示例中我们可以看出，此函数的统计类型只能是数据类型，而不能是文本类型。

二：COUNTIF函数：统计满足条件的单元格数量。

语法结构：COUNTIF(range,create)。

理解为：COUNTIF（统计区域，查找的内容）。

参数说明：

range：必需，要统计数据的范围。create:必需，统计条件。

注意事项：统计范围内的单元格个数，可以是文本，也可以是数字。

示例：

方法：

在目标单元格中输入公式：=COUNTIF(D:D,"男")或=COUNTIF(C:C,">59")。

备注：

从演示示例中我们就可以看出，此函数的统计不仅仅是数据，还可以是文本。

三、COUNTIFS函数：多条件下的单元格个数。

语法结构：

COUNTIFS(criteria_range1, criteria1, [criteria_range2, criteria2],…)。

理解为：COUNTIFS（条件范围1，条件1，条件范围2，条件2……）

参数说明：

criteria_range1 必需。 在其中计算关联条件的第一个区域。criteria1 必需。 条件的形式为数字、表达式、单元格引用或文本，它定义了要计数的单元格范围。 例如，条件可以表示为 32、">32"、B4、"apples"或 "32"。criteria_range2, criteria2, ... 可选。 附加的区域及其关联条件。 最多允许 127 个区域/条件对。

示例：

方法：

在目标单元格输入公式：=COUNTIFS(C:C,">59",D:D,"男")。

Excel中的函数非常的多，但是在我们的实际工作中经常用到的也就那么几个，如果对这些常用的函数能够熟练的掌握，相信对提升我们的工作效率会有很大的帮助。

一、从身份证号中提取性别。

方法：

1、选定目标单元格。

2、在目标单元格中输入公式：=IF(MOD(MID(C3,17,1),2),"男","女")。

3、Ctrl+Enter填充。

二、根据身份证号计算年龄。

方法：

1、选定目标单元格。

2、输入公式：=DATEDIF(TEXT(MID(C3,7,8),"00-00-00"),TODAY(),"y")&"周岁"。

3、Ctrl+Enter填充。

三、计算指定的日期是星期几。

方法：

1、选定目标单元格。

2、输入公式：=TEXT(B3,"aaaa")。

3、Ctrl+Enter填充。

四、指定日期所在月有多少天。

方法：

1、选定目标单元格。

2、输入公式：=DAY(EOMONTH(B3,0))

3、Ctrl+Enter填充。

五、查询日期所在上中下旬。

方法：

1、选定目标单元格。

2、输入公式：=LOOKUP(DAY(B3),{0,11,21},{"上旬","中旬","下旬"})。

3、Ctrl+Enter填充。

六、将日期转换为无分割线格式。

方法：

1、选定目标单元格。

2、输入公式：=TEXT(B3,"emmdd")。

3、Ctrl+Enter填充。

七、将日期转换为有分割线格式。

方法：

1、选定目标单元格。

2、输入公式：=TEXT(B3,"0!/00!/00")。

3、Ctrl+Enter填充。

八、判断所属内容是否重复。

方法：

1、选定目标单元格。

2、输入公式：=IF(COUNTIF($E$3:$E$9,E3)>1,"重复","")。

3、Ctrl+Enter填充。

九、中国式排名。

方法：

1、选定目标单元格。

2、输入公式：=SUMPRODUCT(($E$3:$E$9>E3)/COUNTIF($E$3:$E$9,$E$3:$E$9))+1。

3、Ctrl+Enter填充。

1、取绝对值

=ABS(数字)

2、取整

=INT(数字)

3、四舍五入

=ROUND(数字,小数位数)

二、判断公式

1、把公式产生的错误值显示为空

公式：C2

=IFERROR(A2/B2,"")

说明：如果是错误值则显示为空，否则正常显示。

2、IF多条件判断返回值

公式：C2

=IF(AND(A2<500,B2="未到期"),"补款","")

说明：两个条件同时成立用AND,任一个成立用OR函数。

三、统计公式

1、统计两个表格重复的内容

公式:B2

=COUNTIF(Sheet15!A:A,A2)

说明：如果返回值大于0说明在另一个表中存在，0则不存在。

2、统计不重复的总人数

公式：C2

=SUMPRODUCT(1/COUNTIF(A2:A8,A2:A8))

说明:用COUNTIF统计出每人的出现次数，用1除的方式把出现次数变成分母，然后相加。

四、求和公式

1、隔列求和

公式：H3

=SUMIF($A$2:$G$2,H$2,A3:G3)

或

=SUMPRODUCT((MOD(COLUMN(B3:G3),2)=0)*B3:G3)

说明：如果标题行没有规则用第2个公式

2、单条件求和

公式：F2

=SUMIF(A:A,E2,C:C)

说明：SUMIF函数的基本用法

3、单条件模糊求和

公式：详见下图

说明：如果需要进行模糊求和，就需要掌握通配符的使用，其中星号是表示任意多个字符，如"*A*"就表示a前和后有任意多个字符，即包含A。

4、多条件模糊求和

公式：C11

=SUMIFS(C2:C7,A2:A7,A11&"*",B2:B7,B11)

说明：在sumifs中可以使用通配符*

5、多表相同位置求和

公式：b2

=SUM(Sheet1:Sheet19!B2)

说明：在表中间删除或添加表后，公式结果会自动更新。

6、按日期和产品求和

公式：F2

=SUMPRODUCT((MONTH($A$2:$A$25)=F$1)*($B$2:$B$25=$E2)*$C$2:$C$25)

说明：SUMPRODUCT可以完成多条件求和

五、查找与引用公式

1、单条件查找公式

公式1：C11

=VLOOKUP(B11,B3:F7,4,FALSE)

说明：查找是VLOOKUP最擅长的，基本用法

2、双向查找公式

公式：

=INDEX(C3:H7,MATCH(B10,B3:B7,0),MATCH(C10,C2:H2,0))

说明：利用MATCH函数查找位置，用INDEX函数取值

3、查找最后一条符合条件的记录。

公式：详见下图

说明：0/(条件)可以把不符合条件的变成错误值，而lookup可以忽略错误值

4、多条件查找

公式:详见下图

说明:公式原理同上一个公式

5、指定区域最后一个非空值查找

公式;详见下图

说明：略

6、按数字区域间取对应的值

公式：详见下图

公式说明：VLOOKUP和LOOKUP函数都可以按区间取值，一定要注意，销售量列的数字一定要升序排列。

六、字符串处理公式

1、多单元格字符串合并

公式：c2

=PHONETIC(A2:A7)

说明：Phonetic函数只能对字符型内容合并，数字不可以。

2、截取除后3位之外的部分

公式：

=LEFT(D1,LEN(D1)-3)

说明：LEN计算出总长度,LEFT从左边截总长度-3个

3、截取-前的部分

公式:B2

=Left(A1,FIND("-",A1)-1)

说明：用FIND函数查找位置，用LEFT截取。

4、截取字符串中任一段的公式

公式:B1

=TRIM(MID(SUBSTITUTE($A1," ",REPT(" ",20)),20,20))

说明:公式是利用强插N个空字符的方式进行截取

5、字符串查找

公式：B2

=IF(COUNT(FIND("河南",A2))=0,"否","是")

说明: FIND查找成功，返回字符的位置，否则返回错误值，而COUNT可以统计出数字的个数，这里可以用来判断查找是否成功。

6、字符串查找一对多

公式：B2

=IF(COUNT(FIND({"辽宁","黑龙江","吉林"},A2))=0,"其他","东北")

说明：设置FIND第一个参数为常量数组，用COUNT函数统计FIND查找结果

七、日期计算公式

1、两日期相隔的年、月、天数计算

A1是开始日期（2011-12-1），B1是结束日期(2013-6-10)。计算：

相隔多少天？=datedif(A1,B1,"d") 结果：557

相隔多少月? =datedif(A1,B1,"m") 结果：18

相隔多少年? =datedif(A1,B1,"Y") 结果：1

不考虑年相隔多少月？=datedif(A1,B1,"Ym") 结果：6

不考虑年相隔多少天？=datedif(A1,B1,"YD") 结果：192

不考虑年月相隔多少天？=datedif(A1,B1,"MD") 结果：9

datedif函数第3个参数说明：

"Y" 时间段中的整年数。

"M" 时间段中的整月数。

"D" 时间段中的天数。

"MD" 天数的差。忽略日期中的月和年。

"YM" 月数的差。忽略日期中的日和年。

"YD" 天数的差。忽略日期中的年。

2、扣除周末天数的工作日天数

公式：C2

=NETWORKDAYS.INTL(IF(B2

说明：返回两个日期之间的所有工作日数，使用参数指示哪些天是周末，以及有多少天是周末。周末和任何指定为假期的日期不被视为工作日

Excel的强大之处在于数据的处理分析，如果对简单的数据不会处理分析，那就有些OUT了……

一、自动记录资料录入时间。

方法：

1、选中记录时间单元格。

2、快捷键：Ctrl+1打开【设置单元格格式】对话框，选择【分类】中的【自定义】，【类型】中的【yyyy/m/d h:mm】。

3、确定。

4、【文件】-【选项】-【公式】，选择【计算选项】中的【启用迭代计算】。

5、目标单元格中输入公式：=IF(B3="","",IF(F3="",NOW(),F3))。

二、数据可视化。

方法：

1、设置目标单元格的字体为：Arial Black，字号为80号。

2、输入公式：=REPT("-",C3)。

3、Ctrl+Enter填充。

三、按指定条件填充序号。

方法：

1、选定目标单元格。

2、输入公式：=IF(B3<>"",1,D2+1)。

3、Ctrl+Enter填充。

四、指定条件下的排序。

方法：

1、选定目标单元格。

2、输入公式：=COUNTIF(E$3:E3,E3)。

3、Ctrl+Enter填充。

五、对合并单元格填充序号。

方法：

1、选定目标单元格。

2、输入公式：=MAX(A$2:A2)+1。

3、Ctrl+Enter填充。

六、对合并单元格填充序号。

方法：

1、选定目标单元格。

2、输入公式：=COUNTA(A$2:A2)。

3、Ctrl+Enter填充。

七、合并单元格计数。

方法：

1、选定目标单元格。

2、输入公式：=COUNTA(E3:E9)-SUM(F4:F9)。

3、Ctrl+Enter填充。

八、合并单元格求和。

方法：

1、选定目标单元格。

2、输入公式：=SUM(C3:C9)-SUM(F4:F9)。

3、Ctrl+Enter填充。

相对于高大上的函数公式技巧，在实际的工作中，我们经常使用的反倒是一些常见的函数公式，如果能对常用的函数公式了如指掌，对工作效率的提高绝对不止一点……

一、条件判断：IF函数。

目的：判断成绩所属的等次。

方法：

1、选定目标单元格。

2、在目标单元格中输入公式：=IF(C3>=90,"优秀",IF(C3>=80,"良好",IF(C3>=60,"及格","不及格")))。

3、Ctrl+Enter填充。

解读：

IF函数是条件判断函数，根据判断结果返回对应的值，如果判断条件为TRUE，则返回第一个参数，如果为FALSE，则返回第二个参数。

二、条件求和：SUMIF、SUMIFS函数。

目的：求男生的总成绩和男生中分数大于等于80分的总成绩。

方法：

1、在对应的目标单元格中输入公式：=SUMIF(D3:D9,"男",C3:C9)或=SUMIFS(C3:C9,C3:C9,">=80",D3:D9,"男")。

解读：

1、SUMIF函数用于单条件求和。暨求和条件只能有一个。易解语法结构为：SUMIF（条件范围，条件，求和范围）。

2、SUMIFS函数用于多条件求和。暨求和条件可以有多个。易解语法结构：SUMIFS（求和范围，条件1范围，条件1，条件2范围，条件2,……条件N范围，条件N）。

三、条件计数：COUNTIF、COUNTIFS函数。

目的：计算男生的人数或男生中成绩>=80分的人数。

方法：

1、在对应的目标单元格中输入公式：=COUNTIF(D3:D9,"男")或=COUNTIFS(D3:D9,"男",C3:C9,">=80")。

解读：

1、COUNTIF函数用于单条件计数，暨计数条件只能有一个。易解语法结构为：COUNTIF(条件范围，条件).

2、COUNTIFS函数用于多条件计数，暨计数条件可以有多个。易解语法结构为：COUNTIFS（条件范围1，条件1，条件范围2，条件2……条件范围N，条件N）。

四、数据查询：VLOOKUP函数。

目的：查询相关人员对应的成绩。

方法：

在目标单元格中输入公式：=VLOOKUP(H3,B3:C9,2,0)。

解读：

函数VLOOKUP的基本功能就是数据查询。易解语法结构为：VLOOKUP（查找的值，查找范围，找查找范围中的第几列，精准匹配还是模糊匹配）。

五、逆向查询：LOOKUP函数。

目的：根据学生姓名查询对应的学号。

方法：

在目标单元格中输入公式：=LOOKUP(1,0/(B3:B9=H3),A3:A9)。

解读：

公式LOOKUP函数的语法结构为：LOOKUP（查找的值，查找的条件，返回值的范围）。本示例中使用的位变异用法。查找的值为1，条件为0。根据LOOKUP函数的特点，如果 LOOKUP函数找不到 lookup_value，则该函数会与 lookup_vector 中小于或等于 lookup_value 的最大值进行匹配。

六、查询好搭档：INDEX+MATCH 函数

目的：根据姓名查询对应的等次。

方法：

在目标单元格中输入公式：=INDEX(E3:E9,MATCH(H3,B3:B9,0))。

解读：

1、INDEX函数：返回给定范围内行列交叉处的值。

2、MATCH函数：给出指定值在指定范围内的所在位置。

3、公式：=INDEX(E3:E9,MATCH(H3,B3:B9,0))，查询E3:E9中第MATCH(H3,B3:B9,0)行的值，并返回。

七、提取出生年月：TEXT+MID函数。

目的：从指定的身份证号码中提取出去年月。

方法：

1、选定目标单元格。

2、输入公式：=TEXT(MID(C3,7,8),"00-00-00")。

3、Ctrl+Enter填充。

解读：

1、利用MID函数从C3单元格中提取从第7个开始，长度为8的字符串。

2、利用TEXT函数将字符的格式转换为“00-00-00”的格式，暨1965-08-21。

八、计算年龄：DATEDIF函数。

目的：根据给出的身份证号计算出对应的年龄。

方法：

1、选定目标单元格。

2、输入公式：=DATEDIF(TEXT(MID(C3,7,8),"00-00-00"),TODAY(),"y")&"周岁"。

3、Ctrl+Enter填充。

解读：

1、利用MID获取C3单元格中从第7个开始，长度为8的字符串。

2、用Text函数将字符串转换为：00-00-00的格式。暨1965-08-21。

3、利用DATEDIF函数计算出和当前日期（TODAY（））的相差年份（y）。

九、中国式排名：SUMPRODUCT+COUNTIF函数。

目的：对成绩进行排名。

方法：

1、选定目标单元格。

2、在目标单元格中输入公式：=SUMPRODUCT((C$3:C$9>C3)/COUNTIF(C$3:C$9,C$3:C$9))+1。

3、Ctrl+Enter填充。

解读：公式的前半部分(C$3:C$9>C3)返回的是一个数组，区域C$3:C$9中大于C3的单元格个数。后半部分COUNTIF(C$3:C$9,C$3:C$9)可以理解为：*1/COUNTIF(C$3:C$9,C$3:C$9),公式COUNTIF(C$3:C$9,C$3:C$9)返回的值为1，只是用于辅助计算。所以上述公式也可以简化为：=SUMPRODUCT((C$3:C$9>C3)*1)+1。

复合增长率又称为年均复合增长率，英文为 Compound Annual Growth Rate，通常只用简写 CAGR 代替；它是用来描述一个投资在一定时期内的年度增长率。与算术平均增长率相比，复合增长率是几何平均增长率，也就是平常所说的利滚利，即本年的利息也计入下一年的本金获利。在 Excel 中，计算复合增长率分为百分比和数字两种形式，它们都可用同一个公式计算，下就是它们用 Excel 计算的具体操作方法，操作中所用版本均为 Excel 2016。

一、Excel计算百分比形式的年均复合增长率

1、添加辅助列，并在该列给每个百分比增长率加 1。双击 C2 单元格，输入公式 =b2+1，按回车，返回 113%；选中 C2，把鼠标移到 C2 右下角的单元格填充柄上，鼠标变为加号后双击左键，则 B 列剩余的增长率全部都加 1。

2、计算年均复合增长率。双击 C8 单元格，把公式 =(PRODUCT(C2:C7))^(1/(YEAR(A7)-YEAR(A2)))-1 复制到 C8，按回车，返回 0.056567391；确保当前选项卡为“开始”，单击“百分号（%）”（或按快捷键 Ctrl + Shift + %），则小数转为百分数且不保留小数和自动四舍五入；操作过程步骤，如图1所示：

提示：如果要保留一位小数，选中 C8 后，按 Ctrl + 1（需关闭汉语输入法），打开“设置单元格格式”窗口， 选择“数字”选项卡，再选择左边的“百分比”，在右边“小数位数”后输入 1，单击“确定”，则 6% 变为 5.7%，如图2所示：

3、增长率为什么要加 1？因为本年价值 = 上年价值 × （1 + 增长率），而复合增长率 =（现有价值/基础价值)^(1/年数) - 1，即求复合增长率需要把增长率转为“现有价值/基础价值”形式，则（本年价值/上年价值）= 1 + 增长率。

4、公式 =(PRODUCT(C2:C7))^(1/(YEAR(A7)-YEAR(A2)))-1 说明：

A、PRODUCT(C2:C7) 是把 C2 至 C7 的每个数值相乘，结果为 1.316697512。

B、YEAR(A7) 是取 A7 中日期的年份（即返回 2018），因为 A2 到 A7 的单元格格式为日期型；如果单元格格式为数值型或文本型不需用 Year 函数取年份；YEAR(A7)-YEAR(A2) 用于计算求复合增长率的年数，结果为 5。

C、则公式变为 (1.316697512)^(1/5)-1，接着对小数求指数为 1/5 的指数运算，然后再把计算结果减 1，最后返回 0.056567391。

提示：如果“年份”连续的，还可以用 Count(A2:A7) -1 来统计“年数”，则公式变为 =(PRODUCT(C2:C7))^(1/(Count(A2:A7)-1))-1。

二、Excel计算数字形式的年均复合增长率

1、假如有一个 2013 年到 2018 年的投资表，“资产”列出的是每年的总资产，现在要求年均复合增长率。双击 B8 单元格，把公式 =(B7/B2)^(1/(YEAR(A7)-YEAR(A2)))-1 复制到 B8，按回车，返回 0.108318466，按快捷键 Ctrl + Shift + % 把小数转为百分数；操作过程步骤，如图3所示：

2、公式说明：

A、公式 =(B7/B2)^(1/(YEAR(A7)-YEAR(A2)))-1 由求复合增长率公式代入数值变化而来，B7 为现在价值，B2 为基础价值，也就是用最后一年的价值比第一年的价值；公式中的其它部分与上例中的一样。

B、另外，公式还可以用指数计算函数 Power 计算，即 =POWER(B7/B2,1/(YEAR(A7)-YEAR(A2)))-1。

提示：一年增长下一年亏损且数值大于 0 也可以用上面的方法计算，例如：第一年资产为 12000，第二年为 16000，第三年为 8000，用这个公式 =(8000/12000)^(1/2)-1 计算能获得正确的结果（返回负增长），演示如图4所示：

另外，如果次产中有负数不能简单的用“现有价值/基础价值)^(1/年数) - 1”公式求复合增长率，这样会获得错误的结果。

直接将两个数值相除即可，除号用反斜杠代替。例如求A1单元格数值占A2单元格数值百分比，则=A1/A2即可，然后需要Ctrl+1设置单元格格式为百分比格式。也可以用TEXT函数更改显示格式为百分比格式。

• 任何计算公式都需要以等号开始，例如=A1/A2

• 可以直接用TEXT函数更改格式，例如=TEXT（A1/A2，"#%")

TEXT函数详解：

1. 语法：TEXT(value,format_text)

2. Value 为数值、计算结果为数字值的公式，或对包含数字值的单元格的引用。

3. Format_text 为“单元格格式”对话框中“数字”选项卡上“分类”框中的文本形式的数字格式。

（本文内容由百度知道网友本本经销商贡献）

在 Excel 中，只要把两个数相除且将格式设置为百分比，就可以返回百分比。Excel百分比计算分为简单的、带条件的和分母为0三种情况。其中带条件的，可用 SumIf、CountIf 等函数；分母为0的情况可以用 If、IfError、IsError、IsErr 函数判断，如果分母为0，返回0或空，否返回百分比。以下就是Excel自动计算与带条件计算百分比及分母为0时的解决方法的具体操作实例，实例中操作所用版本均为 Excel 2016。

一、Excel自动计算百分比

1、假如要计算每件服装销量所占的百分比。选中 E2 单元格，输入公式 =D2/$D$11，按回车，则返回小数，单击“开始”选项下的“百分比样式” % 符号，把单元格格式设置为百分比，则小数转为百分比；把鼠标移到 E2 右下角的单元格填充柄上，按住左键，往下拖，则计算出其它服装的销量百分比；操作过程步骤，如图1所示：

2、说明：公式 =D2/$D$11 中的分子 D2 是对单元格的相对引用，分母 $D$11 是对单元格的绝对引用，往下拖时，D2 会自动变为 D3、D4、……，而 $D$11 会一直保持不变，以实现每件服装的销量与总销量相除。

二、Excel带条件计算百分比

1、假如要计算销量大于等于 600 的服装占总数的百分比。把公式 =COUNTIF(D2:D10,">=600")/COUNT(D2:D10) 复制到 E2 单元格，按回车，返回计算结果 67%，操作过程，如图2所示：

2、公式说明：

公式 =COUNTIF(D2:D10,">=600")/COUNT(D2:D10) 中，分子 =COUNTIF(D2:D10,">=600") 用于统计销量大于等于 600 的服装件数，分母 COUNT(D2:D10) 用于统计服装总数。

三、Excel计算百分比分母为0时的解决方法

计算百分比时，如果分母事先无法确定，可能出现分母为0的情况，此时将返回错误的值；因此，遇到这种情况时，应该加判断分母是否为0的条件，当分母为0时，返回0（或""），否则返回计算结果。

（一）方法一：用 if 判断

1、假如要计算1月销量占一季度总销量的百分比。把公式 =IF(G2<>0,D2/G2,0) 复制到 H2 单元格，按回车，则计算出“绿色t恤”1月销量占第一季度销量的百分比；把鼠标移到 H2 右下角的单元格填充柄上，按住左键并往下拖，则计算出其它服装1月销量占一季度销量的百分比；操作过程步骤，如图3所示：

2、公式说明：公式用if函数判断分母 G2 是否为0，如果为0，则返回0；否则返回 D2/G2。从计算结果可知，分母为0的，结果都返回0。除返回0，也可以返加空（""），用 "" 取代公式后面的 0 即可。

（二）方法二：用 IfError 判断

1、同样计算1月销量占第一季度总销量的百分比。把公式 =IFERROR(D2/G2,0) 复制到 H2 单元格，如图4所示：

2、按回车，则计算出“绿色t恤”1月销量占第一季度销量的百分比，与用If函数计算的结果一样，如图5所示：

3、同样用往下拖的方法计算出其它服装的百分比，销量全为0的百分比都为0，如图6所示：

（三）方法三：用 If 结合 IsError 或 IsErr 判断

1、同样计算1月销量占第一季度总销量的百分比。把公式 =IF(ISERROR(D2/G2),0,D2/G2) 复制到 H2 单元格，按回车，则计算出“绿色t恤”1月销量占第一季度销量的百分比；同样用往下的方法，计算出其它服装的百分比，结果与前两种方法完全一至；操作过程步骤，如图7所示：

2、公式说明：ISERROR(D2/G2) 用于判断 D2/G2 是否返回错误，如果是，则返回真，否则返回假；然后再用 if 根据 ISERROR(D2/G2) 的返回值决定是返回0还是返回 D2/G2。

3、用 IsErr 代替 IsError，则公式 =IF(ISERROR(D2/G2),0,D2/G2) 变为 =IF(ISErr(D2/G2),0,D2/G2)，计算结果与上面的三种方法一样。

以上的三种方法中，第二种方法比较简便，其次是第一种方法，第三种方法需要多计算一次百分比，数据量大时可能会影响效率，此时，可选择前两种方法。

1.在数据的最下面把数据汇总一下，在A98单元格输入总计。

2.在右边的单元格，也就是B98单元格，点击工具栏上的求和工具。

3.接着出现了这个界面，按回车键就可以了。

4.这就是求出的总计销售额。

5.接着在销售额的右边，也就是C1单元格输入 百分比。

6.在C2单元格，输入公式 =B2/$B$98 ，这个公式中运用了符号$，这是“固定不变的意思”，也就是说，一会要复制C2内的公式到别的单元格，别的单元格会根据复试的位置改变公式中的变量，加上符号$以后，变量就不变了。如刚刚输入的公式，B2是一个变量，是会改变的，但是B98这个就不变了。B98是刚才得到的销售总额。

7.拖动单元格的右下角就可以快速填充下面的单元格。

最后就得到了所有部门的百分比了。

（本文内容由百度知道网友茗童贡献）