大家好，今天和大家分享“提取数字前面的字母你会几种方法？”，首先大家不要看我的解法，自己想想看，你可以用几种解法解出这个题，要求如下图，字母连续且在左边，数字在右边。我用6种解法分享给大家，记得全是数组公式。

一、解法1：Find找第一个数字出现的位置|更多Excel学习和问题请加群：289393114、570064677

1、公式截图

2、公式

=LEFT(A2,MIN(FIND(ROW($1:$10)-1,A2&5/19))-1)

3、公式解释

用find函数找到第1个数字出现的位置，然后减掉1，得到字母的个数，再从左边提取字母

为什么A2后面要连接一个5/19，目的是防止找不到报错

ROW($1:$10)-1指10个阿拉伯数字

min提取的第一个数字出现的位置

二、解法2：Count统计字母的个数

=LEFT(A2,COUNT(0/(MID(A2,ROW($1:$19),1)>="A")))

MID(A2,ROW($1:$19),1)>="A" 用mid函数分隔每个字符，然后判断是否大于等于A，注意不区分大小写的，得到一个维数组，由True,False构建的

0/true返回0，0/False返回报错

用Count统计0的个数，就是得到字母的个数，最后用Left函数提取字母出来

三、解法3：Match找第一个数字出现的位置

=LEFT(A2,MATCH(,MID(A2,ROW($1:$19),1)*0,)-1)

用函数mid把每一个字母分隔，然后乘0，也就是所有的分隔出来的数全变成了0

MATCH(,MID(A2,ROW($1:$19),1)*0,)-1用Match函数找到第1个0出现的位置，也就是第一个数字出现的位置，所以也要减掉1

然后用Left函数从左边提取

四、解法4：Match找最后一个字母出现的位置

=LEFT(A2,MATCH(1,0/(MID(A2,ROW($1:$19),1)>"9")))

0/(MID(A2,ROW($1:$19),1)>"9")用Mid分隔每个字符，然后判断是否大于9，记得9要加双引号，所以的字母都大于“9”，也就是说所有字母在的位置都返回true,我们找最后一个true的位置，其实就是最后一个字母的位置，用0除，目的让所有的True返回0，所有的False报错

MATCH(1,0/(MID(A2,ROW($1:$19),1)>"9"))用match找最后一个0的位置

最后用lfeft从左边提取

五、解法5：字母的个数=总字符数-数字的个数

=LEFT(A2,LEN(A2)-COUNT(--RIGHT(A2,ROW($1:$19))))

COUNT(--RIGHT(A2,ROW($1:$19)))统计数字的个数

LEN(A2)-COUNT(--RIGHT(A2,ROW($1:$19)))总的字符数减掉数字的个数，得到字母的个数

六、解法6：巧用Match第2参数

=LEFT(A2,COUNT(MATCH(MID(A2,ROW($1:$19),1),CHAR(ROW($65:$90)),)))

用mid把每个字符都分隔出来作match函数第1参数，这里很巧妙用26个字母作match函数的第2参数，也就是说单元格里每一个字符都会返回一个数字位置，这些数字的个数就是字母的总个数，然后用Count函数去统计

CHAR(ROW($65:$90))返回26个大写字母

另注意，Match函数查找字母时，不区分大小写字母

在前面两期教程中为大家讲解了LAGER函数的基础用法。那么今天龚老师就来个升级版的排名函数应用案例讲解。

之前我们讲解的是如何按排名提取成绩。今天跟大家分享一下如何按照排名提取相对应的学员姓名。

举例：

如上表是，我们的学员成绩信息表。我们现在需要快速从表中提取出前三名学员姓名。

函数公式

=LOOKUP(1,0/(LARGE($C$2:$C$13,ROW(D1))=C2:C13),B2:B13)

函数公式解释：

ROW(D1)：返回D1所在行的行号。

LARGE($C$2:$C$13,ROW(D1):返回ROW(D1)对应的排名结果。

LOOKUP(1,0/(LARGE($C$2:$C$13,ROW(D1))=C2:C13),B2:B13)用lookup函数查找学员成绩所对应的学员姓名。

是不是又学到技巧了？记得分享哦！

某财务想了20分钟都没想出来的问题：科目从一级到四级都有，如何提取最后一级科目？

最后一级科目，用Excel的语言就是最后一个文本。查找对应值，当然用查找之王LOOKUP函数。

在F2输入公式，下拉填充公式。

=LOOKUP("座",B2:E2)

当有多个符合条件的值存在，LOOKUP函数是查询最后一个满足条件的值。现在，卢子举一个小例子进行说明，因为汉字不太直观，这里换成字母。

Z是最大的字母，所有字母都小于等于他。如第3行，有D和C，这两个字母都比Z小，就返回最后一个值C。如第5行，C、B、A、F都比Z小，就返回最后一个值F。记住，这里是返回最后一个满足条件的字母，而不是最大的字母。

文本都是按字母排序，而座（ZUO)的首字母是Z，通常情况下的汉字都比座小，利用这个特点可以找到最后一个文本，也就是最后一个科目。

更多LOOKUP函数的用法，详见文章《VLOOKUP函数滚一边去，我才是Excel真正的查找之王！》

科目还有一种比较常用的方法，就是以-作为分隔符号，这种情况，又该如何提取最后一级科目呢？

如果你函数玩得出神入化，可以用函数搞定。

=TRIM(RIGHT(SUBSTITUTE(B2,"-",REPT(" ",50)),50))

不过，这里卢子要教你一种简单的办法——替换法。

将B列的科目复制到C列，按Ctrl+H调出查找和替换对话框，查找内容输入*-，单击全部替换。

*-意思就是将-和之前的所有内容替换掉，剩下的就是最后的科目。

处理复杂的Excel表格时候，如何把单元格里面复杂的数字给提取出来呢?是将单元格里面的数字复制粘贴出来吗?NO不是!在这里教大家几个函数轻松帮你将单元格里面的数字给全部提取出来，完全不费吹灰之力!

1、如何提取单元格文本中数字

代入函数公式：

=MIDB(A2,SEARCHB("?",A2),2*LEN(A2)-LENB(A2))

将函数代入到指定的单元格，即可提取A2单元格数字，前提要将函数的坐标对应好单元格呦!

2、如何提取文本左右数字

(左侧)代入函数公式：

=LEFT(A2,2*LEN(A2)-LENB(A2))

(右侧)代入函数公式：

=RIGHT(A2,2*LEN(A2)-LENB(A2))

同理直接将函数代入到单元格里面，就可以快速提取数字，下面我演示下提取文本左侧数字。

3、如何提取混合在一起的数字

代入函数公式：

=SUM(MID(0&A2,LARGE(ISNUMBER(--MID(A2,ROW($1:$1024),1))* ROW($1:$1024),ROW($1:$308))+1,1)*10^ROW($1:$308)/10)

在复制函数到单元格的同时要按住Shift+Ctrl+Enter键，就可以提取混合在一起的数字了!

使用公式提取单元格内的数字，要根据具体的数据结构找到某种规律从而设计出对应的公式。

例一 数字在左侧，且数字位数固定。

直接用公式：=left(A2,2)

第一个参数是要提取数字的单元格，第二个参数是要提取几位（从左边算起）。对于例一的这一类数据，使用的时候根据数字的长度修改第二参数即可。

例二：数字在左侧，数字位数不固定，但是有明显的分隔符号。

见下面的例子：

1、利用公式=FIND("-",A2,1)可以确定"-"的位置。

2、find函数有三个参数，第一个参数是要找什么内容，第二个参数是从哪里找，第三个参数是从第几个字开始找（从左边算起）。

=FIND("-",A2,1) 意思是在A2单元格找“-”，从开始位置找（左边第一位）。公式的结果是数字，代表“-”在单元格的位置（第几个字符），此时我们需要提取的数字长度就是find的结果减1，因此方法就有了：=LEFT(A2,FIND("-",A2,1)-1)

提取小数部分

大家好，今天和大家分享"提取小数部分"，介绍4种方法

方法一：Int函数实现

1、公式截图

2、公式

=A2-INT(A2)

3、公式解释

这个函数的作用就是取整如果是正数去掉小数部分如果是负数，去掉小数部分，整数部分还要加+1，如A2单元格-45.35，得到是-46，然后-45.35-（-46）得到0.65，所以这个公式不适合负数。更多Excel学习和问题请加群：289393114、570064677

方法二：Trunc函数实现

=A1-TRUNC(A1,0)

Trunc这个函数也是截取整数部分或者指定小数位数INT 和 TRUNC 在处理负数时有所不同：TRUNC(-4.3)返回-4，而INT(-4.3)返回-5，因为 -5 是较小的数。

方法三：Mid+Find实现

=0&MID(A1,FIND(".",A1),10)

先用find找到小数点位置然后用mid提取，包括小数点最后用0&补上小数点前面的0

方法四：Mod实现

=MOD(A1,1)

mod取数函数当除数是1是，得到余数便是小数，缺点是负数不行

应用场景：工作中，常常需要从单元格数据中截取一部分进行统计、计算，或者从不同系统导出的数据中提取中文、数字和英文等，如何快速提取需要的数据呢？介绍4种常用方法。

第一种方法，用文本截取函数三剑客（LEFT/RIGH/MID函数）和文本长度度量函数（LEN /LENB）来提取

1、LEFT函数和RIGHT函数

参数：

LEFT (①要截取的文本或字符串,②要截取的字符个数)

RIGHT (①要截取的文本或字符串,②要截取的字符个数)

2、MID函数

参数：

MID（①要截取的文本或字符串，②从哪个位置开始截取，③要截取的字符个数）

3、LEN和LENB函数

LEN()& LENB()函数的参数很简单，只有一个，就是您要测量长度的文本，LEN()函数和LENB()函数的区别就是前者测量字符数，后者测量字节数，只有在文本字符串中包含汉字时才会有区别。

4、案例

案例1：从身份证号中截取省市区代码、出生年月和顺序及校验码

省区代码：从左边取6位。C2公式：Left(B2,6)

出生年月：从第7位数据开始取，要取出8位数。D2公式：Mid(B2,7,8)

顺序号和校验码：从右边4位数。E2公式：Right（B2,4）

案例2： 将单元格中的中英文分开

提取英文：

①在B2单元格录入公式：=LEFT(A2,LEN(A2)*2-LENB(A2))

②下拉填充公式。

公式解析：

LEN(A2)*2得出的结果是：12 （效果相当于：love爱love爱）

LENB(A2)得出的结果是：8 （效果相当于： love爱爱）

LEN(A2)*2-LENB(A2)得出的结果是：12-8=4（效果相当于：love爱love爱- love爱爱=love）

最后用LEFT函数从左取相对应的英文字母数即可提取英文单词。

提取中文：

①在C2单元格录入公式：=RIGHT(A2,LENB(A2)-LEN(A2))

②下拉填充公式。

公式解析：

LENB(A2)得出的结果是：8 （效果相当于：love爱爱）

LEN(A2)得出的结果是：6（效果相当于：love爱）

LENB(A2)-LEN(A2)得出的结果是8-6=2 （love爱爱- love爱=爱）

最后用RIGHT函数从右取相对应的汉字字符数即可提取中文。

第二种方法：用EXCEL快速填充功能提取

快速填充是EXCEL2013以上版本的一个新功能，她能模拟、识别你的操作，推测你内心的想法，然后按照你的想法进行数据填充。

运用快速填充时，首先直接输入一组到三组数据，让Excel自动识别你的意图，再进行快速填充，快速填充的快捷键为Ctrl+E，也可以单击“数据”选项卡 > 在“数据工具”组中 >单击“快速填充”或选中示例单元格，拖动填充柄往下填充，然后在“自动填充”选项中选择“快速填充”来实现。（详细教程可见“EXCELl学习微课堂分享的《EXCEL快速填充功能如此牛逼，你知道吗？》）

案例动态演示：

第三种方法：用自定义函数myget

函数有两参数，=myget(①从哪提取，②提取什么)

=myget(字符串,0) 取出数字

=myget(字符串,1) 取出中文字符

=myget(字符串,2) 取出英文字母

=myget(字符串,3) 取出特殊字符

=myget(字符串,4) 取出取第一个数字的位置

=myget(字符串,5) 取出取最后一个数字的位置

方法步骤：

首先导入自定义函数的模板文件，点开发工具→VBA或都按ALT+F11 调出VBA 编辑器 →在工程窗口右键选择【导入文件】→选择VBA 模块文件（提取中文、英文和数字自定义函数myget.bas）→关闭VBA 编辑器。然后再输入公式即可。

动态演示：

第四种方法：用【数据】→【分列】的方法

案例步骤：

1、【选中需分列的列】→【数据】→【分列】，在弹出的文本分列向导设置窗口中，根据实际情况选择分隔符号或固定宽度，案例中都是用/分隔的，所以选【分隔符号】→【下一步】

2、选择分隔符号为其他符号【/】→【下一步】

3、选列区域的格式，案例中选择默认的常规格式即可，目标区域选择$B$1（即分列的结果放在哪）点【完成】数据按要求进行了分类提取到3列。

动态演示：

小伙伴们，EXCEL快速提取方法都齐了，大家可根据需要选取不同的方法！

我是EXCEL学习微课堂，分享EXCEL学习小技巧，小经验。如果分享的内容对您有帮助，欢迎点赞、收藏、评论、转发，更多的EXCEL技能，可以关注“EXCEL学习微课堂”。如需自定义函数myget代码文件，可私信联系我！

问题来源

数据取整，是EXCEL数据处理的最常用的方式。可能大家最经常用的是INT函数，但，INT函数并不能满足所有的取整要求。比如，今天一位朋友要按照某位数的倍数取整，INT就解决不了了。

韩老师总结各种取整函数，大家可以收藏起来，遇到不同的取整要求，可以翻出来找合适的函数与方法。

九种方法分析一：INT取整

举例：

特征：

1、对正数，直接截掉小数取整；

2、对负数，截掉小数再-1取整。

二：TRUNC取整

特征：不管正数还是负数，都是直接截掉小数取整。

三：ROUND小数取整

第二个参数为0，采取四舍五入方式取整。

四：ROUND整数取整

第二个参数为负数，采取四舍五入方式取整。

五：ROUNDUP向上舍入函数

1、朝着远离 0（零）的方向将数字进行向上舍入。

2、如果第二个参数为 0，则将数字向上舍入到最接近的整数。

3、如果第二个参数小于 0，则将数字向上舍入到小数点左边的相应位数。

六：ROUNDDOWN向下舍入函数

1、朝着零的方向将数字进行向下舍入；

2、如果第二个参数为 0，则将数字向下舍入到最接近的整数；

3、如果第二个参数小于 0，则将数字向下舍入到小数点左边的相应位数。

七：MROUND函数

1、返回参数按指定基数舍入后的数值；

2、舍入的方式是“四舍五入”；

3、数值和基数参数的符号必须相同。如果不相同，将返回 #NUM 错误。

八：CEILING函数

1、 向上舍入（沿绝对值增大的方向）为最接近的指定基数的倍数。

2、如果数值为正值，基数为负值，则 返回 错误值 #NUM!；

3、如果数值为负，基数为正，则对值按朝向 0 的方向进行向上舍入；

4、如果数值和基数都为负，则对值按远离 0 的方向进行向下舍入。

九：FLOOR函数

1、将数值向下舍入（沿绝对值减小的方向）为最接近的指定基数的倍数

2、如果数值为正值，基数为负值，则 返回 错误值 #NUM!

3、如果数值为负，基数为正，则对值按远离 0 的方向进行向下舍入；

4、如果数值和基数都为负，则对值按朝向 0 的方向进行向上舍入。

关键字：Excel取整

摘要：使用Excel达到处理原始数据已达到预期值，比如四舍五入。

其实Excel里关于这方面的函数挺多的，不知道你是否会用Excel里的这些函数，int、trunc、round、rounddown、roundup、even、floor、ceiling函数。东西有点儿多，我知道你看不完的，不过坚持一下。（比较好奇为什么出这么多函数，感觉没必要的）

总结分6种操作：

1、向上四舍五入数字函数round（扩展roundup、rounddown、mround）2、去除小数点后的数据trunc3、按指定数的倍数向下舍入函数floor4、四舍五入为最接近的偶数函数even5、向上舍入为指定数据倍数函数ceiling6、向下四舍五入到最接近的整数函数int

想讲的

近似值是生活中常用的，不知道你是否记得我们小学时候学的近似值原则，我们学了三种原则，“四舍五入”、“进一原则”、“去尾原则”。忘记的我可以给大家回忆一下，我想四舍五入大家都知道，“进一法”，我还记得小学那个租车旅游的列子，班里33个人，假如一辆车只能坐 5人，那么要租几辆车？（3,2/5=6.4）不管是6.1还是6.9都得进位得7。而“去尾法”刚好相反，例如， 每件衣服要用布1.8米，现有布10米，可以做多少件？（10/1.8=5.56）不管是5.5还是5.9都不能再做一件衣服得去小数位得5。

测试数据

这里给出一些测试数据，可以参考一下（蓝色的是原始值）。比如左侧的=trunc(A1,5)就是一个公式的形式，把A1替换为处理的数据所在的单元格即可。

其实里面好多函数是一个效果，比如：截去小数取整=ROUNDDOWN(A1,0) =FLOOR(A1,1) =TRUNC(A1)。或者是even(A1)函数可以用=2*ROUNDUP(A1/2,0)代替，等等吧，可以自己练一练。

一个表格中有一列身份证号码，我们该如何快速取出身份证后六位呢？而不用逐条录入。该如何做呢？

在这里，我们还是通过Excel函数来解决，right函数即可解决

公式：=RIGHT(B2,6)

公式怎么理解呢？

right：从右面计算

B2：要获取的数值所在的单元格

6：即要获取的位数