求和，是Excel中最基本的技能，但同时也是最高级的技能，听起来好像有点儿矛盾，可能好多同学会说，求和不就是用Sum函数吗，或者快捷键Alt+=……其实你这么想就大错特错了，实际功能中的求和常常附加有条件，条件可能是一项，也可能是多项，当遇到条件求和时，你还在用Sum函数吗？今天我们要学习的是多条件求和函数Sumifs实用技巧，希望对大家的工作有所帮助。

一、功能及语法结构。

功能：对一组给定条件的指定单元格求和。

语法：=SUMIFS（求和范围，条件1范围，条件1，条件2范围，条件2……条件N范围，条件N）。

注意事项：

1、使用Sumifs函数时，至少要有一组条件范围和条件，暨条件1范围和条件1不可省略，条件2范围，条件2和条件N范围，条件N可以省略。

示例：

目的：求“男”、“女”销售员销量大于等于50的销量和。

方法：

在目标单元格中输入公式：=SUMIFS(D3:D9,C3:C9,H3,D3:D9,">=50")。

解读：

1、公式中第一个D3:D9为求和范围，C3:C9为条件1H3的范围，第二个D3:D9为条件而等于等于50的范围。

二、单条件求和。

Sumifs函数为多条件求和函数，但也可以进行单条件求和。也就是至少要有一组条件范围和条件出现。

目的：求男、女销售员的销量和。

方法：

在目标单元格中输入公式：=SUMIFS(D3:D9,C3:C9,H3)。

三、求“王东和小西”在相应地区的销售总额。

方法：

在目标单元格中输入公式：=SUM(SUMIFS(D3:D9,B3:B9,{"王东","小西"},E3:E9,I3))。

解读：

1、首先利用Sumifs求出“王东”和“小西”在相应地区的销量，然后用Sum求和。Sumifs函数在此的作用相当于查找引用。

四、求“王东和小西”在“北京和上海”的销量和。

方法：

在目标单元格中输入公式：=SUM(SUMIFS(D3:D9,B3:B9,{"王东","小西"},E3:E9,{"北京";"上海"}))。

解读：

1、需求“王东和小西”在“北京和上海”的销量和可以理解为“王东和小西”在“北京”的销量加上在“上海”的销量和。也就是“北京”和“上海”这两个条件“王东”和“小西”都要用到。

2、公式=SUM(SUMIFS(D3:D9,B3:B9,{"王东","小西"},E3:E9,{"北京";"上海"}))中第一个条件{"王东","小西"}中间的分隔符为逗号（,），而第二个条件{"北京";"上海"}中间的分隔符为分号（;）原因在于“北京”和“上海”这两个条件“王东和小西”都要用到。大家在学习的时候要注意理解哦！

五、求“王东、小西和小北”在“北京、上海和天津”的销量和。

方法：

在目标单元格中输入公式：=SUM(SUMIFS(D3:D9,B3:B9,{"王东","小西","小北"},E3:E9,{"北京";"上海";"天津"}))。

具体解读请参阅示例4。

结束语：

通过本文的学习，相信大家对多条件求和有了更新的认识，尤其是字段和条件非常繁多是时更能体现出次函数的优势，但需要注意的是如果某几个条件其它条件都要用到，则这几个条件之间必须用分号（;）隔开。

如果亲有更高级的技巧，欢迎在留言区留言讨论哦！

我们肯定知道按单条件、多条件，多表求和，唯独有一种求和我们很少听说过，那就是：按—颜—色—求—和。是的没看错，就是an颜色求和，

【例】如下图所示，要求按颜色进行求和。

Excel中还没提供按颜色求和的函数，但我们可以借用宏表函数（老版本遗留的一种函数，只能在定义名称中使用）获取单元格的颜色值，然后再用sumif函数求和来解决我们的问题。

一、定义名称，为提取颜色值做准备

公式 - 定义名称 ，在定义名称窗口中输入名称 mycolor（可以自定义），然后在下面引用来源中输入公式：=GET.CELL(63,Sheet2!B2)&T(NOW())

公式说明：

Get.cell(63,单元格) 可以获取单元格填充颜色值&T(NOW()) 实现表格在更新时定义名称取值也可以更新

二、获取颜色值

在C列和F列分别输入公式 =mycolor，即可获取B列和D列的单元格填充色。

三、剩下的交给sumif函数吧

单元格内输入 =SUMIF(C:C,E2,B:B)

按颜色求和对高手并不难，但对于新手可能还要用多了才能记住，所以建议大家先收藏起来备用吧。

点击上方「 韩老师讲office 」可快速关注

敬请阅读与分享，让更多学习者一起进步！

函数解释

SUMPRODUCT 函数是 Excel 中的数学函数，将给定的几个数组间对应元素相乘，并返回乘积之和。

其基本语法为：

SUMPRODUCT(array1,[array2], [array3], ...)

SUMPRODUCT 函数语法具有下列参数：

Array1 ：必需。其相应元素需要进行相乘并求和的第一个数组参数。

Array2, array3,... ：可选。 2 到 255 个数组参数，其相应元素需要进行相乘并求和。

特别注意：

数组参数必须具有 相同的维数 。 否则，函数 SUMPRODUCT 将返回 #VALUE! 错误值 #REF! 。

基本用法

SUMPRODUCT 函数最基本的用法是：

数组间对应的元素相乘，并返回乘积之和。

如下图：

公式：=SUMPRODUCT(B2:B9,C2:C9)

该公式的含义是：

B2*C2+B3*C3+B4*C4+B5*C5+B6*C6+B7*C7+B8*C8+B9*C9

单条件求和

如下图，计算女员工业绩得分和：

公式：

=SUMPRODUCT((B2:B11="女")*C2:C11)

其中：

B2:B11="女"：

将B2:B11内每个单元格值与“女”比较，凡是性别为“女”的是TRUE，否则是FALSE，结果返回一组逻辑值：

{FALSE;TRUE;FALSE;TRUE;FALSE;TRUE;FALSE;TRUE;FALSE;TRUE;}

(B2:B11="女")*C2:C11

将上述逻辑数组内的值与对应的C2:C11的数值相乘。

多条件求和

员工业绩得分高于15的得分和：

=SUMPRODUCT((B2:B11="女")*(C2:C11>15),C2:C11)

多条件求和的通用写法是：

=SUMPRODUCT((条件一)*(条件二)*……*(条件N),求和范围)

模糊条件求和

销售 部门 女

销售部门不止一个，要查找所有的销售部门，就要按照关键字“销售”查找，就属于模糊查找。

=SUMPRODUCT(ISNUMBER(FIND("销售",A2:A11))*(C2:C11="女"),D2:D11)

FIND("销售",A2:A11)

在A2:A11各单元格值中查找"销售"，如果能查到，返回"销售"在单元格值中位置，如果差不到，返回错误值#VALUE!。

本部分的结果是：

{#VALUE!;1;1;1;#VALUE!;1;#VALUE!;#VALUE!;1;#VALUE! }

ISNUMBER(FIND("销售",A2:A11)) ：

判断上述数值中各值是不是数字，如果是，返回TRUE，否则返回FALSE,所以，本部分公式的结果是：

{FALSE;TRUE;TRUE;TRUE;FALSE;TRUE;FALSE;FALSE;TRUE;FALSE}

SUMPRODUCT相关知识回顾

Excel | SUMPRODUCT函数注意事项：乘号与逗号有区别

Excel | RANK.EQ（RANK）总排名、SUMPRODUCT分类排名

Excel | SUMPRODUCT计算指定年份与月份的销售总额

Excel | 领导不喜欢看“间断”的排名，RANK换成SUMPRODUCT!

Excel | DGET、SUMIFS、SUMPRODUCT、LOOKUP、OFFSET、VLOOKUP多条件查询

施老师：

在Excel中普通的求和SUM函数大家都知道，而且，之前也有给大家详细介绍过。不过，在大多情况下，我们可能还需要进行多条件求和等。今天，施老师就来给各位分享一下在工作中常用的多条件求和函数公式。

SUMIF函数

SUMIF（条件判断区域,条件，求和区域）

注意：SUMIF函数只能带一个条件，其格式为判断区域，条件，求和区域。

解释：条件判断区域：就是所以求和的条件域；条件：求和条件；求和区域：所示求和的引用单元格区域。

如下图：我们想要计算出格力空调的单价总和。

那么我们可以这样做，在右边品牌格力求和的一栏中输入公式：=SUMIF(A2:A10,"格力",C2:C10)

其中A2:A10是品牌区域，“格力”代表计算的是“格力”空调的总和，C2：C10代表的单价区域，这样就轻松的计算出了格力空调的单价之和。

各位朋友们，你们也试一下吧，点我头像关注我，有不懂的在文章下方的评论区留言问我，我会跟大家一起探讨。本文欢迎转发，转发请注明出处。

求和，一直是Excel中最普通的话题，但是对于求和，大家真的了解吗，尤其是多条件求和？今天我们要掌握的是SUMIF函数和SUMPRODUCT函数多条件求和的技巧。

目的：统计出销售到【上海】地区的【联想】和【华硕】的数量。

方法一：

方法：

在目标单元格中输入公式：=SUM(SUMIFS(D3:D9,B3:B9,"上海",C3:C9,{"联想","华硕"}))。

备注：

SUMIFS(D3:D9,B3:B9,"上海",C3:C9,{"联想","华硕"})对“联想”和“华硕”分别进行统计，然后用SUM函数来求和。

方法二：

方法：

在目标单元格输入公式：=SUMPRODUCT((B3:B9="上海")*(C3:C9={"联想","华硕"})*D3:D9)。

方法三：

方法：

在目标单元中输入公式：=SUMPRODUCT((B3:B9="上海")*((C3:C9="联想")+(C3:C9="华硕")),D3:D9)。

应用场景：

1、有时候单纯的求和公式SUM不能满足我们所有的要求，单一的条件求和SUMIF无法满足多条件求和的需求，这样SUMIFS这个多条件求和函数就应运而生啦！只要学会这个函数，再多条件的求和都不是问题。

函数解析:SUMIFS的参数可分为两类，一类为求和范围参数，另一类为条件参数。

如上图所示，参数1为求和范围参数，参数2,3为条件参数1（需要成组出现，包含条件范围和条件），参数4,5为条件参数2（需要成组出现），如果有更多条件，需要把条件范围和条件成组列明。

案例说明:

案例1：根据下图的销售明细表分别计算出各销售部门1月20日之前的销售总额。

案例条件要求同时满足下面的两个条件：

①按部门划分求和

②销售时间早于1月20日

操作步骤：

1、列出所有需要求和的部门，如下图所示：

2、在I2单元格录入公式：=SUMIFS(F:F,C:C,$H2,A:A,"<2018-1-20")

求和范围：F列销售总额

条件范围1：C列销售部门

条件1：销售一科

条件范围2：A列销售时间

条件2：小于2017-1-20，如果条件不是单元格引用，需要给条件加双引号。

3、下拉填充公式计算其他部门1月20日之前的销售总额。

4、验证：D2和F2单元格我们用SUBTOTAL函数对筛选条件下的数据求和，通过筛选统计销售一科2018年1月20日之前的销售总额数据，检验出我们的函数计算正确。

动态演示：

案例2：根据下图产品销售情况表分别计算出各销售部门销售各种产品（打印机、笔记本、台式机）的总数。

求和范围：E列销售台数

条件范围1：C列销售部门

条件1：销售一科

条件范围2：D列销售产品

条件2：包含H1到J1的产品

思考：案例中同一种销售产品有很多种型号，怎样将同一种产品的不同型号进行求和呢？

其实可以用通配符“*”，它可以代表任意多个字条。

操作步骤：

1、先将需要求和的部门和产品列出，如下图所示：

2、在H2 单元格录入公式：=SUMIFS($E:$E,$C:$C,$G2,$D:$D,H$1&"*")

由于要向右向下拖拉公式，所以求和区域，条件区域都要用绝对引用，而部门条件因为都在G列，所在条件1要锁定G列，而产品条件都在第1行，所以条件2要锁定第1行。

3、向右向下填充公式即可。

动态演示：

温馨提示：

① *为通配符，可以代表任意多个字符。

② 因为要向右向下填充，一定要注意相对引用和绝对引用的问题。

我是EXCEL学习微课堂，分享EXCEL学习的小技巧，小经验。如果分享的内容对您有用，欢迎点赞、收藏、评论、转发，更多的EXCEL技能，可以关注“EXCEL学习微课堂”。

在日常工作当中，对数据求和时，函数sum经常会用到，但是对求和结果赋予几个条件之后你还会用函数公式解决吗？今天就给大家介绍一下多条件求和函数sumifs的应用技巧，首先我们先通过一张图片来认识一下这个函数；

上图中sum-range是指实际求和区域；criteria-range1是指条件区域1；criteria是指条件。

在具体介绍sumifs的具体应用技巧之前，我们先引入一组数据源，如下图所示：

针对上图的数据源，给出的求和条件是计算每日单据类型为收款单的金额合计数；公式展开如下图；

公式讲解：实际求和区域为金额，所以是D列；条件1为日期，故条件区域为B列，条件二为单据类型，故条件区域2为C列。给单元格赋予公式之后计算结果也就完成了，输出结果见下图：

以上就是多条件求和函数sumifs的操作技巧，这里只是用了一个简单的案列来讲解了一下，实际工作中可能赋予的求和条件会更多，但操作逻辑是一样的，对这个函数感兴趣的朋友们可以试着操作一下。多学一个函数的使用技巧对将来的职场生活还是有很大助益的。今天的讲解到此结束，喜欢的朋友欢迎关注、分享 谢谢！

语录分享：生活包含着更广阔的意义，而不在于我们实际得到了什么；关键是我们的心灵是否充实。

End

SumProduct函数是 Excel 中用于数组求和的函数，它有三种表达式，一种为参数全是数组，另两种为前几个参数为条件，最后一个参数为求和区域。SumProduct函数的计算方法为将一个数组的元素与另一个数组的对应元素相乘，然后把所有乘积相加。在应用过程中，即可写一个条件求和，也可以用And/Or组合多条件求和。以下就是Excel SumProduct函数三个表达式与用And/Or组合多条件求和的具体操作方法，实例中操作所用版本均为 Excel 2016。

一、Excel SumProduct函数语法

1、表达式1：SUMPRODUCT(array1, [array2], [array3], ...)

说明：SumProduct 参数全是数组，最少要有一个数组，最多可有 255 数组；计算方法为：每个数组的对应元素相乘，然后求和；非数值当作0处理；每个数组必须有相同的维数。

2、表达式2：SUMPRODUCT(--(条件1)，[--(条件2)，...],(求和区域))

说明：表达式中用 [] 括起来的为可选参数，条件前面的 -- 是把逻辑值转为数值以便于计算。

3、表达式3：SUMPRODUCT((条件1)*[（条件2)，...]*(求和区域))

说明：表达式3是表达式2的另一种写法。

二、Excel SumProduct函数使用举例

（一）表达式1举例

1、假如要求一个服装销量表的所有服装的营业额。选中 G2 ，把公式 =SUMPRODUCT(E2:E9,F2:F9) 复制到 G2，按回车，则求出所有服装的营业额；操作过程步骤，如图1所示：

2、公式说明：计算时，用 E2:E9 中的每个元素乘 F2:F9 中对应的元素并把它们相加，即 89 * 892 + 89 * 874 + 80 * 569 + 99 * 982 + 198 * 897 + 65 * 528 + 185 * 563 + 299 * 159 = 663534。

（二）表达式2举例

1、假如要求“分类”为“衬衫”、销售“地区”为“广州”的“销量”。选中 G2 单元格，把公式 =SUMPRODUCT(--($C$2:$C$12="衬衫"),--($D$2:$D$12="广州"),($F2:$F12)) 复制到 G2，按回车，则求得结果 819；操作过程步骤，如图2所示：

2、公式说明：

公式 =SUMPRODUCT(--($C$2:$C$12="衬衫"),--($D$2:$D$12="广州"),($F2:$F12)) 中 $C$2:$C$12 是对 C2:C12 的绝对引用，以便返回数组；($C$2:$C$12="衬衫") 判断数组中每个是否等于“衬衫”，等于返回真，否则返回假；-- 将真假逻辑值转为数值。条件2与条件1是一个意思；$F2:$F12 为求和区域，$F2 表示对 F 列绝对引用，对行相对引用，即拖动时，列不变、行变。

（三）表达式3举例

1、把表达式2举例中的公式改为表达式3。选中 G3 单元格，把公式 =SUMPRODUCT(($C$2:$C$12="衬衫")*($D$2:$D$12="广州")*($F2:$F12)) 复制到 G3，如图3所示：

2、按回车，同样求得结果 819，如图4所示：

三、Excel SumProduct函数多条件求和

（一）用 And（*）组合多条件求和

1、有一个服装销售表和一个库存表，假如要在库存表中查看销量。选中 E2 单元格，把公式 =SUMPRODUCT((销售!$A$2:$A$12=库存!$A2)*(销售!$C$2:$C$12=库存!$C2)*(销售!$F$2:$F$12)) 复制到 E2，按回车，则求出“编号”为 WS-560 的销量；把鼠标移到 E2 单元格右下角的单元格填充柄上，按住左键，往下拖，则统计出其它服装的销量；操作过程步骤，如图5所示：

2、公式说明：

=SUMPRODUCT((销售!$A$2:$A$12=库存!$A2)*(销售!$C$2:$C$12=库存!$C2)*(销售!$F$2:$F$12))

A、选中 E2 单元格，按住 Alt，按一次 M，按一次 V，打开“公式求值”窗口，每单击一次“求值”计算一步，一直单击直到计算出最终结果，操作过程步骤，如图6所示：

B、公式中条件1 (销售!$A$2:$A$12=库存!$A2) 是把“销售表”与“库存表”用“编号”连接起来，条件2 (销售!$C$2:$C$12=库存!$C2) 是要求“销售表”中的“分类”等于“库存表”中对应的分类，(销售!$F$2:$F$12)) 是求区域。

C、条件1(销售!$A$2:$A$12=库存!$A2) 表示如果“销售表”中的“编号”等于“库存表”中对应“编号”，则返回真，否则返回假，最终返回一个以真（True）假（False)为元素的数组，如图7所示：

D、条件2 (销售!$C$2:$C$12=库存!$C2) 最终也返回一个由真假元素组成的数组，然后把条件1的元素与条件2对应的元素相乘，两个为 True 的元素相乘返回 True、为 False 的返回 False，并把 True 转为 1、False 转为 0。

E、(销售!$F$2:$F$12)) 返回一个由“销售表”F 列数值组成的数组，如图8所示：

此时，仅还有两个数组，把它们对应的数值相乘，然后把相乘结果相加，从而计算出最终结果。

（二）同时用 And（*）与 Or（+）组合多条件求和

1、假如要统计广州和深圳的服装销量之和。把公式 =SUMPRODUCT((F2:F12)*((D2:D12="广州")+(D2:D12="深圳"))) 复制到 G2 单元格，按回车，则统计符合条件的服装销量之和，操作过程步骤，如图9所示：

2、公式说明：

公式中 (F2:F12) 是求和区域，(D2:D12="广州")+(D2:D12="深圳") 是用加号（+）组成的两个表示“或”关系的条件，即统计 F2:F12 中要么在广州要么在深圳销售的服装销量之和。

3、再加一个条件，假如要统计在广州和深圳销售的且分类为雪纺的服装销量之和，公式可以这样写：=SUMPRODUCT((F2:F12)*((D2:D12="广州")+(D2:D12="深圳"))*(C2:C12="雪纺"))。

Excel求和函数，除了Sum、Sumif和Sumifs以外，你还用过其它的函数吗？今天分享一个简单实用又高效的数据库函数DSUM，它集「查找」和「求和」功能为一身，能多条件求和，还能跨表多条件求和，让你一看到就会爱上它！

一、函数解析

DSUM函数：将数据库中符合条件记录的字段列中的数字求和。使用它可以对数据进行多条件累加，这种方式可以很方便地修改求和的条件。

DSUM有3个参数：Dsum(数据区域，求和的列数,条件区域)

① 数据区域：一组数据列表，即需要对该组数据列表中的某些数据进行计算。

② 列数：需要求和数据所在列数（也可以是列标题）比如：如果该参数为“3”，则表示需要计算的数据在参数①第3列中，如果该参数为“销量”，则表示需要计算的数据是参数①中的“销量”那一列。

③ 条件区域：由标题行和条件构成的多行区域（条件为公式时，若使用函数标题应为空）。

二、多条件求和案例

如下图所示，计算侯采和马来军的总销量。

在F2单元格中，输入公式：=DSUM(A1:E13,E1,G1:G3)

其中A1:E13是数据区域，E1是统计列“销售量“，G1:G3是条件区域，即计算侯采和马来军2人的销售量。

三、模糊统计案例

统计销售一科以打印机开头的所有产品销量和销售二科的台式机销售之和。

在I2单元格输入公式=DSUM(A1:E13,E1,G1:H3)

DSUM()函数中的判定条件，支持使用通配符 “*” 和 “？”，如下图所示，H2在单元格中使用了通配符“*“表示包含以打印机开头的A、B型号，但不包括D13的激光打印机，如果要包括则前面要加通配符。案例中，同一行的，销售二科和台式机必须同时满足，即并条件，而不同行的销售一科的打印机和销售二科的台式机是或条件，写在不同的行。

四、符合时间条件的求和案例

统计销售日期在2018-1-7至2018-1-14之间的销售量。

I2单元格输入公式：=DSUM(A1:E13,E1,G1:H2)，销售日期是一个区间，可以在一行用两个销售日期的条件。一个是大于2018-1-6，另一个是小于2018-1-15。

五、条件为公式时，函数标题应为空

统计销售一科销量小于平均销量人员的销量总和，销量小于平均销量必须用到公式=E2

H2单元格输入公式=E2

I2单元格输入公式=DSUM(A1:E13,E1,G1:H2)

六、多数据批量汇总案例

分别计算销售一科、销售二科和销售三科的销量。

H2单元格输入公式=DSUM($A$1:$E$13,$E$1,$G$1:G2)-SUM($H$1:H1)

1、由于公式要往下填充，所以数据区域和列都用了绝对引用

2、条件区域是一个从G1开始的活动区域，所以G1是绝对引用，但G2是相对引用

3、因为不同的行是“或条件”所以在统计销售二科销售总量时，结果会包含销售一科的销售总量，需要减去销售一科的销量，同样的道理，统计销售三科销量时要减去销售一科和销售二科的销售和。

七、跨工作表统计案例

如下图所示，有表1、表2和表3三个工作表，要统计三个表中，张1、张2、张3的销量和。

C2单元格输入公式=

SUM(DSUM(INDIRECT({"表1";"表2";"表3"}&"!A1:D11"),4,A$1:B2))-SUM(C$1:C1)

1、数据区域，跨表引用了3个工作表，所以用工作表引用函数INDIRECT。

2、列数，第4列“销量”。

3、条件区域是从A1开始的活动区域，所以A1是绝对引用，但B2是相对引用。

4、由于是的跨表引用，因此dsum返回的是数组，不是单值，因此要外套sum。

5、因为不同的行是“或条件”所以在统计张2第一周的销量时，结果会包含张1第一周的销量，需要减去张1第一周销量，同样的道理，统计张3第一周的销售时要减去张1和张2第一周的销售和。

温馨提示：

1、条件区域列标题内容要与数据区域一致，比如数据区域列标题是“销售产品”，那你要统计某一产品时，条件列标题也要是“销售产品”如果你改为产品，统计会出错

2、切记“并条件”需要横着写，即写在同一行，“或条件”需要竖着写，即写在不同行。

3、条件为公式时，若使用函数标题应为空。

我是EXCEL学习微课堂，如果我的分享对您有帮助，欢迎点赞、收藏、评论、转发！更多的EXCEL技能，可以关注百家号“EXCEL学习微课堂”。

SumIfs函数是 Excel 中多个求和函数之一，它主要用于统计指定区域满足单个或多个条件的和。SumIfs函数可以有多个参数，除第一个参数“求和区域”外，其它的参数都成组出现，每组由“条件区域和条件”组成，可以有 N 组这样的参数。SumIfs函数的多条件用数组表示，数组中的每个元素就是一个条件；当用数组组合多个条件时，SumIfs函数通常要与Sum函数结合才能统计出满足多个条件的和。以下就是Sumifs函数多字段多条件求和使用实例，实例中操作所用版本均为 Excel 2016。

一、Excel Sumifs 语法

1、表达式：SUMIFS(sum_range, criteria_range1, criteria1, [criteria_range2, criteria2], ...)

中文表达式：SUMIFS(求和区域，条件区域1，条件1，[条件区域2，条件2]，...)

2、说明：

A、表达式中，前三个参数是必需的，括号（[]）中的参数是可选的，省略号（...）表示继续构建[条件区域3，条件3]、[条件区域4，条件4]、...、[条件区域n，条件n]。

B、可以在条件中使用通配符“问号 (?) 和星号 (*)”，问号匹配任意单个字符，星号匹配任意一个或一串字符；果要找“? 和 *”，需要在它们前面加转义字符 ~，例如要查找 ?，需要这样写 ~?。

C、如果在条件中使用文本条件、含有逻辑或数学符号的条件都必须用双引号 (") 括起来；例如使用大于号，应该这样写：">50" 或 ">"&50。

D、SumIfs 只对数值求和，文本则忽略，如果选中的求和区域全为文本，则返回 0；如果既有文本又有数值，则只取数值求和。

二、Excel Sumifs函数的使用方法举例

（一）单条件

1、假如要统计在广州销售的所有服装的销量之和。选中 H2 单元格，把公式 =SUMIFS(F2:F10,D2:D10,"广州") 复制到 H2，按回车，则返回在广州销售的所有服装销量之和，如图1所示：

2、公式说明

公式 =SUMIFS(F2:F10,D2:D10,"广州") 中，F2:F10 是求和区域，D2:D10 是条件区域，“广州”是条件。

（二）多条件

1、双条件

A、假如要统计在广州销售的且为“衬衫”的所有服装销量之和。把公式 =SUMIFS(F2:F10,D2:D10,"广州",C2:C10,"衬衫") 复制到 H2 单元格，按回车，则统计出所有满足条件销量之和，操作过程步骤，如图2所示：

B、公式说明

公式 =SUMIFS(F2:F10,D2:D10,"广州",C2:C10,"衬衫") 的求和区域为 F2:F10；条件区域1为 D2:D10，条件1为“广州”；条件区域2为 C2：C10，条件2为“衬衫”。

2、数组条件且与Sum函数结合

A、假如要统计在广州和深圳销售的衬衫销量之和。选中 H2 单元格，把公式 =SUM(SUMIFS(F2:F10,D2:D10,{"广州","深圳"},C2:C10,"衬衫")) 复制到 H2，按回车，则统计出满足的衬衫销量之和，操作过程步骤，如图3所示：

B、公式说明

公式 =SUM(SUMIFS(F2:F10,D2:D10,{"广州","深圳"},C2:C10,"衬衫")) 由 Sum 和 SumIfs 两个函数组成，其中 SumIfs 函数用来分别统计在“广州”和“深圳”销售的“衬衫”销量之和，Sum函数用来把 SumIfs 求出的在“广州”和“深圳”销售的“衬衫”销量之和加起来。SumIfs 的条件1“{"广州","深圳"}”为数组，数组中只有两个条件，如果还要加条件，可以在后面添加。

提示：如果不用 Sum 函数，仅统计“广州”的“衬衫”销量。

3、多数组条件

A、假如要统计在广州和杭州销售的价格为 86、80 或 65 元的服装销量之和。把公式 =SUM(SUMIFS(F2:F10,D2:D10,{"广州","杭州"},E2:E10,{86;80;65})) 复制到 H2 单元格，如图4所示：

B、按回车，则统计出满足条件的服装销量之和，如图5所示：

注意：条件2 {86;80;65} 中数字之间用半角分号（;），如果用半角逗号（,），只会返回第一条满足条件的销量；结果返回 329，它正是第一条记录“长袖白衬衫”的销量，如图6所示：

（三）用通配符组合条件

1、假如要统计产品名称为四个字、销售地区含有“州”字、价格大于60元的全部服装销量之和。把公式 =SUM(SUMIFS(F2:F10,B2:B10,"????",D2:D10,"*州*",E2:E10,">60")) 复制到 H2 单元格，按回车，则统计所有满足条件的服装销量之和，如图7所示：

2、公式说明

公式 =SUM(SUMIFS(F2:F10,B2:B10,"????",D2:D10,"*州*",E2:E10,">60")) 中的 SumIfs 由三组“条件区域和条件”组成；第一组（B2:B10,"????"）是从 B2:B10 中找出名称为四个字的服装；第二组（D2:D10,"*州*"）是从 D2:D10 中找出含有“州”字的服装；第三组（E2:E10,">60"）是从 E2：E10 中找出“价格”大于 60 元的服装。最后把三组统计出的服装销量用 Sum 求和。