SumIfs函数是 Excel 中多个求和函数之一，它主要用于统计指定区域满足单个或多个条件的和。SumIfs函数可以有多个参数，除第一个参数“求和区域”外，其它的参数都成组出现，每组由“条件区域和条件”组成，可以有 N 组这样的参数。SumIfs函数的多条件用数组表示，数组中的每个元素就是一个条件；当用数组组合多个条件时，SumIfs函数通常要与Sum函数结合才能统计出满足多个条件的和。以下就是Sumifs函数多字段多条件求和使用实例，实例中操作所用版本均为 Excel 2016。

一、Excel Sumifs 语法

1、表达式：SUMIFS(sum_range, criteria_range1, criteria1, [criteria_range2, criteria2], ...)

中文表达式：SUMIFS(求和区域，条件区域1，条件1，[条件区域2，条件2]，...)

2、说明：

A、表达式中，前三个参数是必需的，括号（[]）中的参数是可选的，省略号（...）表示继续构建[条件区域3，条件3]、[条件区域4，条件4]、...、[条件区域n，条件n]。

B、可以在条件中使用通配符“问号 (?) 和星号 (*)”，问号匹配任意单个字符，星号匹配任意一个或一串字符；果要找“? 和 *”，需要在它们前面加转义字符 ~，例如要查找 ?，需要这样写 ~?。

C、如果在条件中使用文本条件、含有逻辑或数学符号的条件都必须用双引号 (") 括起来；例如使用大于号，应该这样写：">50" 或 ">"&50。

D、SumIfs 只对数值求和，文本则忽略，如果选中的求和区域全为文本，则返回 0；如果既有文本又有数值，则只取数值求和。

二、Excel Sumifs函数的使用方法举例

（一）单条件

1、假如要统计在广州销售的所有服装的销量之和。选中 H2 单元格，把公式 =SUMIFS(F2:F10,D2:D10,"广州") 复制到 H2，按回车，则返回在广州销售的所有服装销量之和，如图1所示：

2、公式说明

公式 =SUMIFS(F2:F10,D2:D10,"广州") 中，F2:F10 是求和区域，D2:D10 是条件区域，“广州”是条件。

（二）多条件

1、双条件

A、假如要统计在广州销售的且为“衬衫”的所有服装销量之和。把公式 =SUMIFS(F2:F10,D2:D10,"广州",C2:C10,"衬衫") 复制到 H2 单元格，按回车，则统计出所有满足条件销量之和，操作过程步骤，如图2所示：

B、公式说明

公式 =SUMIFS(F2:F10,D2:D10,"广州",C2:C10,"衬衫") 的求和区域为 F2:F10；条件区域1为 D2:D10，条件1为“广州”；条件区域2为 C2：C10，条件2为“衬衫”。

2、数组条件且与Sum函数结合

A、假如要统计在广州和深圳销售的衬衫销量之和。选中 H2 单元格，把公式 =SUM(SUMIFS(F2:F10,D2:D10,{"广州","深圳"},C2:C10,"衬衫")) 复制到 H2，按回车，则统计出满足的衬衫销量之和，操作过程步骤，如图3所示：

B、公式说明

公式 =SUM(SUMIFS(F2:F10,D2:D10,{"广州","深圳"},C2:C10,"衬衫")) 由 Sum 和 SumIfs 两个函数组成，其中 SumIfs 函数用来分别统计在“广州”和“深圳”销售的“衬衫”销量之和，Sum函数用来把 SumIfs 求出的在“广州”和“深圳”销售的“衬衫”销量之和加起来。SumIfs 的条件1“{"广州","深圳"}”为数组，数组中只有两个条件，如果还要加条件，可以在后面添加。

提示：如果不用 Sum 函数，仅统计“广州”的“衬衫”销量。

3、多数组条件

A、假如要统计在广州和杭州销售的价格为 86、80 或 65 元的服装销量之和。把公式 =SUM(SUMIFS(F2:F10,D2:D10,{"广州","杭州"},E2:E10,{86;80;65})) 复制到 H2 单元格，如图4所示：

B、按回车，则统计出满足条件的服装销量之和，如图5所示：

注意：条件2 {86;80;65} 中数字之间用半角分号（;），如果用半角逗号（,），只会返回第一条满足条件的销量；结果返回 329，它正是第一条记录“长袖白衬衫”的销量，如图6所示：

（三）用通配符组合条件

1、假如要统计产品名称为四个字、销售地区含有“州”字、价格大于60元的全部服装销量之和。把公式 =SUM(SUMIFS(F2:F10,B2:B10,"????",D2:D10,"*州*",E2:E10,">60")) 复制到 H2 单元格，按回车，则统计所有满足条件的服装销量之和，如图7所示：

2、公式说明

公式 =SUM(SUMIFS(F2:F10,B2:B10,"????",D2:D10,"*州*",E2:E10,">60")) 中的 SumIfs 由三组“条件区域和条件”组成；第一组（B2:B10,"????"）是从 B2:B10 中找出名称为四个字的服装；第二组（D2:D10,"*州*"）是从 D2:D10 中找出含有“州”字的服装；第三组（E2:E10,">60"）是从 E2：E10 中找出“价格”大于 60 元的服装。最后把三组统计出的服装销量用 Sum 求和。

Hi，我是秋小叶~

做 Excel 表格，一提到函数公式，很多人就头皮发麻。

为什么？其一，因为表格需求千变万化，数据结构千差万别，一点点细微的差别，用法可能就大相径庭；其二，每个函数都有自己的语法规则，必须一五一十严格遵照它的要求，它才会乖乖听话。

那有什么方法，可以在短时间内，快速提升函数公式的应用能力？答案只有一个——用！

怎么用呢？

在工作中以问题和需求为出发点，去找合适的方法。而要想成为个中高手，还有 2 种方式，系列化延伸和一题多解！通过对比不同的思路和方法，能对 Excel 基本技能有更加深入的认知。真到要用的那一刻，就能信手拈来。

拿工作中最常用到的查找匹配为例，要在左边数据区域中查找出小王的销量数据 11，填写进 F2 单元格，怎么做？

有一点 Excel 基础的人都知道，用一个 VLOOKUP 函数就够了：

=VLOOKUP(E2,A:C,3,0)

（拿着 E2 中的「小王」去匹配区域 (A:C) 的第一列，也就是员工一列中查找，找到以后返回匹配区域中同一行第 3 列的数据，也就是 11，其中最后一个参数 0 表示精确匹配，必须找一模一样的「小王」）

这就是单条件的查找匹配。那……假如工作中需要按多个条件查找匹配呢？还能用 VLOOKUP 实现吗？

举个例子，查找匹配出员工、医院、产品同时满足条件的销量数据，又该怎么做？

直接查找匹配不行，我们可以明修栈道，暗度陈仓。既然多条件复杂，我们可以将多个条件合并成一个条件。

首先插入一个空列，设为合并列。在 D2 单元格输入如下公式，将左边的三列合而为一：

=A2&B2&C2

（ & 是连接运算符，可以将单元格、数据拼接成新的文本）

有了这个辅助列，作为查找匹配的索引，我们用 VLOOKUP 也能轻而易举的实现多条件查找匹配，只要在 J2 单元格输入如下公式即可：

=VLOOKUP(G2&H2&I2,D:E,2,0)

（和前面的公式不同点在于，查找对象换成了 G2、H2、I2 三个单元格合并以后的文本，匹配区域从 D 列开始到 E 列，这是因为VLOOKUP有一个前提条件：只在匹配区域的第一列中查找索引对象。）

通过上述系列化延伸，你就能进一步了解更多知识点：

VLOOKUP 的基本用法：只要在两张表中存在可以索引的数据，就可以查找到同一行中的其他数据

用连接符 & 可以将多列数据合并为一列

VLOOKUP 公式中可以嵌套使用其他公式，比如 G2&H2&I2 的计算结果作为查找对象

VLOOKUP 公式只在匹配范围的第一列里查找匹配，按指定的列序返回结果

到这里，问题已经解决。

但是，学习高手可能会继续纵向深挖：

如果用于索引的查找匹配列不在第一列时，例如合并列在销量列后头时，又该怎么做？

或者横向扩展：

多条件查找匹配，除了用 VLOOKUP+ 辅助列的方法，还有哪些方法？哪一种方法会更简单高效？

要解决这个问题，其实我们就是追求 一题多解。预知详情，我们下期再聊。你也可以在评论区留下思路，交流碰撞说不定会激发出新的灵感。

在做各类数据整理的时候，我们经常会碰到一个问题那就是数据排名。如果只是常见的单一的数据排名，我们可以用简单的RANK函数来操作即可。但是我们经常会碰到的就是大家的成绩都是一样的时候，我们需要再根据另外一个指标的大小来进行排名，这样RANK函数就没有作用了。

今天我们来就学习两种多条件排名的操作方法。

一、RANK函数单一数据排名基础讲解：

函数=RANK(D3,$D$3:$D$9)

备注：如上图：当我们需要根据所有人的销售额由高到低进行排名的时候，只需要用Rank函数显示即可，Rank函数的第三参数可以有也可以省略。（PS：第三参数为0代表从大到小排名，为1代表从小到大排名，省略则默认为从大到小排名）

二、多条件排名操作讲解

场景1：按照不同部门，人员销售额由高到低单独进行排名

函数=SUMPRODUCT(($C$3:$C$9=C3)*($D$3:$D$9>D3))+1

备注：当需要根据不同部门单独进行排名的时候，rank函数就不起作用了。这个时候需要用到Sumproduct函数来进行操作，通过这个函数将部门和销售额两个条件进行计算。最后面有+1是因为，如果不+1最小的那个值会显示为0，+1可以依次将结果进行调整。

场景2：根据销售额由大到小进行排名，当销售额相同时根据满意度由大到小排名

函数=RANK(D3,$D$3:$D$9)+SUMPRODUCT(($D$3:$D$9=D3)*($E$3:$E$9>E3))

备注：从数据中我们可以看到李四和驴儿的销售额是相同的，王五和王吧的销售额是相同的，在销售额相同的情况下我们需要根据客户满意度由高到低进行排名。这里就用到了RANK函数和SUMPRODUCT函数一起操作。

现在你对数据排名是否有不一样的理解了？

这一篇我将从IF函数的基本用法说起，接着介绍多条件IF函数嵌套是怎么理解的，怎样写函数嵌套公式。

IF函数基础

IF函数是我们处理表格最常用的函数之一，是每个人都必须掌握的，它的公式和流程如下：

IF函数共有3个参数，第一个是判断条件，第二个是条件成立时能得到的结果，第三个是条件不成立时得到的结果。

如图，我们输入在B2单元格输入公式“=IF(B2>=60,"及格","不及格")”，由于76大于60，所以得到结果“及格”。

IF函数嵌套

IF函数就像是在抛硬币，硬币落地时要么正面朝上，要么反面朝上，只有这两个结果，IF函数的结果要么是第二个参数，要么是第三个参数。可有时候希望得到三个结果，如考试成绩分为“优秀”、“及格”和“不及格”，怎么办呢？

这就要用到IF函数嵌套。函数嵌套的意思就是一个公式中有两个以上的函数，包括两个相同的函数。

有些朋友看到函数嵌套就头晕，其实你可以先写一个简单的公式“IF(条件，真值，假值)”，再把其中的“真值”或“假值”替换成另一个IF函数即可。

如果对自己写的函数嵌套公式没有把握，不妨画出它的流程图。

除了两层的IF函数嵌套，还可以用三层嵌套，方法也是一样，先写简单的，再慢慢替换。就像我们人为判断一个学生的成绩属于什么水平，会先看他是否及格了，及格了之后看他是否是良或优秀。

IF函数和其他逻辑函数嵌套

IF函数除了在真值部分嵌套IF函数之外，也可以在假值部分嵌套函数，还可以和其他函数嵌套，常见的有求和函数SUM、计数函数COUNT/COUNTIF、逻辑函数AND/OR/NOT。

一个学生有多门课程，当需要综合评价他的成绩时，我们就会用到下图中的公式了。

写一个嵌套函数是很容易出错，另外它看起来总是不那么好理解，因此，不宜嵌套太多层，虽然IF函数最多能支持7层函数嵌套，但我建议不要使用超过4层的函数嵌套，条件过多时，可以寻找其他的替代函数如lookup/round等。

谢谢阅读，每天学一点，省下时间充实自己。欢迎点赞、评论、关注和点击头像。

Excel求和函数，除了Sum、Sumif和Sumifs以外，你还用过其它的函数吗？今天分享一个简单实用又高效的数据库函数DSUM，它集「查找」和「求和」功能为一身，能多条件求和，还能跨表多条件求和，让你一看到就会爱上它！

一、函数解析

DSUM函数：将数据库中符合条件记录的字段列中的数字求和。使用它可以对数据进行多条件累加，这种方式可以很方便地修改求和的条件。

DSUM有3个参数：Dsum(数据区域，求和的列数,条件区域)

① 数据区域：一组数据列表，即需要对该组数据列表中的某些数据进行计算。

② 列数：需要求和数据所在列数（也可以是列标题）比如：如果该参数为“3”，则表示需要计算的数据在参数①第3列中，如果该参数为“销量”，则表示需要计算的数据是参数①中的“销量”那一列。

③ 条件区域：由标题行和条件构成的多行区域（条件为公式时，若使用函数标题应为空）。

二、多条件求和案例

如下图所示，计算侯采和马来军的总销量。

在F2单元格中，输入公式：=DSUM(A1:E13,E1,G1:G3)

其中A1:E13是数据区域，E1是统计列“销售量“，G1:G3是条件区域，即计算侯采和马来军2人的销售量。

三、模糊统计案例

统计销售一科以打印机开头的所有产品销量和销售二科的台式机销售之和。

在I2单元格输入公式=DSUM(A1:E13,E1,G1:H3)

DSUM()函数中的判定条件，支持使用通配符 “*” 和 “？”，如下图所示，H2在单元格中使用了通配符“*“表示包含以打印机开头的A、B型号，但不包括D13的激光打印机，如果要包括则前面要加通配符。案例中，同一行的，销售二科和台式机必须同时满足，即并条件，而不同行的销售一科的打印机和销售二科的台式机是或条件，写在不同的行。

四、符合时间条件的求和案例

统计销售日期在2018-1-7至2018-1-14之间的销售量。

I2单元格输入公式：=DSUM(A1:E13,E1,G1:H2)，销售日期是一个区间，可以在一行用两个销售日期的条件。一个是大于2018-1-6，另一个是小于2018-1-15。

五、条件为公式时，函数标题应为空

统计销售一科销量小于平均销量人员的销量总和，销量小于平均销量必须用到公式=E2

H2单元格输入公式=E2

I2单元格输入公式=DSUM(A1:E13,E1,G1:H2)

六、多数据批量汇总案例

分别计算销售一科、销售二科和销售三科的销量。

H2单元格输入公式=DSUM($A$1:$E$13,$E$1,$G$1:G2)-SUM($H$1:H1)

1、由于公式要往下填充，所以数据区域和列都用了绝对引用

2、条件区域是一个从G1开始的活动区域，所以G1是绝对引用，但G2是相对引用

3、因为不同的行是“或条件”所以在统计销售二科销售总量时，结果会包含销售一科的销售总量，需要减去销售一科的销量，同样的道理，统计销售三科销量时要减去销售一科和销售二科的销售和。

七、跨工作表统计案例

如下图所示，有表1、表2和表3三个工作表，要统计三个表中，张1、张2、张3的销量和。

C2单元格输入公式=

SUM(DSUM(INDIRECT({"表1";"表2";"表3"}&"!A1:D11"),4,A$1:B2))-SUM(C$1:C1)

1、数据区域，跨表引用了3个工作表，所以用工作表引用函数INDIRECT。

2、列数，第4列“销量”。

3、条件区域是从A1开始的活动区域，所以A1是绝对引用，但B2是相对引用。

4、由于是的跨表引用，因此dsum返回的是数组，不是单值，因此要外套sum。

5、因为不同的行是“或条件”所以在统计张2第一周的销量时，结果会包含张1第一周的销量，需要减去张1第一周销量，同样的道理，统计张3第一周的销售时要减去张1和张2第一周的销售和。

温馨提示：

1、条件区域列标题内容要与数据区域一致，比如数据区域列标题是“销售产品”，那你要统计某一产品时，条件列标题也要是“销售产品”如果你改为产品，统计会出错

2、切记“并条件”需要横着写，即写在同一行，“或条件”需要竖着写，即写在不同行。

3、条件为公式时，若使用函数标题应为空。

我是EXCEL学习微课堂，如果我的分享对您有帮助，欢迎点赞、收藏、评论、转发！更多的EXCEL技能，可以关注百家号“EXCEL学习微课堂”。

今天准备了一组日常工作中常用的多条件判断、统计Excel函数公式，让同学们提升工作效率，不再头疼。

1、IF函数多条件判断

要求：如果部门为生产、岗位为主操 有高温补助。

公式：

=IF(AND(B2="生产",C2="主操"),"有","无")

AND函数对两个条件判断，如果同时符合，IF函数返回“有”，否则为无。

2、SUMIF多条件求和

要求：统计E2和E3单元格中两个部门的岗位补助总额

=SUMPRODUCT(SUMIF(B2:B9,E2:E3,C2:C9))

SUMIF函数求和条件使用E2:E3，分别得到两个部门的岗位补助额，再使用SUMPRODUCT函数进行求和。

3、SUMIFS多条件求和

要求：统计部门为生产,并且岗位为主操的补助总额

=SUMIFS(D2:D9,B2:B9,F2,C2:C9,G2)

SUMIFS函数求和区域为D2:D9，求和条件为B2:B9=F2并且C2:C9=G2

4、包含关键字的多条件求和

要求：统计部门包含“生产”,并且岗位为主操的补助总额

=SUMIFS(D2:D9,B2:B9,"*"&F2&"*",C2:C9,G2)

SUMIFS函数支持使用通配符。

5、多条件计数

要求：统计统计部门为生产,并且岗位为主操的人数

=COUNTIFS(B2:B9,F2,C2:C9,G2)

COUNTIFS函数也支持使用通配符，用法与SUMIFS函数相同。

6、多条件计算平均值

要求：统计统计部门为生产,并且岗位为主操的平均补助额

=AVERAGEIFS(D2:D9,B2:B9,F2,C2:C9,G2)

第一参数是要统计的数值区域，之后分别是成对的条件区域和指定条件。

7、多条件计算最大值和最小值

要求：统计统计部门为生产,并且岗位为主操的最高补助额

数组公式，注意按Shift+ctrl+回车：

=MAX(IF((B2:B9=F2)*(C2:C9=G2),D2:D9))

数组公式中，判断多条件时不能使用AND或是OR函数，因此先使用两个判断条件相乘，表示两个条件要求同时符合。

再使用IF函数对结果进行判断，两个条件同时符合时，IF函数返回D2:D9中的数值，否则返回逻辑值FALSE。

最后使用MAX函数忽略其中的逻辑值计算出最大值。

要计算多个条件的最小值时，只要将公式中的MAX换成MIN函数即可。

8、多条件查找

要求：查询部门为生产,并且岗位为部长的姓名

=LOOKUP(1,0/((B2:B9=F2)*(C2:C9=G2)),A2:A9)

LOOKUP函数多条件查询套路为：

=LOOKUP(1,0/(条件1*条件2*条件n),查询区域)

9、使用DSUM函数多条件汇总

要求：统计部门为生产、并且工资在7000~12000之间的总额

=DSUM(A1:C9,"实发工资",E2:G3)

第一参数为整个数据表区域，第二参数是要汇总的列标题，第三参数是指定的条件区域。

注意，第二参数中的列标题以及条件区域的列标题要和数据源中的标题相同。

好了，今天的分享就是这些，祝各位一天好心情！

图文制作：祝洪忠

经常使用Excel函数的小伙伴们都知道，在Excel中使用频率最高的还是那些比较简单的函数，其中IF函数就是高频率函数之一，那么，能不能用IF函数来进行多条件运算呢？

一、IF+AND：同时满足多个条件

目的：将“上海”地区的“男”通知标识为“Y”。

方法：

在目标单元格中输入公式：=IF(AND(D3="男",E3="上海"),"Y","")。

解读：

1、AND函数的语法：AND(条件1,=标准1，条件2=标准2……条件N=标准N）。如果每个条件和标准都相等，则返回TRUE，否则返回FALSE 。

2、用IF函数判断AND函数的返回结果，如果为TRUE，则返回“Y”，否则返回""。

二、IF+OR:满足多个条件中的一个即可。

目的：将性别为“男”或地区为“上海”的标记为“Y”。

方法：

在目标单元格中输入公式：=IF(OR(D3="男",E3="上海"),"Y","")。

解读：

1、OR函数的语法结构为：(条件1,=标准1，条件2=标准2……条件N=标准N）。如果任意参数的值为TRUE，则返回TRUE ,当所有条件为FALSE时，才返回FALSE。

2、用IF函数判断OR函数的返回结果，如果为TRUE,则返回“Y”，否则返回""。

在进行数据统计时，有时需要挑选出同时满足多个条件的数据。例如在进行三好学生、优秀学生等评选时，有时会需要挑选出各学科考试成绩都大于某个数值的学生，作为参评的条件之一。例如要挑选出各学科成绩都大于80的学生。这时在班级里学生较多的情况下，如果采用逐个查看每个学生各科成绩来进行挑选的方法将会花费一定的时间，还有可能因为马虎而出现疏漏，这样不但影响工作效率，还可能影响最终结果的准确性。这种情况可以考虑用Excel来帮助我们较轻松和准确的完成这个任务，这里以Excel2007为例介绍如何操作，以供参考。

在Excel中挑选出同时满足多个条件的数据可以考虑采用“AND”函数，其语法为：AND(logical1,logical2, ...)，括号内的“logical1,logical2, ...”为各种条件的表达式，如果各种条件的表达式都成立，Excel就会返回“TRUE” 否则返回“FALSE”。

但如果表格中只显示英文的“TRUE”和“FALSE”，会显得不太美观，也不够明了。这时可以组合使用其他的函数，如“IF”函数，让Excel显示我们自定义的字符。IF”函数的语法为：IF(logical_test,value_if_true,value_if_false)，括号中的“Logical_test”为表达式（例如可以用上述的“AND”函数作为表达式），“value_if_true”为表达式结果为TRUE”时Excel返回的结果，“value_if_false”为表达式结果为“FALSE”时Excel返回的结果。

例如要从下图表格中挑选出各科成绩都大于80的学生：

●统计时可先在表格右侧添加一个显示统计结果的列，然后点击选中该列的列首单元格。

●选中单元格后，在编辑栏中输入“=AND(C4>=80,D4>=80,E4>=80,F4>=80)”，其中的C4、D4、E4、F4为该行中的学生各科考试成绩所在的单元格，>=80为判断条件，即要求考试成绩大于等于80分。如果AND后面的括号中各判断条件都成立，即各科成绩都大于等于80分，则Excel会返回“TRUE” 否则如果有一科或者多科成绩不大于等于80，Excel会返回“FALSE”。

●输入上述函数公式后，按键盘回车键或者点击编辑栏左侧的对号，该单元格中就会显示出计算结果。

●再用下拉填充柄或者选择性粘贴公式的方法在该列的其他单元格中快速填充公式，就会显示出所有学生的判断结果，其中结果为“TRUE”的表示该学生的各科成绩都大于等于80，结果为“FALSE”的表示该学生至少有一科成绩不大于等于80。但这种显示结果不太美观和明了，最好再组合IF函数来显示中文或者其他符号的判断结果。

●我们可以把列首单元格中的公式改成=IF(AND(C4>=80,D4>=80,E4>=80,F4>=80),"是","否")，即如果公式"AND(C4>=80,D4>=80,E4>=80,F4>=80)"的判断结果为“TRUE”，则Excel会显示字符“是”；反之如果判断结果为“FALSE”则Excel会显示字符“否”，这样看起来比英文的“TRUE”和“FALSE”要明了一些。

●这样再下拉填充或者选择性粘贴公式后，该列其他单元格中就都显示出中文的判断结果了。

●我们还可以用对号来表示符合条件，用空白来表示不符合条件。即把上述公式修改为=IF(AND(C4>=80,D4>=80,E4>=80,F4>=80),"√","")。

●这样，符合条件的学生就都会显示对号，不符合条件的学生会显示空白，感觉更加一目了然。

上述例子介绍的只是AND函数和IF函数相组合的一种应用方法，熟练掌握这两种函数的用法后，可以给数据统计带来更多的方便。

经常使用函数的小伙伴们都知道excel if函数是我们工作中经常用到的函数，那么excel if函数怎么实现满足多个条件来使用呢?今天就为大家唠一下excel if函数多个条件的使用方法!希望可以帮助大家更有效的运用在工作当中!那么excel if函数的多个条件实现到底怎么用？我们首先要明白，满足多个条件也可以分两种情况：1)需要多个条件同时满足;2)或者一个、几个或多个条件。我们以下图的数据来举例说明。

首先，利用AND()函数来说明同时满足多个条件。举例：如果A列的文本是“A”并且B列的数据大于210，则在C列标注“Y”。

在C2输入公式：=IF(AND(A2=”A”,B2>210),”Y”,””)知识点说明：AND()函数语法是这样的，AND(条件1=标准1，条件2=标准2……)，每个条件和标准都去判断是否相等，如果等于返回TRUE，否则返回FALSE。只有所有的条件和判断均返回TRUE，也就是所有条件都满足时AND()函数才会返回TRUE。

然后，利用OR()函数来说明只要满足多个条件中的一个或一个以上条件。举例：如果A列的文本是“A”或者B列的数据大于150，则在C列标注“Y”。

在C2单元格输入公式：=IF(OR(A2=”A”,B2>150),”Y”,””)知识点说明：OR()函数语法是这样的：OR(条件1=标准1，条件2=标准2……)，和AND一样，每个条件和标准判断返回TRUE或者FALSE，但是只要所有判断中有一个返回TRUE，OR()函数即返回TRUE。

以上的方法是在单个单元格中进行判断，也可以写成数组公式形式在单个单元格中一次性完成在上述例子中若干个辅助单元格的判断，这样我们就可以随心所欲的对excel if函数的条件设置咱们需要的规则了！

好了，今天的excel if函数不知道各位小伙伴们有没有掌握到呢？如果你有更好的方法也可以在评论区和大家一起交流，谢谢

if函数是 Excel 中的条件判断函数，它由条件与两个返回结果组成，当条件成立时，返回真，否则返回假。if函数中的条件既可以单条件，也可以是多条件；多条件组合有三种方式，一种为多个 if 嵌套，第二种为用 And（或 *）组合多个条件，第三种为用 Or（或 +）组合多个条件。用 And（或 *）组合条件是“与”的关系，用 Or(或 +）组合条件是“或”的关系，它们的写法比 if 嵌套简单。以下就是它们的具体操作方法，实例中操作所用版本均为 Excel 2016。

一、Excel if函数语法

1、表达式：IF（logical_test,[value_if_true],[value_if_false])

中文表达式：如果（条件，条件为真时执行的操作，条件为假时执行的操作）

2、说明：[value_if_true] 和 [value_if_false] 表示可选项，即它们可以不写，如图1所示：

按回车，返回 False，因为 E2 为 435，F2 为 528，E2 > F2 不成立，如图2所示：

另外，=IF(3 > 2,)，返回 0，此处 0 表示假。

二、Excel if函数单条件使用方法

1、一个服装销量表中，价格为0的表示已下架，否则表示正在出售，假如要把它们分别用“下架”和“出售中”标识出来，操作过程步骤，如图3所示：

2、操作过程步骤说明：选中 H2 单元格，输入公式 =IF(E2<=0,"下架","出售中")，按回车，则返回“出售中”；把鼠标移到 H2 右下角的单元格填充柄上，按住左键并往下拖，则所经过单元格全填充为“出售中”，按 Ctrl + S 保存，则价格为 0 的单元格用“下架”填充，其它单元格用“出售中”填充。

3、公式说明：公式 =IF(E2<=0,"下架","出售中") 中，E2<=0 为条件，当条件为真时，返回“下架”，否同返回“出售中”。

三、Excel if函数嵌套多条件使用方法

1、假如要标出服装销量表中，“大类”为“女装”、“价格”大于等于 80 且“销量”大于 800 的服装，操作过程步骤，如图4所示：

2、操作过程步骤说明：选中 H2 单元格，把公式 =IF(C2="女装",IF(E2>=80,IF(F2>800,"满足条件","不满足条件"),"不满足条件"),"不满足条件") 复制到 H2，按回车，则返回“不满足条件”；再次选中 H2，把鼠标移到 H2 的单元格填充柄上，按住左键并往下拖，则所经过单元格用“不满足条件”填充，按 Ctrl + S 保存，同样 H3 用“满足条件”填充，其它单元格仍用“不满足条件”填充。

3、公式说明：

=IF(C2="女装",IF(E2>=80,IF(F2>800,"满足条件","不满足条件"),"不满足条件"),"不满足条件")

由三个 if 组成，即在一个 if 中嵌套了两个 if。第一个 if 的条件为 C2="女装"，如果条件为真，则执行 IF(E2>=80,IF(F2>800,"满足条件","不满足条件"),"不满足条件")；否则返回“不满足条件”。第二个 if 的条件为 E2>=80，如果条件为真，则执行 IF(F2>800,"满足条件","不满足条件")，否则返回“不满足条件”。第三个 if 的条件为 F2>800，如果条件为真，返回“满足条件”，否则返回“不满足条件”。

提示：if 最多只能嵌套 64 个 if，尽管如此，在写公式过程中，尽量少嵌套 if；一方面便于阅读与修改，另一方面执行效率也高一些。

四、Excel if函数用 And 与 OR 组合多个条件使用方法

（一）用 And 组合多个条件，为“与”的关系

1、把上例中的多 if 嵌套公式 =IF(C2="女装",IF(E2>=80,IF(F2>800,"满足条件","不满足条件"),"不满足条件"),"不满足条件") 改为用 And 组合，操作过程步骤，如图5所示：

2、操作过程步骤说明：选中 H2 单元格，把公式 =IF(AND(C2="女装",E2>=80,F2>800),"满足条件","不满足条件") 复制到 H2，按回车，则返回“不满足条件”；同样往下拖并保存，返回跟上例一样的结果，说明公式正确。

3、公式说明：

=IF(AND(C2="女装",E2>=80,F2>800),"满足条件","不满足条件")

公式用 And 函数组合了三个条件，分别为 C2="女装",E2>=80,F2>800，当同时满足三个条件时（即 AND(C2="女装",E2>=80,F2>800) 返回“真”），返回“满足条件”，否则返回“不满足条件”。

4、用 * 代替 And

A、把公式　　=IF(AND(C2="女装",E2>=80,F2>800),"满足条件","不满足条件")

用 * 代替 And 后变为：

=IF((C2="女装")*(E2>=80)*(F2>800),"满足条件","不满足条件")

如图6所示：

B、按回车，返回“不满足条件”，往下拖保存后，也是返回一样的结果。

（二）用 Or 组合多个条件，为“或”的关系

1、把上例中的 And 组合多个条件公式 =IF(AND(C2="女装",E2>=80,F2>800),"满足条件","不满足条件") 改为用 Or 组合，操作过程步骤，如图7所示：

2、操作过程步骤说明：选中 H2 单元格，把公式 =IF(OR(C2="女装",E2>=80,F2>800),"满足条件","不满足条件") 复制到 H2，按回车，则返回“满足条件”；同样往下拖并保存，全部返回“满足条件”。

3、公式说明：

=IF(OR(C2="女装",E2>=80,F2>800),"满足条件","不满足条件")

公式用 Or 函数组合了三个条件，分别为 C2="女装",E2>=80,F2>800，即 OR(C2="女装",E2>=80,F2>800)，意思是：只要满足一个条件，就返回“真”；一条件都不满足才返回“假”。演示中，每条记录都满足一个条件，所以全返回“满足条件”。

4、用 + 代替 Or

A、把公式

=IF(OR(C2="女装",E2>=80,F2>800),"满足条件","不满足条件")

用 + 代替 Or 后变为：

=IF((C2="女装")+(E2>=80)+(F2>800),"满足条件","不满足条件")

如图8所示：

B、按回车，返回“满足条件”，往下拖保存后，也是全部返回“满足条件”，说明公式正确。