Excel求和函数，除了Sum、Sumif和Sumifs以外，你还用过其它的函数吗？今天分享一个简单实用又高效的数据库函数DSUM，它集「查找」和「求和」功能为一身，能多条件求和，还能跨表多条件求和，让你一看到就会爱上它！

一、函数解析

DSUM函数：将数据库中符合条件记录的字段列中的数字求和。使用它可以对数据进行多条件累加，这种方式可以很方便地修改求和的条件。

DSUM有3个参数：Dsum(数据区域，求和的列数,条件区域)

① 数据区域：一组数据列表，即需要对该组数据列表中的某些数据进行计算。

② 列数：需要求和数据所在列数（也可以是列标题）比如：如果该参数为“3”，则表示需要计算的数据在参数①第3列中，如果该参数为“销量”，则表示需要计算的数据是参数①中的“销量”那一列。

③ 条件区域：由标题行和条件构成的多行区域（条件为公式时，若使用函数标题应为空）。

二、多条件求和案例

如下图所示，计算侯采和马来军的总销量。

在F2单元格中，输入公式：=DSUM(A1:E13,E1,G1:G3)

其中A1:E13是数据区域，E1是统计列“销售量“，G1:G3是条件区域，即计算侯采和马来军2人的销售量。

三、模糊统计案例

统计销售一科以打印机开头的所有产品销量和销售二科的台式机销售之和。

在I2单元格输入公式=DSUM(A1:E13,E1,G1:H3)

DSUM()函数中的判定条件，支持使用通配符 “*” 和 “？”，如下图所示，H2在单元格中使用了通配符“*“表示包含以打印机开头的A、B型号，但不包括D13的激光打印机，如果要包括则前面要加通配符。案例中，同一行的，销售二科和台式机必须同时满足，即并条件，而不同行的销售一科的打印机和销售二科的台式机是或条件，写在不同的行。

四、符合时间条件的求和案例

统计销售日期在2018-1-7至2018-1-14之间的销售量。

I2单元格输入公式：=DSUM(A1:E13,E1,G1:H2)，销售日期是一个区间，可以在一行用两个销售日期的条件。一个是大于2018-1-6，另一个是小于2018-1-15。

五、条件为公式时，函数标题应为空

统计销售一科销量小于平均销量人员的销量总和，销量小于平均销量必须用到公式=E2

H2单元格输入公式=E2

I2单元格输入公式=DSUM(A1:E13,E1,G1:H2)

六、多数据批量汇总案例

分别计算销售一科、销售二科和销售三科的销量。

H2单元格输入公式=DSUM($A$1:$E$13,$E$1,$G$1:G2)-SUM($H$1:H1)

1、由于公式要往下填充，所以数据区域和列都用了绝对引用

2、条件区域是一个从G1开始的活动区域，所以G1是绝对引用，但G2是相对引用

3、因为不同的行是“或条件”所以在统计销售二科销售总量时，结果会包含销售一科的销售总量，需要减去销售一科的销量，同样的道理，统计销售三科销量时要减去销售一科和销售二科的销售和。

七、跨工作表统计案例

如下图所示，有表1、表2和表3三个工作表，要统计三个表中，张1、张2、张3的销量和。

C2单元格输入公式=

SUM(DSUM(INDIRECT({"表1";"表2";"表3"}&"!A1:D11"),4,A$1:B2))-SUM(C$1:C1)

1、数据区域，跨表引用了3个工作表，所以用工作表引用函数INDIRECT。

2、列数，第4列“销量”。

3、条件区域是从A1开始的活动区域，所以A1是绝对引用，但B2是相对引用。

4、由于是的跨表引用，因此dsum返回的是数组，不是单值，因此要外套sum。

5、因为不同的行是“或条件”所以在统计张2第一周的销量时，结果会包含张1第一周的销量，需要减去张1第一周销量，同样的道理，统计张3第一周的销售时要减去张1和张2第一周的销售和。

温馨提示：

1、条件区域列标题内容要与数据区域一致，比如数据区域列标题是“销售产品”，那你要统计某一产品时，条件列标题也要是“销售产品”如果你改为产品，统计会出错

2、切记“并条件”需要横着写，即写在同一行，“或条件”需要竖着写，即写在不同行。

3、条件为公式时，若使用函数标题应为空。

我是EXCEL学习微课堂，如果我的分享对您有帮助，欢迎点赞、收藏、评论、转发！更多的EXCEL技能，可以关注百家号“EXCEL学习微课堂”。

如果想求出每一种类的数据和，不一定要通过筛选命令，当然用筛选也没有问题

至少有三个命令，可以实现每种类数据的求和

1.sumif

根据案例中，我们想求出黑龙江省的销售总额，我们该怎么做？

SUMIF 在 EXCEL 中被用来按条件进行求和。

语法

SUMIF(range,criteria,sum_range)

range:条件区域，笼统的来讲就是需要判断条件的区域

criteria:条件，这里可以用等于、大于、小于，可以比对各种数值类型

sum_range:求和的区域

我们看到黑龙江的销售额，就被轻松的求出来了

2.SUBTOTAL

首先需要在数据命令下，对数据进行筛选，筛选完成后，使用SUBTOTAL

SUBTOTAL函数语法：SUBTOTAL(function_num, ref1, ref2, ...)

第一参数：Function_num为 1 到 11（包含隐藏值）或 101 到 111（忽略隐藏值）之间的数字，指定使用何种函数在列表中进行分类汇总计算。

第二参数：Ref1、ref2为要进行分类汇总计算的 1 到 254 个区域或引用。

SUBTOTAL函数在筛选命令，对数据处理的功能是很强大的

3.数据透视表

在对数据处理时，数据透视表也是一个十分有效的命令，可以动手试一试

如果看了这篇文章还是搞不定，可以直接给我留言

在评论区留言，告诉小编，你想学习哪些Excel技巧？

在日常工作当中，对数据求和时，函数sum经常会用到，但是对求和结果赋予几个条件之后你还会用函数公式解决吗？今天就给大家介绍一下多条件求和函数sumifs的应用技巧，首先我们先通过一张图片来认识一下这个函数；

上图中sum-range是指实际求和区域；criteria-range1是指条件区域1；criteria是指条件。

在具体介绍sumifs的具体应用技巧之前，我们先引入一组数据源，如下图所示：

针对上图的数据源，给出的求和条件是计算每日单据类型为收款单的金额合计数；公式展开如下图；

公式讲解：实际求和区域为金额，所以是D列；条件1为日期，故条件区域为B列，条件二为单据类型，故条件区域2为C列。给单元格赋予公式之后计算结果也就完成了，输出结果见下图：

以上就是多条件求和函数sumifs的操作技巧，这里只是用了一个简单的案列来讲解了一下，实际工作中可能赋予的求和条件会更多，但操作逻辑是一样的，对这个函数感兴趣的朋友们可以试着操作一下。多学一个函数的使用技巧对将来的职场生活还是有很大助益的。今天的讲解到此结束，喜欢的朋友欢迎关注、分享 谢谢！

语录分享：生活包含着更广阔的意义，而不在于我们实际得到了什么；关键是我们的心灵是否充实。

End

我们肯定知道按单条件、多条件，多表求和，唯独有一种求和我们很少听说过，那就是：按—颜—色—求—和。是的没看错，就是an颜色求和，

【例】如下图所示，要求按颜色进行求和。

Excel中还没提供按颜色求和的函数，但我们可以借用宏表函数（老版本遗留的一种函数，只能在定义名称中使用）获取单元格的颜色值，然后再用sumif函数求和来解决我们的问题。

一、定义名称，为提取颜色值做准备

公式 - 定义名称 ，在定义名称窗口中输入名称 mycolor（可以自定义），然后在下面引用来源中输入公式：=GET.CELL(63,Sheet2!B2)&T(NOW())

公式说明：

Get.cell(63,单元格) 可以获取单元格填充颜色值&T(NOW()) 实现表格在更新时定义名称取值也可以更新

二、获取颜色值

在C列和F列分别输入公式 =mycolor，即可获取B列和D列的单元格填充色。

三、剩下的交给sumif函数吧

单元格内输入 =SUMIF(C:C,E2,B:B)

按颜色求和对高手并不难，但对于新手可能还要用多了才能记住，所以建议大家先收藏起来备用吧。

今天和新手们分享有关条件求和的内容，高手请忽略。

先来看一组销售数据，是某商场不同品牌电视机的三天销售记录：

现在需要根据G列的品牌，计算其三天的销售总和。

想必有表亲已经想到办法了，既然是按条件求和，就用SUMIF呗：

=SUMIF(B:B,G2,C:C)+SUMIF(B:B,G2,D:D)+SUMIF(B:B,G2,E:E)

公式分别对C、D、E列条件求和，最后相加。

这样看是没有问题的，可是如果需要对30列数据条件求和，那岂不是太费劲了哦。

嗯，还有一种简便一点的公式：

这里用到了数组公式：

=SUM(IF(B$2:B$72=G2,C$2:E$72))

首先用IF函数进行处理，如果B2:B72中等于G2单元格指定的品牌，就返回C2:E72单元格区域中对应行的数值，否则返回逻辑值FLASE，最后使用SUM函数求和。

这里因为执行了数组运算，所以公式编辑完成后，要单击编辑栏，再按住Shift+Ctrl不放，按回车。注意公式两侧的花括号是自动生成的，手工敲入是无效的哦。

这个公式比较简短，但是需要按三键才能输入，有些新人朋友可能一时还找不到感觉，耐心点，多试几次吧。

还有一个不需要按三键输入的公式：

=SUMPRODUCT((B$2:B$72=G2)*C$2:E$72)

首先使用B$2:B$72=G2判断B列是否等于指定的品牌，得到逻辑值TRUE或是FLASE，再用逻辑值与C2:E72的数值相乘，最后使用SUMPRODUCT计算出乘积之和。

本例中，除了使用以上公式之外，如果使用数据透视表汇总，将会更加便捷方便，你会使用吗？

作者：Hoa小熊猫 图文整理：祝洪忠

ExcelHome，微软技术社区联盟成员

我们在使用Excel表格中，求和就是我们常用的函数之一，那么，各位知道求和都有哪些用途么，今天就和小编一起学习求和的多种用法吧。

一、快速求和快捷键

选定目标求和区域或行或列，使用自动求和的快捷键【ALT+=】，末尾的单元格下一个单元格将快速的显示出求和的结果，也可以批量快速求和哟。

二、隔列求和

求和的函数为SUM（），意为计算单元格区域中的所有数值的和。如果希望能够实现隔列求和，仅需要在输入函数后，以英文格式下的逗号作为分隔符即可，Sum(number1,number2,…)，共计最多可添加255个待求和数值。

三、SUMIF条件求和

SUM是求和，IF是如果，而Sumif就是按条件求和，对满足条件的单元格求和，Sumif（range,criteria,[sum_range]），range必须项，表示条件范围；criteria必须项，表示条件；sum_range可选项，表示求和范围。Sumifs函数，在英文中尾数s是复数的表示，在函数中同样也是，对一组给定条件指定的单元格求和，Sumifs(sum_range,criteria_range1,criteria1,[riteria_range2,criteria2]...)，sum_range是要求和的范围，criteria_range1是条件的范围，criteria1是条件，criteria_range2是条件的范围，criteria2是条件。

四、忽略隐藏行单元格求和

有的时候我们在运算过程中，比如说表格中有全年的数据，但是我只想其中几个月份的求和，未参加运算的月份则被隐藏。为了让隐藏数据不参与计算，微软则给出了我们另外一个公式：Subtotal函数。它的计算处理语法为Subtotal(function_num,ref1,ref2, ...)，其中Function_num 为 1 到 11（包含隐藏值）或 101 到 111（忽略隐藏值）之间的数字，指定使用何种函数在列表中进行分类汇总计算，求和的数字为9和109。

欢迎关注，以上。

问题情景

很多电商、工资等数据统计的时候都会遇到这样的问题：数据以不同的部门，或者不同的月份，也或不同的年份等情况分布在不同的工作表里，经常要求对分表根据相同数据项对数据进行汇总统计。

示例数据如下图：

共12月的数据，无需合并，直接汇总到“汇总”工作表“年销售业绩”列中。

注意：各分表的结构一致，姓名都在B列，求和的数据都在C列。

关键操作第一种情况：所有表“姓名”排序一致

这种求和方法很简单，只要在“汇总”表C2单元格输入公式“=SUM('*'!C2)”就可以了，回车以后，公式自动变成：=SUM('1月:12月'!C2)。

第二种情况：所有表“姓名”排序不一致

这种情况下求和稍有麻烦，我们一步一步分析：

第一步：

如果是仅对一个表，只需要Sumif函数直接求和即可，比如：

=SUMIF('1月'!$B$2:$B$37,汇总!B2,'1月'!$C$2:$C$37)；

第二步：

现在是对12个表汇总，需借助INDIRECT函数生成对多个表区域的引用，即是：

INDIRECT(ROW($1:$12)&"月!$B$2:$B$37")--引用每个表的B列姓名数据区域

以及

INDIRECT(ROW($1:$12)&"月!$C$2:$C$37")--引用每个表的C列销量数据区域。

第三步：

写入Sumif函数，即是：

SUMIF(INDIRECT(ROW($1:$12)&"月!$B$2:$B$37"),汇总!B2,INDIRECT(ROW($1:$12)&"月!$c$2:$c$37"))

第四步：

INDIRECT函数引用的是一组数，数组求和，最后最外层加Sumproduct函数，即是：

=SUMPRODUCT(SUMIF(INDIRECT(ROW($1:$12)&"月!$B$2:$B$37"),汇总!B2,INDIRECT(ROW($1:$12)&"月!$c$2:$c$37")))。

结果如下：

另：

本例使用INDIRECT函数产生多维引用，其中：

使用ROW($1:$12)产生月份序号数组：

{1;2;3;4;5;6;7;8;9;10;11;12}

公式中的INDIRECT(ROW($1:$12)&"月!$B$2:$B$37")作为SUMIF函数的range参数，表示每个月销售记录表的$B$2:$B$37区域，共12个区域：

{"1月!$B$2:$B$37";"2月!$B$2:$B$37";"3月!$B$2:$B$37";"4月!$B$2:$B$37";"5月!$B$2:$B$37";"6月!$B$2:$B$37";"7月!$B$2:$B$37";"8月!$B$2:$B$37";"9月!$B$2:$B$37";"10月!$B$2:$B$37";"11月!$B$2:$B$37";"12月!$B$2:$B$37"}

同理，公式中的INDIRECT(ROW($1:$12)&"月!$c$2:$c$37")表示每个月销售记录表的$c$2:$c$37区域，作为SUMIF函数的sum_range参数。

SumIfs函数是 Excel 中多个求和函数之一，它主要用于统计指定区域满足单个或多个条件的和。SumIfs函数可以有多个参数，除第一个参数“求和区域”外，其它的参数都成组出现，每组由“条件区域和条件”组成，可以有 N 组这样的参数。SumIfs函数的多条件用数组表示，数组中的每个元素就是一个条件；当用数组组合多个条件时，SumIfs函数通常要与Sum函数结合才能统计出满足多个条件的和。以下就是Sumifs函数多字段多条件求和使用实例，实例中操作所用版本均为 Excel 2016。

一、Excel Sumifs 语法

1、表达式：SUMIFS(sum_range, criteria_range1, criteria1, [criteria_range2, criteria2], ...)

中文表达式：SUMIFS(求和区域，条件区域1，条件1，[条件区域2，条件2]，...)

2、说明：

A、表达式中，前三个参数是必需的，括号（[]）中的参数是可选的，省略号（...）表示继续构建[条件区域3，条件3]、[条件区域4，条件4]、...、[条件区域n，条件n]。

B、可以在条件中使用通配符“问号 (?) 和星号 (*)”，问号匹配任意单个字符，星号匹配任意一个或一串字符；果要找“? 和 *”，需要在它们前面加转义字符 ~，例如要查找 ?，需要这样写 ~?。

C、如果在条件中使用文本条件、含有逻辑或数学符号的条件都必须用双引号 (") 括起来；例如使用大于号，应该这样写：">50" 或 ">"&50。

D、SumIfs 只对数值求和，文本则忽略，如果选中的求和区域全为文本，则返回 0；如果既有文本又有数值，则只取数值求和。

二、Excel Sumifs函数的使用方法举例

（一）单条件

1、假如要统计在广州销售的所有服装的销量之和。选中 H2 单元格，把公式 =SUMIFS(F2:F10,D2:D10,"广州") 复制到 H2，按回车，则返回在广州销售的所有服装销量之和，如图1所示：

2、公式说明

公式 =SUMIFS(F2:F10,D2:D10,"广州") 中，F2:F10 是求和区域，D2:D10 是条件区域，“广州”是条件。

（二）多条件

1、双条件

A、假如要统计在广州销售的且为“衬衫”的所有服装销量之和。把公式 =SUMIFS(F2:F10,D2:D10,"广州",C2:C10,"衬衫") 复制到 H2 单元格，按回车，则统计出所有满足条件销量之和，操作过程步骤，如图2所示：

B、公式说明

公式 =SUMIFS(F2:F10,D2:D10,"广州",C2:C10,"衬衫") 的求和区域为 F2:F10；条件区域1为 D2:D10，条件1为“广州”；条件区域2为 C2：C10，条件2为“衬衫”。

2、数组条件且与Sum函数结合

A、假如要统计在广州和深圳销售的衬衫销量之和。选中 H2 单元格，把公式 =SUM(SUMIFS(F2:F10,D2:D10,{"广州","深圳"},C2:C10,"衬衫")) 复制到 H2，按回车，则统计出满足的衬衫销量之和，操作过程步骤，如图3所示：

B、公式说明

公式 =SUM(SUMIFS(F2:F10,D2:D10,{"广州","深圳"},C2:C10,"衬衫")) 由 Sum 和 SumIfs 两个函数组成，其中 SumIfs 函数用来分别统计在“广州”和“深圳”销售的“衬衫”销量之和，Sum函数用来把 SumIfs 求出的在“广州”和“深圳”销售的“衬衫”销量之和加起来。SumIfs 的条件1“{"广州","深圳"}”为数组，数组中只有两个条件，如果还要加条件，可以在后面添加。

提示：如果不用 Sum 函数，仅统计“广州”的“衬衫”销量。

3、多数组条件

A、假如要统计在广州和杭州销售的价格为 86、80 或 65 元的服装销量之和。把公式 =SUM(SUMIFS(F2:F10,D2:D10,{"广州","杭州"},E2:E10,{86;80;65})) 复制到 H2 单元格，如图4所示：

B、按回车，则统计出满足条件的服装销量之和，如图5所示：

注意：条件2 {86;80;65} 中数字之间用半角分号（;），如果用半角逗号（,），只会返回第一条满足条件的销量；结果返回 329，它正是第一条记录“长袖白衬衫”的销量，如图6所示：

（三）用通配符组合条件

1、假如要统计产品名称为四个字、销售地区含有“州”字、价格大于60元的全部服装销量之和。把公式 =SUM(SUMIFS(F2:F10,B2:B10,"????",D2:D10,"*州*",E2:E10,">60")) 复制到 H2 单元格，按回车，则统计所有满足条件的服装销量之和，如图7所示：

2、公式说明

公式 =SUM(SUMIFS(F2:F10,B2:B10,"????",D2:D10,"*州*",E2:E10,">60")) 中的 SumIfs 由三组“条件区域和条件”组成；第一组（B2:B10,"????"）是从 B2:B10 中找出名称为四个字的服装；第二组（D2:D10,"*州*"）是从 D2:D10 中找出含有“州”字的服装；第三组（E2:E10,">60"）是从 E2：E10 中找出“价格”大于 60 元的服装。最后把三组统计出的服装销量用 Sum 求和。

求和，是最常见的统计工作，但花样繁多的求和要求和条件，常常让不少人限入苦思冥想不得其解的困惑之中，今天运用EXCEL函数与公式，总结从初级到高级的10个求和技巧，与大家一起学习和交流。

初级篇

1、运用“=”、“+”来计算

这是最基础的求和方法，适合无规律或指定单元格求和。如下图：计算1、3、5月份的销售量。J2单元格：=E2+G2+I2，然后，向下复制

2、运用函数SUM求和

这是基础求和函数，适合连续区域求和，高级应用多为与其他函数结合形成SUM数组公式。说明一点，SUM函数的参数，可以是单元格区间，也可以是单个单元格。如下图：计算1、3、5月份的销售量。J2单元格：=SUM(E2,G2,I2)，然后，向下复制

中级篇

3、忽略文本跨列求和

如下图，计算全部销售人员的销售额。C10单元格：=SUM(A2:I7)

利用Excel中sum函数本身对文本类型数值自动忽略的规定，所以，可以用来直接对跨列的数值型数据求和。

4、单条件求和，运用求和函数：SUMIF。

如图，计算1月份冰箱的销售量。K2单元格：=SUMIF($D$2:$D$18,"冰箱",$E$2:$E$18)

SUMIF函数基本结构：SUMIF（条件区域，条件，求和区域）

5、多条件求和，运用求和函数：SUMIFS。

如图，计算销售一部1月份相机销售量。L2单元格：=SUMIFS($E$2:$E$18,$A$2:$A$18,"销售一部",D$2:D$18,"相机")

SUMIFS函数基本结构：SUMIF（求和区域，条件区域1，条件1，条件区域2，条件2...）

6、避开错误值求和。

如下图：计算1-5月份总销售量。C12单元格：=SUMIF(A2:E10,"<9.9E+307")

应用函数SUMIF设置条件完成，其中设置条件"<9.9E+307"，其含义是，9.9*10^307，即9.9乘10的307次方，9.9E+307是一个极大的数值，根据EXCEL的通过规则：数值<文本

7、通配符求和

如下图：计算1月份包含电脑的的总销量。G2单元格：=SUMIF(C2:C18,"*电脑",D2:D18)

应用函数SUMIF设置条件完成，通配符*代表任何字符或字符串，只要总字符不超过255个，设置条件"*电脑"，或“*电脑*”，在选定区域中查找包含“电脑”的所有商品，在计算区域求和。

8、快速累计求和

利用“$”对求和区域首个单元格进行绝对引用，马上就能对一列数值快速累计求和，如下图，C2单元格：=SUM($B$2:B2)，向下复制即可。

9、求和的快捷键："Alt + =",选中要求和的区域和拟计算结果的空白区域，一键即可在空白区域产生求和结果

高级篇

10、求和之王：SUMPRODUCT

SUMPRODUCT函数跟SUM函数的数组公式条件求和语法一样。

=SUMPRODUCT((条件区域=条件)*求和区域)

如上面案例，计算1月份冰箱的销售量。K2单元格：=SUMIF($D$2:$D$18,"冰箱",$E$2:$E$18)，也可以写成：=SUMPRODUCT((D2:D18="冰箱")*E2:E18)

如上面案例，计算销售一部1月份相机销售量。L2单元格：=SUMIFS($E$2:$E$18,$A$2:$A$18,"销售一部",D$2:D$18,"相机")，也可写成：=SUMPRODUCT((A2:A18="销售一部")*(D2:D18="相机")*E2:E18)

下面，举个复杂一点点的例子，昨天，世界杯开始，首场比赛，俄罗斯队5：0大胜沙特队，拟统计本次世界杯，各小组球队进、失球队总数。

以A组为例，第一场有真实比分，其余为模拟分。就可以用SUMPRODUCT计算，进球数：J2单元格：=SUMPRODUCT(($B$2:$B$7=$I3)*($C$2:$C$7))+SUMPRODUCT(($F$2:$F$7=$I3)*($E$2:$E$7))；失球数：K2单元格：=SUMPRODUCT(($B$2:$B$7=$I3)*($E$2:$E$7))+SUMPRODUCT(($F$2:$F$7=$I3)*($C$2:$C$7))

SUMPRODUCT与其他函数结合还可以解决你意想不到的求和需求，以后我们会专门进行分享。请关注后，期待好文。

每天学习一点点，每天进步一点点，积硅步，必能致千里，得大成。

今天给大家传授一项Excel常用快捷功能：一键求和！

说起Excel数据求和，大家一定不陌生，但是Excel里有一项快捷键能够帮你高效求和，并且可以多行多列一键求和，大大提高你的工作效率，下面我们就来看一下吧。

大家看下面的数据表，需对各月和每名员工季度业绩进行求和汇总，此数据表是典型的多行多列求和，你看到的第一反应是怎样的。

你还在手动输入sum公式进行求和吗？在行末尾输入sum公式，然后下拉；在列的末尾输入sum公式，然后向右拖拽。

这样求和方式简直太低效了，那就看一下如何多行多列一键求和吧！

首先选中需要求和的行和列，然后按住“Alt”和“=”，如此行和列的求和结果就一键展示出来了，是不是很神奇呀！

一键求和是不是非常的快速高效并且很简单呢？大家学会了吗？

小编在这里要提醒大家，学会之后一定要在日常工作学习中应用哦，这样才会熟练于心。

好了，今天的Excel小教程就这样了，下次再回！如果对你有帮助，记得收藏转发哦。