“办公室大雁”9月7日准时在线，之前有朋友跟我说，我分享的东西虽然小，但也很实用，这话外之音，大雁有点明白了，就是大雁前面分享的东西过于简单了。其实办公室里不会Excel的大多为小白，他们初识Excel，有很多地方都需要慢慢进步，所以后面的日子，我会难易并存，综合一点和大家分享。

办公室大雁今日分享：SUM函数家族

说起SUM大家都知道，是用来求和的，但说起求和，有很多方法，有人说用计算器可比表格中输入数字快多了，那你就错了，当遇到条件较多，数据量较大的时候，你就会发现Excel，SUM的重要性。

在平时，我们经常会用到一些表格，一列数字需要求和，有些朋友有会手动输入这样的公式

这种方式未尝不可，但并不适用于数字较多的时候，否则很浪费时间，那这个时候就是用到SUM的时候了

1、让我们求一下所有产品的数量总和

=sum(C2:C9)

在求和的时候需要大家注意的是，SUM对于文本格式的数字会自动忽略掉的，所以一定要检查一下自己的单元格格式哦。

2、你能求出所有日期中布鞋的销售总和吗？

这个时候就要用到SUMIF函数了，让我们来解读一下SUMIF，SUMIF→SUM+IF，IF就是如果的意思，也就是说如果满足条件就对区域中的数据进行求和，具体的解读呢就是

=SUMIF（条件区域，条件，求和区域）

那刚才的问题就需要输入如下的内容进行求和了

=SUMIF(B2:B9,"布鞋",C2:C9)

这个函数其实是可以被活学活用的，当条件区域和求和区域是同一区域是，是可以省掉一个区域，不用写的。

比如，我们来求一下每天销售量超过30的，一共有多少销售量。按照语法本应该是=SUMIF(C2:C9,">30",C2:C9)，因为条件区域和求和区域是同一区域，所以可以直接缩写为=SUMIF(C2:C9,">30")，一定要牢记哦。

3、上面的SUMIF是针对于一个条件的求和，其实，SUM 还可以针对多个条件的求和。这就用到了SUMIFS

我们先解读一下SUMIFS的语法吧。

=SUMIFS（求和区域，条件区域1，条件1，条件区域2，条件2，条件区域n，条件n）

还是看一下我们刚才的表格，我们想求出2017/8/20之前英伦鞋的总销售量

=SUMIFS(C2:C9,A2:A9,"<2017/8/20",B2:B9,"英伦鞋")

如此一来，就算你的表格求和条件再多，也能一个公式全部搞定了。

办公室大雁今日附带技能：怎样让你的老板不用眼花缭乱？

很多时候因为表格数据太多，有很多的行和列，这就会让看表的人眼花缭乱，我第一次拿表给老板的时候，老板让我给表格各行填充颜色，我很细心的把200多行的数据隔行挑出来，填上颜色，填完颜色之后，老板眼睛不花了，我的眼睛却花了。

后来无意中看见了表格样式，打开之后才发现当时的自己有多可爱，比如我现在想把这个表各行填充颜色

只需要选中表格的数据区域，然后单击“开始”，“表格样式”，接下来任意的颜色随便你挑选。

然后检查一下数据来源区域是否正确，表格中是否含有标题，是否需要筛选按钮，然后点击确定就可以了。

这样是不是就省了很多时间，哈哈，但我还是好喜欢当时的那个傻傻的填充颜色的自己，我是有多有耐心啊，哈哈。

好了，今日分享到此结束，SUM函数还有一些技能，不过呢，用的概率不是很大，今天就分享这么多了，如果有朋友还需要SUM其他的技能，请在评论区告诉我，我们后期继续分享~大雁祝你今日早点下班，么么哒~

我们经常在使用excel的工作中会涉及到各种数据的求和，大家都知道各种求和的方式非常多，不知道你会多少种？今天我们主要来分享一个简单粗暴的excel超实用技巧，一秒钟快速求和！

如上图所显示的：我们需要把横向和竖向的和分别求出来显示在黄色的表格里，如果是你会用哪一种方式呢？一个一个的代入公式？（不会是你这时的想法吧？）能不用达到一秒钟快速求和的目的呢？好了不卖关子了，其实没有那么麻烦，一秒就可以搞定，一起来看看方法吧！

首先，我们要选中求和的区域。

接着按下快捷键Alt+=，就可以快速的完成求和，怎么样？这种结果和你经常使用的方法一样吗？是不是非常方便快捷呢？

各位小伙伴们，不知道喜不喜欢类似这样的简单粗暴有效的学习教程呢？如果喜欢的话记得点个赞或在评论区发表一下您的意见，这样我们就能做出更多适合您的教程了！当然，想要快速查看往期更精彩的内容别忘了点击关注！

Hi，大家好，我是胖斯基

周末闲暇，整理了下那铺满灰尘的书架。

透过尘埃，在故纸堆中发现这么一本连环画图册，脑海中瞬间回忆起那真假美猴王的剧幕，那一幕幕，完美的演绎了真亦假时假亦真，无为有处有还无……

其实，在Excel中，这种真真假假也同样存在，也一样带来了求和困扰！

求和，在Excel中很简单，相信小白都可以脱口而出，直接函数SUM即可，然后有时候，事实并非如此：

当采用最傻瓜的方式直接逐个相加时，发现结果正确；

但是当采用SUM求和时，结果却错误。

不明其中缘由的你，可能会非常困扰，明明就这几个数相加，怎么就不对了呢？

其源头就是“真假数据”，在Excel中的专业叫法是文本型数据（不参与直接运算）。

So，当这类“假数据”参与SUM时，自然不进行正确的求和运算。

1

那如何判定文本型的数值参与了运算？

技巧1：观察法

如果是文本型的数据，则在其单元格的左上角，会有一个三角符号提示

相信只要视力没问题，基本可以快速排查出所谓的“假数据”

当然，更BT的一种就是其单元格上没有小三角符合，那如何快速判定这一系列数据是否有问题呢？

依旧采用观察法：

选中这一列数据，然后观察Excel的右下方，会有文字提示：计数：6，数值计数：5，很明显，这其中有1个数字为“假数据”，So，找到Ta，解决Ta即可！

那如何从茫茫人海中找到这个“假数据”呢？

技巧2 ： 函数判断法

在Excel中，判断一个数字是否是真正的数值，有一个函数ISNUMBER，当其结果为TRUE的时候，其为真数字，当其结果为FALES时，其为假数字（文本型数字）

从函数检测结果来看，很容易就分辨出了那些数据有问题

发现问题很重要，解决问题更重要

2

如何解决文本型数值参与的计算？

技巧3 ： 文本转数值法

如果单元格里面的数值已经明确判定为文本型的“假数据”了，那可以采用文本转数值的模式，如下：

选中数据列，在右侧的提示框中选择转化为数值即可

技巧4 ： 公式计算法

当然，如果单元格里面的数据是从其他表，通过公式引入过来的，又该如何处理呢？

无论单元格里面公式是什么，在其后乘以1（*1）即可，通过数据运算让文本型转化为数值型数据

当然，也许发懒的你，什么都不想改，想直接在求和中自动计算，又该如何处理呢？

公式1：=SUM(1*(A2:A7)) ， 输入公式后，三键一起按（数组公式）

公式2：=SUMPRODUCT(1*(A2:A7))

其核心内涵，还是采用数据乘以1的方式，将文本转化为数值。

胖斯基|说

无论文本型数据也好，还是数值型数据也好，当掌握了上面4个小技巧时，真真假假，假假真真，便不那么重要了。

如果想求出每一种类的数据和，不一定要通过筛选命令，当然用筛选也没有问题

至少有三个命令，可以实现每种类数据的求和

1.sumif

根据案例中，我们想求出黑龙江省的销售总额，我们该怎么做？

SUMIF 在 EXCEL 中被用来按条件进行求和。

语法

SUMIF(range,criteria,sum_range)

range:条件区域，笼统的来讲就是需要判断条件的区域

criteria:条件，这里可以用等于、大于、小于，可以比对各种数值类型

sum_range:求和的区域

我们看到黑龙江的销售额，就被轻松的求出来了

2.SUBTOTAL

首先需要在数据命令下，对数据进行筛选，筛选完成后，使用SUBTOTAL

SUBTOTAL函数语法：SUBTOTAL(function_num, ref1, ref2, ...)

第一参数：Function_num为 1 到 11（包含隐藏值）或 101 到 111（忽略隐藏值）之间的数字，指定使用何种函数在列表中进行分类汇总计算。

第二参数：Ref1、ref2为要进行分类汇总计算的 1 到 254 个区域或引用。

SUBTOTAL函数在筛选命令，对数据处理的功能是很强大的

3.数据透视表

在对数据处理时，数据透视表也是一个十分有效的命令，可以动手试一试

如果看了这篇文章还是搞不定，可以直接给我留言

在评论区留言，告诉小编，你想学习哪些Excel技巧？

今天的Excel技巧可能出乎99%人的意外，不信向下看。

需要设置求和公式的表格

最笨的方法莫过于输入一个Sum公式然后向右拖，（这种同学笨的没救了）

聪明的方法是选取求和行后向按Σ，或按alt+=。（估计很多同学会以为它是小编所说最快的方法）

但遇到很大的表格，向下找到最下面一行，然后向拖使劲拖到最右，是不是有点麻烦。

小编所说最快的方法出场了：

按Ctrl+A,再按Σ（或alt+=）

更神奇的在后面，如果有多个相同格式的表格需要设置求和公式，全选工作表 - Ctrl+A - 点Σ ，竟然所有选中的表都设置了求和公式。

小编说：最后再补充一个小技巧，大家知道Σ是怎么输入的吗？小编是打了拼音 xigema。

转载自百家号作者：EXCEL学习微课堂

最实用Excel求和函数公式大全，小伙伴快来收藏备用！

一、快速求和：快捷键【ALT+=】快速求和

选取整个区域（B2:G14），点按快捷键【ALT+=】

二、含小计行的总计求和公式

如下图所示，要求在单元格设置累计求和公式，等于各小计之和。

B12=SUM(B2:B11)/2

三、隔列求和

隔列求和，如下图所示的计划与实际对比的表中，要计算全年的计划和实际完成情况，可以直接用sumif求和。

F3单元格公式为：=SUMIF($B$2:$E$2,F$2,$B3:$E3)

四、合并单元格求和

如下图所示，要求在D列对A列的类别求和。

D3=SUM(C3:C10)-SUM(D4:D10)

注：公式输入方法，选取D3：D10,在编辑栏中输入公式后按Ctrl+Enter完成输入。

五、含文本型数字求和

含文本型数字的求和，用sum得不到正确的结果，可以用Sumproduct函数进行求和，如下图所示，用Sum求和得到的结果明显不对。

六、忽略错误值求和

如下图所示，如果一个区域中含有错误值，那么在用sum求和时，结果也会显示错误。如果要忽略错误值求和，可用sumif函数解决。

=SUMIF(G2:C12,"<9E+307")或者=SUMIF(G2:G12,">0")

公式解析：

9E+307是接近最大的数字，一种约定俗成的写法。在excel中，错误值比最大的数字大，因此"<9E+307"就是对小于最大值的数字求和，就实现了我们的目标：忽略错误值只对数字求和。反过来，excel忽略错误值求和，我们也可以这样写公式：=SUMIF(G2:G12,">0")

七、多条件求和

根据条件对数据分类求和也是常遇到的求和方式，如果是单条件用SUMIF函数，如果是多条件就用SUMIFS函数。

如下图，根据销售情况表，求出各销售部门2018年1月20日之前的销售总额

I2单元格公式为：=SUMIFS(F:F,C:C,H2,A:A,"<2018-1-20")

八、模糊条件求和

如果需要进行模糊求和，就需要掌握通配符的使用，其中星号是表示任意多个字符。

如下图，根据销售情况表分别计算出各销售部门销售各种产品（打印机、笔记本、台式机）的总数。H2=SUMIFS($E:$E,$C:$C,$G2,$D:$D,H$1&"*")，由于打印机、笔记本和台式机有多个型号，所有要用通配符“*”。

九、多个表格同一位置求和

1月至12月的12个工作表如果格式完全相同，可以用sum函数的多表求和功能。

如下图所示，要求在汇总表里设置合计公式，汇总12个月员工各产品的销售情况。

B2单元格公式为： =SUM('1月:12月'!B2)

十、多个表格多条件求和

多表多条件求和可以用SUM函数和DSUM函数嵌套使用。

如下图所示，有表1、表2和表3三个工作表，要统计三个表中，张1、张2、张3的销量和。

C2单元格输入公式=

SUM(DSUM(INDIRECT({"表1";"表2";"表3"}&"!A1:D11"),4,A$1:B2))-SUM(C$1:C1)

公式解析：

1、数据区域，跨表引用了3个工作表，所以用工作表引用函数INDIRECT。

2、列数，第4列“销量”。

3、条件区域是从A1开始的活动区域，所以A1是绝对引用，但B2是相对引用。

4、由于是跨表引用，因此DSUM返回的是数组，不是单值，因此要外套sum。

5、因为不同的行是“或条件”所以在统计张2第一周的销量时，结果会包含张1第一周的销量，需要减去张1第一周销量，同样的道理，统计张3第一周的销售时要减去张1和张2第一周的销售和。

十一、按颜色求和

excel中还没提供按颜色求和的函数，需要借用宏表函数获取单元格的颜色值，然后再用sumif函数求和。

1、定义名称：公式 - 定义名称 ，在定义名称窗口中输入名称【颜色】，也可以自定义其它名称），然后在下面引用来源中输入公式：=GET.CELL(63,1月!B2)&T(NOW())

公式解析：

①Get.cell(63,单元格) 可以获取单元格填充颜色值

② &T(NOW) 实现表格在更新时定义名称取值也可以更新

2、获取颜色值：在C列和F列分别输入公式 =颜色，即可获取B列和D列的单元格填充色。

3、通过sumif函数求和。在F3单元格输入公式=SUMIF(C:C,E3,B:B)

我是EXCEL学习微课堂，百家号教育视频原创作者，如果我的分享对您有帮助，欢迎点赞、收藏、评论和转发！更多的EXCEL技能，可以关注百家号“EXCEL学习微课堂”。

与本教程有关的往期分享教程有：

1、Excel秒杀一切的求和函数SUMIFS, 多条件求和就靠它了！

2、EXCEL多条件求和、跨表多条件求和函数DSUM，让你求和效率更高！

本文由“EXCEL学习微课堂”原创，欢迎关注，带你一起长知识！

自动求和功能：在Excel“编辑”功能区，清除功能的上方有一个“自动求和”，可以紧接所选单元格之后显示所选单元格的求和值。

注：点击求和功能右边的黑色小三角，还会有平均值，计数值，最大值和最小值。意义就是：紧接所选单元格之后显示所选单元格的平均值（计数值、最大值、最小值）

一、 求和功能。

选择你需要求和的单元格，点击自动求和下拉按钮，选择求和，求和值会自动计算到选定单元格之后的一个单元格。

注：平均值、计数值等功能和自动求和功能一样（且在Excel右下角选定单元格时会出现平均值、计数值以及求和值。）

二、 多行（列）自动求和的使用。

A、选定需要求和的单元格，再多选择一个单元格容纳计算值，点击自动求和下拉菜单，选择你需要计算的功能，点击即可。

注：

1、 一定要多拉一个空白单元格，否则自动求和功能默认为是按列计算，计算值会出现在这列的第一个空白单元格内。

2、 利用快捷键“Alt”+“=”也可以实现上述自动求和（只能用于求和）

三、 选择多个指定单元格进行求和。

我们在使用Excel过程中，也可能遇到同列表格中，隔几行求一次和的情况，这种情况该如何？

按住“Ctrl”+“你需要求和的单元格”，然后点击自动求和下拉菜单，选择求和即可。

excel求和，有汉字怎么办？好烦人啊，有解决的办法吗？有！

很多用excel计算的朋友，会经常遇到这样的情况：

我们得到的excel数据

有人说这个不是很简单吗？我们在后面的单元格输入=B2*C2，往下一拉不就行了吗，来吧我们试试看：

excel出现的结果竟然是这样的：

简单的求和，excel出错了

那应该怎么办呢？假如我们想要的是，待定，未定，这些忽略，目前确定的数量是多少，我们在需要求和的单元格输入=SUMPRODUCT(B2:B6,C2:C6)，哇，竟然没出错，太神奇了！

excel在有汉字的情况下，完美的计算出了结果

这是什么意思呢？我们需要的结果是单价和数量乘积之和，而SUMPRODUCT是专门解决这个问题的函数，函数 SUMPRODUCT 将非数值型的数组元素作为 0 处理，所以汉字就被excel视为0。

怎么样，很简单吧，你学会了吗？快去试试吧！非常感谢您观看文本，如果你有更好的方法适用这个情况，请您留言分享！分享好玩、有趣、实用的手机和电脑技巧，您的支持就是我的最大动力！

日常工作中，总会遇到一些奇葩的表格。

这些表格普遍具有以下特征：

1、使用大量的合并单元格

2、内容都挤在一个单元格内，名称和数量不分家

3、数量单位不统一，一包一盒一箱一把抓

……

俗话说，有病的时候不能放弃治疗。

接下来咱们就看看下图中的数据如何破：

B列中的数据就是名称数量不分家的典范了，这么多的单元格不用，所有的内容都挤在一个格子里。

话说妹纸啊，你这样做表，妹夫知道吗？

这样的数据如何计算每天的消费额呢？

首先复制Excel中的数据，粘贴到Word中：

按Ctrl +H调出替换对话框：

替换完成后的效果如下：

复制Word中的内容，粘贴到Excel中：

这样就计算出了每个单元格内的数值之和，也就是每天的消费总额。

替换时用到的[!0-9.]{1,} 是Word通配符

[!0-9.]的意思是除了0-9和小数点以外的字符

{1,} 是一个或一个以上的字符。

也就是将一个或一个以上的、除了0-9和小数点以外的字符替换为+（加号）

求和，是最常见的统计工作，但花样繁多的求和要求和条件，常常让不少人限入苦思冥想不得其解的困惑之中，今天运用EXCEL函数与公式，总结从初级到高级的10个求和技巧，与大家一起学习和交流。

初级篇

1、运用“=”、“+”来计算

这是最基础的求和方法，适合无规律或指定单元格求和。如下图：计算1、3、5月份的销售量。J2单元格：=E2+G2+I2，然后，向下复制

2、运用函数SUM求和

这是基础求和函数，适合连续区域求和，高级应用多为与其他函数结合形成SUM数组公式。说明一点，SUM函数的参数，可以是单元格区间，也可以是单个单元格。如下图：计算1、3、5月份的销售量。J2单元格：=SUM(E2,G2,I2)，然后，向下复制

中级篇

3、忽略文本跨列求和

如下图，计算全部销售人员的销售额。C10单元格：=SUM(A2:I7)

利用Excel中sum函数本身对文本类型数值自动忽略的规定，所以，可以用来直接对跨列的数值型数据求和。

4、单条件求和，运用求和函数：SUMIF。

如图，计算1月份冰箱的销售量。K2单元格：=SUMIF($D$2:$D$18,"冰箱",$E$2:$E$18)

SUMIF函数基本结构：SUMIF（条件区域，条件，求和区域）

5、多条件求和，运用求和函数：SUMIFS。

如图，计算销售一部1月份相机销售量。L2单元格：=SUMIFS($E$2:$E$18,$A$2:$A$18,"销售一部",D$2:D$18,"相机")

SUMIFS函数基本结构：SUMIF（求和区域，条件区域1，条件1，条件区域2，条件2...）

6、避开错误值求和。

如下图：计算1-5月份总销售量。C12单元格：=SUMIF(A2:E10,"<9.9E+307")

应用函数SUMIF设置条件完成，其中设置条件"<9.9E+307"，其含义是，9.9*10^307，即9.9乘10的307次方，9.9E+307是一个极大的数值，根据EXCEL的通过规则：数值<文本

7、通配符求和

如下图：计算1月份包含电脑的的总销量。G2单元格：=SUMIF(C2:C18,"*电脑",D2:D18)

应用函数SUMIF设置条件完成，通配符*代表任何字符或字符串，只要总字符不超过255个，设置条件"*电脑"，或“*电脑*”，在选定区域中查找包含“电脑”的所有商品，在计算区域求和。

8、快速累计求和

利用“$”对求和区域首个单元格进行绝对引用，马上就能对一列数值快速累计求和，如下图，C2单元格：=SUM($B$2:B2)，向下复制即可。

9、求和的快捷键："Alt + =",选中要求和的区域和拟计算结果的空白区域，一键即可在空白区域产生求和结果

高级篇

10、求和之王：SUMPRODUCT

SUMPRODUCT函数跟SUM函数的数组公式条件求和语法一样。

=SUMPRODUCT((条件区域=条件)*求和区域)

如上面案例，计算1月份冰箱的销售量。K2单元格：=SUMIF($D$2:$D$18,"冰箱",$E$2:$E$18)，也可以写成：=SUMPRODUCT((D2:D18="冰箱")*E2:E18)

如上面案例，计算销售一部1月份相机销售量。L2单元格：=SUMIFS($E$2:$E$18,$A$2:$A$18,"销售一部",D$2:D$18,"相机")，也可写成：=SUMPRODUCT((A2:A18="销售一部")*(D2:D18="相机")*E2:E18)

下面，举个复杂一点点的例子，昨天，世界杯开始，首场比赛，俄罗斯队5：0大胜沙特队，拟统计本次世界杯，各小组球队进、失球队总数。

以A组为例，第一场有真实比分，其余为模拟分。就可以用SUMPRODUCT计算，进球数：J2单元格：=SUMPRODUCT(($B$2:$B$7=$I3)*($C$2:$C$7))+SUMPRODUCT(($F$2:$F$7=$I3)*($E$2:$E$7))；失球数：K2单元格：=SUMPRODUCT(($B$2:$B$7=$I3)*($E$2:$E$7))+SUMPRODUCT(($F$2:$F$7=$I3)*($C$2:$C$7))

SUMPRODUCT与其他函数结合还可以解决你意想不到的求和需求，以后我们会专门进行分享。请关注后，期待好文。

每天学习一点点，每天进步一点点，积硅步，必能致千里，得大成。