关注

转发

收藏

会让小编更有动力输出高价值的内容

上周

我们讲过在EXCEL中求和的7种公式

至于哪一种用起来最方便、最好用

自然是看你自己的喜好

但是呢

大多数人用的最多，用的最好的

自然还是SUM函数

就是上周文章中的公式一啦

公式一：=SUM(C2:C10)

这也是有一种先入为主的观念的存在

当然

小编我也不列外

SUM函数也是我的最爱

那么有朋友就问了

EXCEL求和还有没有更快捷的方法

答案当然是有的

就是使用我们的快捷键啦

快捷键【ALT+=】

选中单元格，按下“ALT”键“+”和“=”

看下图的演示，千万别眨眼哦

有没有看清楚

是不是只有一瞬间

求和结果就出来了

但是

要注意的是

一定先按住ALT键不放，再按“+”和“=”哟

所以这个EXCEL求和的快捷键

你们都get到了吗

相信那么聪明的你

一下就get到了！

转发

收藏

会让小编更有动力输出高价值的内容

转载自百家号作者：EXCEL学习微课堂

最实用Excel求和函数公式大全，小伙伴快来收藏备用！

一、快速求和：快捷键【ALT+=】快速求和

选取整个区域（B2:G14），点按快捷键【ALT+=】

二、含小计行的总计求和公式

如下图所示，要求在单元格设置累计求和公式，等于各小计之和。

B12=SUM(B2:B11)/2

三、隔列求和

隔列求和，如下图所示的计划与实际对比的表中，要计算全年的计划和实际完成情况，可以直接用sumif求和。

F3单元格公式为：=SUMIF($B$2:$E$2,F$2,$B3:$E3)

四、合并单元格求和

如下图所示，要求在D列对A列的类别求和。

D3=SUM(C3:C10)-SUM(D4:D10)

注：公式输入方法，选取D3：D10,在编辑栏中输入公式后按Ctrl+Enter完成输入。

五、含文本型数字求和

含文本型数字的求和，用sum得不到正确的结果，可以用Sumproduct函数进行求和，如下图所示，用Sum求和得到的结果明显不对。

六、忽略错误值求和

如下图所示，如果一个区域中含有错误值，那么在用sum求和时，结果也会显示错误。如果要忽略错误值求和，可用sumif函数解决。

=SUMIF(G2:C12,"<9E+307")或者=SUMIF(G2:G12,">0")

公式解析：

9E+307是接近最大的数字，一种约定俗成的写法。在excel中，错误值比最大的数字大，因此"<9E+307"就是对小于最大值的数字求和，就实现了我们的目标：忽略错误值只对数字求和。反过来，excel忽略错误值求和，我们也可以这样写公式：=SUMIF(G2:G12,">0")

七、多条件求和

根据条件对数据分类求和也是常遇到的求和方式，如果是单条件用SUMIF函数，如果是多条件就用SUMIFS函数。

如下图，根据销售情况表，求出各销售部门2018年1月20日之前的销售总额

I2单元格公式为：=SUMIFS(F:F,C:C,H2,A:A,"<2018-1-20")

八、模糊条件求和

如果需要进行模糊求和，就需要掌握通配符的使用，其中星号是表示任意多个字符。

如下图，根据销售情况表分别计算出各销售部门销售各种产品（打印机、笔记本、台式机）的总数。H2=SUMIFS($E:$E,$C:$C,$G2,$D:$D,H$1&"*")，由于打印机、笔记本和台式机有多个型号，所有要用通配符“*”。

九、多个表格同一位置求和

1月至12月的12个工作表如果格式完全相同，可以用sum函数的多表求和功能。

如下图所示，要求在汇总表里设置合计公式，汇总12个月员工各产品的销售情况。

B2单元格公式为： =SUM('1月:12月'!B2)

十、多个表格多条件求和

多表多条件求和可以用SUM函数和DSUM函数嵌套使用。

如下图所示，有表1、表2和表3三个工作表，要统计三个表中，张1、张2、张3的销量和。

C2单元格输入公式=

SUM(DSUM(INDIRECT({"表1";"表2";"表3"}&"!A1:D11"),4,A$1:B2))-SUM(C$1:C1)

公式解析：

1、数据区域，跨表引用了3个工作表，所以用工作表引用函数INDIRECT。

2、列数，第4列“销量”。

3、条件区域是从A1开始的活动区域，所以A1是绝对引用，但B2是相对引用。

4、由于是跨表引用，因此DSUM返回的是数组，不是单值，因此要外套sum。

5、因为不同的行是“或条件”所以在统计张2第一周的销量时，结果会包含张1第一周的销量，需要减去张1第一周销量，同样的道理，统计张3第一周的销售时要减去张1和张2第一周的销售和。

十一、按颜色求和

excel中还没提供按颜色求和的函数，需要借用宏表函数获取单元格的颜色值，然后再用sumif函数求和。

1、定义名称：公式 - 定义名称 ，在定义名称窗口中输入名称【颜色】，也可以自定义其它名称），然后在下面引用来源中输入公式：=GET.CELL(63,1月!B2)&T(NOW())

公式解析：

①Get.cell(63,单元格) 可以获取单元格填充颜色值

② &T(NOW) 实现表格在更新时定义名称取值也可以更新

2、获取颜色值：在C列和F列分别输入公式 =颜色，即可获取B列和D列的单元格填充色。

3、通过sumif函数求和。在F3单元格输入公式=SUMIF(C:C,E3,B:B)

我是EXCEL学习微课堂，百家号教育视频原创作者，如果我的分享对您有帮助，欢迎点赞、收藏、评论和转发！更多的EXCEL技能，可以关注百家号“EXCEL学习微课堂”。

与本教程有关的往期分享教程有：

1、Excel秒杀一切的求和函数SUMIFS, 多条件求和就靠它了！

2、EXCEL多条件求和、跨表多条件求和函数DSUM，让你求和效率更高！

本文由“EXCEL学习微课堂”原创，欢迎关注，带你一起长知识！

求和的解法在Excel中是千变万化的，也有很多种方法，但是有一种问题，不知道各位小伙伴们有没有注意到，这也是一位朋友在工作中遇到的一个例子。

下面就给大家举例说明一下这个题目，如何用公式来完成。

问题：求下面三个型号的数量的合计。

关于以上题目的做法，很多朋友也说出了一些基本操作的方法，但是好像都不能奏效。

小A说：可以用透视表的作法。小编在这里拉了一个透视表，但是只出现了大写的型号的合计，而小写的也没有出现。并且在统计的金额上也出现了错误。

如下图所示：

小B说：可以用合并计算的方法。但是好像也没有起到作用，合并计算出来的结果与透视表的结果是一样的，当你去逐一验证的时候又是不对，也没有出现小写的型号。

小C说：再不行的话就用筛选的方法进行原始的合并计算。小编验证了一下，好像也是不行的。

小D说：那就是用sumif的基本用法进行条件求和。小编同样满足了他的要求，但是求和的结果也同上面的是一样的。

上面的众多的方法都尝试过了，但都不是最好的办法，那么说没有好的方法了吗？

并不是的，条条大路通罗马嘛，方法还是有的哈，听小编给大家一一讲来。

大家都知道，Sum、Sumif、Sumifs、Sumproduct在单独使用的时候是不区分英文字母的大小写的，包括之前讲过的Vookup也是一样的。所以大家在使用的时候一定要注意一些单独的字符或者字符串在查找或者求值的过程中要注意区分大小写。在Excel中，基本区分大小写的函数有Find、Exact、Substitute等函数。

下面，我们就使用这些函数进行求和。

方法一：Sum/Sumproduct+Exact组合法

在G5单元格中输入以下的公式：

=SUM(EXACT(F5,$A$2:$A$21)*($B$2:$B$21))

并按组合键确定并填充。

此处也可以将Sum替换成Ssumproduct，直接按Enter键即可。

解析：Exact可以区分大小写。先用此函数将目标查找值与查找区域进行对比，确定符合条件的区域值，EXACT(F5,$A$2:$A$21)返回值为：

{TRUE;FALSE;FALSE;FALSE;FALSE;FALSE;FALSE;FALSE;FALSE;FALSE;FALSE;FALSE;FALSE;FALSE;FALSE;TRUE;FALSE;FALSE;FALSE;FALSE}，在前几期中过，逻辑值是可民认参与运算的，此处就转换为了0，1的值，然后再将数量区域乘上，产生

=SUM({TRUE;FALSE;FALSE;FALSE;FALSE;FALSE;FALSE;FALSE;FALSE;FALSE;FALSE;FALSE;FALSE;FALSE;FALSE;TRUE;FALSE;FALSE;FALSE;FALSE}*{85;37;35;24;72;80;21;43;6;24;73;62;50;13;61;52;47;53;80;8})，然后再用sum函数将以上的相乘的值进行相加。

方法二：Sum/Sumproduct+Substitute组合法

=SUM((SUBSTITUTE($A$2:$A$21,F5,"")="")*($B$2:$B$21))

此处也可以将Sum替换成Sumproduct，直接按Enter键即可。

解析：Substitute是替换函数，此处使用该函数将要查找的目标值替换为空白，然后以此为条件进行逻辑值运算，从面得出结果。SUBSTITUTE($A$2:$A$21,F5,"")的执行结果为：

{"";"AB002";"AB003";"AB004";"AB005";"AB006";"AB007";"Ab001";"Ab002";"Ab003";"Ab004";"Ab005";"Ab006";"Ab007";"ab001";"";"ab003";"ab004";"ab005";"ab006"}，然后再将“=“” ”得出逻辑值为：

{TRUE;FALSE;FALSE;FALSE;FALSE;FALSE;FALSE;FALSE;FALSE;FALSE;FALSE;FALSE;FALSE;FALSE;FALSE;TRUE;FALSE;FALSE;FALSE;FALSE},然后同以上方法中的运算一样，进行求积求和运算即可。

遗留问题：关于在筛选状态下、合并计算求和、透视表求和会出现错误的结果？

以上问题供各位小伙伴自己去解决，这里不再做过多的阐述。

End.

来自：Excel学堂

小编今天给大家介绍一下如何计算时长，时长和的问题主要聚焦在1）分钟和时间转换问题2）如何提取时间数据3）处理异常数据如空值等等。来看下面示例：

解决步骤：

1.提取小时数据：

E3=VALUE(IFERROR(LEFT(D3,FIND("小",D3,1)-1),0))

解释为：FIND函数找“小”字在D3字符串的位置，减去1,作为左侧小时的位数，LEFT函数截取左侧的小时数，如果不存在小时或者没有记录则用IFERROR函数用0表示，最后用VALUE函数把截取到的数字字符串转换为数字格式。

2.提取分钟数据：

F3=VALUE(IFERROR(MID(D3,IFERROR(FIND("时",D3,1),0)+1,FIND("分",D3,1)-IFERROR(FIND("时",D3,1),0)-1),0))

解释为：分别用FIND函数找“分”和“时”在D3中的位置。找到后用MID函数截取分钟数，起始位置就是FIND函数找“时”加上1，如果FIND“时”函数错误，用IFERROR把错误值变成0，同理截取的字符串个数就是FIND“分”的位置-FIND“时”的位置再减去1，然后套个IFERROR来排除空值错误显示为0，最后套个VALUE函数转变为数字。

3.统一单位为分钟：

G3=E3*60+F3

解释为小时*60+分钟

4.求和时长

H3=CONCATENATE(INT(SUM(G3:G18)/60),"小时",MOD(SUM(G3:G18),60),"分钟")

解释为：先把统一后的分钟数求和，然后除以60在向下取整作为小时数,再把除以60的余数作为分钟数，用到MOD函数求余数。最后用CONCATENATE函数连接，显示格式为：数字+小时+数字+分钟

当然最后还可以不用统一为分钟，去掉G列，后面总小时数为E列的求和加上F列求和除以60的向下取整，然后F列的余数作为分钟数。

自动求和功能：在Excel“编辑”功能区，清除功能的上方有一个“自动求和”，可以紧接所选单元格之后显示所选单元格的求和值。

注：点击求和功能右边的黑色小三角，还会有平均值，计数值，最大值和最小值。意义就是：紧接所选单元格之后显示所选单元格的平均值（计数值、最大值、最小值）

一、 求和功能。

选择你需要求和的单元格，点击自动求和下拉按钮，选择求和，求和值会自动计算到选定单元格之后的一个单元格。

注：平均值、计数值等功能和自动求和功能一样（且在Excel右下角选定单元格时会出现平均值、计数值以及求和值。）

二、 多行（列）自动求和的使用。

A、选定需要求和的单元格，再多选择一个单元格容纳计算值，点击自动求和下拉菜单，选择你需要计算的功能，点击即可。

注：

1、 一定要多拉一个空白单元格，否则自动求和功能默认为是按列计算，计算值会出现在这列的第一个空白单元格内。

2、 利用快捷键“Alt”+“=”也可以实现上述自动求和（只能用于求和）

三、 选择多个指定单元格进行求和。

我们在使用Excel过程中，也可能遇到同列表格中，隔几行求一次和的情况，这种情况该如何？

按住“Ctrl”+“你需要求和的单元格”，然后点击自动求和下拉菜单，选择求和即可。

在工作中，有时候excel表格需要每天统计数据，表格的行数会随着每天记录的数据而不断增加。像下表，每天都要记录出库数量，并且每天都要统计出库合计数量。当每天新增记录时，出库合计数量不需要再重新计算，根据新增的记录数据自动求和。

今天的小技巧运用到OFFSET函数和COUNTA函数。

OFFSET函数：以指定的引用为参照系，通过给定的偏移量返回新的引用。

函数语法：OFFSET(reference, rows, cols, [height], [width])

这个函数有5个参数：

第一个参数是基点。

第二个参数是要偏移几行，正数向下，负数向上。

第三个参数是要偏移几列，正数向右，负数向左。

第四个参数是新引用几行。

第五个参数是新引用几列。

第一至第三个参数为必需，第四个和第五个参数为可选。

例如公式：=OFFSET(B2,3,2,3,2)

就是以B2为基点，向下偏移3行，向右偏移2列，新引用的行数是3行，新引用的列数是2列，最终得到对D5:E8区域的引用。和SUM函数组合=SUM(OFFSET(B2,3,2,3,2))就是对D5:E8区域求和。

COUNTA函数：计算区域中不为空的单元格的个数。

接下里求出库数量合计，在B1单元格输入公式：=SUM(OFFSET(C3,0,0,COUNTA(C:C)-1,1))。当我们再次想数据表格中增加数据时，就会自动统计出库数量。

如果想求出每一种类的数据和，不一定要通过筛选命令，当然用筛选也没有问题

至少有三个命令，可以实现每种类数据的求和

1.sumif

根据案例中，我们想求出黑龙江省的销售总额，我们该怎么做？

SUMIF 在 EXCEL 中被用来按条件进行求和。

语法

SUMIF(range,criteria,sum_range)

range:条件区域，笼统的来讲就是需要判断条件的区域

criteria:条件，这里可以用等于、大于、小于，可以比对各种数值类型

sum_range:求和的区域

我们看到黑龙江的销售额，就被轻松的求出来了

2.SUBTOTAL

首先需要在数据命令下，对数据进行筛选，筛选完成后，使用SUBTOTAL

SUBTOTAL函数语法：SUBTOTAL(function_num, ref1, ref2, ...)

第一参数：Function_num为 1 到 11（包含隐藏值）或 101 到 111（忽略隐藏值）之间的数字，指定使用何种函数在列表中进行分类汇总计算。

第二参数：Ref1、ref2为要进行分类汇总计算的 1 到 254 个区域或引用。

SUBTOTAL函数在筛选命令，对数据处理的功能是很强大的

3.数据透视表

在对数据处理时，数据透视表也是一个十分有效的命令，可以动手试一试

如果看了这篇文章还是搞不定，可以直接给我留言

在评论区留言，告诉小编，你想学习哪些Excel技巧？

excel求和，有汉字怎么办？好烦人啊，有解决的办法吗？有！

很多用excel计算的朋友，会经常遇到这样的情况：

我们得到的excel数据

有人说这个不是很简单吗？我们在后面的单元格输入=B2*C2，往下一拉不就行了吗，来吧我们试试看：

excel出现的结果竟然是这样的：

简单的求和，excel出错了

那应该怎么办呢？假如我们想要的是，待定，未定，这些忽略，目前确定的数量是多少，我们在需要求和的单元格输入=SUMPRODUCT(B2:B6,C2:C6)，哇，竟然没出错，太神奇了！

excel在有汉字的情况下，完美的计算出了结果

这是什么意思呢？我们需要的结果是单价和数量乘积之和，而SUMPRODUCT是专门解决这个问题的函数，函数 SUMPRODUCT 将非数值型的数组元素作为 0 处理，所以汉字就被excel视为0。

怎么样，很简单吧，你学会了吗？快去试试吧！非常感谢您观看文本，如果你有更好的方法适用这个情况，请您留言分享！分享好玩、有趣、实用的手机和电脑技巧，您的支持就是我的最大动力！

日常工作中，总会遇到一些奇葩的表格。

这些表格普遍具有以下特征：

1、使用大量的合并单元格

2、内容都挤在一个单元格内，名称和数量不分家

3、数量单位不统一，一包一盒一箱一把抓

……

俗话说，有病的时候不能放弃治疗。

接下来咱们就看看下图中的数据如何破：

B列中的数据就是名称数量不分家的典范了，这么多的单元格不用，所有的内容都挤在一个格子里。

话说妹纸啊，你这样做表，妹夫知道吗？

这样的数据如何计算每天的消费额呢？

首先复制Excel中的数据，粘贴到Word中：

按Ctrl +H调出替换对话框：

替换完成后的效果如下：

复制Word中的内容，粘贴到Excel中：

这样就计算出了每个单元格内的数值之和，也就是每天的消费总额。

替换时用到的[!0-9.]{1,} 是Word通配符

[!0-9.]的意思是除了0-9和小数点以外的字符

{1,} 是一个或一个以上的字符。

也就是将一个或一个以上的、除了0-9和小数点以外的字符替换为+（加号）

求和，是最常见的统计工作，但花样繁多的求和要求和条件，常常让不少人限入苦思冥想不得其解的困惑之中，今天运用EXCEL函数与公式，总结从初级到高级的10个求和技巧，与大家一起学习和交流。

初级篇

1、运用“=”、“+”来计算

这是最基础的求和方法，适合无规律或指定单元格求和。如下图：计算1、3、5月份的销售量。J2单元格：=E2+G2+I2，然后，向下复制

2、运用函数SUM求和

这是基础求和函数，适合连续区域求和，高级应用多为与其他函数结合形成SUM数组公式。说明一点，SUM函数的参数，可以是单元格区间，也可以是单个单元格。如下图：计算1、3、5月份的销售量。J2单元格：=SUM(E2,G2,I2)，然后，向下复制

中级篇

3、忽略文本跨列求和

如下图，计算全部销售人员的销售额。C10单元格：=SUM(A2:I7)

利用Excel中sum函数本身对文本类型数值自动忽略的规定，所以，可以用来直接对跨列的数值型数据求和。

4、单条件求和，运用求和函数：SUMIF。

如图，计算1月份冰箱的销售量。K2单元格：=SUMIF($D$2:$D$18,"冰箱",$E$2:$E$18)

SUMIF函数基本结构：SUMIF（条件区域，条件，求和区域）

5、多条件求和，运用求和函数：SUMIFS。

如图，计算销售一部1月份相机销售量。L2单元格：=SUMIFS($E$2:$E$18,$A$2:$A$18,"销售一部",D$2:D$18,"相机")

SUMIFS函数基本结构：SUMIF（求和区域，条件区域1，条件1，条件区域2，条件2...）

6、避开错误值求和。

如下图：计算1-5月份总销售量。C12单元格：=SUMIF(A2:E10,"<9.9E+307")

应用函数SUMIF设置条件完成，其中设置条件"<9.9E+307"，其含义是，9.9*10^307，即9.9乘10的307次方，9.9E+307是一个极大的数值，根据EXCEL的通过规则：数值<文本

7、通配符求和

如下图：计算1月份包含电脑的的总销量。G2单元格：=SUMIF(C2:C18,"*电脑",D2:D18)

应用函数SUMIF设置条件完成，通配符*代表任何字符或字符串，只要总字符不超过255个，设置条件"*电脑"，或“*电脑*”，在选定区域中查找包含“电脑”的所有商品，在计算区域求和。

8、快速累计求和

利用“$”对求和区域首个单元格进行绝对引用，马上就能对一列数值快速累计求和，如下图，C2单元格：=SUM($B$2:B2)，向下复制即可。

9、求和的快捷键："Alt + =",选中要求和的区域和拟计算结果的空白区域，一键即可在空白区域产生求和结果

高级篇

10、求和之王：SUMPRODUCT

SUMPRODUCT函数跟SUM函数的数组公式条件求和语法一样。

=SUMPRODUCT((条件区域=条件)*求和区域)

如上面案例，计算1月份冰箱的销售量。K2单元格：=SUMIF($D$2:$D$18,"冰箱",$E$2:$E$18)，也可以写成：=SUMPRODUCT((D2:D18="冰箱")*E2:E18)

如上面案例，计算销售一部1月份相机销售量。L2单元格：=SUMIFS($E$2:$E$18,$A$2:$A$18,"销售一部",D$2:D$18,"相机")，也可写成：=SUMPRODUCT((A2:A18="销售一部")*(D2:D18="相机")*E2:E18)

下面，举个复杂一点点的例子，昨天，世界杯开始，首场比赛，俄罗斯队5：0大胜沙特队，拟统计本次世界杯，各小组球队进、失球队总数。

以A组为例，第一场有真实比分，其余为模拟分。就可以用SUMPRODUCT计算，进球数：J2单元格：=SUMPRODUCT(($B$2:$B$7=$I3)*($C$2:$C$7))+SUMPRODUCT(($F$2:$F$7=$I3)*($E$2:$E$7))；失球数：K2单元格：=SUMPRODUCT(($B$2:$B$7=$I3)*($E$2:$E$7))+SUMPRODUCT(($F$2:$F$7=$I3)*($C$2:$C$7))

SUMPRODUCT与其他函数结合还可以解决你意想不到的求和需求，以后我们会专门进行分享。请关注后，期待好文。

每天学习一点点，每天进步一点点，积硅步，必能致千里，得大成。