在 Excel 中，Match函数用于返回查找值在数组的位置，它共有三个参数，分别为 lookup_value、lookup_array 和 match_type；其中 match_type 有三个参数，即 1、0、-1，当取不同值时返回不同的结果，其中取 0 时，可用通配符问号（?）和星号（*）进行模糊查找。Match函数除单独使用外，还常常与Index函数一起使用。以下就是Match函数的使用方法及与Index组合使用实例的具体操作方法，实例中操作所用版本均为 Excel 2016。

一、Excel Match函数语法

1、表达式：MATCH(lookup_value, lookup_array, [match_type])

中文表达式：MATCH(查找值, 查找数组, [查找类型])

2、说明：

A、Match函数用于返回 lookup_value 在数组中的位置；lookup_value 和 lookup_array 是必选项，match_type 是可选项；如果省略 match_type，则默认值为 1。

B、match_type 的取值说明：取 1 表示查找小于或等于查找值 lookup_value 的最大值，返回该值在数组中的位置，要求数组按升序排序；取 0 表示查找等于 lookup_value 的第一个值，返回该值在数组中的位置，不要求数组按升序或降序排序；取 -1 表示查找大于或等于 lookup_value 的最小值，返回该值在数组中的位置，要求数组按降序排序。

C、当 match_type 为 0 且 lookup_value 是文本，可在 lookup_value 中使用通配符“问号 (?) 和星号 (*)”；问号表示任意一个字符，星号表示任意一个或一串字符；如果要查找问号或星号，需要在它们前加转义波形符（~）。

二、Excel Match函数的使用方法

（一）match_type 取 1（或省略）的使用实例

1、假如要查找服装销量表中价格为 80 与 95 元在 E 列中的位置。首先把 E 列按升序排序，框选 E2:E12，选择“数据”选项卡，单击“升序”，在弹出的“排序提醒”窗口中，选择“扩展选定区域”，单击“确定”，则表格记录按价格升序排序；在 G2 中输入公式 =MATCH(80,E2:E12)，按回车，则返回 80 在 E2:E12 中的位置 2；再在 G3 中输入公式 =MATCH(95,E2:E12,1)，按回车，则返回 5，操作过程步骤，如图1所示：

2、说明：公式 =MATCH(80,E2:E12) 和 =MATCH(95,E2:E12,1)，一个省略 1，另一个未省略，都表示查找小于或等于 lookup_value 的最大值；80 在 E2:E12 中有，因此返回它所在的位置 2，95 在 E2:E12 中没有，所以返回小于它的最大值 89 所在位置，E2:E12 中有两个 89，返回的是第二个 89 的位置。

（二）match_type 取 0 的使用实例

1、查找数值

A、假如要查找价格为 89 元在 E 列中的位置。把公式 =MATCH(89,E2:E12,0) 复制到 G2 单元格，按回车，返回结果为 4，正是 89 在 E2:E12 中位置，操作过程步骤，如图2所示：

B、当 match_type 取 0 时，数组不用排序。如果查找数组中没有的值，则会返回 #N/A 错误，例如查找 87，如图3所示：

按回车后，返回 #N/A 错误，如图4所示：

2、用通配符问号（?）与星号（*）

A、假如要查找以“T恤”结尾的服装在 B 列中的位置。把公式 =MATCH("*T恤",B2:B12,0) 复制到 G2 单元格，按回车，返回结果 2，正是“绿色T恤”在 B2:B12 中的位置（返回的是第一个以“T恤”结束的服装在 B2:B12 中的位置），操作过程步骤，如图5所示：

B、假如要查找只有三个字的服装在 B 列中的位置。把公式 =MATCH("???",B2:B12,0) 复制到 G2 单元格，如图6所示：

按回车，返回结果 10，正是“白衬衫”在 B2:B12 中的位置，如图7所示：

（三）match_type 取 -1 的使用实例

1、假如要查找销量为 681 与 750 在 E 列中的位置。框选 F2:F12，选择“数据”选项卡，单击“降序”，在打开“排序提醒”窗口中，选择“扩展选项区域”，单击“确定”，将记录按销量降序排列；把公式 =MATCH(681,F2:F12,-1) 复制到 G2 单元格，按回车，返回结果为 5，正是 681 在 F:F12 中位置；把 681 改为 750，公式变为 =MATCH(750,F2:F12,-1)，按回车，结果为 4，操作过程步骤，如图8所示：

B、说明：第二个公式 =MATCH(750,F2:F12,-1) 要查找 750，由于 F2:F12 中没有这个值，因此返回大于或等于 750 的最大值 874 在 F2:F12 中的位置，所以结果为 4。

三、Excel Index 与 Match 组合使用实例

1、假如要查找价格为 65 元的服装的编号。把公式 =INDEX(A:A,MATCH(65,E1:E12,0)) 复制到 G2 单元格，按回车，返回结果为 WS-585，正是价格为 65 元的服装编号；操作过程步骤，如图9所示：

B、公式说明：

公式 =INDEX(A:A,MATCH(65,E1:E12,0)) 先用 MATCH(65,E1:E12,0) 返回价格为 65 元的服装在 E 列中的位置，结果为 8；再用Index函数返回行号为 8 的服装编号。

index函数的表达式为：INDEX(array, row_num, [column_num])，第一个参数为数组，第二个参数为行号，第三个参数为列号（可选）；示例中省略了列号，因此只返行号为的服装编号。如果既有行号又有列号，则返回行号与列号对应的值。

if函数是 Excel 中的条件判断函数，它由条件与两个返回结果组成，当条件成立时，返回真，否则返回假。if函数中的条件既可以单条件，也可以是多条件；多条件组合有三种方式，一种为多个 if 嵌套，第二种为用 And（或 *）组合多个条件，第三种为用 Or（或 +）组合多个条件。用 And（或 *）组合条件是“与”的关系，用 Or(或 +）组合条件是“或”的关系，它们的写法比 if 嵌套简单。以下就是它们的具体操作方法，实例中操作所用版本均为 Excel 2016。

一、Excel if函数语法

1、表达式：IF（logical_test,[value_if_true],[value_if_false])

中文表达式：如果（条件，条件为真时执行的操作，条件为假时执行的操作）

2、说明：[value_if_true] 和 [value_if_false] 表示可选项，即它们可以不写，如图1所示：

按回车，返回 False，因为 E2 为 435，F2 为 528，E2 > F2 不成立，如图2所示：

另外，=IF(3 > 2,)，返回 0，此处 0 表示假。

二、Excel if函数单条件使用方法

1、一个服装销量表中，价格为0的表示已下架，否则表示正在出售，假如要把它们分别用“下架”和“出售中”标识出来，操作过程步骤，如图3所示：

2、操作过程步骤说明：选中 H2 单元格，输入公式 =IF(E2<=0,"下架","出售中")，按回车，则返回“出售中”；把鼠标移到 H2 右下角的单元格填充柄上，按住左键并往下拖，则所经过单元格全填充为“出售中”，按 Ctrl + S 保存，则价格为 0 的单元格用“下架”填充，其它单元格用“出售中”填充。

3、公式说明：公式 =IF(E2<=0,"下架","出售中") 中，E2<=0 为条件，当条件为真时，返回“下架”，否同返回“出售中”。

三、Excel if函数嵌套多条件使用方法

1、假如要标出服装销量表中，“大类”为“女装”、“价格”大于等于 80 且“销量”大于 800 的服装，操作过程步骤，如图4所示：

2、操作过程步骤说明：选中 H2 单元格，把公式 =IF(C2="女装",IF(E2>=80,IF(F2>800,"满足条件","不满足条件"),"不满足条件"),"不满足条件") 复制到 H2，按回车，则返回“不满足条件”；再次选中 H2，把鼠标移到 H2 的单元格填充柄上，按住左键并往下拖，则所经过单元格用“不满足条件”填充，按 Ctrl + S 保存，同样 H3 用“满足条件”填充，其它单元格仍用“不满足条件”填充。

3、公式说明：

=IF(C2="女装",IF(E2>=80,IF(F2>800,"满足条件","不满足条件"),"不满足条件"),"不满足条件")

由三个 if 组成，即在一个 if 中嵌套了两个 if。第一个 if 的条件为 C2="女装"，如果条件为真，则执行 IF(E2>=80,IF(F2>800,"满足条件","不满足条件"),"不满足条件")；否则返回“不满足条件”。第二个 if 的条件为 E2>=80，如果条件为真，则执行 IF(F2>800,"满足条件","不满足条件")，否则返回“不满足条件”。第三个 if 的条件为 F2>800，如果条件为真，返回“满足条件”，否则返回“不满足条件”。

提示：if 最多只能嵌套 64 个 if，尽管如此，在写公式过程中，尽量少嵌套 if；一方面便于阅读与修改，另一方面执行效率也高一些。

四、Excel if函数用 And 与 OR 组合多个条件使用方法

（一）用 And 组合多个条件，为“与”的关系

1、把上例中的多 if 嵌套公式 =IF(C2="女装",IF(E2>=80,IF(F2>800,"满足条件","不满足条件"),"不满足条件"),"不满足条件") 改为用 And 组合，操作过程步骤，如图5所示：

2、操作过程步骤说明：选中 H2 单元格，把公式 =IF(AND(C2="女装",E2>=80,F2>800),"满足条件","不满足条件") 复制到 H2，按回车，则返回“不满足条件”；同样往下拖并保存，返回跟上例一样的结果，说明公式正确。

3、公式说明：

=IF(AND(C2="女装",E2>=80,F2>800),"满足条件","不满足条件")

公式用 And 函数组合了三个条件，分别为 C2="女装",E2>=80,F2>800，当同时满足三个条件时（即 AND(C2="女装",E2>=80,F2>800) 返回“真”），返回“满足条件”，否则返回“不满足条件”。

4、用 * 代替 And

A、把公式　　=IF(AND(C2="女装",E2>=80,F2>800),"满足条件","不满足条件")

用 * 代替 And 后变为：

=IF((C2="女装")*(E2>=80)*(F2>800),"满足条件","不满足条件")

如图6所示：

B、按回车，返回“不满足条件”，往下拖保存后，也是返回一样的结果。

（二）用 Or 组合多个条件，为“或”的关系

1、把上例中的 And 组合多个条件公式 =IF(AND(C2="女装",E2>=80,F2>800),"满足条件","不满足条件") 改为用 Or 组合，操作过程步骤，如图7所示：

2、操作过程步骤说明：选中 H2 单元格，把公式 =IF(OR(C2="女装",E2>=80,F2>800),"满足条件","不满足条件") 复制到 H2，按回车，则返回“满足条件”；同样往下拖并保存，全部返回“满足条件”。

3、公式说明：

=IF(OR(C2="女装",E2>=80,F2>800),"满足条件","不满足条件")

公式用 Or 函数组合了三个条件，分别为 C2="女装",E2>=80,F2>800，即 OR(C2="女装",E2>=80,F2>800)，意思是：只要满足一个条件，就返回“真”；一条件都不满足才返回“假”。演示中，每条记录都满足一个条件，所以全返回“满足条件”。

4、用 + 代替 Or

A、把公式

=IF(OR(C2="女装",E2>=80,F2>800),"满足条件","不满足条件")

用 + 代替 Or 后变为：

=IF((C2="女装")+(E2>=80)+(F2>800),"满足条件","不满足条件")

如图8所示：

B、按回车，返回“满足条件”，往下拖保存后，也是全部返回“满足条件”，说明公式正确。

Excel中的函数公式非常的强大，全部掌握很显然是不现实的，但是对常用的Excel函数公式，我们必须掌握。对于单个函数的使用我们已经在前面学习了很多，其功能也是非常的有限，但是如果我们将函数组合使用，那效率不是翻倍那么简单。

马一波超实用函数公式↓↓学生党、职场人士都用得到 ！

平时工作中，我们经常用到的函数可能就是：如果“IF”，根据字面意思理解，基本上就是如果什么什么，那么什么什么，否则什么什么。但是，有是我们需要对IF增加条件的情况，就难免会遇到And和Or了，字面意思上也就是什么和什么，什么或什么的情况。下面就给大家简单介绍下二者与IF函数的组合使用。

函数简析

1、IF函数

=IF(条件,条件为真返回值,条件为假返回值)，如：=IF（A2>=60，"及格"，"不及格"）

2、AND函数

=AND（条件1，条件2），同时满足

3、=OR（条件1，条件2），满足其一

实例演示

利用AND函数或OR函数与IF函数组合，判断不同条件下，某同志项目工作完成量是否达标

条件一：项目之一完成率超60%达标

公式：=IF(OR(C3>=60%,D3>=60%),"达标","不达标")

条件二：2个项目均超过60%达标

公式：=IF(AND(C3>=60%,D3>=60%),"达标","不达标")

小结

本文以Excel2007为例，理论上支持所有Excel版本。文中紧给大家做了AND和OR与IF函数简单的嵌套使用，可以根据自身使用情况，做多层嵌套效果，或三者混合嵌套效果，利用IF函数的输出结果可实现多层嵌套哟！

如果对您有所帮助，感谢点赞！关注获取更多电脑或Office经验分享！

小伙伴们好啊，情人节过的咋样？

据说昨天的Excel曾经一度出现了严重Bug，主要有两种比较悲催的情况，首先是这种：

更加悲催的是这种：

言归正传，今天和大家分享一组常用函数公式的使用方法：

年龄计算

如下图所示，要根据C列的出生年月计算年龄。

经典套路：

=DATEDIF(C2,TODAY(),"y")

套路指南：

虽是隐藏函数，却早已是众人皆知的秘密。

第一参数是开始日期，第二参数是结束日期，第三参数是返回的数据类型。

使用Y，表示返回整年数。

使用M，则表示返回整月数。

身份证计算

如下图所示，要根据C列的身份证号码计算出生年月。

=--TEXT(MID(C2,7,8),"0-00-00")

先使用MID函数，从C2单元格提取出表示出生年月的8位数字，再用TEXT函数将其转换为日期样式的文本。

最后使用两个负号进行运算，变成真正的日期序列值。

中国式排名

如下图所示，要对E列的成绩进行中国式排名，也就是相同成绩不占用名次。

=SUMPRODUCT((E$2:E$6>E2)/COUNTIF(E$2:E$6,E$2:E$6))+1

运算过程比较复杂，三言两语说不清了。

使用的时候，只要把公式中的单元格地址换成实际的数据区域即可。

快速整理数据

如下图所示，要对C列数据进行整理，只提取其中的姓名。

E2单元格公式

=INDEX(C:C,ROW(A1)*2)

1、ROW(A1)*2 部分结果为2，公式向下复制时，依次变成4、6、8……，也就是以2递增的序列值。

2、再使用INDEX函数，从C列返回对应位置的内容。

提取混合内容中的姓名

如下图所示，要提取C列混合内容中的姓名。

=LEFT(C2,LENB(C2)-LEN(C2))

1、LEN函数计算出C2单元格的字符数，将每个字符计算为1。

2、LENB函数计算出C2单元格的字节数，将字符串中的双字节字符（如中文汉字）计算为2，单字节字符（如数字、半角字母）计算为1。

3、用LENB计算结果减去LEN计算结果，就是字符串中的双字节字符个数。

4、最后用LEFT函数从C2单元格右侧，按指定位数取值。

图文制作：祝洪忠

ExcelHome，微软技术社区联盟成员

Hi，大家好，我是小雨。Excel做为一个强大的数据处理工具被广泛用于各种各样的办公环境中。同样的工具在不同人手里发挥的作用也是不一样的。就像一片树叶，在普通人手里可能它就是一片树叶而已。而在武林高手眼中它有可能就是一个强大的武器。

在普通人手里使用Excel可能只是填充数据或者做简单的数据计算。面对同样的工作任务，小白和大神的工作方法和工作效率是截然不同的。比如，要从一组身份证号码中提取出对应的出生年月日。小白可能需要一个一个的输入好半天，而大神一般只用一个快捷键【Ctrl+E】在1秒内就搞定。这就差距。

今天，小雨主要给大家讲讲Excel中【Ctrl+E】这个组合键的几种经典用法。一个神奇的Excel组合键，批量填充只需1秒，不服来试？

以下应用场景中的动画演示由秋叶Excel制作，如侵联删！

01、连接文本

将A列和B列中的文本连接在一起。

02、拆分字符

将A列中的文字和数字拆分开来，分别填充在B列和C列中。

03、快速替换字符

将A列中的“公司”替换为“区”。

04、号码加密或者分段

05、提取出生年月日

从A列中身份证号码中提取出生年月日并填充在B列。

06、格式化文本

将A列中乱七八糟的文本按照指定的格式填充。

07、批量换行

将A列中的整行文字按照指定格式换行填充。

08、文本之中提取数字

将A列文本中所包含的数字快速提取出来并填充在B列。

09、文字分段

将A列中的文本按照指定格式填充在B列。

10、乱序重组

将A列中杂乱的数据按照指定顺序重新排序并填充在B列中。

以上10种Excel的应用场景在工作中都是很常见的，尤其是在人事管理方面更容易遇到。当然实现的方法有很多种，逐个敲进去或者调用函数计算都是常见的手法。但是我想最实用且效率最高的方法莫过于使用【Ctrl+E】这个神奇的组合键。所以，Excel看似简单，实则包含着许许多多的技巧。

PS：以上用到的【Ctrl+E】组合键需要在Excel2013及以上版本中使用。

以上场景如果是你，你会怎么完成？欢迎大家留言评论交流！看看谁才是深藏不露的Excel达人。

转载自百家号作者：office小超老师

在excel中，单元格的内容拆分是我们经常碰到了，不过偶尔也会用到单元格之间的组合，那么你知道怎么解决单元格与单元格之间的拼接组合吗？

最简单的方法我们会借助于拼接符号（&）来进行，其这个键所在的位置是标准键盘上方数字“7”，只不过在输入的过程中需要先按住shift键，然后再输入其内容。

那么，我们在输入公式的时候直接输入所对应的单元格然后输入“&”符号来拼接即可。

如果说我们在拼接的过程中需要添加“；”符号，那么只能在公式编辑栏处继续用“&”符号拼接。

那么，你也会发现会添加很多的“&”符号，如果拼接的很多，这样很容易出现错误。

所以说，对于它的拼接，我们可以借助于phonetic函数来解决。

此函数的官方解释为“获取拼音信息的字符串”，在国内这个拼音信息几乎用不到，我们借助于此函数一般用来解决的就是单元格的拼接。

只有一个参数，直接在其中选中要拼接的范围即可。

那么对于如果相邻的单元格之间要添加“;”符号来分隔呢？对于这种情况，我们还是直接在其右侧添加一列，然后最后的拼接选择全部的范围即可。

你学会了吗？如果有不懂得地方，欢迎底部留言评论。

在工作中，单个函数的运用往往达不到我们想要的结果，我们一般是一个或这几个函数嵌套使用，今天小编就跟常用的函数嵌套组合，熟悉使用这些嵌套函数，可以提高工作效率哦。

组合一：LEN+SUBSTITUTE 计算一个单元格内有几个项目。

如下图所示，要计算每个部门的人数。

这样的表格大家应该比较熟悉：

在一个单元格内有多个姓名而且每个姓名之间用顿号隔开

C2单元格的函数公式为： =LEN(B2)-LEN(SUBSTITUTE(B2,"、",))+1

函数公式解释：

先用LEN函数计算出B列单元格的字符长度，然后再用SUBSTITUTE函数将顿号全部替换掉之后，计算替换后的字符长度。用字符长度减去替换后的字符长度，就是单元格内顿号的个数。

接下来，加1即是实际的人数。

组合二：VLOOKUP+MATCH 用于不确定列数的数据查询。

如下图所示，要根据B13单元格的姓名，在数据表中查询对应的项目。

C13单元格的函数公式为： =VLOOKUP(B13,A1:G9,MATCH(C12,1:1,),0)

函数公式解释：

如果数据表的列数非常多，在使用VLOOKUP函数时，还需要掰手指头算算查询的项目在数据表中是第几列，真是麻烦的很。先用MATCH函数来查询项目所在是第几列，然后VLOOKUP函数就根据MATCH函数提供的情报，返回对应列的内容。

组合三：MIN+IF 用于计算指定条件的最小值。

如下图所示，要计算生产部的最低分数。

G3单元格可以使用数组公式： =MIN(IF(A2:A9=F3,D2:D9))

函数公式解释：

先用IF函数判断A列的部门是否等于F3指定的部门，如果条件成立，则返回D列对应的分数，否则返回逻辑值FALSE：

{FALSE;45;FALSE;FALSE;FALSE;66;FALSE;72}接下来再使用MIN函数计算出其中的最小值。

备注：由于执行了多项计算，所以在输入公式时，要按Shift+ctrl+Enter键

MIN函数有一个特性，就是可以自动忽略逻辑值，所以只会对数值部分计算，最终得到指定部门的最低分数。

大家学会了吗？有问题欢迎到评论区骚扰哦！后期不断更新软件学习技巧干货，保证一看就会！如果觉得有用可以转发一下，谢谢大家支持！

关注

转发

收藏

会让小编更有动力输出高价值的内容

俗话说

一个人的力量是渺小的

集体的力量是庞大的

但小编说

在Excel函数的世界里

也贯彻着这种思想

单个函数在运用时

作用和功能都比较单一

而将函数组合使用

操作更灵活

运算更方便

所以

今天

小编给大家带来

两组函数组合

让我们一起来看看

组合的力量

MAX+IF(MIN+IF)

组合一是MAX(MIN)和IF的应用

主要用于计算指定条件的最大值或最小值

如上图

若要计算四班成绩的最高分或最低分

就可使用此组合

如图所示

F2单元格的数组公式为

=MAX(IF(A2:A10=E2,C2:C10))

方法为

先用IF函数判断A列的班级是否等于E2指定的班级

如果条件成立

则返回C列对应的成绩

如果条件不成立

则返回逻辑FALSE

即{ FALSE;98; FALSE;82; FALSE ; FALSE ; FALSE ;72; FALSE }

接着使用MAX函数计算指定班级中的最大值

输入公式后

同时按下Ctrl+Shift+Enter键

（数组函数运算的要求哦）

即可得到四班的最高成绩

同理

利用

=MIN(IF(A2:A10=E2,C2:C10))

可得到四班的最低成绩

.............................▼.............................

INDEX+MATCH

组合二是INDEX和MATCH的应用

主要应用于函数对象的查询

且可实现逆向查询

即从左向右、从右向左

从上向下、从下向上

的全方位查询

如上图

若要根据姓名查询对应的班级

就可使用此类组合

如图所演示

D2单元格使用公式为

=INDEX(A2:A10,MATCH(E2,B2:B10,))

方法是

先使用MATCH函数来定位查询值E2的位置

即精确查询到E2单元格中的“小玉”

位于B列中的第四行

此结果用作INDEX函数的参数（索引值）

再使用INDEX函数返回指定区域中指定的位置

即根据第四行返回A列中对应的值

得到最终结果“三班”

小编说

在函数组合的应用中

MAX(MIN)函数和IF函数的组合

功能强大，使用简便

INDEX函数和MATCH函数的组合

看似繁琐，实则灵活多变

组合的力量无限大

Excel函数也不落下

你还不快学起来！！！

关注

转发

收藏

会让小编更有动力输出高价值的内容

在excel中我们有时候需要将多个图表组合在一起，以便我们更清楚地查看其中的数据。以下面的“成本费用预算表”为例，看看如何应用组合图。

首先我们插入“簇状柱形图”，选择数据源，设置图例、标题等得到如下图表。

这时我们发现：图表中没有出现“增减率”的图。因为“增减率”的数据远远小于“上年实际”、“本年预算”的数据，所以在图表中，“增减率”数据不能有效地呈现出来。如何解决？我们想到设置次坐标轴的方法，来显示增减率数据，也即创建组合图来呈现。

方法：1、选择“增减率”图例项，鼠标右键选择更改图表类型，得到下图所示：

2、选择次坐标轴“增减率”，图表类型选择“带数据标记的折线图”，下图所示：

单击确定，组合图创建完毕，最终效果如下：

“增减率”数据清楚地呈现出来了。

office微信公众号

相关链接：

制作九九乘法口诀表

频数分析||Excel在统计中的应用

Word也能制作工资条

AND、OR、NOT函数使用介绍

EXCEL中获取外部数据

15个模式化的EXCEL表格公式

超简便的个税计算方法