有了选票的数据，我们要对其进行汇总，快速的选出选票最多的人选。一般的方法就是一个个的等级候选人，然后在等级他们的选票数。比较费时，费力。那么在Excel中如何快速的筛选出选票最高得人选了？

一、登记选票数据。

将选票逐一进行登记，如下图。

二、提取选票最高的姓名。

方法：

在目标单元格中输入公式：=INDEX(B:B,MODE(MATCH(B3:B12,B:B,0)))。

思路：

先用Match函数计算每个姓名首次出现的位置，然后在用Mode函数提取其中出现频率最高的那个，最后定位返回。

有关INDEX,MODE,MATCH函数的基础用法可以查阅历史消息中的有关文章。

在实际的办公中，时长需要提取指定的数字、文本等数据，这时我们就要用到LEFT、RIGHT、MID等函数了。

一、LEFT:提取左侧字段。

方法：

1、选定目标单元格。

2、输入公式：=LEFT(B3,2)。

3、Ctrl+Enter填充。

4、在联系方式处输入第一个人的联系电话。

6、选定给所有目标单元格（包括输入电话的单元格）。

7、Ctrl+E填充。

二、RIGHT：右侧提取。

方法：

1、选定目标单元格。

2、输入公式：=RIGHT(B3,11)。

3、Ctrl+Enter填充。

三、LEFT+LEN:不规则字段中数字或文本的提取。

方法：

1、选定目标单元格。

2、输入公式：=LEFT(B3,2*LEN(B3)-LENB(B3))或=RIGHT(B3,LENB(B3)-LEN(B3))。

3、Ctrl+Enter填充。

四、MID：中间提取。

方法：

1、选定目标单元格。

2、输入公式：=TEXT(MID(C3,7,8),"00-00-00")。

3、Ctrl+Enter填充。

五、FIND：返回指定值左右的字符。

方法：

1、选定目标单元格。

2、输入公式：=LEFT(B3,FIND("-",B3)-1)或=RIGHT(B3,LEN(B3)-FIND("-",B3))。

3、Ctrl+Enter填充。

施老师：

做人事的朋友们经常需要录入员工信息表，那么我们可以利用EXCEL将身份证号码的出生年月提取出来，自动生成年龄。这样就省去很多的工作量，提高工作效率

方法一、按当前系统日期计算

在单元格，输入公式：【=DATEDIF(TEXT(MID(当前单元格,7,8),"#-00-00"),TODAY(),"Y")】

DATEDIF：计算机日期比较函数；

TEXT：将数值转换为按指定数字格式表示的文本；

MID：截取出指定数量的字符；

TODAY：用于返回当前时间；

Y：指计算两个日期的年差数；

方法二、同样也是按照当前系统日期

输入公式：【=DATEDIF(TEXT((LEN(A2)=15)*19&MID(A2,7,6+(LEN(A2)=18)*2),"#-00-00"),TODAY(),"y")】。也可以同样的计算出年龄。

大家平时碰到输入人员身份证信息和年龄的，大家是按笨办法一个一个的输入还是用函数去计算呢？欢迎大家在下方评论区留言写下你的看法，更多问题请关注宁双学好网施老师！

我们一般在这里学生档案以及员工的身份证信息时，在Excel输入身认证号以后，我们一般还得手动去输入身份证号码内的出生年月，这样无形中增加了我们的工作量，接下来小编就用一组模拟的数据，来演示如何快速的提取身份证号码中的出生年月：

提取方法一：使用函数公式提取，在C2单元格内输入以下公式，并向下填充即可。

=TEXT(MID(B2,7,8),"0-00-00")+0

注意：如果说你输入公式后，结果变成“30597”，那么我们就需要单元格的格式，如图：

解释：这个公式是有“MID函数”“TEXT函数”组成，我们现在身份证号码B2单元格中从它的第7位开始截取，截取的字符长度是8位，得到的计算结果就是“19831008”。然后在通过TEXT函数“TEXT(MID(B2,7,8),"0-00-00")”让它变成“1983-10-08”这样的格式。

经过这样的公式后，就有了日期的格式“1983-10-08”，但是这样的结果还不是真正的日期格式。经过“MID函数”“TEXT函数”等函数计算后得出的数值都是文本格式，一般情况下，不能参与后续的计算处理。

那么，在TEXT函数后面加零是什么意思呢？通常把这种形式叫做加零运算，通过运算，将文本格式的数值变成真正的日期格式，如果将加零换成1*（1乘以），也可以实现将文本格式向数值格式的转换的。

提取方法二：使用基础操作“数据分列”的方法来提取。

第一步：选择B列数据区域，单击【数据】【分列】，在弹出【文本分列向导 第1步，共3步】对话框中，选择“固定宽度”，单击下一步。

在【文本分列向导 第2步，共3步】对话框数据预览窗口中，单击第6位和第7位之间的刻度，再单击第14位和第15位之间的刻度（也就是留出出生日期的宽度），单击【下一步】。

在【文本分列向导 第3步，共3步】对话框中，依次点击最左侧列，点选【不导入此列（跳过）】。点击最右侧列，点选【不导入此列（跳过）】。点击中间列，点选【日期】。目标区域选择C2，单击完成。

这样，所有的出生日期就马上可以提取出来了。

学会了吗？这样是不是就减轻了你的工作压力~~

在Excel中，提取指定的字段，也是Excel常见的应用之一，但是你知道怎么提取吗？

一、从邮箱地址中提取用户名。

方法：

在目标单元格中输入公式：=LEFT(E3,FIND("@",E3)-1)。

释义：

1、此功能是利用LEFT和FIND函数共同完成的。

2、利用FIND函数查找“@”符号在E3（相对引用）中的位置，其位置减去1正好是用户名的长度。

3、利用LEFT函数提取用户名。

二、提取域名。

方法：

在目标单元格中输入公式：=RIGHT(E3,LEN(E3)-FIND("@",E3))。

释义：

1、此功能是利用RIGHT、LEN、FIND函数共同完成的。

2、字符串的长度（LEN(E3)）减去符号“@”前字符的长度，正好为域名起始字符串的位置。

3、然后利用RIGHT函数提取即可。

假设A列有500个数据，如何选出这一列里的第5、10、15、20、25个数据，以此类推。

=INDEX($A:$A,ROW(1:1)*5+1)

INDEX函数有2种语法结构。这里介绍她的第一种结构：

INDEX(要取数的目标区域，行号，列号)，其中列号可以省略。如果列号省略，则目标区域必须为单列。

使用公式提取单元格内的数字，要根据具体的数据结构找到某种规律从而设计出对应的公式。

例一 数字在左侧，且数字位数固定。

直接用公式：=left(A2,2)

第一个参数是要提取数字的单元格，第二个参数是要提取几位（从左边算起）。对于例一的这一类数据，使用的时候根据数字的长度修改第二参数即可。

例二：数字在左侧，数字位数不固定，但是有明显的分隔符号。

见下面的例子：

1、利用公式=FIND("-",A2,1)可以确定"-"的位置。

2、find函数有三个参数，第一个参数是要找什么内容，第二个参数是从哪里找，第三个参数是从第几个字开始找（从左边算起）。

=FIND("-",A2,1) 意思是在A2单元格找“-”，从开始位置找（左边第一位）。公式的结果是数字，代表“-”在单元格的位置（第几个字符），此时我们需要提取的数字长度就是find的结果减1，因此方法就有了：=LEFT(A2,FIND("-",A2,1)-1)

应用场景：工作中，常常需要从单元格数据中截取一部分进行统计、计算，或者从不同系统导出的数据中提取中文、数字和英文等，如何快速提取需要的数据呢？介绍4种常用方法。

第一种方法，用文本截取函数三剑客（LEFT/RIGH/MID函数）和文本长度度量函数（LEN /LENB）来提取

1、LEFT函数和RIGHT函数

参数：

LEFT (①要截取的文本或字符串,②要截取的字符个数)

RIGHT (①要截取的文本或字符串,②要截取的字符个数)

2、MID函数

参数：

MID（①要截取的文本或字符串，②从哪个位置开始截取，③要截取的字符个数）

3、LEN和LENB函数

LEN()& LENB()函数的参数很简单，只有一个，就是您要测量长度的文本，LEN()函数和LENB()函数的区别就是前者测量字符数，后者测量字节数，只有在文本字符串中包含汉字时才会有区别。

4、案例

案例1：从身份证号中截取省市区代码、出生年月和顺序及校验码

省区代码：从左边取6位。C2公式：Left(B2,6)

出生年月：从第7位数据开始取，要取出8位数。D2公式：Mid(B2,7,8)

顺序号和校验码：从右边4位数。E2公式：Right（B2,4）

案例2： 将单元格中的中英文分开

提取英文：

①在B2单元格录入公式：=LEFT(A2,LEN(A2)*2-LENB(A2))

②下拉填充公式。

公式解析：

LEN(A2)*2得出的结果是：12 （效果相当于：love爱love爱）

LENB(A2)得出的结果是：8 （效果相当于： love爱爱）

LEN(A2)*2-LENB(A2)得出的结果是：12-8=4（效果相当于：love爱love爱- love爱爱=love）

最后用LEFT函数从左取相对应的英文字母数即可提取英文单词。

提取中文：

①在C2单元格录入公式：=RIGHT(A2,LENB(A2)-LEN(A2))

②下拉填充公式。

公式解析：

LENB(A2)得出的结果是：8 （效果相当于：love爱爱）

LEN(A2)得出的结果是：6（效果相当于：love爱）

LENB(A2)-LEN(A2)得出的结果是8-6=2 （love爱爱- love爱=爱）

最后用RIGHT函数从右取相对应的汉字字符数即可提取中文。

第二种方法：用EXCEL快速填充功能提取

快速填充是EXCEL2013以上版本的一个新功能，她能模拟、识别你的操作，推测你内心的想法，然后按照你的想法进行数据填充。

运用快速填充时，首先直接输入一组到三组数据，让Excel自动识别你的意图，再进行快速填充，快速填充的快捷键为Ctrl+E，也可以单击“数据”选项卡 > 在“数据工具”组中 > 单击“快速填充”或选中示例单元格，拖动填充柄往下填充，然后在“自动填充”选项中选择“快速填充”来实现。（详细教程可见“EXCELl学习微课堂分享的《EXCEL快速填充功能如此牛逼，你知道吗？》）

案例动态演示：

第三种方法：用自定义函数myget

函数有两参数，=myget(①从哪提取，②提取什么)

=myget(字符串,0) 取出数字

=myget(字符串,1) 取出中文字符

=myget(字符串,2) 取出英文字母

=myget(字符串,3) 取出特殊字符

=myget(字符串,4) 取出取第一个数字的位置

=myget(字符串,5) 取出取最后一个数字的位置

方法步骤：

首先导入自定义函数的模板文件，点开发工具→VBA或都按ALT+F11 调出VBA 编辑器 →在工程窗口右键选择【导入文件】→选择VBA 模块文件（提取中文、英文和数字自定义函数myget.bas）→关闭VBA 编辑器。然后再输入公式即可。

动态演示：

第四种方法：用【数据】→【分列】的方法

案例步骤：

1、【选中需分列的列】→【数据】→【分列】，在弹出的文本分列向导设置窗口中，根据实际情况选择分隔符号或固定宽度，案例中都是用/分隔的，所以选【分隔符号】→【下一步】

2、选择分隔符号为其他符号【/】→【下一步】

3、选列区域的格式，案例中选择默认的常规格式即可，目标区域选择$B$1（即分列的结果放在哪）点【完成】数据按要求进行了分类提取到3列。

动态演示：

小伙伴们，EXCEL快速提取方法都齐了，大家可根据需要选取不同的方法！

我是EXCEL学习微课堂，分享EXCEL学习小技巧，小经验。如果分享的内容对您有帮助，欢迎点赞、收藏、评论、转发，更多的EXCEL技能，可以关注“EXCEL学习微课堂”。如需自定义函数myget代码文件，可私信联系我！

每按条件提取最大值

大家好，今天和大家分享“按条件提取最大值”，当单元格D2输入"1月"时，在E2单元格显示1月的最大值30；当单元格D2输入"2月"时，在E2单元格显示2月的最大值50；当单元格D2输入"3月"时，在E2单元格显示3月的最大值90。更多Excel学习和问题请加群：289393114、570064677

一、动画操作效果

二、公式截图

三、公式

=MAX((A2:A10=D2)*(B2:B10))

四、公式解释

记得是数组公式，把公式输好之后，光标移到编辑栏里，三键一齐下Ctrl+Shift+回车键

如果A2:A10=D2，那么就和数量B2:B10相乘

A2:A10=D2返回的是布尔值，有的也叫逻辑值True,False，单元格区域A2:A10等于3月的就返回true，其它的返回false

在运算时true当作1，False当作0，(A2:A10=D2)*(B2:B10)这个返回{0;0;0;0;0;60;70;80;90}，然后我们在外面嵌套一个最大值函数Max

五、这个也可以用if函数解出来

公式截图

公式

=MAX(IF(A2:A10=D2,B2:B10,0))

公式解释

1、也是数组公式

2、IF(A2:A10=D2,B2:B10,0)如果单元格区域A2:A10有等于3月的，那么就显示数量B2:B10,否则就显示0

3、最后也是在外面嵌套一个max函数提取最大值

Hi，大家好，我是胖斯基

慵懒的午后，销售MM带着82°C的微笑走过来，问：如何在这一堆繁杂的数据中，把手机号提取出来？

本着务实主义，打开表格一看，密密麻麻，瞬间眼花……

典型密集型恐惧患者的魔障

当然魔障归魔障，问题是依旧存在和处理的

那针对这种类型的问题处理，一般有套路可遵循，而这套路就是所谓的模板公式

1

LOOKUP经典款

公式：=-LOOKUP(,-MID(B2,ROW($1:$50),11))

说明：1是通过MID来获取多个固定长度为11的数字串，2是通过LOOKUP来取所需数值

注意：这里仅仅只获取了最后一个手机号（因LOOKUP函数的查询原理导致）

2

SUBSTITUTE替换款

公式：=MAX(IFERROR(--CLEAN(MID(SUBSTITUTE(B2,";",REPT(" ",90)),{1,91,181},90)),))

说明：这里通过分析联系电话中，电话号码的间隔是通过";"进行，故整体将";"替换为90个长度的空格，这样就可以分段获取带空格的手机号，在通过CLEAN函数和MAX函数，来获取最终的手机号

注意：这里仅仅只获取了最后一个手机号（原因，可以思考下）

3

VLOOKUP查询款

公式：=VLOOKUP(,MID(B2,ROW($1:$99),11)*{0,1},2,)

说明：这里本质上，也是通过MID来构建出一连串的11个长度的数字串，与第1种方法不同的特点在于，这里通过Vlookup函数并结合{0,1}，构建出了一个查询区域，并反馈对应手机号的结果。

注意：这里仅仅只获取了第一个手机号（因VLOOKUP函数的查询原理导致）

到这里，发现这3个套路公式要么获取了第1个手机号，要么获取了最后一个手机号，如果数据信息中，涵盖了多个手机号呢。如何获取？

没问题，变通一下即可！

4

COLUMN变通款

公式：=LARGE(--TEXT(MID($B2,ROW($1:$99),11),"0;;0;!0"),COLUMN(A1))

说明：这里利用LARGE函数来构造出一个数组（里面的内容就是手机号），通过COLUMN(A1)函数并往右拖动鼠标，横向的提取一个个手机号

胖斯基 | 说

模板公司看不懂无所谓，会用即可，赶紧收藏吧！