Excel中产生随机数的函数有两个，Rand函数和Randbetween函数

Rand函数使用

Rand()不带任何参数，表示生成一个0-1的随机实数，其后面小数点可以具体到15位，如下所示：

Randbetween函数使用

在单元格中输入=randbetween(1,20)，产生的是1-20区间的随机整数

如果我们现在想要生成一串数字，它是某个区间不重复的数据

例1、生成1-10区间的不重复数据。

如果想抽取其中的几个，例如5个，则在A列中输入函数=rand()，生成的是1-10区间的，有10个数，所以从A1填充至A10，总共10个随机数，然后在B列输入=rank(a1,a:a)，需要几个就向下填充几个即可，得到的就是不重复的5个数据

如果想得到10个不重复的随机数， 那只需要将B列填充10个即可，如下所示：

例2，生成30-39区间的不重复随机数

【30-39】区间共有10个数，所以在A列生成10个rand()函数，然后在B列输入公式

=29+RANK(A1,A:A)即可

例3，生成2000-3000能除以100的整数的随机不重复整数

【2000-3000】中有11个，所以在A列填充11个rand()函数，然后在B列输入公式：=(19+RANK(A1,A:A))*100即可

其他情况也都是举一反三的，本节完

你学会了吗？为自己持续学习的态度点个赞呗！

---------------------

欢迎留言，转发，关注，更多精彩内容持续更新中...

找对比，你会首先想到

Vlookup

函数。但在Excel中只会Vlookup函数是远远不够的。今天兰色对查找公式进行一次全面的整理。

对于一个地方需要用到对比的时候我们肯定想到的是Vlookup函数，但是你在用Excel的时候只会用它可不行，今天我们就一起来梳理下常用的！

地球人都知道：一题多解的只选取最优公式！

1、普通查找VLOOKUP函数

我们需要查找李晓峰的应发工资

公式：=VLOOKUP(H2,B:F,5,0)

2、反向查找INDEX

函数

查找吴刚的员工编号

公式：=INDEX(A:A,MATCH(H2,B:B,0))

反向查找

3、交叉查找VLOOKUP函数：

查找3月办公费的金额

公式：=VLOOKUP(H2,A:F,MATCH(I2,1:1,0),0)

4、多条件查找

VLOOKUP函数

查找上海产品B的销量

公式：=LOOKUP(1,0/((A2:A7=E2)*(B2:B7=F2)),C2:C7)

5、区间查找

根据销量从右表中查找提成比率。

公式：=LOOKUP(A2,$D$2:$E$5)

6、双区间查找

根据销量和比率完成情况，从表中查找返利。

公式：=INDEX(B3:F7,MATCH(D11,A3:A7),MATCH(E11,B2:F2))

7、线型插值

A列是数量，B列是数量对应的系数值。现要求出数字8所对应的系数值。

公式：=TREND(OFFSET(B1,MATCH(D3,A2:A6,1),,2,1),OFFSET(A1,MATCH(D3,A2:A6,1),,2,1),D3)

8、查找最后一个符合条件记录

要求查找A产品的最后一次进价。

公式：=LOOKUP(1,0/(B2:B9=A13),C2:C9)

9、模糊查找

要求根据提供的城市从上表中查找该市名的第2列的值。

公式：=VLOOKUP("*"&A7&"*",A1:B4,2,0)

10、匹配查找

要求根据地址从上表中查找所在城市的提成。

公式：=lookup(9^9.find(A$3:A$6,A10),B$3:B$6)

11、最后一个非空值查找

要求查找最后一次还款日期

公式：=LOOKUP(1,0/(B2:B13<>""),$A2:$A13)

12、多工作表查找

【例10】从各部门中查找员工的基本工资，在哪一个表中不一定。

方法1

公式：=IFERROR(VLOOKUP(A2,服务!A:G,7,0),IFERROR(VLOOKUP(A2,人事!A:G,7,0),IFERROR(VLOOKUP(A2,综合!A:G,7,0),IFERROR(VLOOKUP(A2,财务!A:G,7,0),IFERROR(VLOOKUP(A2,销售!A:G,7,0),"无此人信息")))))

方法2：

公式：=VLOOKUP(A2,INDIRECT(LOOKUP(1,0/COUNTIF(INDIRECT({"销售";"服务";"人事";"综合";"财务"}&"!a:a"),A2),{"销售";"服务";"人事";"综合";"财务"})&"!a:g"),7,0)

13、一对多查找

【例】根据产品查找相对应的所有供应商

公式：

A2 =B2&COUNTIF(B$1:B2,B2)

B11=IFERROR(VLOOKUP($A11&COLUMN(A1),$A:$C,3,0),"")

14、查找销量最大的城市

查找销量最大的城市。注意：注意：注意：数组公式按ctrl+shift+enter三键输入

公式：{=INDEX(A:A,MAX((MAX(B3:B7)=B3:B7)*ROW(B3:B7)))}

15、最接近值查找

根据D4的价格，在B列查找最接近的价格，并返回相对应的日期

注意：注意：注意：数组公式按ctrl+shift+enter三键输入

公式：{=LOOKUP(1,0/(MIN(ABS(B3:B7-D4))=ABS(B3:B7-D4))*ROW(B3:B7),A3:A7)}

15、跨多文件查找

跨多个文件查找，网上大概很难找到这样的教程，仔细想想其实原理和跨多表查找一样，也是借助lookup等函数实现。

文件夹中有N个仓库产品表格，需要在“查询”文件完成查询

仓库表样式

在查询表中设置公式，根据产品名称从指定的文件中sheet1工作表查询

入库单价

公式：=VLOOKUP(A2,INDIRECT(LOOKUP(1,0/COUNTIF(INDIRECT("["&{"仓库1";"仓库2";"仓库3"}&".xlsx]sheet1!a:a"),A2),"["&{"仓库1";"仓库2";"仓库3"}&".xlsx]sheet1")&"!a:b"),2,0)。

如果你在用vlookup函数做多文件查找的时候也可以用iferror+vlookup的模式的这种模式，看起来公式很长，但是这样不会出错。此外，如果一个表用到的函数太多就需要用宏表函数用Files获取所有excel文件名称了。

老男孩PS

：我能想到的基本上都已经列出来了，但是我相信有很多大家可能看不懂，但是看不懂没关系，赶紧收藏起来，然后直接套用就可以了。

把会计常用的Excel公式进行一次大整理，大约15个，希望对做会计工作的同学们有用。

1、文本与百分比连接公式

如果直接连接，百分比会以数字显示，需要用Text函数格式化后再连接

="本月利润完成率为"&TEXT(C2/B2,"0%")

2、账龄分析公式

用lookup函数可以划分账龄区间

=LOOKUP(D2,G$2:H$6)

如果不用辅助区域，可以用常量数组

=LOOKUP(D2,{0,"小于30天";31,"1~3个月";91,"3~6个月";181,"6-1年";361,"大于1年"})

3、屏蔽错误值公式

把公式产生的错误值显示为空

公式：C2

=IFERROR(A2/B2,"")

说明：如果是错误值则显示为空，否则正常显示。

4、完成率公式

如下图所示，要求根据B的实际和C列的预算数，计算完成率。

公示：E2

=IF(C3<0,2-B3/C3,B3/C3)

5、同比增长率公式

如下图所示，B列是本年累计，C列是去年同期累计，要求计算同比增长率。

公示：E2

=(B2-C2)/IF(C2>0,C2,-C2)

6、金额大小写公式

=TEXT(LEFT(RMB(A2),LEN(RMB(A2))-3),"[>0][dbnum2]G/通用格式元;[<0]负[dbnum2]G/通用格式元;;")&TEXT(RIGHT(RMB(A2),2),"[dbnum2]0角0分;;整")

7、多条件判断公式

公式：C2

=IF(AND(A2<500,B2="未到期"),"补款","")

说明：两个条件同时成立用AND,任一个成立用OR函数。

8、单条件查找公式

公式1：C11

=VLOOKUP(B11,B3:F7,4,FALSE)

9、双向查找公式

公式：

=INDEX(C3:H7,MATCH(B10,B3:B7,0),MATCH(C10,C2:H2,0))

说明：利用MATCH函数查找位置，用INDEX函数取值

10、多条件查找公式

公式：C35

=Lookup(1,0/((B25:B30=C33)*(C25:C30=C34)),D25:D30)

11、单条件求和公式

公式：F2

=SUMIF(A:A,E2,C:C)

12、多条件求和公式

=Sumifs(c2:c7,a2:a7,a11,b2:b7,b11)

13、隔列求和公式

公式H3:

=SUMIF($A$2:$G$2,H$2,A3:G3)

如果没有标题，那只能用稍复杂的公式了。

=SUMPRODUCT((MOD(COLUMN(B3:G3),2)=0)*B3:G3)

14、两条查找相同公式

公式:B2

=COUNTIF(Sheet15!A:A,A2)

说明：如果返回值大于0说明在另一个表中存在，0则不存在。

15、两表数据多条件核对

如下图所示，要求核对两表中同一产品同一型号的数量差异，显示在D列。

公式：D10

=SUMPRODUCT(($A$2:$A$6=A10)*($B$2:$B$6=B10)*$C$2:$C$6)-C10

根据日期计算年、月、日等都有相对应的函数，你知道怎么算吗？其实非常的简单。年：=YEAR(C3)；月：=MONTH(C3)；日：=DAY(C3)。其中C3为对应的日期所在的单元格地址。

如果给定了日期，让你去判断上旬、中旬、下旬，你会吗？

根据日期自动计算上旬、中旬、下旬。

方法：

1、选定目标单元格。

2、输入公式：=LOOKUP(DAY(C3),{1,11,21},{"上旬","中旬","下旬"})。

3、Ctrl+Enter填充。

备注：

1、从公式中我们可以看出，此功能就是用DAY函数和LOOKUP函数配合实现的。

2、原理：1-10号是上旬，11-20号是中旬，21号至月底是下旬，搞清楚上中下旬的时间之后才能进行进一步的计算。

3、利用DAY函数提取日期。

4、公式：=LOOKUP(DAY(C3),{1,11,21},{"上旬","中旬","下旬"})中的参数{1,11,21}就是为了界定三个区间。

5、根据三个区间的值返回对应的值。

到期提醒，看字眼就觉得温馨实用，尤其在智能化管理的现在。但是在Excel中如何去设置呢？

一、到期前“7”天提醒。

方法：

在目标单元格中输入公式：=IF((E3-TODAY())<8,"合同快到期了","")。

二、一定范围内，还剩X天到期提醒。

方法：

=IF((E3-TODAY())<8,"此合同还有"&E3-TODAY()&"天就到期了","")

三、还剩X天到期提醒。

方法：

在目标单元格中输入公式：="此合同还有"&E3-TODAY()&"天就到期了"。

四、颜色和文字共同提醒。

方法：

1、选定合同到期日期。

2、【条件格式】-【新建规则】-【使用公式确定要设置格式的单元格】。

3、输入公式：=e3-today()<8，并【确定】。

4、在文字提醒单元格输入公式：=IF((E3-TODAY())<8,"此合同还有"&E3-TODAY()&"天就到期了","")。

在需要查找时，很多童鞋会首先想到VLOOKUP函数。但有时候仅仅只会VLOOKUP函数是远远不够的。今天小编为大家进行了一次全面的整理，一起来看吧！

一、普通查找

查找李晓峰的应发工资。在对应单元格中输入“=VLOOKUP(H2,B:F,5,0)”

二、反向查找

查找吴刚的员工编号。在对应单元格中输入“=INDEX(A:A,MATCH(H2,B:B,0))”

三、交叉查找

查找3月办公费的金额。在对应单元格中输入“=VLOOKUP(H2,A:F,MATCH(I2,1:1,0),0)”

四、多条件查找

查找上海产品B的销量。在对应单元格中输入“=LOOKUP(1,0/((A2:A7=E2)*(B2:B7=F2)),C2:C7)”

五、区间查找

根据销量从右表中查找提成比率。在对应单元格中输入“=LOOKUP(A2,$D$2:$E$5)”

六、双区间查找

根据销量和比率完成情况，从表中查找返利。

在对应单元格中输入“=IDNEX(B3:F7,MATCH(D11,A3:A7),MATCH(E11,B2:F2))”

七、线性插值

求数字8所对应的系数值。在对应单元格中输入“=TREND(OFFSET(B1,MATCH(D3,A2:A6,1),,2,1),OFFSET(A1,MATCH(D3,A2:A6,1),,2,1),D3）”

八、查找最后一个符合条件记录

查找A产品最后一次进价。在对应单元格中输入“=LOOKUP(1,0/(B2:B9=A13),C2:C9)”

九、模糊查找

根据提供的城市从表中查找该市名的第2列的值。在对应单元格中输入“VLOOKUP("*"&A7&"*",A1:B4,2,0)”

十、匹配查找

根据地址从表中查找所在城市的提成。在对应单元格中输入“=LOOKUP(9^9.FIND(A$3:A$6,A10),B$3:B$6)”

十一、最后一个非空值查找

查找最后一次还款日期。在对应单元格中输入“=LOOKUP(1,0/(B2:B13<>""),$A2:$A13)”

十二、多工作表查找

从各部门中查找员工的基本工资，在哪个表中不一定。

方法1：

在对应单元格中输入“=IFERROR(VLOOKUP(A2,服务!A:G,7,0),IFERROR(VLOOKUP(A2,人事!A:G,7,0),IFERROR(VLOOKUP(A2,综合!A:G,7,0),IFERROR(VLOOKUP(A2,财务!A:G,7,0),IFERROR(VLOOKUP(A2,销售!A:G,7,0),"无此人信息”)))))”

方法2：

在对应单元格中输入“=VLOOKUP(A2,INDIRECT(LOOKUP(1,0/COUNTIF(INDIRECT({"销售";"服务";"人事";"综合";"财务"}&"!a:a"),A2),{"销售";"服务";"人事";"综合";"财务"})&"!a:g"),7,0)

十三、一对多查找

根据产品查找对应的所有供应商。在A2单元格中输入“=B2&COUNTIF(B$1:B2,B2)”;

在B11单元格中输入“=IFERROR(VLOOKUP($A11&COLUMN(A1),$A:$C,3,0),""”

十四、查找销量最大的城市

查找销量最大的城市（数组公式按ctrl+shift+enter三键输入）

在对应单元格输入“{=INDEX(A:A,MAX((MAX(B3:B7)=B3:B7)*ROW(B3:B7)))}”

十五、最接近值查找

根据D4的价格，在B列查找最接近的价格，并返回相对应的日期。（数组公式按ctrl+shift+enter三键输入）

在对应单元格输入“=LOOKUP(1,0/MIN(ABS(B3:B7-D4))=ABS(B3:B7-D4))*ROW(B3:B7),A3:A7)}”

十六、跨多文件查找

文件夹中有N个仓库产品表格，需要在“查询”文件完成查询。

仓库表样式

在查询表中设置公式，根据产品名称从指定文件中sheet1工作表查询入库单价。在对应单元格输入“=VLOOKUP(A2,INDIRECT(LOOKUP(1,0/COUNTIF(INDIRECT("["&{"仓库1";"仓库2";"仓库3"}&".xlsx]sheet1!a:a")A2),"["&{"仓库1";"仓库2";"仓库3"}&".xlsx]sheet1")&"!a:b"),2,0)”

平时会用到的查找公式基本就这么多了。其中有不少公式需要有一定基础才能看懂，如果不太明白可以先套用，日后慢慢理解。

今天的Excel查找公式就讲到这里了，这些内容对于你的工作或学习有没有帮助呢？如果你有任何问题，记得在评论区留言，小编看到后会第一时间回复。

如果评选提问最多的Excel公式，就是各种多条件公式。比如多条件判断，多条件查找，多条件求和，多条件求平均值、多条件求最大值....今天就把这些工作中应用最多又最难的公式整理！

1、多条件区间判断

【例1】按销售量计算计成比率。

2、多条件组合判断

【例2】如果金额小于500并且B列为“未到期”则返回补款，否则为空

=IF(AND(A2<500,B2="未到期"),"补款","")

说明：两个条件同时成立用AND,任一个成立用OR函数。

3、多条件求和

【例3】计算A列产品中包含“电视”并且B列地区为郑州的数量之和

公式：C11

=SUMIFS(C2:C7,A2:A7,A11&"*",B2:B7,B11)

说明：在sumifs中可以使用通配符*

4、多条件计数

【例4】根据下图，统计公司1人事部有多少人

=COUNTIFS(A2:A6,"公司1",B2:B6,"人事部")

5、多条件查找

【例5】要求根据入库时间和产品名称进行查找。

6、双向查找

【例6】要求在上表中根据姓名和月份查找销售量

公式：

=INDEX(C3:H7,MATCH(B10,B3:B7,0),MATCH(C10,C2:H2,0))

说明：利用MATCH函数查找位置，用INDEX函数取值

7、多条件求平均值

【例7】要求计算公司1人事部的平均工资

公式

=AVERAGEIFS(D2:D9,A2:A9,"公司1",B2:B9,"人事部")

8、多条件求最大值

【例8】要求计算公司1人事部的最高工资

数组公式（输入后同时按ctrl+shift+enter三键结束输入）

{=MAX((A2:A9="公司1")*(B2:B9="人事部")*D2:D9)}

这几个excel公式在实际工作中起着非常重要的作用。所以小伙伴们，千万不要独享

Excel函数公式的威力强大众所周知，但很多人还是用不好，原因之一是没有将千变万化的各种形式的公式实质性看透，只懂皮毛。

为了让大家更容易理解公式的框架结构和扩展方法，今天带来的这几个万能公式，会结合Excel实例展开，并且给出不同应用场景下的扩展方法。

1 多条件计数统计

2 多条件求和统计

3 多条件查找引用数据

万能公式的万能之处，最终不在于公式本身，而在于使用公式的人。

1 多条件计数统计

按照多个条件进行计数统计，是工作中很常见的需求。

咱们先看个按照两个条件统计符合条件的个数的数据的案例吧

案例场景截图如下：

F2=COUNTIFS(A:A,E2,C:C,">500")

多条件计数统计的万能公式

=COUNTIFS(条件区域1，条件1，条件区域2，条件2.....条件区域N，条件N)

这样，即使有再多的条件，以此类推，在公式中添加参数扩展即可。

2 多条件求和统计

按照多个条件进行求和汇总统计，也是办公一族常遇到的事了。

案例场景截图如下：

G2=SUMIFS($D:$D,$A:$A,$F2,$C:$C,G$1)

注意这个公式中的单元格混合引用的应用

多条件求和统计的万能公式

=SUMIFS(求和区域，条件区域1，条件1，条件区域2，条件2.....条件区域N，条件N)

利用SUMIFS，先声明求和区域，再依次罗列各种条件区域和条件，即使有再多的条件，以此类推，在公式中添加参数扩展即可。

3 多条件查找引用数据

查找引用数据的需求，几乎每天都有，如果你还只会Vlookup，那很多问题是无法解决的。

比如下面的这个多条件查找引用数据的问题。

案例场景截图如下：

=LOOKUP(1,0/(($B$2:$B$13=F2)*($C$2:$C$13=G2)),$D$2:$D$13)

多条件查找引用数据的万能公式

=LOOKUP(1,0/((查找条件1)*(查找条件2)*......*(查找条件N)),查找结果所在区域)

利用LOOKUP函数可以忽略错误值查找，以及支持区间判断查找的特性，再多的查找条件，按如上万能公式套用即可。

今天的分享就到这里，希望能够帮到大家轻松应对各种情况的工作日计算！

如果你觉得有用，就分享给朋友们看看吧~ 记得关注我哦 谢谢大家！！ 明天再见

　　例：某商店随机抽查10名营业员，统计他们的日营业额（千元）如附图5-1中的“A2：A11”。假定该商店各营业员的日营业额是服从正态分布，试以95%的置信水平估计该商店营业员的日营业额的置信区间。为构造区间估计的工作表，在工作表中输入下列内容：A列输入样本数据，B列输入变量名称，C列输入计算公式，其实C列中当计算公式输入后显现的是计算结果，为了说明计算过程，在D列中展示C列的计算公式。

　　第1步：把样本数据输入到A2：A11单元格

　　第2步：在C2中输入公式“＝COUNT（A2：A11）”，得到计算结果“10”。“COUNT”是计数函数，得出样本容量（n＝10）。

　　第3步：在C3中输入“＝AVERAGE（A2：A11）”，在C4中输入“＝STDEV（A2：A11）”，在C5中输入“＝C4/SQRT（C2）”，在C6中输入0.95，在C7中输入“＝C2-1”，在C8中输入“＝TINV（1-C6，C7）”，在C9中输入“＝C8*C5”，在C10中输入“＝C3-C9”，在C11中输入“＝C3＋C9”。在输入每一个公式回车后，便可得到如下图的结果。

　　从上面的结果可以知道，该商店营业员的日营业额的置信下限为35.3989071 （千元），置信上限为41.4010929 （千元）。计算结果可以得出，有95%的把握认为该商店营业员的日营业额平均在35.3989071（千元）到41.4010929（千元）之间。

　　在附表中，对于不同的样本数据，依上表的格式，只要输入新的样本数据，再对C列公式略加修改，置信区间就会自动给出。

（本文内容由百度知道网友yjtkgg321贡献）

Excel中，多层区间查询时非常普遍的应用，遇到此类问题，大多同学都是一一对照手动填充的，其实，我们也可以使用Excel函数公式来自动完成查询填充功能。

一、问题描述。

如下图：

我们要从右侧的消费规则中查询消费人员对应的会员等级，该如何去实现了？

二、解决办法。

1、IF函数嵌套法。

方法：

在目标单元格中输入公式：=IF(C3>=50000,"至尊卡",IF(C3>=30000,"金卡",IF(C3>=15000,"银卡",IF(C3>=8000,"五级",IF(C3>=5000,"四级",IF(C3>=3000,"三级",IF(C3>=2000,"二级",IF(C3>=1000,"一级","无等级"))))))))。

释义：

1、此方法利用IF函数嵌套的方式实现，如果会员等级复杂，嵌套的次数就非常的繁多，并且容易出错。

2、书写公式时必须从“高等级”依次向“低等级”书写，不能跳跃，否则就会出现错误。

2、VLOOKUP函数模糊查询法。

方法：

在目标单元格中输入公式：=IFERROR(VLOOKUP(C3,$H$3:$I$10,2),"无等级")。

释义：

1、IFERROR函数为辅助函数，如果数值在表格中查询不到对应的数据，则返回“无等级”。暨消费金额小于1000元时为“无等级”。

2、如果消费金额大于1000原始，执行VLOOKUP(C3,$H$3:$I$10,2)查询，我们不难发现，VLOOKUP函数得第四个参数被省略，此时为模糊查询，暨在第二个参数中找不到第一个参数时，返回比查询值小但最接近查询值的对应值。例如：查询2100时，返回的是2000所对应的值。

3、LOOKUP函数查询法。

方法：

在目标单元格中输入公式：=IFERROR(LOOKUP(C3,$H$3:$I$10),"无等级")。

释义：

1、IFERROR函数为辅助函数，当查询不到对应的值时返回“无等级”。暨消费金额小于1000元时，返回“无等级”。

2、当消费金额大于等于1000元时，执行LOOKUP(C3,$H$3:$I$10)，查询，如果查询不到对应的值，则返回小于且最接近于查询值的对应值。例如：查询2100时，返回的是2000所对应的值。