在制作 Excel 表格过程中，有时需要用颜色标出满足一定条件的单元格，有时又需要标出满足一定条件的整行；它们可以用“条件格式”中的“使用公式确定要设置格式的单元格”加if条件实现。用这个方法不但可以标出满足一个条件的单元格或整行，并且可以标出满足多个条件的单元格或整行；另外，还可以自由选择用何种颜色标示。以下就是用条件格式加if标出满足一个条件或多条件的单元格或整行的具体操作方法，实例中操作所用版本均为 Excel 2016。

一、Excel条件格式怎么用if公式标出满足条件的单元格

1、假如要用绿色标出某班各科成绩平均分80分以上的学生姓名。框选所有学生成绩记录（即 A3:K30 这片区域），选择“开始”选项卡，单击“条件格式”，在弹出的菜单中选择“新建规则”，打开“新建格式规则”窗口，选择“使用公式确定要设置格式的单元格”，在“为符合此公式的值设置格式”下输入公式 =IF(K3>=80,B3)；单击“格式”，打开“设置单元格格式”窗口，选择“绿色”，单击“确定”，返回“新建格式规则”窗口，再单击“确定”，则用绿色标出所有平均分在80分以上的学生姓名，操作过程步骤，如图1所示：

2、注意：

A、不能框选表格的标题列，应该从表格记录行（即从 A3 单元格）开始框选，否则会发生错误，错误通常发生在标题行下的第一行，往往是不符合要求也用颜色标出。

B、要求用颜色标出第一列，但公式 =IF(K3>=80,B3) 中却不能写直接写 A3，因为 A3 这列不是数值，如果直接写 A3，将无法标出满条件的学生姓名，所以用数值列 B3 代替。

二、Excel条件格式怎么用if公式标出满足条件的整行

1、假如把某班学生成绩表中平均分在90分以上的整行用蓝色标出。按住 Alt，按一次 H，按一次 L，按一次 N，打开“新建格式规则”窗口，选择“使用公式确定要设置格式的单元格”，在“为符合此公式的值设置格式”下输入公式 =$K3>=90；单击“格式”，选择“填充”选项卡，选择“蓝色”，单击两次“确定”；再次按住 Alt，按一次 H，按一次 L，按一次 R，打开“条件格式规则管理器”窗口，选中“公式：=$K3>=90，在“应用于下”对应的输入框中把引用改为 =$3:$30；单击“编辑规则”，原来输入的公式发生了变化，把它改回原来的公式 =$K3>=90，单击两次“确定”，则用蓝色标出平均分在90分以上的学生，操作过程步骤，如图2所示：

2、在“条件格式规则管理器”窗口修改引用单元格后，原来输入的公式常常会发生变化，所以一定要返回检查，变化了则把它改回原来的公式。

3、=$3:$30 是对行的绝对引用，即绝对引用第三行到第30行，也就是只引用记录行，不要引用表格标题行，否则可能发生错误。

三、Excel怎么用多个if条件标出满足条件的单元格

1、假如要用橙色标出平均分在80分以上、C语言在90分以上的学生姓名。框选学生成绩表（即可选中 A3:K30 这片区域），按住 Alt，按一次 H，按一次 L，按一次 N，打开“新建格式规则”窗口，选择“使用公式确定要设置格式的单元格”，输入公式 =IF(K3>=80,IF(G3>=90,B3))，如图3所示：

2、单击“格式”，打开“设置单元格格式”窗口，选择“填充”选项卡，选择“标准色”下的“橙色”，如图4所示：

3、单击“确定”，返回“新建格式规则”窗口，再次单击“确定”，则用橙色标出所有平均分在80分以上、C语言在90分以上的学生姓名，如图5所示：

4、公式说明。公式 =IF(K3>=80,IF(G3>=90,B3)) 共有两个 IF，即 IF 中嵌套 IF；其中 K3>=80 是第一个 IF 的条件，如果 K3>=80 为真，则执行第二个 IF；如果为假，则什么了不返回；如果第二个 IF 为真，则返回 B3，否则什么也不返回。

没有最快，

只有更快！

复制公式的方法有n种，

你独爱哪一种？

01拖动填充柄复制

首先选择含有公式的单元格，然后用鼠标左键拖动填充柄（黑色实心十字），即可复制。

优点：可向上、下、左、右四个方向拖动复制公式。

缺点：要复制的目标区域（数据列或数据行）非常多的情况下，操作会非常不方便。

02双击填充柄复制

首先选择含有公式的单元格，然后用鼠标左键快速双击填充柄。

优点：操作快，效率高。

缺点：只适用于数据列的公式复制，即只能向下复制公式。

03使用快捷键Ctrl+C

首先选择含有公式的单元格，然后使用快捷键【Ctrl+C】，选择要复制到的目标区域后，使用快捷键【Ctrl+V】进行粘贴即可。

优点：要复制公式的目标区域可灵活选择，可以不连续。

缺点：目标区域如有非常多的单元格区域时，选择目标区域的操作效率会降低。

04使用快捷键Ctrl+Enter

首先选择含有公式的单元格，然后选择要复制到的目标区域，把光标定位到公式编辑栏后，按下快捷键【Ctrl+Enter】即可。

缺点：目标区域如有较多的不连续单元格区域，操作效率会降低。

实际工作过程中，要复制的目标区域往往包含非常多的行或列。如果数据行超过几百行，用鼠标选择单元格区域会非常不方便，此时我们可通过在名称栏中输入单元格区域地址的方式，对单元格区域进行定位和选择。

见如下演示视频：

首先选择要复制公式的单元格，然后在名称栏中输入目标单元格区域地址（确保当前单元格为要复制公式的单元格，本示例为E2），最后按【Ctrl+Enter】即可。

另外，也可通过如下方式操作：

首先选择要复制公式的单元格，然后在名称栏中输入E145单元格后按快捷键【Shift+Enter】，最后按【Ctrl+Enter】即可。

——END——

实际的工作中，我们有是需要对表格进行行列转置，暨原来的列位现在的行，原来的行为现在的列。在Excel中如何完成了？

一、选择性粘贴法。

方法：

1、选定原数据。

2、快捷键Ctrl+C复制。

3、选定目标单元格，并【右键】-【选择性粘贴】-【转置】。

4、【确定】。

二、TRANSPOSE函数法。

方法：

1、选定目标单元格。

2、输入公式：=TRANSPOSE(A2:F9)。

3、Ctrl+Shift+Enter填充。

解读：

公式=TRANSPOSE(A2:F9)中的A2:F9为需要转置的数据范围。

职场中的人少不了与数据打交道，Excel中的函数公式无疑是提高工作效率的神器，但是Excel中的函数公式太多，一下记不住，但我们如果掌握常用的函数公式，则会提高工作效率。

一、IF+COUNTIF:查找重复值。

方法：

在目标单元格中输入公式：=IF(COUNTIF($E$3:$E$9,E3)>1,"重复","")。

二、IF+COUNTIF：重复两次以上提示。

方法：

在目标单元格中输入公式：=IF(COUNTIF(E$3:E3,E3)>1,"重复","")。

备注：

重复提示和重复两次及以上提示，COUNTIF函数的第一个单数，暨范围不一样，重复提示的范围是当前所有范围的绝对引用。而重复两次以上提示是第一条记录到当前记录的相对引用。

三、TEXT+MID：提取出生日期。

方法：

1、选定目标单元格。

2、在单元格中输入公式：=TEXT(MID(C3,7,8),"0-00-00")。

3、Ctrl+Enter填充。

四、DATEDIF：计算年龄。

方法：

1、选定目标单元格。

2、输入公式：=DATEDIF(D3,NOW(),"y")。

3、Ctrl+Enter填充。

五、IF+MOD+MID：提取性别。

方法：

1、选定目标单元格。

2、输入公式：=IF(MOD(MID(C3,17,1),2),"男","女")。

3、Ctrl+Enter填充。

六、RANK：排名。

方法：

1、选定目标单元格。

2、输入公式：=RANK(E3,$E$3:$E$9,1)。

3、Ctrl+Enter填充。

七、SUMPRODUCT+COUNTIF:中国式排名。

排名过程中，我们经常会遇到成绩或数值相同的情况，如果用RANK函数来时排名，其计算的结果不符合我们的实际需求。于是就有了中国式排名。

方法：

1、选定目标单元格。

2、输入公式：=SUMPRODUCT(($E$3:$E$9>E3)/COUNTIF($E$3:$E$9,$E$3:$E$9))+1。

3、Ctrl+Enter填充。

八、SUMPRODUCT+COUNTIF:统计不重复个数。

方法：

在目标单元格输入公式：=SUMPRODUCT(1/COUNTIF(B3:B9,B3:B9))。

九、INDEX+MATCH+COUNTIF:提取不重复的值。

方法：

1、在目标单元格输入公式：=INDEX($B$3:$B$9,MATCH(,COUNTIF($J$2:J2,$B$3:$B$9),))&""。

2、快捷组合键：Ctrl+Shift+Enter填充。

备注：

填充时，用快捷组合键Ctrl+Shift+Enter，而不是Ctrl+Enter。因为此公式是数组公式。

　　方式：

　　1.　在E1单元格中输入乘法公式“=A1*B1*C1*D1”。

　　2.　然后依次在A1、B1、C1、D1中输入需要相乘的数据，结果就会显示在“E1”中。

　　3.用鼠标选中“F1”单元格，直到鼠标变成黑色的十字架的时候，左键按住不动往下拖。

　　4.此时，从 F1 到下面的 F2、F3、F4等等，都已经复制了“F1”中的公式，下次你需要运算的时候，直接在前面输入数据，在F2、F3、F4等单元格中就会自动显示运算的结果了。

（本文内容由百度知道网友manxueyuntian贡献）

有时我们需要把表格的两列合并在一起，如果我们一个个去复制，太浪费时间，还有可能出错。那有没有简单的方法呢？我们可以用公式一下子就搞定，效率是非常的高，下面我们就把过程做一下。

1、比如下列表格A列和B列合并到C列上

2、我们可以选择C2元单元格，输入公式： =A2&B2，即表示A2单元格和B2单元格相连接

3、当我们回车后，表格如下，C2单元格内容就变成了 上海张三

4、我们选择C2单元格后，鼠标放在单元格右下角，当光标变成十字状，按住鼠标左键往下拖动。将下面的内容填充完整，填充后的表格如下：

总结，通过上面用公式连接单元格，并且通过拖动快速填充数据的方法。很快就能实现两列数据合并一列数据的需求，用时短，效率高，你快试试吧！

本百家号：时代新生分享工作、生活、技能方面的经验，愿和您一起成长。请多多关注哦！

Excel曾经一度出现了严重Bug，主要有两种比较悲催的情况，首先是这种：

更加悲催的是这种：

言归正传，今天和大家分享一组常用函数公式的使用方法：职场人士必须掌握的12个Excel函数，用心掌握这些函数，工作效率就会有质的提升。

建议收藏备用着，有时间多学习操练下。

目录：数字处理、判断公式、统计公式、求和公式、查找与引用公式、字符串处理公式、其他常用公式等

一、数字处理

01.取绝对值

=ABS(数字)

02.数字取整

=INT(数字)

03.数字四舍五入

=ROUND(数字,小数位数)

二、判断公式

04.把公式返回的错误值显示为空

公式：C2

=IFERROR(A2/B2,"")

说明：如果是错误值则显示为空，否则正常显示。

05.IF的多条件判断

公式：C2

=IF(AND(A2<500,B2="未到期"),"补款","")

说明：两个条件同时成立用AND,任一个成立用OR函数。

三、统计公式

06.统计两表重复

公式:B2

=COUNTIF(Sheet15!A:A,A2)

说明：如果返回值大于0说明在另一个表中存在，0则不存在。

07.统计年龄在30~40之间的员工个数

=FREQUENCY(D2:D8,{40,29})

08.统计不重复的总人数

公式：C2

=SUMPRODUCT(1/COUNTIF(A2:A8,A2:A8))

说明:用COUNTIF统计出每人的出现次数，用1除的方式把出现次数变成分母，然后相加。

09.按多条件统计平均值

F2公式

=AVERAGEIFS(D:D,B:B,"财务",C:C,"大专")

10.中国式排名公式

=SUMPRODUCT(($D$4:$D$9>=D4)*(1/COUNTIF(D$4:D$9,D$4:D$9)))

四、求和公式

11.隔列求和

公式：H3

=SUMIF($A$2:$G$2,H$2,A3:G3)

或

=SUMPRODUCT((MOD(COLUMN(B3:G3),2)=0)*B3:G3)

说明：如果标题行没有规则用第2个公式

12.单条件求和

公式：F2

=SUMIF(A:A,E2,C:C)

说明：SUMIF函数的基本用法

13.单条件模糊求和

公式：详见下图

说明：如果需要进行模糊求和，就需要掌握通配符的使用，其中星号是表示任意多个字符，如"*A*"就表示a前和后有任意多个字符，即包含A。

14.多条求模糊求和

公式：C11

=SUMIFS(C2:C7,A2:A7,A11&"*",B2:B7,B11)

说明：在sumifs中可以使用通配符*

15.多表相同位置求和

公式：b2

=SUM(Sheet1:Sheet19!B2)

说明：在表中间删除或添加表后，公式结果会自动更新。

16.按日期和产品求和

公式：F2

=SUMPRODUCT((MONTH($A$2:$A$25)=F$1)*($B$2:$B$25=$E2)*$C$2:$C$25)

说明：SUMPRODUCT可以完成多条件求和

五、查找与引用公式

17.单条件查找

公式1：C11

=VLOOKUP(B11,B3:F7,4,FALSE)

说明：查找是VLOOKUP最擅长的，基本用法

18.双向查找

公式：

=INDEX(C3:H7,MATCH(B10,B3:B7,0),MATCH(C10,C2:H2,0))

说明：利用MATCH函数查找位置，用INDEX函数取值

19.查找最后一个符合条件记录

公式：详见下图

说明：0/(条件)可以把不符合条件的变成错误值，而lookup可以忽略错误值

20.多条件查找

公式:详见下图

说明:公式原理同上一个公式

21.指定非空区域最后一个值查找

公式;详见下图

说明：略

22.区间取值

公式：详见下图

公式说明：VLOOKUP和LOOKUP函数都可以按区间取值，一定要注意，销售量列的数字一定要升序排列。

六、字符串处理公式

23.多单元格字符合并

公式：c2

=PHONETIC(A2:A7)

说明：Phonetic函数只能对字符型内容合并，数字不可以。

24.截取除后3位之外的部分

公式：

=LEFT(D1,LEN(D1)-3)

说明：LEN计算出总长度,LEFT从左边截总长度-3个

25.截取 - 之前的部分

公式:B2

=Left(A1,FIND("-",A1)-1)

说明：用FIND函数查找位置，用LEFT截取。

26.截取字符串中任一段

公式:B1

=TRIM(MID(SUBSTITUTE($A1," ",REPT(" ",20)),20,20))

说明:公式是利用强插N个空字符的方式进行截取

27.字符串查找

公式：B2

=IF(COUNT(FIND("河南",A2))=0,"否","是")

说明: FIND查找成功，返回字符的位置，否则返回错误值，而COUNT可以统计出数字的个数，这里可以用来判断查找是否成功。

28.字符串查找一对多

公式：B2

=IF(COUNT(FIND({"辽宁","黑龙江","吉林"},A2))=0,"其他","东北")

说明：设置FIND第一个参数为常量数组，用COUNT函数统计FIND查找结果

七、日期计算公式

29.两日期间隔的年、月、日计算

A1是开始日期（2011-12-1），B1是结束日期(2013-6-10)。计算：

相隔多少天？=datedif(A1,B1,"d") 结果：557

相隔多少月? =datedif(A1,B1,"m") 结果：18

相隔多少年? =datedif(A1,B1,"Y") 结果：1

不考虑年相隔多少月？=datedif(A1,B1,"Ym") 结果：6

不考虑年相隔多少天？=datedif(A1,B1,"YD") 结果：192

不考虑年月相隔多少天？=datedif(A1,B1,"MD") 结果：9

datedif函数第3个参数说明：

"Y" 时间段中的整年数。

"M" 时间段中的整月数。

"D" 时间段中的天数。

"MD" 天数的差。忽略日期中的月和年。

"YM" 月数的差。忽略日期中的日和年。

"YD" 天数的差。忽略日期中的年。

30.扣除周末的工作日天数

公式：C2

=NETWORKDAYS.INTL(IF(B2

说明：返回两个日期之间的所有工作日数，使用参数指示哪些天是周末，以及有多少天是周末。周末和任何指定为假期的日期不被视为工作日

八、其他常用公式

31.创建工作表目录的公式

把所有的工作表名称列出来，然后自动添加超链接，管理工作表就非常方便了。

使用方法：

第1步：在定义名称中输入公式：

=MID(GET.WORKBOOK(1),FIND("]",GET.WORKBOOK(1))+1,99)&T(NOW())

第2步、在工作表中输入公式并拖动，工作表列表和超链接已自动添加

=IFERROR(HYPERLINK("#'"&INDEX(Shname,ROW(A1))&"'!A1",INDEX(Shname,ROW(A1))),"")

32.中英文互译公式

=FILTERXML(WEBSERVICE("http://fanyi.youdao/translate?&i="&A2&"&doctype=xml&version"),"//translation")

excel中的函数公式千变万化，今天就整理这么多了。如果你能掌握一半，在工作中也基本上遇到不难题了。

建议收藏备用着，有时间多学习操练下。

批量输入公式批量修改公式快速查找公式显示公式部分计算结果保护公式隐藏公式显示所有公式把公式转换为数值显示另一个单元格的公式把表达式转换为计算结果快速查找公式错误原因

1批量输入公式

选取要输入的区域，在编辑栏中输入公式，按CTRL+ENTER即可批量填充公式。

2批量修改公式

如果是修改公式中的相同部分，可以直接用替换功能即可。

3快速查找公式

选取表格区域 - 按Ctrl+g打开定位窗口 - 定位条件 - 公式，即可选取表中所有的公式

4显示公式部分计算结果

选取公式中的要显示的部分表达式，按F9键

按F9键后的结果

想恢复公式，按esc退出编辑状态即可。

5保护公式

选取非公式的填写区域，取消单元格锁定。公式区域不必操作。

设置单元格格式后，还需要保护工作表：审阅 - 保护工作表。

6隐藏公式

隐藏公式和保护公式多了一步：选取公式所在单元格区域，设置单元格格式 - 保护 - 勾选“隐藏” - 保护工作表。

隐藏公式效果：

7显示所有公式

需要查看表中都设置了哪些公式时，你只需按alt+~组合键（或 公式选项卡 - 显示公式）

把公式转换为数值

8把公式转换为数值

公式转换数值一般方法，复制 - 右键菜单上点123（值）

9显示另一个单元格的公式

如果想在B列显示A列的公式，可以通过定义名称来实现。

公式 - 名称管理器 - 新建名称：G =get.cell(6,sheet3!a4)

在B列输入公式=G，即可显示A列的公式。

excel2013中新增了FORMULATEXT函数，可以直接获取公式文本。

10把表达式转换为计算结果

方法同上，只需要定义一个转换的名称即可。

zhi =Evaluate(b2)

在B列输入公式 =zhi即可把B列表达式转换为值

11快速查找公式错误原因

当一个很长的公式返回错误值，很多新手会手足无措，不知道哪里出错了。兰色介绍排查公式错误的技巧，3秒就可以找到错误。

下面兰色做了一个简单的小例子

【例】：如下图所示，单元格的公式返回值错误。要求排查出公式的哪部分出现了错误。

操作方法：

1、 打开单元格左上角绿三角，点“显示计算步骤”

2、在打开的“公式求值”窗口中，求值会自动停在即将出错的位置。这时通过和编辑栏中的公式比对，就可以找出产生错误的单元格。（D7）

如果公式中有多处错误，可以先修正前一次，然后再点显示计算步骤，查找下一处错误。

实际的工作中，填写序列号的地方非常的多，如果手动去处理，非常的麻烦，是否可以用函数公式来解决了？

一、字母序列。

目的：生成字母序列（大写、小写）。

方法：

在目标单元格中输入公式：=CHAR(ROW(A65))、=CHAR(ROW(A97))。

解读：

1、大写字母A的ASCII码为65，利用函数ROW函数获取单元格A65的行号，及字母A的ASCII码，然后利用函数CHAR转为为对应的字母。

2、利用ROW函数获取行号的目的在于变量为动态值。便于填充。

二、星期序列（中文、英文）。

目的：根据日期快速的填充星期。

方法：

在目标单元格中输入公式：=TEXT(A3,"aaaa")、=TEXT(A3,"dddd")。

三、中文大写数字。

目的：根据对应的阿拉伯数字生成中文大写数字。

方法：

在目标单元格总输入公式：=TEXT(A3,"[dbnum2]")。

在 Excel 中，把公式应用到整列或整行通常用往下拖或往右拖的方法，记录不多用这种方法还可以；如果记录几百行甚至几千几万行，再用拖动的方法显然不现实，这就需要用将公式应用到整列或整行的方法，常用的方法有四种，分别为：引用单元格法、定位空值法、定位空值与快捷键法和双击单元格填充柄法，其中后面两种方法特别快，尤其是最后一种方法。以下就是Excel快速将公式应用到整列或整行的具体操作方法，实例中操作所用版本均为 Excel 2016。

一、引用单元格法

1、将公式应用到整列。按 Ctrl + G 组合键，打开“定位”窗口，在“引用位置”下面输入要引用的单元格，例如 I2:I100，单击“确定”，则选中 I2:I100，输入求和公式 =sum(b2:h2)，按 Ctrl + Enter 组合键，则求出第二行到第100行所有学生的总分，没有记录的行值为0，下移到最后一行可以看到；操作过程步骤，如图1所示：

2、将公式应用到整行。同样按 Ctrl + G 组合键，打开“定位”窗口，在“引用位置”下面输入 B30:Z30，如图2所示：

按回车，则选中第 30 行的 B 列到 Z 列，输入求和公式 =sum(B2:B29)，如图3所示：

按 Ctrl + Enter 组合键，则统计出各科成绩的总分，空列统计结果为 0，如图4所示：

二、定位空值法

1、选中 I 列，按 Ctrl + G 组合键，打开“定位”窗口，单击“定位条件”，在打开的窗口中选择“空值”，单击“确定”，则选中 I 列的所有空值单元格，输入公式 =sum(b2:h2)，按回车，则求出所有学生的总分；按 Ctrl + 向下方向键，定位到表格最后一行，无数据的行没有填充公式；操作过程步骤，如图5所示：

2、这个方法也可以用于把公式应用到整行，方法与把公式应用到整列一样，只需选中一行，按照把公式应用到整列的方法操作即可。

三、定位空值与快捷键法

1、选中 I 列，按 Ctrl + G 组合键，打开“定位”窗口，单击“定位条件”，在打开的窗口中选择“空值”，按回车，则选中 I 列所有空单元格，按 Alt + = 组合键，则所有选中的单元格都统计出学生的成绩；按 Ctrl + “向下方向键”定位到表格最后一行，没记录的行也没有统计；操作过程步骤，如图6所示：

2、这个方法也适用将公式应用到整行，只需选中一行，按将公式应用到整列的步骤操作即可。

四、最快速的方法

1、选中 I2 单元格，按 Alt + = 组合键，公式 =SUM(B2:H2) 自动输入到 I2 单元格，按回车，则求出李子和的总分：再次选中 I2，把鼠标移到 I2 右下角的单元格填充柄上，鼠标随即变为黑色的十字架，此时双击，则统计出所有学生的总分；按 Ctrl + 向下方向键，定位到表格最后一行，记录末尾的空行没有统计；操作过程步骤，如图7所示：

2、提示：这个方法不能用于把公式应用到整行，把鼠标移到单元格填充柄上变黑色十字架后，再怎么双击也不会填充整行；如果要把公式应用到整行，可以用上面三种方法。