在 Excel 中，SumIf函数用于在满足指定条件的范围内求和，它共由三个参数组成，其中第一二个参数是必选项，第三个参数是可选项。第一、三个参数是范围，第二个参数是条件；在条件中可以用通配符“问号 (?) 和星号 (*)”；此外，如果在条件中含有文本条件、逻辑或数学符号的条件都必须用双引号 (") 括起来。以下就是Excel sumif函数用文本数组、通配符和日期作条件的使用方法，实例中操作所用版本均为 Excel 2016。

一、Excel sumif 语法

1、表达式：SUMIF(range, criteria, [sum_range])

中文表达式：SUMIF(根据条件进行计算的范围, 求和条件, [实际求和范围])

2、说明：

A、表达式中，第一二个参数 range 和 criteria 是必选项，第三个参数 [sum_range] 是可选项；如果省略 [sum_range]，则在 range 中求和；如果有 [sum_range]，则在 [sum_range] 中求和。

B、可以在第二个参数求和条件 criteria 中使用通配符“问号 (?) 和星号 (*)”，问号匹配任意单个字符，星号匹配任意一个或一串字符；如果要找“? 和 *”，需要在它们前面加转义字符 ~，例如要查找 ?，需要这样写 ~?。

C、如果在求和条件 criteria 中，使用文本条件、含有逻辑或数学符号的条件都必须用双引号 (") 括起来；例如使用大于号，应该这样写：">"&60。

D、SumIf 只对数值求和，文本则忽略，如果选中的范围全为文本，则返回 0。

二、Excel sumif函数的使用方法举例

（一）省略第三个参数 sum_range 与使用大于、等于和小于的实例

1、假如要求销量大于 500 所有服装的销量之和。选中 H2 单元格，输入公式 =SUMIF(F2:F10,">500")，按回车，返回 5986，即求得销量大于 500 所有服装的销量之和，如图1所示：

2、公式 =SUMIF(F2:F10,">500") 中的条件 ">500" 也可以这样写：">"&500。

（二）用文本与数组文本作条件

1、假如要求“女装”的所有服装销量之和。把公式 =SUMIF(C2:C10,"女装",F2:F10) 复制到 H2 单元格，按回车，则计算出所有女装的销量之和，操作过程步骤，如图2所示：

提示：公式 =SUMIF(C2:C10,"女装",F2:F10) 中条件"女装"也可以用单元格代替，即公式可变为 =SUMIF(C2:C10,C2,F2:F10)，如图3所示：

2、假如要求所有“非女装”的服装销量之和。把公式 =SUMIF(C2:C10,"<>女装",F2:F10) 复制到 H2 单元格，，如图4所示：

按回车，则返回计算结果 2753，如图5所示：

3、假如要求“小类”中“T恤”和“雪纺”的所有服装销量之和。把公式 =SUMIF(D2:D10,{"T恤","雪纺"},F2:F10) 复制到 H2 单元格，按回车，则求出全部“T恤”和“雪纺”的服装销量之和，操作过程步骤，如图6所示：

公式 =SUMIF(D2:D10,{"T恤","雪纺"},F2:F10) 中，用数组文本"T恤","雪纺"作条件。

（三）用通配符组合条件

1、用问号“?”组合条件

A、把公式 =SUMIF(C2:C10,"??",F2:F10) 复制到 H2 单元格，按回车，则计算出所有服装的销量总和，操作过程步骤，如图7所示：

B、一个问号（?）表示任意一个字符，公式 =SUMIF(C2:C10,"??",F2:F10) 中的两个问号"??"表示两个字，即计算“大类”中所有为两个字的服装销量之和。

2、用星号“*”组合条件

A、假如要求以“衬衫”结尾的全部服装的销量之和。把公式 =SUMIF(B2:B10,"*衬衫",F2:F10) 复制到 H2 单元格，按回车，则求出以“衬衫”结尾的所有服装的销量之和，操作过程步骤，如图8所示：

B、如果要求以某个字或词（例如“白色”）开头的所有服装销量之和，公式可以这样写：=SUMIF(B2:B10,"白色*",F2:F10)；如果求包含某个字或词组（例如“白”）的所有服装销量之和，公式可以这样写 =SUMIF(B2:B10,"*白*",F2:F10)，如图9所示：

（四）用日期作为条件

1、把公式 =SUMIF(F2:F10,"<2018/9/4") 复制到 H2 单元格，按回车，则计算出所有服装的销量之和，操作过程步骤，如图10所示：

2、表格中并没有日期字段，但 Excel 会自动用系统时间与条件中的日期"2018/9/4"进行比较，由计算之时正是 2018年9月4日，所以条件成立，因此，统计出了所有服装的销量总和。

如果要计算条件为空的所有服装销量之和，公式可以这样写：=SUMIF(F2:F10,"")。

在平时用Excel进行各类数据处理的时候，很多朋友都会碰到的一个问题就是数据查询，说到查询函数大家可能也会说到的就是Vlookup函数。其实在Excel中还有其他更加实用的数据查找函数公式，今天我们就来完整的学习一遍Excel中12种查询方式。

场景1：正常情况下数据查找

案例：查找出对应人员的语文成绩

函数=VLOOKUP(F5,B:C,2,0)

场景2：向左数据查找

案例：根据学号查询出对应姓名

函数=INDEX(B:B,MATCH(G5,C:C,0))

场景3：多函数条件交叉查询

案例：求出赵二第三周考试成绩

函数=VLOOKUP(I6,B:G,MATCH(J6,B$2:G$2,0),0)

场景4：LOOKUP多条件查询

案例：求出B产品在京东平台的销量

函数=LOOKUP(1,0/(B:B=F6)*(C:C=G6),D:D)

场景5：数据等级区间查询

案例：求出销售额对应的提成比例

函数=LOOKUP(F5,$B$3:$C$6)

场景6：横向纵向区间数据查询

案例：根据当月销售额及完成比例求出对应提成

函数=INDEX(C3:F9,MATCH(I4,B3:B9),MATCH(I5,C2:F2))

场景7：根据规律自动提取数值对应系数

案例：按照规律根据我们需要的数值提取出对应的系数

函数=TREND(OFFSET(B1,MATCH(D3,A2:A6,1),,2,1),OFFSET(A1,MATCH(D3,A2:A6,1),,2,1),D3)

场景8：查找符合条件的最后一个数

案例：查找出王五最后一天的销售额

函数=LOOKUP(1,0/(B:B=J4),F:F)

场景9：通配符模糊查找

案例：查找出姓王的人的销售额

函数=VLOOKUP(G5&"*",C:D,2,0)

场景10：高级匹配查找

案例：从对应完整地址中提取所在城市的提成点数

=lookup(9^9.find(A$3:A$6,A10),B$3:B$6)

场景11：查找最后一个非空的单元格内容

案例：求出对应人员最近一次缴纳社保的月份

函数=LOOKUP(1,0/(E4:E10<>""),$A$4:$A$10)

场景12：轻松实现一对多查询

案例：轻松提取部门人员全天的门禁记录

函数=IFERROR(VLOOKUP(ROW(A1),A:D,4,0),"")，首先需要在A列做辅助列，函数=COUNTIF(B$2:B2,G$2)

现在Excel关于数据查询你学会了吗？

多条件排序的使用方法

操作示例

1、将表中销售业绩按从低到高排列，选中销售业绩所在列中的任意一个单元格，我们选【销售业绩】，依次点击开始菜单下的【排序和筛选】——【升序】，排序完成；

2、降序同理，依次点击开始菜单下的【排序和筛选】——【降序】，排序完成；

3、我们排序后发现，存在销售业绩相同的数据，如下图，有两个销售业绩为“3600”的员工，年龄分别24岁和28岁；

4、此时，我们想在销售业绩已经从高到低排列的基础上，对相同销售业绩的员工按年龄从大到小排列；我们将数据选中，依次点击开始菜单中的【排序和筛选】——【自定义排序】；

5、排序窗口弹出后可以看到，已经存在一个排序的条件，因为我们已经按销售业绩做了降序排列；

6、点击【添加条件】，将次要关键字按“年龄”、“数值”、“降序”来设置；

7、确定后，数据已重新排列，28岁的员工已按设置排到了24岁员工之前，如下图；

关注我们，推送每日更新，查看更多Excel小技巧：

Excel表格实用技巧01、将阿拉伯数字快速批量转换成中文小写或大写

Excel表格实用技巧04、巧用格式刷快速复制表格样式

Excel表格实用技巧05、快速给单元格添加边框，原来边框可以画出来

Excel表格实用技巧08、如何将满足条件的数据突出标记显示

Excel表格实用技巧09、利用条件格式给包含特定文字的单元格设置格式

Excel表格实用技巧10、如何在一堆数据中找出重复的数据

Excel表格实用技巧11、如何快速从数据中找出最大值或最小值

Excel表格实用技巧12、为数字添加数据条显示让对比一目了然

Excel表格实用技巧13、快速计算数据总值及数据平均值的两种方式

关注

转发

收藏

会让小编更有动力输出高价值的内容

今天是冬至

小编要先给大家送上

热腾腾的饺子和汤圆

吃完饺子和汤圆

我们来思考一个这样的问题

在EXCEL中

我们如何在一堆数据中反向查找到我们需要的某个数据？

其实在EXCEL中

想要进行单条件反向查找

方法有很多

那么我们

就来看看有哪几种反向查找的方法吧

方法一：LOOKUP函数

=LOOKUP(,0/($B$2:$B$10=D3),$A$2:$A$10)

方法二：INDEX+MATCH

=INDEX($A$2:$A$10,MATCH(D3,$B$2:$B$10,0))

方法三：OFFSET

=OFFSET(A$2,MATCH(D3,$B$2:$B$10,0)-1,)

方法四：INDIRECT+MATCH

=INDIRECT("A"&MATCH(D3,B:B,0))

方法五：VLOOKUP

=VLOOKUP(D3,IF({0,1},$A$2:$A$10,$B$2:$B$10),2,FALSE)

=VLOOKUP(D3,IF({1,0},$B$2:$B$10,$A$2:$A$10),2,FALSE)

以上

就是在EXCEL中单条件反向查找的5种方法

不知你们学会了没

赶快收藏起来慢慢看吧

最后再祝大家冬至快乐哟

关注

转发

收藏

会让小编更有动力输出高价值的内容

Hi，我是秋小叶~

做 Excel 表格，一提到函数公式，很多人就头皮发麻。

为什么？其一，因为表格需求千变万化，数据结构千差万别，一点点细微的差别，用法可能就大相径庭；其二，每个函数都有自己的语法规则，必须一五一十严格遵照它的要求，它才会乖乖听话。

那有什么方法，可以在短时间内，快速提升函数公式的应用能力？答案只有一个——用！

怎么用呢？

在工作中以问题和需求为出发点，去找合适的方法。而要想成为个中高手，还有 2 种方式，系列化延伸和一题多解！通过对比不同的思路和方法，能对 Excel 基本技能有更加深入的认知。真到要用的那一刻，就能信手拈来。

拿工作中最常用到的查找匹配为例，要在左边数据区域中查找出小王的销量数据 11，填写进 F2 单元格，怎么做？

有一点 Excel 基础的人都知道，用一个 VLOOKUP 函数就够了：

=VLOOKUP(E2,A:C,3,0)

（拿着 E2 中的「小王」去匹配区域 (A:C) 的第一列，也就是员工一列中查找，找到以后返回匹配区域中同一行第 3 列的数据，也就是 11，其中最后一个参数 0 表示精确匹配，必须找一模一样的「小王」）

这就是单条件的查找匹配。那……假如工作中需要按多个条件查找匹配呢？还能用 VLOOKUP 实现吗？

举个例子，查找匹配出员工、医院、产品同时满足条件的销量数据，又该怎么做？

直接查找匹配不行，我们可以明修栈道，暗度陈仓。既然多条件复杂，我们可以将多个条件合并成一个条件。

首先插入一个空列，设为合并列。在 D2 单元格输入如下公式，将左边的三列合而为一：

=A2&B2&C2

（ & 是连接运算符，可以将单元格、数据拼接成新的文本）

有了这个辅助列，作为查找匹配的索引，我们用 VLOOKUP 也能轻而易举的实现多条件查找匹配，只要在 J2 单元格输入如下公式即可：

=VLOOKUP(G2&H2&I2,D:E,2,0)

（和前面的公式不同点在于，查找对象换成了 G2、H2、I2 三个单元格合并以后的文本，匹配区域从 D 列开始到 E 列，这是因为VLOOKUP有一个前提条件：只在匹配区域的第一列中查找索引对象。）

通过上述系列化延伸，你就能进一步了解更多知识点：

VLOOKUP 的基本用法：只要在两张表中存在可以索引的数据，就可以查找到同一行中的其他数据

用连接符 & 可以将多列数据合并为一列

VLOOKUP 公式中可以嵌套使用其他公式，比如 G2&H2&I2 的计算结果作为查找对象

VLOOKUP 公式只在匹配范围的第一列里查找匹配，按指定的列序返回结果

到这里，问题已经解决。

但是，学习高手可能会继续纵向深挖：

如果用于索引的查找匹配列不在第一列时，例如合并列在销量列后头时，又该怎么做？

或者横向扩展：

多条件查找匹配，除了用 VLOOKUP+ 辅助列的方法，还有哪些方法？哪一种方法会更简单高效？

要解决这个问题，其实我们就是追求 一题多解。预知详情，我们下期再聊。你也可以在评论区留下思路，交流碰撞说不定会激发出新的灵感。

统计成绩的时候，统计成下图这种方式：

COUNTIFS函数介绍：

语法：COUNTIFS(criteria_range1, criteria1, [criteria_range2, criteria2],…)

中文语法：COUNTIFS(区域1, 条件1, [区域2, 条件2],[区域3, 条件3],…)

最多允许 127 个区域/条件对。

在本示例中：

在F2单元格输入公式：“=COUNTIFS($A$2:$A$135,G$1,$C$2:$C$135,">="&$F2)”

函数解读：

函数在向右与向下填充的过程中，一定要注意“所有班级区域”与“所有分数区域”的绝对引用、“要统计的班级”与“要统计的分数段”单元格的相对引用。

在数据统计中会经常筛选符合一个条件或多个条件的数据个数，这对数据分析是非常重要的。筛选符合多个条件数据时是通过countifs函数实现的，首先来看下这个函数的语法。

countifs(criteria_range1,criteria1,criteria_range2,criteria2,…)criteria_range1为第一个需要计算其中满足某个条件的单元格数目的单元格区域（简称条件区域），criteria1为第一个区域中将被计算在内的条件（简称条件），其形式可以为数字、表达式或文本。例如，条件可以表示为48、"48"、">48" 、 "广州" 或 A3；

同理，criteria_range2为第二个条件区域，criteria2为第二个条件，依次类推。最终结果为多个区域中满足所有条件的单元格个数。

下面通过实例来具体操作下，一个班级的考试成绩表，分别筛选出各科成绩都不及格的人数及各科成绩都90分以上的人数。

数据表

对都不及格的条件进行设置，也就是各科成绩都在60以下，涉及到的数据列从B到I，这些条件满足后就可以了。所以公式也就出来了： =count(B2:B21,"<60",C2:C21,"<60",D2:D21,"<60",E2:E21,"<60",F2:F21,"<60",G2:G21,"<60",H2:H21,"<60",I2:I21,"<60")。

公式1

同理都90分以上的人数公式：=COUNTIFS(B2:B21,">90",C2:C21,">90",D2:D21,">90",E2:E21,">90",F2:F21,">90",G2:G21,">90",H2:H21,">90",I2:I21,">90")。

公式2

到此需要的数据个数就都有了，这对于数据量的比较大的数据是非常有用的，希望对你有所帮助。

经常使用函数的小伙伴们都知道excel if函数是我们工作中经常用到的函数，那么excel if函数怎么实现满足多个条件来使用呢?今天就为大家唠一下excel if函数多个条件的使用方法!希望可以帮助大家更有效的运用在工作当中!那么excel if函数的多个条件实现到底怎么用？我们首先要明白，满足多个条件也可以分两种情况：1)需要多个条件同时满足;2)或者一个、几个或多个条件。我们以下图的数据来举例说明。

首先，利用AND()函数来说明同时满足多个条件。举例：如果A列的文本是“A”并且B列的数据大于210，则在C列标注“Y”。

在C2输入公式：=IF(AND(A2=”A”,B2>210),”Y”,””)知识点说明：AND()函数语法是这样的，AND(条件1=标准1，条件2=标准2……)，每个条件和标准都去判断是否相等，如果等于返回TRUE，否则返回FALSE。只有所有的条件和判断均返回TRUE，也就是所有条件都满足时AND()函数才会返回TRUE。

然后，利用OR()函数来说明只要满足多个条件中的一个或一个以上条件。举例：如果A列的文本是“A”或者B列的数据大于150，则在C列标注“Y”。

在C2单元格输入公式：=IF(OR(A2=”A”,B2>150),”Y”,””)知识点说明：OR()函数语法是这样的：OR(条件1=标准1，条件2=标准2……)，和AND一样，每个条件和标准判断返回TRUE或者FALSE，但是只要所有判断中有一个返回TRUE，OR()函数即返回TRUE。

以上的方法是在单个单元格中进行判断，也可以写成数组公式形式在单个单元格中一次性完成在上述例子中若干个辅助单元格的判断，这样我们就可以随心所欲的对excel if函数的条件设置咱们需要的规则了！

好了，今天的excel if函数不知道各位小伙伴们有没有掌握到呢？如果你有更好的方法也可以在评论区和大家一起交流，谢谢

在进行数据统计时，有时需要挑选出同时满足多个条件的数据。例如在进行三好学生、优秀学生等评选时，有时会需要挑选出各学科考试成绩都大于某个数值的学生，作为参评的条件之一。例如要挑选出各学科成绩都大于80的学生。这时在班级里学生较多的情况下，如果采用逐个查看每个学生各科成绩来进行挑选的方法将会花费一定的时间，还有可能因为马虎而出现疏漏，这样不但影响工作效率，还可能影响最终结果的准确性。这种情况可以考虑用Excel来帮助我们较轻松和准确的完成这个任务，这里以Excel2007为例介绍如何操作，以供参考。

在Excel中挑选出同时满足多个条件的数据可以考虑采用“AND”函数，其语法为：AND(logical1,logical2, ...)，括号内的“logical1,logical2, ...”为各种条件的表达式，如果各种条件的表达式都成立，Excel就会返回“TRUE” 否则返回“FALSE”。

但如果表格中只显示英文的“TRUE”和“FALSE”，会显得不太美观，也不够明了。这时可以组合使用其他的函数，如“IF”函数，让Excel显示我们自定义的字符。IF”函数的语法为：IF(logical_test,value_if_true,value_if_false)，括号中的“Logical_test”为表达式（例如可以用上述的“AND”函数作为表达式），“value_if_true”为表达式结果为TRUE”时Excel返回的结果，“value_if_false”为表达式结果为“FALSE”时Excel返回的结果。

例如要从下图表格中挑选出各科成绩都大于80的学生：

●统计时可先在表格右侧添加一个显示统计结果的列，然后点击选中该列的列首单元格。

●选中单元格后，在编辑栏中输入“=AND(C4>=80,D4>=80,E4>=80,F4>=80)”，其中的C4、D4、E4、F4为该行中的学生各科考试成绩所在的单元格，>=80为判断条件，即要求考试成绩大于等于80分。如果AND后面的括号中各判断条件都成立，即各科成绩都大于等于80分，则Excel会返回“TRUE” 否则如果有一科或者多科成绩不大于等于80，Excel会返回“FALSE”。

●输入上述函数公式后，按键盘回车键或者点击编辑栏左侧的对号，该单元格中就会显示出计算结果。

●再用下拉填充柄或者选择性粘贴公式的方法在该列的其他单元格中快速填充公式，就会显示出所有学生的判断结果，其中结果为“TRUE”的表示该学生的各科成绩都大于等于80，结果为“FALSE”的表示该学生至少有一科成绩不大于等于80。但这种显示结果不太美观和明了，最好再组合IF函数来显示中文或者其他符号的判断结果。

●我们可以把列首单元格中的公式改成=IF(AND(C4>=80,D4>=80,E4>=80,F4>=80),"是","否")，即如果公式"AND(C4>=80,D4>=80,E4>=80,F4>=80)"的判断结果为“TRUE”，则Excel会显示字符“是”；反之如果判断结果为“FALSE”则Excel会显示字符“否”，这样看起来比英文的“TRUE”和“FALSE”要明了一些。

●这样再下拉填充或者选择性粘贴公式后，该列其他单元格中就都显示出中文的判断结果了。

●我们还可以用对号来表示符合条件，用空白来表示不符合条件。即把上述公式修改为=IF(AND(C4>=80,D4>=80,E4>=80,F4>=80),"√","")。

●这样，符合条件的学生就都会显示对号，不符合条件的学生会显示空白，感觉更加一目了然。

上述例子介绍的只是AND函数和IF函数相组合的一种应用方法，熟练掌握这两种函数的用法后，可以给数据统计带来更多的方便。

今天在论坛有个小伙伴问到一个关于Excel查找的相关问题，但是他的要求是多个条件进行限制，然后匹配对应的数据出来，今天小菜就以这种情况和大家分享关于Excel双（多）条件查找的5种技巧！

现在需求是匹配出营销部的小菜底薪。会发现公司叫小菜的不只是营销部，因此不能做为单一条件去匹配，故此这类我们称多条件查找。

方法1：用SUMPRODUCT函数

公式：=SUMPRODUCT(($A$2:$A$8=E2)*($B$2:$B$8=F2)*($C$2:$C$8))

满足姓名是小菜，部门是营销部，然后对底新列求和。

方法2：用max函数+数组

公式：=MAX(($A$2:$A$8=E2)*($B$2:$B$8=F2)*($C$2:$C$8))，编辑完公式在三键结束。

方法3：Index+Match实现

公式：=INDEX($C$2:$C$8,MATCH(E2&F2,$A$2:$A$8&$B$2:$B$8,0))

Match这里巧妙把两个条件用&连接起来，就变成了一个条件，MATCH(E2&F2,$A$2:$A$8&$B$2:$B$8,0)

方法4：使用lookup函数

公式：=LOOKUP(1,0/(($A$2:$A$8=E2)*($B$2:$B$8=F2)),$C$2:$C$8)

这是lookup一个常用套路=lookup(1,0/((条件1区域=条件1)*(条件2区域=条件2)),(返回的结果区域))

方法5：数据库函数DSUM

此函数有3个参数。第1参数：要引用的数据源；第2参数要求和的列；第3参数：条件，注意一定要引用单元格区域包括列标题字段，如E1:F2

方法还有其他的，希望这些方法能解决大家的问题，如果OK，记得点个赞，分享个朋友圈，这样小菜也有更加的动力为大家写文章……

如果你是新朋友，扫码关注下方二维码，便每天可以和小菜一起学习，一起提升技能！当然大家也可以技巧分享，学习更多办公技巧哦！

每天一起学习，一起进步。