SumIfs函数是 Excel 中多个求和函数之一，它主要用于统计指定区域满足单个或多个条件的和。SumIfs函数可以有多个参数，除第一个参数“求和区域”外，其它的参数都成组出现，每组由“条件区域和条件”组成，可以有 N 组这样的参数。SumIfs函数的多条件用数组表示，数组中的每个元素就是一个条件；当用数组组合多个条件时，SumIfs函数通常要与Sum函数结合才能统计出满足多个条件的和。以下就是Sumifs函数多字段多条件求和使用实例，实例中操作所用版本均为 Excel 2016。

一、Excel Sumifs 语法

1、表达式：SUMIFS(sum_range, criteria_range1, criteria1, [criteria_range2, criteria2], ...)

中文表达式：SUMIFS(求和区域，条件区域1，条件1，[条件区域2，条件2]，...)

2、说明：

A、表达式中，前三个参数是必需的，括号（[]）中的参数是可选的，省略号（...）表示继续构建[条件区域3，条件3]、[条件区域4，条件4]、...、[条件区域n，条件n]。

B、可以在条件中使用通配符“问号 (?) 和星号 (*)”，问号匹配任意单个字符，星号匹配任意一个或一串字符；果要找“? 和 *”，需要在它们前面加转义字符 ~，例如要查找 ?，需要这样写 ~?。

C、如果在条件中使用文本条件、含有逻辑或数学符号的条件都必须用双引号 (") 括起来；例如使用大于号，应该这样写：">50" 或 ">"&50。

D、SumIfs 只对数值求和，文本则忽略，如果选中的求和区域全为文本，则返回 0；如果既有文本又有数值，则只取数值求和。

二、Excel Sumifs函数的使用方法举例

（一）单条件

1、假如要统计在广州销售的所有服装的销量之和。选中 H2 单元格，把公式 =SUMIFS(F2:F10,D2:D10,"广州") 复制到 H2，按回车，则返回在广州销售的所有服装销量之和，如图1所示：

2、公式说明

公式 =SUMIFS(F2:F10,D2:D10,"广州") 中，F2:F10 是求和区域，D2:D10 是条件区域，“广州”是条件。

（二）多条件

1、双条件

A、假如要统计在广州销售的且为“衬衫”的所有服装销量之和。把公式 =SUMIFS(F2:F10,D2:D10,"广州",C2:C10,"衬衫") 复制到 H2 单元格，按回车，则统计出所有满足条件销量之和，操作过程步骤，如图2所示：

B、公式说明

公式 =SUMIFS(F2:F10,D2:D10,"广州",C2:C10,"衬衫") 的求和区域为 F2:F10；条件区域1为 D2:D10，条件1为“广州”；条件区域2为 C2：C10，条件2为“衬衫”。

2、数组条件且与Sum函数结合

A、假如要统计在广州和深圳销售的衬衫销量之和。选中 H2 单元格，把公式 =SUM(SUMIFS(F2:F10,D2:D10,{"广州","深圳"},C2:C10,"衬衫")) 复制到 H2，按回车，则统计出满足的衬衫销量之和，操作过程步骤，如图3所示：

B、公式说明

公式 =SUM(SUMIFS(F2:F10,D2:D10,{"广州","深圳"},C2:C10,"衬衫")) 由 Sum 和 SumIfs 两个函数组成，其中 SumIfs 函数用来分别统计在“广州”和“深圳”销售的“衬衫”销量之和，Sum函数用来把 SumIfs 求出的在“广州”和“深圳”销售的“衬衫”销量之和加起来。SumIfs 的条件1“{"广州","深圳"}”为数组，数组中只有两个条件，如果还要加条件，可以在后面添加。

提示：如果不用 Sum 函数，仅统计“广州”的“衬衫”销量。

3、多数组条件

A、假如要统计在广州和杭州销售的价格为 86、80 或 65 元的服装销量之和。把公式 =SUM(SUMIFS(F2:F10,D2:D10,{"广州","杭州"},E2:E10,{86;80;65})) 复制到 H2 单元格，如图4所示：

B、按回车，则统计出满足条件的服装销量之和，如图5所示：

注意：条件2 {86;80;65} 中数字之间用半角分号（;），如果用半角逗号（,），只会返回第一条满足条件的销量；结果返回 329，它正是第一条记录“长袖白衬衫”的销量，如图6所示：

（三）用通配符组合条件

1、假如要统计产品名称为四个字、销售地区含有“州”字、价格大于60元的全部服装销量之和。把公式 =SUM(SUMIFS(F2:F10,B2:B10,"????",D2:D10,"*州*",E2:E10,">60")) 复制到 H2 单元格，按回车，则统计所有满足条件的服装销量之和，如图7所示：

2、公式说明

公式 =SUM(SUMIFS(F2:F10,B2:B10,"????",D2:D10,"*州*",E2:E10,">60")) 中的 SumIfs 由三组“条件区域和条件”组成；第一组（B2:B10,"????"）是从 B2:B10 中找出名称为四个字的服装；第二组（D2:D10,"*州*"）是从 D2:D10 中找出含有“州”字的服装；第三组（E2:E10,">60"）是从 E2：E10 中找出“价格”大于 60 元的服装。最后把三组统计出的服装销量用 Sum 求和。

Excel中，多层区间查询时非常普遍的应用，遇到此类问题，大多同学都是一一对照手动填充的，其实，我们也可以使用Excel函数公式来自动完成查询填充功能。

一、问题描述。

如下图：

我们要从右侧的消费规则中查询消费人员对应的会员等级，该如何去实现了？

二、解决办法。

1、IF函数嵌套法。

方法：

在目标单元格中输入公式：=IF(C3>=50000,"至尊卡",IF(C3>=30000,"金卡",IF(C3>=15000,"银卡",IF(C3>=8000,"五级",IF(C3>=5000,"四级",IF(C3>=3000,"三级",IF(C3>=2000,"二级",IF(C3>=1000,"一级","无等级"))))))))。

释义：

1、此方法利用IF函数嵌套的方式实现，如果会员等级复杂，嵌套的次数就非常的繁多，并且容易出错。

2、书写公式时必须从“高等级”依次向“低等级”书写，不能跳跃，否则就会出现错误。

2、VLOOKUP函数模糊查询法。

方法：

在目标单元格中输入公式：=IFERROR(VLOOKUP(C3,$H$3:$I$10,2),"无等级")。

释义：

1、IFERROR函数为辅助函数，如果数值在表格中查询不到对应的数据，则返回“无等级”。暨消费金额小于1000元时为“无等级”。

2、如果消费金额大于1000原始，执行VLOOKUP(C3,$H$3:$I$10,2)查询，我们不难发现，VLOOKUP函数得第四个参数被省略，此时为模糊查询，暨在第二个参数中找不到第一个参数时，返回比查询值小但最接近查询值的对应值。例如：查询2100时，返回的是2000所对应的值。

3、LOOKUP函数查询法。

方法：

在目标单元格中输入公式：=IFERROR(LOOKUP(C3,$H$3:$I$10),"无等级")。

释义：

1、IFERROR函数为辅助函数，当查询不到对应的值时返回“无等级”。暨消费金额小于1000元时，返回“无等级”。

2、当消费金额大于等于1000元时，执行LOOKUP(C3,$H$3:$I$10)，查询，如果查询不到对应的值，则返回小于且最接近于查询值的对应值。例如：查询2100时，返回的是2000所对应的值。

在做各类数据整理的时候，我们经常会碰到一个问题那就是数据排名。如果只是常见的单一的数据排名，我们可以用简单的RANK函数来操作即可。但是我们经常会碰到的就是大家的成绩都是一样的时候，我们需要再根据另外一个指标的大小来进行排名，这样RANK函数就没有作用了。

今天我们来就学习两种多条件排名的操作方法。

一、RANK函数单一数据排名基础讲解：

函数=RANK(D3,$D$3:$D$9)

备注：如上图：当我们需要根据所有人的销售额由高到低进行排名的时候，只需要用Rank函数显示即可，Rank函数的第三参数可以有也可以省略。（PS：第三参数为0代表从大到小排名，为1代表从小到大排名，省略则默认为从大到小排名）

二、多条件排名操作讲解

场景1：按照不同部门，人员销售额由高到低单独进行排名

函数=SUMPRODUCT(($C$3:$C$9=C3)*($D$3:$D$9>D3))+1

备注：当需要根据不同部门单独进行排名的时候，rank函数就不起作用了。这个时候需要用到Sumproduct函数来进行操作，通过这个函数将部门和销售额两个条件进行计算。最后面有+1是因为，如果不+1最小的那个值会显示为0，+1可以依次将结果进行调整。

场景2：根据销售额由大到小进行排名，当销售额相同时根据满意度由大到小排名

函数=RANK(D3,$D$3:$D$9)+SUMPRODUCT(($D$3:$D$9=D3)*($E$3:$E$9>E3))

备注：从数据中我们可以看到李四和驴儿的销售额是相同的，王五和王吧的销售额是相同的，在销售额相同的情况下我们需要根据客户满意度由高到低进行排名。这里就用到了RANK函数和SUMPRODUCT函数一起操作。

现在你对数据排名是否有不一样的理解了？

查找引用，是Excel中的基本应用和必备的技能之一，常用的函数有Lookup、Vlookup等，对这两个函数的用法如果能够熟练掌握，查找引用将会发挥极大的作用。

一、作用及语法结构。

作用：搜索某个单元格区域的第一列，然后返回该区域相同行上任何单元格中的值。

语法结构：

=Vlookup(找什么，在哪儿找，返回范围中对应的第几列的值，查找模式（精准查找还是模糊查找）)。

二、应用实例。

1、单条件查找。

方法：

在目标单元格中输入公式：=VLOOKUP(H3,B3:D9,3,0)。

解读：

1、查找值为H3单元格的值，查找范围为B3:D9，返回B3:D9范围中第3列的值，暨D列的值，匹配模式为精准匹配。

2、多条件查找。

方法：

1、在目标单元格中输入公式：=VLOOKUP(H3&I3,IF({1,0},B3:B9&E3:E9,D3:D9),2,0)。

2、Ctrl+Shift+Enter填充。

3、根据一个条件查询所有关联信息。

目的：根据姓名查询关联的所有值。

方法：

在目标单元格中输入公式：=VLOOKUP($H$3,$B$3:$F$9,COLUMN(B$2),0)。

解读：

1、公式：=VLOOKUP($H$3,$B$3:$F$9,COLUMN(B$2),0)中除了Column(b$2)之外，没有特别之处，其实重点就在函数Column()。

2、函数Column(b$2)提取B列的列数，由于参数是混合引用，故完成了范围中相对位置的提取。

4、从右向左查询。

目的：根据【名次】查询对应的【姓名】。

方法：

在目标单元格中输入公式：=VLOOKUP(I3,IF({1,0},F3:F9,B3:B9),2,0)。

解读：

公式中的IF({1,0},F3:F9,B3:B9)的作用在于组成新的数组，其值为{3,"王东";2,"小西";2,"小南";5,"小北";6,"小中";4,"小王";7,"小李"}。然后根据名次查找值，并返回对应位置的值。

5、划分区间等级。

目的：查询销量对应的等级。

方法：

在目标单元格中输入公式：=VLOOKUP(D3,$I$3:$J$6,2)。

解读：

当Vlookup函数的第四个参数为1或省略时，为模糊查询。应为查询的是销量所在的范围，所以只能用模糊查询，不能精准查询。

结束语：

Vlookup函数是我们常用的查询引用函数，不仅可以实现单条件查询、多条件查询、还可以实现从右向左查询，以及实用通配符查询等。如果能够熟练掌握，对我们的查找引用工作将会有很大的帮助。

学习过程中，如果遇到任何困难，欢迎在留言区留言讨论哦！

在数据统计中会经常筛选符合一个条件或多个条件的数据个数，这对数据分析是非常重要的。筛选符合多个条件数据时是通过countifs函数实现的，首先来看下这个函数的语法。

countifs(criteria_range1,criteria1,criteria_range2,criteria2,…)criteria_range1为第一个需要计算其中满足某个条件的单元格数目的单元格区域（简称条件区域），criteria1为第一个区域中将被计算在内的条件（简称条件），其形式可以为数字、表达式或文本。例如，条件可以表示为48、"48"、">48" 、 "广州" 或 A3；

同理，criteria_range2为第二个条件区域，criteria2为第二个条件，依次类推。最终结果为多个区域中满足所有条件的单元格个数。

下面通过实例来具体操作下，一个班级的考试成绩表，分别筛选出各科成绩都不及格的人数及各科成绩都90分以上的人数。

数据表

对都不及格的条件进行设置，也就是各科成绩都在60以下，涉及到的数据列从B到I，这些条件满足后就可以了。所以公式也就出来了： =count(B2:B21,"<60",C2:C21,"<60",D2:D21,"<60",E2:E21,"<60",F2:F21,"<60",G2:G21,"<60",H2:H21,"<60",I2:I21,"<60")。

公式1

同理都90分以上的人数公式：=COUNTIFS(B2:B21,">90",C2:C21,">90",D2:D21,">90",E2:E21,">90",F2:F21,">90",G2:G21,">90",H2:H21,">90",I2:I21,">90")。

公式2

到此需要的数据个数就都有了，这对于数据量的比较大的数据是非常有用的，希望对你有所帮助。

LOOKUP函数是我们常用的查找函数之一，其语法决定，想要得到正确的查询结果，必须对查询的数据进行升序排序，但是一般情况下我们都不会先排序在查询，而是采用：=LOOKUP(1,0/(B3:B9=H3),C3:C9)类似结构的语法来完成查询。但是，对于上述方法，大多同学一知半解……

一、应用场景。

目的：查询销售员对应的销量。

方法：

1、在目标单元格中输入公式：=LOOKUP(1,0/(B3:B9=H3),C3:C9)。

2、选定数据源，【条件格式】-【新建规则】-【使用公式确定要设置格式的单元格】，在【为符合此公式的值设置格式】中输入：=($B3=$H$3)。

3、单击右下角【格式】-【填充】，选取填充色，并【确定】完成查询设置。

二、公式解读。

（一）、(B3:B9=H3)的运算结果。

1、如果A=B，会返回结果TRUE，TRUE在运算中相当于数字1。

2、如果A<>B，会返回结果FALSE，FALSE在运算中相当于数字0。

所以：(B3:B9=H3)的运算结果是有TRUE和FALSE构成的一组值，结果如下图：

（二），提取所需值

1、0/(B3:B9=H3)的结果我们可以归纳为：0，#p/0！，#p/0！，#p/0！，#p/0！，#p/0！，#p/0！。如下图：

2、LOOKUP函数:特征1：查找时可以忽略错误值且，这样一组数值忽略后只剩下一个值0。

3、LOOKUP函数特征2：当查找的值不存在时，按照小于此值的最大值进行匹配。故设置查找值为1，从而实现查询的目的。

备注：

“0/”的目的就是把符合条件的值变为0，不符合条件的变为错误，利用LOOKUP函数的特征查找到符合条件的值。

三、多条件查询。

目的：查询销售员在相应地区的销售额。

方法：

在目标单元格中输入公式：=IFERROR(LOOKUP(1,0/((B3:B9=H3)*(E3:E9=I3)),C3:C9),"")。

释义：

1、原理和单条件查询是一样的。

2、TRUE*TRUE=1，TRUE*FALSE=0。

各位亲，如果对多条件查询不理解，可以在评论区留言提问哦！

Hi，我是秋小叶~

做 Excel 表格，一提到函数公式，很多人就头皮发麻。

为什么？其一，因为表格需求千变万化，数据结构千差万别，一点点细微的差别，用法可能就大相径庭；其二，每个函数都有自己的语法规则，必须一五一十严格遵照它的要求，它才会乖乖听话。

那有什么方法，可以在短时间内，快速提升函数公式的应用能力？答案只有一个——用！

怎么用呢？

在工作中以问题和需求为出发点，去找合适的方法。而要想成为个中高手，还有 2 种方式，系列化延伸和一题多解！通过对比不同的思路和方法，能对 Excel 基本技能有更加深入的认知。真到要用的那一刻，就能信手拈来。

拿工作中最常用到的查找匹配为例，要在左边数据区域中查找出小王的销量数据 11，填写进 F2 单元格，怎么做？

有一点 Excel 基础的人都知道，用一个 VLOOKUP 函数就够了：

=VLOOKUP(E2,A:C,3,0)

（拿着 E2 中的「小王」去匹配区域 (A:C) 的第一列，也就是员工一列中查找，找到以后返回匹配区域中同一行第 3 列的数据，也就是 11，其中最后一个参数 0 表示精确匹配，必须找一模一样的「小王」）

这就是单条件的查找匹配。那……假如工作中需要按多个条件查找匹配呢？还能用 VLOOKUP 实现吗？

举个例子，查找匹配出员工、医院、产品同时满足条件的销量数据，又该怎么做？

直接查找匹配不行，我们可以明修栈道，暗度陈仓。既然多条件复杂，我们可以将多个条件合并成一个条件。

首先插入一个空列，设为合并列。在 D2 单元格输入如下公式，将左边的三列合而为一：

=A2&B2&C2

（ & 是连接运算符，可以将单元格、数据拼接成新的文本）

有了这个辅助列，作为查找匹配的索引，我们用 VLOOKUP 也能轻而易举的实现多条件查找匹配，只要在 J2 单元格输入如下公式即可：

=VLOOKUP(G2&H2&I2,D:E,2,0)

（和前面的公式不同点在于，查找对象换成了 G2、H2、I2 三个单元格合并以后的文本，匹配区域从 D 列开始到 E 列，这是因为VLOOKUP有一个前提条件：只在匹配区域的第一列中查找索引对象。）

通过上述系列化延伸，你就能进一步了解更多知识点：

VLOOKUP 的基本用法：只要在两张表中存在可以索引的数据，就可以查找到同一行中的其他数据

用连接符 & 可以将多列数据合并为一列

VLOOKUP 公式中可以嵌套使用其他公式，比如 G2&H2&I2 的计算结果作为查找对象

VLOOKUP 公式只在匹配范围的第一列里查找匹配，按指定的列序返回结果

到这里，问题已经解决。

但是，学习高手可能会继续纵向深挖：

如果用于索引的查找匹配列不在第一列时，例如合并列在销量列后头时，又该怎么做？

或者横向扩展：

多条件查找匹配，除了用 VLOOKUP+ 辅助列的方法，还有哪些方法？哪一种方法会更简单高效？

要解决这个问题，其实我们就是追求 一题多解。预知详情，我们下期再聊。你也可以在评论区留下思路，交流碰撞说不定会激发出新的灵感。

在进行数据统计时，有时需要挑选出同时满足多个条件的数据。例如在进行三好学生、优秀学生等评选时，有时会需要挑选出各学科考试成绩都大于某个数值的学生，作为参评的条件之一。例如要挑选出各学科成绩都大于80的学生。这时在班级里学生较多的情况下，如果采用逐个查看每个学生各科成绩来进行挑选的方法将会花费一定的时间，还有可能因为马虎而出现疏漏，这样不但影响工作效率，还可能影响最终结果的准确性。这种情况可以考虑用Excel来帮助我们较轻松和准确的完成这个任务，这里以Excel2007为例介绍如何操作，以供参考。

在Excel中挑选出同时满足多个条件的数据可以考虑采用“AND”函数，其语法为：AND(logical1,logical2, ...)，括号内的“logical1,logical2, ...”为各种条件的表达式，如果各种条件的表达式都成立，Excel就会返回“TRUE” 否则返回“FALSE”。

但如果表格中只显示英文的“TRUE”和“FALSE”，会显得不太美观，也不够明了。这时可以组合使用其他的函数，如“IF”函数，让Excel显示我们自定义的字符。IF”函数的语法为：IF(logical_test,value_if_true,value_if_false)，括号中的“Logical_test”为表达式（例如可以用上述的“AND”函数作为表达式），“value_if_true”为表达式结果为TRUE”时Excel返回的结果，“value_if_false”为表达式结果为“FALSE”时Excel返回的结果。

例如要从下图表格中挑选出各科成绩都大于80的学生：

●统计时可先在表格右侧添加一个显示统计结果的列，然后点击选中该列的列首单元格。

●选中单元格后，在编辑栏中输入“=AND(C4>=80,D4>=80,E4>=80,F4>=80)”，其中的C4、D4、E4、F4为该行中的学生各科考试成绩所在的单元格，>=80为判断条件，即要求考试成绩大于等于80分。如果AND后面的括号中各判断条件都成立，即各科成绩都大于等于80分，则Excel会返回“TRUE” 否则如果有一科或者多科成绩不大于等于80，Excel会返回“FALSE”。

●输入上述函数公式后，按键盘回车键或者点击编辑栏左侧的对号，该单元格中就会显示出计算结果。

●再用下拉填充柄或者选择性粘贴公式的方法在该列的其他单元格中快速填充公式，就会显示出所有学生的判断结果，其中结果为“TRUE”的表示该学生的各科成绩都大于等于80，结果为“FALSE”的表示该学生至少有一科成绩不大于等于80。但这种显示结果不太美观和明了，最好再组合IF函数来显示中文或者其他符号的判断结果。

●我们可以把列首单元格中的公式改成=IF(AND(C4>=80,D4>=80,E4>=80,F4>=80),"是","否")，即如果公式"AND(C4>=80,D4>=80,E4>=80,F4>=80)"的判断结果为“TRUE”，则Excel会显示字符“是”；反之如果判断结果为“FALSE”则Excel会显示字符“否”，这样看起来比英文的“TRUE”和“FALSE”要明了一些。

●这样再下拉填充或者选择性粘贴公式后，该列其他单元格中就都显示出中文的判断结果了。

●我们还可以用对号来表示符合条件，用空白来表示不符合条件。即把上述公式修改为=IF(AND(C4>=80,D4>=80,E4>=80,F4>=80),"√","")。

●这样，符合条件的学生就都会显示对号，不符合条件的学生会显示空白，感觉更加一目了然。

上述例子介绍的只是AND函数和IF函数相组合的一种应用方法，熟练掌握这两种函数的用法后，可以给数据统计带来更多的方便。

今天准备了一组日常工作中常用的多条件判断、统计Excel函数公式，让同学们提升工作效率，不再头疼。

1、IF函数多条件判断

要求：如果部门为生产、岗位为主操 有高温补助。

公式：

=IF(AND(B2="生产",C2="主操"),"有","无")

AND函数对两个条件判断，如果同时符合，IF函数返回“有”，否则为无。

2、SUMIF多条件求和

要求：统计E2和E3单元格中两个部门的岗位补助总额

=SUMPRODUCT(SUMIF(B2:B9,E2:E3,C2:C9))

SUMIF函数求和条件使用E2:E3，分别得到两个部门的岗位补助额，再使用SUMPRODUCT函数进行求和。

3、SUMIFS多条件求和

要求：统计部门为生产,并且岗位为主操的补助总额

=SUMIFS(D2:D9,B2:B9,F2,C2:C9,G2)

SUMIFS函数求和区域为D2:D9，求和条件为B2:B9=F2并且C2:C9=G2

4、包含关键字的多条件求和

要求：统计部门包含“生产”,并且岗位为主操的补助总额

=SUMIFS(D2:D9,B2:B9,"*"&F2&"*",C2:C9,G2)

SUMIFS函数支持使用通配符。

5、多条件计数

要求：统计统计部门为生产,并且岗位为主操的人数

=COUNTIFS(B2:B9,F2,C2:C9,G2)

COUNTIFS函数也支持使用通配符，用法与SUMIFS函数相同。

6、多条件计算平均值

要求：统计统计部门为生产,并且岗位为主操的平均补助额

=AVERAGEIFS(D2:D9,B2:B9,F2,C2:C9,G2)

第一参数是要统计的数值区域，之后分别是成对的条件区域和指定条件。

7、多条件计算最大值和最小值

要求：统计统计部门为生产,并且岗位为主操的最高补助额

数组公式，注意按Shift+ctrl+回车：

=MAX(IF((B2:B9=F2)*(C2:C9=G2),D2:D9))

数组公式中，判断多条件时不能使用AND或是OR函数，因此先使用两个判断条件相乘，表示两个条件要求同时符合。

再使用IF函数对结果进行判断，两个条件同时符合时，IF函数返回D2:D9中的数值，否则返回逻辑值FALSE。

最后使用MAX函数忽略其中的逻辑值计算出最大值。

要计算多个条件的最小值时，只要将公式中的MAX换成MIN函数即可。

8、多条件查找

要求：查询部门为生产,并且岗位为部长的姓名

=LOOKUP(1,0/((B2:B9=F2)*(C2:C9=G2)),A2:A9)

LOOKUP函数多条件查询套路为：

=LOOKUP(1,0/(条件1*条件2*条件n),查询区域)

9、使用DSUM函数多条件汇总

要求：统计部门为生产、并且工资在7000~12000之间的总额

=DSUM(A1:C9,"实发工资",E2:G3)

第一参数为整个数据表区域，第二参数是要汇总的列标题，第三参数是指定的条件区域。

注意，第二参数中的列标题以及条件区域的列标题要和数据源中的标题相同。

好了，今天的分享就是这些，祝各位一天好心情！

图文制作：祝洪忠

今天在论坛有个小伙伴问到一个关于Excel查找的相关问题，但是他的要求是多个条件进行限制，然后匹配对应的数据出来，今天小菜就以这种情况和大家分享关于Excel双（多）条件查找的5种技巧！

现在需求是匹配出营销部的小菜底薪。会发现公司叫小菜的不只是营销部，因此不能做为单一条件去匹配，故此这类我们称多条件查找。

方法1：用SUMPRODUCT函数

公式：=SUMPRODUCT(($A$2:$A$8=E2)*($B$2:$B$8=F2)*($C$2:$C$8))

满足姓名是小菜，部门是营销部，然后对底新列求和。

方法2：用max函数+数组

公式：=MAX(($A$2:$A$8=E2)*($B$2:$B$8=F2)*($C$2:$C$8))，编辑完公式在三键结束。

方法3：Index+Match实现

公式：=INDEX($C$2:$C$8,MATCH(E2&F2,$A$2:$A$8&$B$2:$B$8,0))

Match这里巧妙把两个条件用&连接起来，就变成了一个条件，MATCH(E2&F2,$A$2:$A$8&$B$2:$B$8,0)

方法4：使用lookup函数

公式：=LOOKUP(1,0/(($A$2:$A$8=E2)*($B$2:$B$8=F2)),$C$2:$C$8)

这是lookup一个常用套路=lookup(1,0/((条件1区域=条件1)*(条件2区域=条件2)),(返回的结果区域))

方法5：数据库函数DSUM

此函数有3个参数。第1参数：要引用的数据源；第2参数要求和的列；第3参数：条件，注意一定要引用单元格区域包括列标题字段，如E1:F2

方法还有其他的，希望这些方法能解决大家的问题，如果OK，记得点个赞，分享个朋友圈，这样小菜也有更加的动力为大家写文章……

如果你是新朋友，扫码关注下方二维码，便每天可以和小菜一起学习，一起提升技能！当然大家也可以技巧分享，学习更多办公技巧哦！

每天一起学习，一起进步。