if从字面上了解是“如果”“是否”“假设”的意思，而各大编程语言都会用到if这个单词，它的功能也正是字面所说的那样，行使判断的功能，Excel中的if函数也是如此。

Excel if函数是根据指定的条件来判断其“真”（TRUE）、“假”（FALSE），从而返回相应的内容。下面给大家讲个实例，如下表所示，判断“学生考试成绩是否及格”来说明Excel if函数的用法。

步骤

选中D2单元格，在编辑栏输入=IF(C2>=60,"及格","不及格")。

按下回车键，即可判断是否及格，并返回相应值。

选中D2单元格，双击右下角的自动填充柄，即可实现下面单元格的自动填充。

Excel if函数用法

1．IF函数的语法结构 IF函数的语法结构：IF(条件,结果1,结果2)。2．IF函数的功能 对满足条件的数据进行处理，条件满足则输出结果1，不满足则输出结果2。可以省略结果1或结果2，但不能同时省略。3．条件表达式 把两个表达式用关系运算符(主要有=，<>，>，<，>=，<=等6个关系运算符)连接起来就构成条件表达式。4．IF函数嵌套的执行过程 如果按等级来判断某个变量，IF函数的格式如下： =IF(C2>=90,"优",IF(C2>=75,"良"，IF(C2>=60,"及格"，"不及格")))。函数从左向右执行。首先计算C2>=90，如果该表达式成立，则显示“优”，如果不成立就继续计算C2>=75，如果该表达式成立，则显示“良”，否则继续计算C2>=60，如果该表达式成立，则显示“及格”，否则显示“不及格”。现在把这个公式用到成绩判定上，结果如下图所示。

鸣谢：

若喜欢本篇文章，记得点赞、评论和转发哦！

如有问题，欢迎向小编提问。

突出显示重复数据

1、选中A2:A11单元格区域，新建格式规则

2、使用公式为：

=COUNTIF(A$2:A2,A2)>1

3、设置突出显示的格式

提示：

COUNTIF函数第一参数使用A$2:A2，表示从A2单元格开始至公式所在行的A列。在这个动态扩展的范围中，统计有多少个单元格与公式所在行的内容相同。

突出显示每种商品的最低价格

1、选中B4:F13单元格区域，新建格式规则

=B4=MIN($B4:$F4)

1、MIN($B4:$F4)部分计算出公式所在行的最小值。

2、然后判断B4（活动单元格），是否等于公式所在行的最小值。

3、在条件格式中，针对活动单元格的设置，将被作用到所选区域的每一个单元格。

突出显示已完成合同

1、选中A4:F13单元格区域，新建格式规则

=$F4="是"

本例需要特别注意引用方式，因为每一列都是依据F列的判断结果来显示条件格式，所以要使用列绝对引用。

突出显示周末日期

1、选中A3:F7单元格区域，新建格式规则

=WEEKDAY(A$3,2)>5

1、WEEKDAY函数返回某日期为星期几。第二参数使用2，表示以1~7表示星期一到星期日。

2、对第三行中的日期进行判断后，如果数值大于5，即表示该日期为周六或是周日。

合同到期提醒

1、选中A4:D7单元格区域，新建格式规则

=AND($D4>TODAY(),$D4-TODAY()<7)

使用两个条件对D4单元格中的日期进行判断，第一个条件是大于系统当前日期，第二个条件是和系统当前日期的间隔小于7。

员工生日一周内提醒

=DATEDIF($D4,NOW()+7,"yd")<=7

1、DATEDIF函数用于计算两个日期之间的间隔。

2、第三参数使用yd，表示计算两个日期忽略年的间隔天数。

注意：

由于DATEDIF函数的第三参数在使用“YD”时有特殊的计算规则，因此当结束日期是3月份时，计算结果可能会出现一天的误差。

数据有效性不仅能够对单元格的输入数据进行条件限制，还可以在单元格中创建下拉列表菜单方便用户选择输入。

普通青年这样用：

步骤简要说明：

选中区域，设置数据验证，允许条件选择序列，输入要在下拉菜单中显示的内容：

男,女

注意不同选项要使用半角的逗号隔开。

文艺青年这样用：

选中数据区域，设置数据验证，在【输入信息】选项卡下输入提示内容。

强迫症青年这样用：

选中数据区域，设置数据验证，自定义公式为：

=COUNTA(E$3:E3)=ROW(A1)

注意：公式中的E3是选中数据区域的首个单元格。

走你青年这样用：

=COUNTIF(E:E,E3)=1

注意：公式中的E3是实际选中数据区域的首个单元格。

牛B青年这样用：

任意单元格（如H3）输入公式=NOW()

选中数据区域，设置数据验证，序列来源为：

=H3

注意：要预先设置所选数据区域的数字格式为：H:MM:SS

图文制作：祝洪忠

IF函数是Excel的常用函数之一，它是根据指定的条件来判断其“真”（TRUE）、“假”（FALSE），根据逻辑计算的真假值，从而返回相应的内容的一个函数。

使用语法：=IF( logical_test , [value_if_true] , [value_if_false])

通俗理解：=IF(条件, 条件成立返回的值, 条件不成立返回的值)

1、实例：单条件判断，销售台数>=35台才完成任务，判断销售员是否完成任务。

G2单元格公式： =if(D2>=35,"完成","未完成"），往下填充即可

2、计算各部门销售总额

I2公式：={SUM(IF(C:C=H2,F:F)}

大括号表示数组公式，即输入公式=SUM(IF(C:C=H2,F:F)后，一定要按CTRL+SHIFT+ENTER三键结束，才可得出下图结果。

3、IF函数嵌套使用及多级嵌套变通办法

①根据给定的奖金评定标准的A级至E级标准的奖金数，计算出不同等级销售员应发奖金数。

②根据销售员等级计算出奖金等级。

说明1：如果IF函数嵌套太多，最好用VLOOKUP函数。

说明2：如果IF函数嵌套太多，又一定要用IF，对于数值而言可以用"+"，文本则用"&"来回避嵌套，看起来公式比较长，但比嵌套来说要简单一点。

嵌套公式：

F2单元格公式：

=IF(E3=$A$3,$B$3,IF(E3=$A$4,$B$4,IF(E3=$A$5,$B$5,IF(E3=$A$6,$B$6,$B$7))))

G2单元格公式

=IF(E3=$I$3,$J$3,IF(E3=$I$4,$J$4,IF(E3=$I$5,$J$5,IF(E3=$I$6,$J$6,$J$7))))

变通后公式（公式长度更长，但没那么容易出错）：

F2单元格公式：

=IF(E3=$A$3,$B$3,0)+IF(E3=$A$4,$B$4,0)+IF(E3=$A$5,$B$5,0)+IF(E3=$A$6,$B$6,0)+IF(E3=$A$7,$B$7,0)

G2单元格公式：=IF(E3=$I$3,$J$3,"")&IF(E3=$I$4,$J$4,"")&IF(E3=$I$5,$J$5,"")&IF(E3=$I$6,$J$6,"")&IF(E3=$I$7,$J$7,"")

4、IF函数与AND和OR混合使用

①对于60岁以上（含）的男性员工给予1000元奖金，两个条件同时满足用AND

C3单元格公式：=IF(AND(A3="男",B3>=60),1000,0)

②对于60岁以上或40岁以下的员工给予1000元奖金，两个条件满足其中一个即可，用OR

C10单元格公式：=IF(OR(B10>=60,B10<=40),1000,0)

③对于60岁以上的男员工或40岁以下的女员工给予1000元奖金，即有60岁以上和男员工要同时满足，40岁以下和女员工也要同时满足用AND，这两个大条件中间的或又要用到OR，有点复杂，逻辑一定要清楚。

C17单元格公式：＝if(or(and(A17="男"，B17>60),and(A17="女",B17<40)),1000,0)

温馨提示：

① 在使用IF多层嵌套时，函数执行的命令是从左向右执行的，要注意括号的对应关系，不要遗漏或增多括号。

② 2003及以下版本对嵌套有7层的限制，可用前面介绍的方法变通使用。

③ 嵌套太多建议改用VLOOKUP等其他函数。

我是EXCEL学习微课堂，分享EXCEL学习小技巧，小经验。如果分享的内容对您有帮助，欢迎点赞、收藏、评论、转发，更多的EXCEL技能，可以关注“EXCEL学习微课堂”。

IFS 函数检查是否满足一个或多个条件，且是否返回与第一个 TRUE 条件对应的值。

IFS 可以取代多个嵌套 IF 语句，并且可通过多个条件更轻松地读取。

01

函数语法

IFS(logical_test1,value_if_true1,logical_test2,value_if_true2,...)

IFS(测试条件1，真值1，测试条件2，真值2，。。。)

logical_test1：表示计算结果为 TRUE 或 FALSE 的任意值或表达式。

value_if_true1当 logical_test1 的计算结果为 TRUE 时要返回结果。

作为IF函数的一个升级版本，IFS 函数允许测试最多 127 个不同的条件，可以免去IF函数的过多嵌套。

（注意IF和IFS函数都不要嵌套过多，必要时可以采用VLOOKUP等函数解决）

02

基础应用

IFS函数在用法上和IF的几乎一样，

如下案例。

IF公式应该这样=IF(A2>60,IF(A2>70,IF(A2>80,"优秀","良好"),"及格"),"不及格")，

IFS函数却是可以这样，=IFS(A2>80,"优秀",A2>70,"良好",A2>60,"及格",A2<60,"不及格")< span="">，中间就省去了IF函数的多重嵌套。

03

参数问题

①如果在没有相应 value_if_true 的情况下提供了 logical_test 参数，则此函数将显示典型的“你为此函数输入的参数过少”错误消息。

②如果 logical_test 参数经计算解析为 TRUE 或 FALSE 以外的值，则此函数将返回 #VALUE! 错误。

③如果找不到 TRUE 条件，则此函数将返回 #N/A!错误。

04

支持问题

很多人电脑上的office可能没有这个函数，，，

部分office2016里面也不一定有。

在Office365(2016)和WPS高版本（2016有，2013可能就没有）里面有这个函数。

没有用office高版本的小伙伴没有这个函数也不用纠结咯，后续会有用其他函数做这种匹配的咯。

用WPS的小伙伴个人版的话可以升级到WPS2013或2016的专业版本，里面内含VBA，而且是无广告的。

可以后台回复"WPS"获得下载链接。

用office的小伙伴可以依旧用office就不错，据说。。WPS和office两个软件交叉编辑文档是会出错的咯。

在工作中会遇到很多数据判断的情况，我们要学会利用函数让Excel帮你进行判断，下面我们就来看一下IF条件判断函数的应用。

IF函数有三个参数， =IF("表达式","为TRUE时的返回值","为FALSE时的返回值")。

例如对下面人员的成绩进行判断，大于等于90分的为“优秀”，小于90分的为“空”。

下面我们就来操作看一下三个参数的实际应用：

我们可以清楚地看到上述表格的具体判断要求和IF函数的运营，理想家提醒大家，在运用IF函数的时候要谨记参数的返回顺序，这样在使用公式的时候会更得心应手。

当然IF函数还可以进行嵌套来进行多条件判断，这个在以后的文章里再详细给大家介绍，这次就先到这里了，记得转发关注哦！

今天准备了一组日常工作中常用的多条件判断、统计Excel函数公式，让同学们提升工作效率，不再头疼。

1、IF函数多条件判断

要求：如果部门为生产、岗位为主操 有高温补助。

公式：

=IF(AND(B2="生产",C2="主操"),"有","无")

AND函数对两个条件判断，如果同时符合，IF函数返回“有”，否则为无。

2、SUMIF多条件求和

要求：统计E2和E3单元格中两个部门的岗位补助总额

=SUMPRODUCT(SUMIF(B2:B9,E2:E3,C2:C9))

SUMIF函数求和条件使用E2:E3，分别得到两个部门的岗位补助额，再使用SUMPRODUCT函数进行求和。

3、SUMIFS多条件求和

要求：统计部门为生产,并且岗位为主操的补助总额

=SUMIFS(D2:D9,B2:B9,F2,C2:C9,G2)

SUMIFS函数求和区域为D2:D9，求和条件为B2:B9=F2并且C2:C9=G2

4、包含关键字的多条件求和

要求：统计部门包含“生产”,并且岗位为主操的补助总额

=SUMIFS(D2:D9,B2:B9,"*"&F2&"*",C2:C9,G2)

SUMIFS函数支持使用通配符。

5、多条件计数

要求：统计统计部门为生产,并且岗位为主操的人数

=COUNTIFS(B2:B9,F2,C2:C9,G2)

COUNTIFS函数也支持使用通配符，用法与SUMIFS函数相同。

6、多条件计算平均值

要求：统计统计部门为生产,并且岗位为主操的平均补助额

=AVERAGEIFS(D2:D9,B2:B9,F2,C2:C9,G2)

第一参数是要统计的数值区域，之后分别是成对的条件区域和指定条件。

7、多条件计算最大值和最小值

要求：统计统计部门为生产,并且岗位为主操的最高补助额

数组公式，注意按Shift+ctrl+回车：

=MAX(IF((B2:B9=F2)*(C2:C9=G2),D2:D9))

数组公式中，判断多条件时不能使用AND或是OR函数，因此先使用两个判断条件相乘，表示两个条件要求同时符合。

再使用IF函数对结果进行判断，两个条件同时符合时，IF函数返回D2:D9中的数值，否则返回逻辑值FALSE。

最后使用MAX函数忽略其中的逻辑值计算出最大值。

要计算多个条件的最小值时，只要将公式中的MAX换成MIN函数即可。

8、多条件查找

要求：查询部门为生产,并且岗位为部长的姓名

=LOOKUP(1,0/((B2:B9=F2)*(C2:C9=G2)),A2:A9)

LOOKUP函数多条件查询套路为：

=LOOKUP(1,0/(条件1*条件2*条件n),查询区域)

9、使用DSUM函数多条件汇总

要求：统计部门为生产、并且工资在7000~12000之间的总额

=DSUM(A1:C9,"实发工资",E2:G3)

第一参数为整个数据表区域，第二参数是要汇总的列标题，第三参数是指定的条件区域。

注意，第二参数中的列标题以及条件区域的列标题要和数据源中的标题相同。

好了，今天的分享就是这些，祝各位一天好心情！

图文制作：祝洪忠

if函数是 Excel 中的条件判断函数，它由条件与两个返回结果组成，当条件成立时，返回真，否则返回假。if函数中的条件既可以单条件，也可以是多条件；多条件组合有三种方式，一种为多个 if 嵌套，第二种为用 And（或 *）组合多个条件，第三种为用 Or（或 +）组合多个条件。用 And（或 *）组合条件是“与”的关系，用 Or(或 +）组合条件是“或”的关系，它们的写法比 if 嵌套简单。以下就是它们的具体操作方法，实例中操作所用版本均为 Excel 2016。

一、Excel if函数语法

1、表达式：IF（logical_test,[value_if_true],[value_if_false])

中文表达式：如果（条件，条件为真时执行的操作，条件为假时执行的操作）

2、说明：[value_if_true] 和 [value_if_false] 表示可选项，即它们可以不写，如图1所示：

按回车，返回 False，因为 E2 为 435，F2 为 528，E2 > F2 不成立，如图2所示：

另外，=IF(3 > 2,)，返回 0，此处 0 表示假。

二、Excel if函数单条件使用方法

1、一个服装销量表中，价格为0的表示已下架，否则表示正在出售，假如要把它们分别用“下架”和“出售中”标识出来，操作过程步骤，如图3所示：

2、操作过程步骤说明：选中 H2 单元格，输入公式 =IF(E2<=0,"下架","出售中")，按回车，则返回“出售中”；把鼠标移到 H2 右下角的单元格填充柄上，按住左键并往下拖，则所经过单元格全填充为“出售中”，按 Ctrl + S 保存，则价格为 0 的单元格用“下架”填充，其它单元格用“出售中”填充。

3、公式说明：公式 =IF(E2<=0,"下架","出售中") 中，E2<=0 为条件，当条件为真时，返回“下架”，否同返回“出售中”。

三、Excel if函数嵌套多条件使用方法

1、假如要标出服装销量表中，“大类”为“女装”、“价格”大于等于 80 且“销量”大于 800 的服装，操作过程步骤，如图4所示：

2、操作过程步骤说明：选中 H2 单元格，把公式 =IF(C2="女装",IF(E2>=80,IF(F2>800,"满足条件","不满足条件"),"不满足条件"),"不满足条件") 复制到 H2，按回车，则返回“不满足条件”；再次选中 H2，把鼠标移到 H2 的单元格填充柄上，按住左键并往下拖，则所经过单元格用“不满足条件”填充，按 Ctrl + S 保存，同样 H3 用“满足条件”填充，其它单元格仍用“不满足条件”填充。

3、公式说明：

=IF(C2="女装",IF(E2>=80,IF(F2>800,"满足条件","不满足条件"),"不满足条件"),"不满足条件")

由三个 if 组成，即在一个 if 中嵌套了两个 if。第一个 if 的条件为 C2="女装"，如果条件为真，则执行 IF(E2>=80,IF(F2>800,"满足条件","不满足条件"),"不满足条件")；否则返回“不满足条件”。第二个 if 的条件为 E2>=80，如果条件为真，则执行 IF(F2>800,"满足条件","不满足条件")，否则返回“不满足条件”。第三个 if 的条件为 F2>800，如果条件为真，返回“满足条件”，否则返回“不满足条件”。

提示：if 最多只能嵌套 64 个 if，尽管如此，在写公式过程中，尽量少嵌套 if；一方面便于阅读与修改，另一方面执行效率也高一些。

四、Excel if函数用 And 与 OR 组合多个条件使用方法

（一）用 And 组合多个条件，为“与”的关系

1、把上例中的多 if 嵌套公式 =IF(C2="女装",IF(E2>=80,IF(F2>800,"满足条件","不满足条件"),"不满足条件"),"不满足条件") 改为用 And 组合，操作过程步骤，如图5所示：

2、操作过程步骤说明：选中 H2 单元格，把公式 =IF(AND(C2="女装",E2>=80,F2>800),"满足条件","不满足条件") 复制到 H2，按回车，则返回“不满足条件”；同样往下拖并保存，返回跟上例一样的结果，说明公式正确。

3、公式说明：

=IF(AND(C2="女装",E2>=80,F2>800),"满足条件","不满足条件")

公式用 And 函数组合了三个条件，分别为 C2="女装",E2>=80,F2>800，当同时满足三个条件时（即 AND(C2="女装",E2>=80,F2>800) 返回“真”），返回“满足条件”，否则返回“不满足条件”。

4、用 * 代替 And

A、把公式　　=IF(AND(C2="女装",E2>=80,F2>800),"满足条件","不满足条件")

用 * 代替 And 后变为：

=IF((C2="女装")*(E2>=80)*(F2>800),"满足条件","不满足条件")

如图6所示：

B、按回车，返回“不满足条件”，往下拖保存后，也是返回一样的结果。

（二）用 Or 组合多个条件，为“或”的关系

1、把上例中的 And 组合多个条件公式 =IF(AND(C2="女装",E2>=80,F2>800),"满足条件","不满足条件") 改为用 Or 组合，操作过程步骤，如图7所示：

2、操作过程步骤说明：选中 H2 单元格，把公式 =IF(OR(C2="女装",E2>=80,F2>800),"满足条件","不满足条件") 复制到 H2，按回车，则返回“满足条件”；同样往下拖并保存，全部返回“满足条件”。

3、公式说明：

=IF(OR(C2="女装",E2>=80,F2>800),"满足条件","不满足条件")

公式用 Or 函数组合了三个条件，分别为 C2="女装",E2>=80,F2>800，即 OR(C2="女装",E2>=80,F2>800)，意思是：只要满足一个条件，就返回“真”；一条件都不满足才返回“假”。演示中，每条记录都满足一个条件，所以全返回“满足条件”。

4、用 + 代替 Or

A、把公式

=IF(OR(C2="女装",E2>=80,F2>800),"满足条件","不满足条件")

用 + 代替 Or 后变为：

=IF((C2="女装")+(E2>=80)+(F2>800),"满足条件","不满足条件")

如图8所示：

B、按回车，返回“满足条件”，往下拖保存后，也是全部返回“满足条件”，说明公式正确。

经常使用函数的小伙伴们都知道excel if函数是我们工作中经常用到的函数，那么excel if函数怎么实现满足多个条件来使用呢?今天就为大家唠一下excel if函数多个条件的使用方法!希望可以帮助大家更有效的运用在工作当中!那么excel if函数的多个条件实现到底怎么用？我们首先要明白，满足多个条件也可以分两种情况：1)需要多个条件同时满足;2)或者一个、几个或多个条件。我们以下图的数据来举例说明。

首先，利用AND()函数来说明同时满足多个条件。举例：如果A列的文本是“A”并且B列的数据大于210，则在C列标注“Y”。

在C2输入公式：=IF(AND(A2=”A”,B2>210),”Y”,””)知识点说明：AND()函数语法是这样的，AND(条件1=标准1，条件2=标准2……)，每个条件和标准都去判断是否相等，如果等于返回TRUE，否则返回FALSE。只有所有的条件和判断均返回TRUE，也就是所有条件都满足时AND()函数才会返回TRUE。

然后，利用OR()函数来说明只要满足多个条件中的一个或一个以上条件。举例：如果A列的文本是“A”或者B列的数据大于150，则在C列标注“Y”。

在C2单元格输入公式：=IF(OR(A2=”A”,B2>150),”Y”,””)知识点说明：OR()函数语法是这样的：OR(条件1=标准1，条件2=标准2……)，和AND一样，每个条件和标准判断返回TRUE或者FALSE，但是只要所有判断中有一个返回TRUE，OR()函数即返回TRUE。

以上的方法是在单个单元格中进行判断，也可以写成数组公式形式在单个单元格中一次性完成在上述例子中若干个辅助单元格的判断，这样我们就可以随心所欲的对excel if函数的条件设置咱们需要的规则了！

好了，今天的excel if函数不知道各位小伙伴们有没有掌握到呢？如果你有更好的方法也可以在评论区和大家一起交流，谢谢

经常使用Excel函数的小伙伴们都知道，在Excel中使用频率最高的还是那些比较简单的函数，其中IF函数就是高频率函数之一，那么，能不能用IF函数来进行多条件运算呢？

一、IF+AND：同时满足多个条件

目的：将“上海”地区的“男”通知标识为“Y”。

方法：

在目标单元格中输入公式：=IF(AND(D3="男",E3="上海"),"Y","")。

解读：

1、AND函数的语法：AND(条件1,=标准1，条件2=标准2……条件N=标准N）。如果每个条件和标准都相等，则返回TRUE，否则返回FALSE 。

2、用IF函数判断AND函数的返回结果，如果为TRUE，则返回“Y”，否则返回""。

二、IF+OR:满足多个条件中的一个即可。

目的：将性别为“男”或地区为“上海”的标记为“Y”。

方法：

在目标单元格中输入公式：=IF(OR(D3="男",E3="上海"),"Y","")。

解读：

1、OR函数的语法结构为：(条件1,=标准1，条件2=标准2……条件N=标准N）。如果任意参数的值为TRUE，则返回TRUE ,当所有条件为FALSE时，才返回FALSE。

2、用IF函数判断OR函数的返回结果，如果为TRUE,则返回“Y”，否则返回""。

在进行数据统计时，有时需要挑选出同时满足多个条件的数据。例如在进行三好学生、优秀学生等评选时，有时会需要挑选出各学科考试成绩都大于某个数值的学生，作为参评的条件之一。例如要挑选出各学科成绩都大于80的学生。这时在班级里学生较多的情况下，如果采用逐个查看每个学生各科成绩来进行挑选的方法将会花费一定的时间，还有可能因为马虎而出现疏漏，这样不但影响工作效率，还可能影响最终结果的准确性。这种情况可以考虑用Excel来帮助我们较轻松和准确的完成这个任务，这里以Excel2007为例介绍如何操作，以供参考。

在Excel中挑选出同时满足多个条件的数据可以考虑采用“AND”函数，其语法为：AND(logical1,logical2, ...)，括号内的“logical1,logical2, ...”为各种条件的表达式，如果各种条件的表达式都成立，Excel就会返回“TRUE” 否则返回“FALSE”。

但如果表格中只显示英文的“TRUE”和“FALSE”，会显得不太美观，也不够明了。这时可以组合使用其他的函数，如“IF”函数，让Excel显示我们自定义的字符。IF”函数的语法为：IF(logical_test,value_if_true,value_if_false)，括号中的“Logical_test”为表达式（例如可以用上述的“AND”函数作为表达式），“value_if_true”为表达式结果为TRUE”时Excel返回的结果，“value_if_false”为表达式结果为“FALSE”时Excel返回的结果。

例如要从下图表格中挑选出各科成绩都大于80的学生：

●统计时可先在表格右侧添加一个显示统计结果的列，然后点击选中该列的列首单元格。

●选中单元格后，在编辑栏中输入“=AND(C4>=80,D4>=80,E4>=80,F4>=80)”，其中的C4、D4、E4、F4为该行中的学生各科考试成绩所在的单元格，>=80为判断条件，即要求考试成绩大于等于80分。如果AND后面的括号中各判断条件都成立，即各科成绩都大于等于80分，则Excel会返回“TRUE” 否则如果有一科或者多科成绩不大于等于80，Excel会返回“FALSE”。

●输入上述函数公式后，按键盘回车键或者点击编辑栏左侧的对号，该单元格中就会显示出计算结果。

●再用下拉填充柄或者选择性粘贴公式的方法在该列的其他单元格中快速填充公式，就会显示出所有学生的判断结果，其中结果为“TRUE”的表示该学生的各科成绩都大于等于80，结果为“FALSE”的表示该学生至少有一科成绩不大于等于80。但这种显示结果不太美观和明了，最好再组合IF函数来显示中文或者其他符号的判断结果。

●我们可以把列首单元格中的公式改成=IF(AND(C4>=80,D4>=80,E4>=80,F4>=80),"是","否")，即如果公式"AND(C4>=80,D4>=80,E4>=80,F4>=80)"的判断结果为“TRUE”，则Excel会显示字符“是”；反之如果判断结果为“FALSE”则Excel会显示字符“否”，这样看起来比英文的“TRUE”和“FALSE”要明了一些。

●这样再下拉填充或者选择性粘贴公式后，该列其他单元格中就都显示出中文的判断结果了。

●我们还可以用对号来表示符合条件，用空白来表示不符合条件。即把上述公式修改为=IF(AND(C4>=80,D4>=80,E4>=80,F4>=80),"√","")。

●这样，符合条件的学生就都会显示对号，不符合条件的学生会显示空白，感觉更加一目了然。

上述例子介绍的只是AND函数和IF函数相组合的一种应用方法，熟练掌握这两种函数的用法后，可以给数据统计带来更多的方便。