如果我们有这样一个条件，让26个英文字母，分别等于1~26的数字，就比如这样：

英文字母对应数字

当我们把这些看似毫无关系的字母和我们人生、命运息息相关的几个英文单词拆分开来，会发生什么不可思议的事情？

1、知识： Knowledge

K + N + O + W + L + E + D + G + E＝11+14+15+23+12+5+4+7+5=96%

2、努力工作： Workhard

W + O + R + K + H + A + R + D＝23+15+18+11+8+1+18+4=98%

也就是说知识和努力工作对我们人生的影响可以达到96％和98％。

3、好运： Luck

L + U + C + K ＝12+21+3+11=47%

4、爱情： Love

L + O + V + E＝12+15+22+5=54%。

通过以上四个算法，得出结论，通常我们认为非常重要的东西，往往没有起到最重要的作用，

那么问题来了，怎么样才能做到我们人生的100％呢？

5、是金钱Money 吗？

M + O + N + E + Y = 13+15+14+5+25=72%

NO。

6、是领导能力Leadership吗？

L + E + A + D + E + R + S + H + I + P =12+5+1+4+5+18+19+9+16=89%

NONO。

金钱，权力也不能完全决定我们的生活。那是什么呢？

其实，真正能使我们生活圆满的东西就在我们自己身上！

7、心态

ATTITUDE

A + T + T + I + T + U + D + E ＝1+20+20+9+20+21+4+5=

100%

没错这个理论绝对是正确的，虽然看似巧合，但是绝不是毫无根据。

这个确实太牛了！什么样的态度，就有什么样的人生！

但，更牛的是这些数字都可以用Excel自动算出来，

不用再象上面这位大神一样逐个字母加总了。

说到这儿可能大家就要问老男孩了，这和EXCEL有什么关系啊？那么大家看下下面的图片就知道了！

公式1

=SUMPRODUCT(LOOKUP(MID(C3,ROW(INDIRECT("1:"&LEN(C3))),1),CHAR(ROW($65:$90)),ROW($1:$26)))

公式说明：先拆分（用mid函数拆分成单个字母），再查找（用lookup函数查找每个字母的对应的数字），最后求和（Sumproduct函数）。

公式2：

=SUMPRODUCT((CODE(PROPER(MID(C3,ROW(INDIRECT("1:"&LEN(C3))),1)))-64)*1)

公式说明：用Proper函数把拆分后的字母转换成大写，然后用CODE返回数字代码（如A会返回65），再-64后正好让字母对应1~26的数字。

老男孩PS ：不要以为EXCEL只能做表格加减乘除。其实Excel在数据处理能力上，不比任何软件差。俗话是万能的EXCEL，可不是徒有虚名的哦，为了强大的Excel，同学们赶快收藏转发吧!

       用来判断真假值，或者进行复合检验的Excel函数，我们称为逻辑函数。在Excel中提供了六种逻辑函数。即AND、OR、NOT、FALSE、IF、TRUE函数。这章我们主要讲解AND、OR、NOT三个函数。详细介绍见下：

（一）AND函数

      所有参数的逻辑值为真时返回 TRUE；只要一个参数的逻辑值为假即返回 FALSE。简言之，就是当AND的参数全部满足某一条件时，返回结果为TRUE，否则为FALSE。

      语法为AND(logical1,logical2, ...)，其中Logical1, logical2, ... 表示待检测的 1 到 30 个条件值，各条件值可能为TRUE，可能为 FALSE。 参数必须是逻辑值，或者包含逻辑值的数组或引用。举例说明：

      1、 在B2单元格中输入数字50，在C2中写公式=AND(B2>30,B2<60)。由于B2等于50的确大于30、小于60。所以两个条件值（logical）均为真，则返回结果为TRUE。

图1 AND函数示例1

      2、 如果 B1-B3 单元格中的值为 TRUE、FALSE、TRUE，显然三个参数并不都为真，所以 在B4单元格中的公式=AND(B1:B3) 等于 FALSE

图2 AND函数示例2

（二）OR函数

      OR函数指在其参数组中，任何一个参数逻辑值为 TRUE，即返回 TRUE。它与AND函数的区别在于，AND函数要求所有函数逻辑值均为真，结果方为真。而OR函数仅需其中任何一个为真即可为真。比如，上面的示例2，如果在B4单元格中的公式写为=OR(B1:B3)则结果等于TRUE　

图3 OR函数示例

（三）NOT函数

      NOT函数用于对参数值求反。当要确保一个值不等于某一特定值时，可以使用 NOT 函数。简言之，就是当参数值为TRUE时，NOT函数返回的结果恰与之相反，结果为FALSE.

      比如NOT(2+2=4)，由于2+2的结果的确为4，该参数结果为TRUE，由于是NOT函数，因此返回函数结果与之相反，为FALSE。

据许多调查显示，SUM、VLOOKUP、IF是使用量最大的三个函数，前两个函数我们都已经说过了，本次我们就一起来揭开IF函数的神秘面纱。

其实只要我们留心观察，生活中到处都充满了IF函数。

如果成绩大于60分，就能及格，否则就不及格；

如果明天下雨，我就不去露营；

如果有网，我就玩电脑，否则睡觉；

如果我是女生，我一定会嫁给他。

太多这样的例子，三天三夜都举不完。

如下是某个班级的学生成绩表，根据成绩等级评判标准，<60为不及格，60-70为及格，70-80为中等，80-90为良好，90-100为优秀，如何快速对学生进行成绩等级判定呢？

这时我们就要用到IF函数啦，先判断小于60分：=IF(C3<60,"不及格")。那60-70分的怎么判断呢？可能很多人都会想到按照数学上的方法为：=IF(C3<60,"不及格",IF(60≤C3<70,"及格"))

公式报错了。其实，在计算机中处理多条件时，和我们所学的数学的表达方式是有差别的。当条件为小于等于时，我们使用<=而不是使用≤，同理大于等于使用>=。

对于多条件，我们还需要使用到另外的两个函数AND和OR，AND表示并且的意思，只有当所有的条件都为真时，结果才为真，其余都为假；OR表示或者的意思，当条件中全部为假时，结果才为假，其余均为真。二者的语法如下：

=AND(条件1，条件2，条件n)

=OR(条件1，条件2，条件n)

则上述的公式可以更改为：

=IF(C2<60,"不及格",IF(AND(C2>=60,C2<70),"及格",IF(AND(C2>=70,C2<80),"中等",IF(AND(C2>=80,C2<90),"良好",IF(AND(C2>=90,C2<100),"优秀")))))，结果如下：

针对本例中的成绩判断，其实如果我们换一个思路，公式可以简化很多，也就不用使用AND函数。我们从高等级向低等级判断，如果大于等于90为优秀，如果不大于90但是大于等于80为优秀，只有当成绩不是优秀时，才会继续判断，所示此时第二个条件中没必要再判断是否小于90，如下：

=IF(C2>=90,"优秀",IF(C2>=80,"良好",IF(C2>=70,"中等",IF(C2>=60,"及格","不及格"))))。这样是不是简洁了许多？在

Excel函数和公式的运用中，有时候我们要多角度的考虑问题，这样才能写出更高效的公式！！！

IF函数家族起到的主要是辅助的作用，其实也不用学得太深，只要知道常用的方法就行了，如果大家学了数组函数之后，IF函数还会有一些更高级的用法，此处先不说。

有时候Excel里面的数字会出现不能求和的情况，你遇到过吗？是什么原因造成的了？我们看到的明明是数字，但是SUM函数计算的结果却是0……。其实这种现象的主要原因就是表格里面的事文本数字，导致SUM求和结果为0。要向得到正确结果，得把文本数字转换为数值才行，你知道怎么做吗？

一、根据提示按钮转换。

方法：

选中目标数字，单击【黄色感叹号】-【转换为数字】。

二、分列法。

方法：

1、选中目标数据源。

2、【数据】-【分列】-【完成】。

三、选择性粘贴法。

方法：

1、单击任意空单元格，Ctrl+C复制。

2、选中目标数据源。【右键】-【选择性粘贴】-选择运算中的【加】-【确定】。

3、美化表格。

逻辑函数，顾名思义就是用来判断值的真假，进行检验的函数，在Excel中有着广泛的应用。

一、AND、OR、NOT。

1、目的：统计未“缺考”人数的总分。

方法：

在目标单元格中输入公式：=IF(OR(C3="",D3="",E3="")," ",SUM(C3:E3))。

解读：

1、条件OR(C3="",D3="",E3="")的意思为C3、D3、E3中如果有一个单元格为空，公式=IF(OR(C3="",D3="",E3="")," ",SUM(C3:E3))返回空值，否则返回SUM(C3:E3）。

2、OR函数的作用可以理解为“或”。

2、目的：所有科目都缺考的人员成绩不予计算。

方法：

在目标单元格中输入公式：=IF(AND(C3="",D3="",E3=""),"",SUM(C3:E3))。

解读：

1、条件AND(C3="",D3="",E3="")的意思是C3、D3、E3中的三个单元格的值如果全部为空，公式=IF(AND(C3="",D3="",E3=""),"",SUM(C3:E3))返回空值，否则返回SUM(C3:E3)。

2、AND函数的作用可以理解为“并且”。

3、目的：判断每个科目的成绩，如果全部大于等于60分，责任合格，否则不合格。

方法：

在目标单元格中输入公式：=IF(AND(C3>=60,D3>=60,E3>=60),"合格","不合格")。

解读：

1、条件AND(C3>=60,D3>=60,E3>=60)的意思是如果C3、D3、E3三个单元格的值全部大于等于60，则返回“合格”，否则返回“不合格”。

4、目的：3科中有至少1科成绩大于等于60则为“及格”，否则为“不及格”。

方法：

在目标单元格中输入公式：=IF(OR(C3>=60,D3>=60,E3>=60),"及格","不及格")。

解读：

1、条件OR(C3>=60,D3>=60,E3>=60)的意思就是3科中至少有1科成绩大于等于60分，则返回“及格”，如果都小于60分，则返回“不及格”。

5、目的：判断“英语”成绩是否及格。

方法:

在目标单元格中输入公式：=IF(NOT(E3>=60),"不及格","及格")。

解读：

1、条件NOT(E3>=60)等同于C3<60，公式：=IF(NOT(E3>=60),"不及格","及格")就可以变换为:=IF(C3<60,"不及格","及格")。

2、NOT函数的作用就可以理解为“相反”。

6、目的：隐藏公式以外的其它错误。

方法：

在目标单元格中输入公式：=IFERROR(SUM(C3:E3)/COUNT(C3:E3),"")。

解读：

如果公式得不到正确的计算结果，则返回参数二的值。本示例中参数二的值为空，所以不予显示。

转载自百家号作者：Excel函数公式

在Excle的实际应用中，技巧占很大的比重，如果能够熟练掌握一些特定技巧，对工作的效率有很大的提高作用。

一、去零统计平均值。

方法：

1、在目标单元格中输入公式：=AVERAGE(IF(C3:C9<>0,C3:C9))。

2、Ctrl+Shift+Enter填充。

解读：

首先判断C3:C9范围中的值是否等于0，如果不等于0，返回对应的单元格值，并参与AVERAGE的计算当中。

二、时间差，精准到分。

方法：

1、在目标单元格中输入：=D3-C3（结束时间减去起始时间）。

2、Ctrl+1打开【自定义单元格格式】对话框，选择【分类】中的【自定义】，并在【类型】中输入：[h]小时m分。

3、【确定】。

三、特殊表头排序。

方法：

1、选中需要排序的数据源。

2、【数据】-【排序】，选中右上角的【数据包含标题】。

3、选择【主要关键字】、【排序依据】、【次序】并【确定】。

四、快速核对两列数据是否相同。

方法：

1、选中需要对比的两列数据。

2、快捷键：Ctrl+\（反斜杠）。

3、填充颜色。

五、快速的将公式转换为值。

方法：

1、利用Ctrl键分段全选所有带有公式的单元格区域。

2、Ctrl+C复制。

3、在目标单元格Ctrl+V。

六、快速输入。

方法：

1、在目标单元格中输入大写的R或S，R为对号，S为错号。

2、设置目标单元格的字体为：Wingdings 2。

七、快速合并多行数据。

方法：

1、选中需要合并的单元格。

2、【开始】-【填充】-【内容重排】。

八、快速放大局部数据。

方法：

1、选定目标单元格。

2、【视图】-【显示比例】。

3、选择或数据比例并【确定】。

九、复制可见单元格数据。

方法：

1、选定目标单元格。

2、快捷键：Alt+；。

3、复制并粘贴数据。

结束语：

通过对上述实用技巧的学习，相信大家对Excel又多了几分了解和认识，如果你有好的建议或意见，请在留言区留言讨论哦！

现在我们的工作中可能没有谁能离开电脑了吧，处理文件的时候用到了各种各样的软件，有的人看似很牛逼，实际上他可能是经过数一万次的实践或者摸索而得来的经验。办公软件是我们工作中常用的工具，那一套系统看似简单，实际上这当中的花样多了去了，不行你往下看。这些东西你都见过，但是有的却不会做，如果你掌握了这些小的技巧对你的工作提升的档次不是一两倍的问题哦!感觉来学习下看看小编又为大家准备了什么好东西~~、

1.将我们所输入的文字给他颠倒一下顺序

首先我们先将需要颠倒的文字复制粘贴下来，然后在这些文字字体的前面加上一个“@”，点击向下旋转文字，自动换行即可2.制作多选框

其实多选框就是一个字母。在单元格里面输入字母R，然后设置这个字母的字体为Wingdings23.给汉字标注拼音

主要是运用到了标注拼音这个控件，选中需要标注的文字，单击标注拼音选择拼音设置，将文字居中设置输入拼音即可4.插入带音调的拼音

上一个小技巧我们学习了插入拼音，那么怎么插入音调呢 ？请仔细往下看：首先在输入拼音的位置插入符号，选择拉丁语扩充-B然后就可以输入带有音调的拼音了（备注：动图中“们”应为第二声。）5.用斜线分割单个单元格

选中我们需要调整的对象，再插入中添加形状（此处用直线），之后按住Alt+鼠标移动 调整好单元格的边角，F4（重复动作）添加一个分割线到文本框，最后调整好字体就OK了6.隐藏不需要显示区域

选中你需要隐藏的对象按组合键Ctrl+1点击自定义在对话框里面输入；；；7.分段显示手机号码

选中号码按下组合键Ctrl+1进入弹出对话框的自定义页面输入格式000-0000-00008.如何让数据以万为单位显示呢

选中对象按住组合键Ctrl+1进入自定义输入0！.0,万即可9.对个案百分比排序

选中对象→→排序→→取消勾选数据包含标题→选择序列

在Excel中，当我们遇到困难时，喜欢去看帮助，尤其是函数的语法结构等，但是看了也未必看得懂，如果能用比较通俗易懂的方式来解释，那将是学习者的福音……下面我们来学习集中常见的函数用法。

一、VLOOKUP函数。

1、语法结构：=VLOOKUP（查找的内容，查找范围，具体在什么位置，是准确查找还是模糊查找）。

2、作用：查找对应的值。

3、示例：

目的：查找销售员对于的销量。

方法：

在目标单元格输入公式：=VLOOKUP(H3,B3:C9,2,0)。

备注：

公式中的H3就是需要【查找的内容】，B3:C9就是【查找的范围】，2就是在查找范围中的第二列，也就是【具体在什么位置】，0就是精准查找。

二、INDEX函数。

1、语法结构：=INDEX(队列方阵，相对于队列方阵的行数，相对于队列方阵的列数）。

2、作用：提取队列方阵中行数和列数交叉处的值。

3、示例：

目的：提取第4行第4列的值。

方法：

在目标单元格中输入公式：=INDEX(B3:E9,4,4)。

备注：

1、公式中的B3:E9是【队列方阵】，也就是需要提取值所在的范围。第一个4为所需要提取值在第4行，第二个4为所需要提取的值在第4列。

2、返回B3:E9这个相对范围内第4行第4列交汇处的值。

三、MATCH函数。

1、语法结构：=MATCH（查找的内容，队列方阵，匹配方式）。

2、作用：所要查找的内容在队列方阵中处于什么位置？也可以理解为【你算老几？】

3、示例：

目的：查找【苏州】的位置。

方法：

在目标单元格中输入公式：=MATCH("苏州",E3:E9,0)。

备注：

1、“苏州”为【查找的内容】，E3:E9为【队列方阵】，0为精准匹配。

2、返回值3表示“苏州”在E3：E9这个范围中的第三个。

3、队列方阵除了是列以外，还可以是行。

四、CHOOSE函数。

1、语法结构：=CHOOSE(指定的位置，队列方阵）。

2、作用：从队列方阵中返回指定位置上的值。

3、示例：

目的：提取指定数组中第3个值。

方法：

在目标单元格中输入公式：=CHOOSE(3,"北京","上海","苏州","天津")。

备注：

数据方阵中也可以使用数组，返回整个数组。

五、FIND函数。

1、语法结构：=FIND(查找内容，查找范围，从第几个开始找）。

2、作用：返回查找内容在查找范围中的相对起始位置。

3、示例：

目的：返回“Excel函数公式”的相对起始位置。

方法：

在目标单元格中输入公式：=FIND("Excel函数公式","请关注Excel函数公式",1)。

图文/ 小龙，兰色整理

作者简介：小龙, Excel精英讲师团函数班辅导、讲师。精通Excel函数应用。

昨天遇到一位同学问如下问题

如下图所示:

当A列数据为整数时，该数乘2当数据为小数时，小数部分小于等于0.5，则该数乘2加1，小数部分大于0.5时，该数乘2加2

最初写的答案是用IF函数

=IF(INT(A2)=A2,A2*2,IF(A2-INT(A2)<=0.5,INT(A2)*2+1,IF(A2-INT(A2)>0.5,INT(A2)*2+2)))

马上有同学提出来了，最后一个If是多余的，没有任何意义，因为当小数部分不小于等于0.5，那么必然会大于0.5，因此

=IF(INT(A2)=A2,A2*2,IF(A2-INT(A2)<=0.5,INT(A2)*2+1,INT(A2)*2+2))

好象是大功告成，其实....看了下面的公式，你会如何感想：

=CEILING(A2,0.5)*2

这么牛叉的函数，不学怎么行。下面就来学习一下

Ceiling函数

=ceiling(number,significance)

返回将参数 number 向上舍入（沿绝对值增大的方向）为最接近的指定基数的倍数。它有两个参数，第一参数为需要舍入的数值，第二参数为一个倍数关系。例如：

=CEILING(2.5,1)数值2.5对于1来说，向上最接近的1的倍数，就是3，因此函数结果为3

如果任何一个参数是非数值型，则 CEILING 返回 #VALUE! 错误值。不论参数 number 的符号如何，数值都是沿绝对值增大的方向向上舍入。 如果 number 正好是 significance 的倍数，则不进行舍入。如果number 和 significance 都为负，则对值按远离 0 的方向进行向下舍入。如果number 为负，significance 为正，则对值按朝向 0 的方向进行向上舍入。

如果你觉得该剧终，就错了，原来公式还可以再简化：

=CEILING(A2*2,1)

好吧，借用大家的留言：老太太倒地我都不扶，就扶你。

对于新手来说，公式还是以易懂为主，长一点没关系。但如果能象小龙老师写出这么简捷公式，是不是更帅呢？

CountIfs函数在 Excel 中用于组合多个条件区域/条件对，以弥补CountIf函数只能组合一个条件区域/条件对的不足。如果要统计同时满足两个条件的某种产品个数，用 CountIf 需要用数组组合条件，比较麻烦，而用 CountIfs 组合两个条件区域/条件对即可，比较简单明了。CountIfs 与 CountIf 一样，条件中可以用逻辑值与通配符（问号和星号）。以下就是 Excel CountIfs函数的使用方法及实例，包括不为空和多个条件的实例的具体操作方法，实例中操作所用版本均为 Excel 2016。

一、CountIfs函数语法

1、表达式：COUNTIFS(Criteria_Range1, Criteria1, [Criteria_Range2, Criteria2], …)

中文表达式：COUNTIFS(条件区域1, 条件1, [条件区域2, 条件2], …)

2、说明：

A、条件区域和条件组成一个条件区域/条件对，至少包含一个条件区域/条件对，最多只能有 127 个条件区域/条件对。

B、如果有多个条件区域，每个条件区域必须有相同的行数和列数，它们可以不相邻。

C、如果单元格为空，CountIfs 将它的值视为 0。

D、在条件中可以使用通配符问号（?）和星号（*），问号表示任意一个字符，星号表示一个或一串字符；如果要查找问号或星号，需要在它们前面加转义字符~，例如查找问号，表达式可以这样写 ~?。

二、CountIfs函数的使用方法及实例

(一）只有一个条件区域/条件对

1、假如要统计“销售地区”为“广州”的个数。选中 D13 单元格，输入公式 =COUNTIFS(D2:D12,"广州")，按回车，返回统计结果 4；操作过程步骤，如图1所示：

2、公式说明：公式 =COUNTIFS(D2:D12,"广州") 只有一个条件区域/条件对，条件区域为 D2:D12，条件为“广州”，是用文字作条件，并且可以在文字前面加等号，即 =COUNTIFS(D2:D12,"=广州")；另外，仅数值也可以作条件。

（二）有两个条件区域/条件对

1、假如要统计“销售地区”为“广州”且销量大于等于 500 的服装件数。把公式 =COUNTIFS(D2:D12,"广州",F2:F12,">=500") 复制到 F13 单元格，按回车，返回统计结果为 3，操作过程步骤，如图2所示：

2、公式中第一个条件区域/条件对为 D2:D12,"广州"，第二个条件区域/条件对为 F2:F12,">=500"，即先统计 D2:D12 中为“广州”的个数，再统计 F2:F12 中销量大于等于 500 的个数；条件2 ">=500" 也可以用 ">="&500。

（三）用通配符问号与星号组合条件

1、假如要统计以“T恤”结尾、以“白”字开头、仅有三个字的服装件数；把公式 =COUNTIFS(B2:B12,"*T恤",B2:B12,"白*",B2:B12,"???") 复制到 B13 单元格，如图3所示：

2、按回车，返回结果 1，如图4所示：

3、如果要统计以一个指定字（或词）开头且以另一个指定字（或词）结果的服装件数，例如统计以“粉”字开头且以“衬衫”结尾的服装件数，公式可以这样写：=COUNTIFS(B2:B12,"粉*衬衫")。

（四）条件为空、不为空和不等于

1、假如要统计“分类”不等于“衬衫”且“销量”为空的服装件数。把公式 =COUNTIFS(C2:C12,"<>衬衫",F2:F12,"") 复制到 F13 单元格，按回车，返回统计结果 2，操作过程步骤，如图5所示：

2、如果要统计“分类”不等于“衬衫”且“销量”不为空的服装件数，则公式可以这样写：=COUNTIFS(C2:C12,"<>衬衫",F2:F12,"<>"&"")，如图6所示：

（五）CountIfs 与 Average 组合使用

1、假如要统计“分类”为“T恤”、销售地区为“杭州”且大于平均销量的服装件数。把公式 =COUNTIFS(C2:C12,"T恤",D2:D12,"杭州",F2:F12,">"&AVERAGE(F2:F12)) 复制到 F13 单元格，按回车，返回结果 2，操作过程步骤，如图7所示：

2、在条件中，只需用 & 连接 > 与求平均值的函数 Average，如果要用其它函数也是一样的连接方法。

三、CountIfs函数与CountIf函数用多条件的比较

1、CountIfs函数可轻松组合多个条件，而CountIf函数需要用数组才能组合多个条件。假如要统计销量大于等于 500 且小于等于 800 的服装件数。用 CountIfs函数公式可这样写：=COUNTIFS(F2:F12,">=500",F2:F12,"<=800")，而用 CountIf函数，公式需要这样写：=SUM(COUNTIF(F2:F12,{">=500",">800"})*{1,-1})，两个公式统计结果都为 4；操作过程步骤，如图8所示：

2、用CountIfs函数写要简单得多，且它们的计算顺序是一样的，都先统计满足第一个条件的个数，再统计满足第二个条件的件数，因此遇到多个条件的情况，可以先选用CountIfs函数。