下拉列表，使用起来非常的方便，不仅提高了工作效率，还规范了数据的输入。但是，该如何去制作了？Word中和Excel中的制作方法一样吗？

一、Excel中下拉列表制作方法。

目的：制作下拉列表。

方法1：

步骤：

1、选定目标单元格。

2、【数据】-【数据验证】，选择【允许】中的【序列】，在【来源】中输入：男,女。

3、【确定】。

备注：

【来源】中输入的值一定要用英文状态下的逗号隔开。

方法2：

步骤：

1、选定目标单元格。

2、【数据】-【数据验证】，选择【允许】中的【序列】，单击【来源】右侧的箭头，选取需要下拉显示的数据并【确定】。

二、WORD中下拉列表制作方法。

方法：

1、选定目标单元格。

2、【开发工具】-【下拉列表内容控件】-【属性】-【添加】，输入某一个值-【确定】。重复【添加】之后的动作，直到需要的值全部显示之后【确定】。

3、验证数据。

小编今天给大家介绍4个常用的Excel函数公式，让你摆脱不会使用Excel统计函数的烦恼。

1.条件求和公式

我们来求所有服务员的金额总和

我们在条件求和输入公式：=SUMPRODUCT((C2:C11="服务员")*(D2:D11))

回车我们这样就可以计算出所有服务员金额总和。具体操作如下图所示：

2. 对数据进行排序

考试成绩出来了，老师想要将这些成绩进行一个排名，我们应该怎么去做呢？

方法：1.我们只用一个函数公式就可以轻松解决。我们在名次下方输入公式：=RANK(A2,$A$2:$A$28)，如图

2.然后选中B2单元格，将鼠标放在右下角，鼠标变成小十字的时候，按下鼠标左键不放，往下拉到B28单元格，这样所有分数的排名就显示出来了。具体操作如下图所示：

3. 计算数据合

老师在录入每个学生各科成绩之后，肯定会将各科成绩做一个综合，那么，在Excel中，有什么方法可以快速录入学生各科成绩总和呢？

方法：输入函数公式：=SUM(B2:F2)即可，具体如下图所示：

4.计算出男生女生在表格中的语文成绩平均分

老师想看看班上男生女生在语文成绩上的平均分，应该怎么做呢？

方法：输入Excel函数：=AVERAGEIF(B2:B28,"男",C2:C28)

我们会使用Excel函数公式制作一些财务报表，考勤表等等一系列报表，但是利用函数公式制作起来太麻烦了，我们可以选择套用模板，“办公资源网”中就有着丰富的Excel模板资源，要选择套用模板的朋友可以选择到“办公资源网”去看看。

好了，分享就到这里啦~要想了解更多Excel函数公式的小伙伴，可以私信“Excel函数公式”，下期小编就会出不一样的函数公式。

Excel表格中 符号 大全 汇总

一、公式中常用符号

： 表示一个单元格区域，如A1:B10+ - * / 加减乘除运算符> 大于号>= 大于等于号< 小于号<= 小于等于号<> 不等于号，如=IF(A1<>"销售部",,)^数字 乘方运算，如2^3结果8。^(1/数字) 开方运算 8^(1/3)结果为2& 文本连续符，如 "A"& 1 结果为 A1* 通配符 表示任意字符多个字符? 通配符，表示单个任意字符{数字} 常量数组{公式} 数组公式标志，在公式后按Ctrl + shift + Enter后在公式两端自动添加的。$ 绝对引用符号，可以在复制公式时防止行号或列标发生变动，如A&1公式向下复制时，1不会变成2,3..如果不加$则会变化！ 工作表和单元格的隶属关于，如表格sheet1的单元格A1,表示为 Sheet1!A1

二、自定义格式中的符号

0 单个数字占位符，如果0的位数大于数字个数，会用0补齐，如123设置格式00000, 会显示成 00123# 单个数字占位符，和0区别是不会补位! 强制显示它后面的字符\ 作用同 ![ ] 设置条件，如 [>100][红色] 大于100的数字显示红色yyyy 4位年d 日m 月aaa 星期代码，只显示大写数字aaaa 星期代码，显示星期+大写数字ddd 星期代码，英文简写dddd 星期代码，英文全称mmm 英文短月份mmmm 英文月份完整单词h 小时[h] 显示大于24小时的数字m 分种s 秒* 用*后的字符补齐位置，让字符长度填满单元格_ 添加一个空格和_后的字符宽度相等@ 文本占位符，可以显示单元格的文本内容，如爱你 设置@@后可以显示为爱你爱你

Excel解释说明：想整理Excel中常用符号的想法来由来以久，由于lan一直没动手，可左等右等几还不见网上有动静，所以必须要动手了，同学们收藏备用吧。

相对于高大上的函数公式技巧，在实际的工作中，我们经常使用的反倒是一些常见的函数公式，如果能对常用的函数公式了如指掌，对工作效率的提高绝对不止一点……

一、条件判断：IF函数。

目的：判断成绩所属的等次。

方法：

1、选定目标单元格。

2、在目标单元格中输入公式：=IF(C3>=90,"优秀",IF(C3>=80,"良好",IF(C3>=60,"及格","不及格")))。

3、Ctrl+Enter填充。

解读：

IF函数是条件判断函数，根据判断结果返回对应的值，如果判断条件为TRUE，则返回第一个参数，如果为FALSE，则返回第二个参数。

二、条件求和：SUMIF、SUMIFS函数。

目的：求男生的总成绩和男生中分数大于等于80分的总成绩。

方法：

1、在对应的目标单元格中输入公式：=SUMIF(D3:D9,"男",C3:C9)或=SUMIFS(C3:C9,C3:C9,">=80",D3:D9,"男")。

解读：

1、SUMIF函数用于单条件求和。暨求和条件只能有一个。易解语法结构为：SUMIF（条件范围，条件，求和范围）。

2、SUMIFS函数用于多条件求和。暨求和条件可以有多个。易解语法结构：SUMIFS（求和范围，条件1范围，条件1，条件2范围，条件2,……条件N范围，条件N）。

三、条件计数：COUNTIF、COUNTIFS函数。

目的：计算男生的人数或男生中成绩>=80分的人数。

方法：

1、在对应的目标单元格中输入公式：=COUNTIF(D3:D9,"男")或=COUNTIFS(D3:D9,"男",C3:C9,">=80")。

解读：

1、COUNTIF函数用于单条件计数，暨计数条件只能有一个。易解语法结构为：COUNTIF(条件范围，条件).

2、COUNTIFS函数用于多条件计数，暨计数条件可以有多个。易解语法结构为：COUNTIFS（条件范围1，条件1，条件范围2，条件2……条件范围N，条件N）。

四、数据查询：VLOOKUP函数。

目的：查询相关人员对应的成绩。

方法：

在目标单元格中输入公式：=VLOOKUP(H3,B3:C9,2,0)。

解读：

函数VLOOKUP的基本功能就是数据查询。易解语法结构为：VLOOKUP（查找的值，查找范围，找查找范围中的第几列，精准匹配还是模糊匹配）。

五、逆向查询：LOOKUP函数。

目的：根据学生姓名查询对应的学号。

方法：

在目标单元格中输入公式：=LOOKUP(1,0/(B3:B9=H3),A3:A9)。

解读：

公式LOOKUP函数的语法结构为：LOOKUP（查找的值，查找的条件，返回值的范围）。本示例中使用的位变异用法。查找的值为1，条件为0。根据LOOKUP函数的特点，如果 LOOKUP函数找不到 lookup_value，则该函数会与 lookup_vector 中小于或等于 lookup_value 的最大值进行匹配。

六、查询好搭档：INDEX+MATCH 函数

目的：根据姓名查询对应的等次。

方法：

在目标单元格中输入公式：=INDEX(E3:E9,MATCH(H3,B3:B9,0))。

解读：

1、INDEX函数：返回给定范围内行列交叉处的值。

2、MATCH函数：给出指定值在指定范围内的所在位置。

3、公式：=INDEX(E3:E9,MATCH(H3,B3:B9,0))，查询E3:E9中第MATCH(H3,B3:B9,0)行的值，并返回。

七、提取出生年月：TEXT+MID函数。

目的：从指定的身份证号码中提取出去年月。

方法：

1、选定目标单元格。

2、输入公式：=TEXT(MID(C3,7,8),"00-00-00")。

3、Ctrl+Enter填充。

解读：

1、利用MID函数从C3单元格中提取从第7个开始，长度为8的字符串。

2、利用TEXT函数将字符的格式转换为“00-00-00”的格式，暨1965-08-21。

八、计算年龄：DATEDIF函数。

目的：根据给出的身份证号计算出对应的年龄。

方法：

1、选定目标单元格。

2、输入公式：=DATEDIF(TEXT(MID(C3,7,8),"00-00-00"),TODAY(),"y")&"周岁"。

3、Ctrl+Enter填充。

解读：

1、利用MID获取C3单元格中从第7个开始，长度为8的字符串。

2、用Text函数将字符串转换为：00-00-00的格式。暨1965-08-21。

3、利用DATEDIF函数计算出和当前日期（TODAY（））的相差年份（y）。

九、中国式排名：SUMPRODUCT+COUNTIF函数。

目的：对成绩进行排名。

方法：

1、选定目标单元格。

2、在目标单元格中输入公式：=SUMPRODUCT((C$3:C$9>C3)/COUNTIF(C$3:C$9,C$3:C$9))+1。

3、Ctrl+Enter填充。

解读：公式的前半部分(C$3:C$9>C3)返回的是一个数组，区域C$3:C$9中大于C3的单元格个数。后半部分COUNTIF(C$3:C$9,C$3:C$9)可以理解为：*1/COUNTIF(C$3:C$9,C$3:C$9),公式COUNTIF(C$3:C$9,C$3:C$9)返回的值为1，只是用于辅助计算。所以上述公式也可以简化为：=SUMPRODUCT((C$3:C$9>C3)*1)+1。

最近收到在某快递上班的周同学问题求助，主要是在计算包裹的体积时遇到了些麻烦事。

下表是周同学近期整理的快递包裹尺寸数据，其中重要一项工作就是通过长*宽*高来计算出包裹的体积。

周同学表示其实自己也能做出来，只不过是方法比较笨拙原始。

一、分列数据计算体积

周同学自己使用的方式是分列，由于长宽高 3个数字均由星号隔开，所以使用分列的方式将数字分别放置在三个单元格中即可完成计算体积。

操作步骤

1、选中G列数据后单击【数据】选项卡中的【分列】

2、出现分列向导对话框，我们一共需要3步完成数据分列。第一步是选择分列的方式：【分隔符号】、【固定宽度】，周同学的表中有星号分隔数据，可以使用分隔符号分列，所以我们选择【分隔符号】后单击【确定】。

注：【分隔符号】方式分列主要运用于有明显字符隔开的情况，【固定宽度】主要运用于无字符隔开或者无明显规律的情况手工设置分列字符的宽度。

3、单击【下一步】进入文本分列向导第二步，在这里我们可以选择分隔符号，可以是TAB键、分号、逗号、空格、其他自定义。由于默认选项中没有星号，所以我们勾选其他，然后输入星号即可。

当输入完成后，下方数据预览可以看到数据中的星号字符变成了竖线，已经完成了分列。

4、单击【下一步】，列数据格式为常规，直接单击【完成】即可。

此时出现提示：此处已有数据。是否替换它？

由于分列前G列内容包含长宽高尺寸数据，分列后，G列被替换成“长”。

直接单击【确定】，可看到分列结果。

5、根据长宽高轻松计算出包裹体积。

周同学觉得这样还不是最好的方案，因为表格列数是固定的，而且数据都已经和其他表格相互关联，分列数据后插入了2个新列，那数据岂不是都乱了吗？

二、提取数字计算体积

我们来试试用文本函数来解决。（前方高能，这里只需要了解一下就可以了，主要是为了突出第三种方式的简单）

既然我们要计算包裹的体积，那么我们只需要将G列中的长宽高数据分别提取出来然后相乘即可。

提取长度数据：

函数公式：

=LEFT(G2,FIND("*",G2,1)-1)

提取宽度数据：

函数公式：

=MID(G2,FIND("*",G2,1)+1,FIND("-",SUBSTITUTE(G2,"*","-",2))-1-FIND("*",G2,1))

提取高度数据：

函数公式：

=RIGHT(G2,LEN(G2)-FIND("-",SUBSTITUTE(G2,"*","-",2),1))

最后我们将3个函数公式合并嵌套统计得出包裹的体积。

好了，我知道上方的函数公式太复杂，大家都不想学，所以也没给大家做过多的函数解析，简单粗暴，下面给大家隆重推荐一个最简单的方法：宏表函数。

三、EVALUATE函数计算体积

首先我们了解一下EVALUATE的含义，其实EVALUATE是宏表函数，宏表函数又称为Excel4.0版函数，需要通过定义名称(并启用宏)或在宏表中使用，其中多数函数功能已逐步被内置函数和VBA功能所替代，但是你一分钟学不会VBA，却可以学会宏表函数。

下面我们开始操作演示：

1、选中G列，单击【公式】选项中的【名称管理器】

弹出如下所示对话框：

2、单击【新建】，在【新建名称】对话框中输入名称为TJ，应用位置输入函数公式

=EVALUATE(Sheet1!$G$2:$G$44)/1000/1000( 备注：由于之前单位是厘米，我要将统计结果转化为立方米，所以需要除1000000)后单击【确定】。最后关闭名称管理器。

公式解析：

由于G列数据是长*宽*高，*在excel中就是乘法的意思，G列的数据本身就可以看作一个公式，我们只需要得到这个公式结果就可以啦，而EVALUATE的功能就是得到单元格内公式的值，所以在上图中，大家会发现，EVALUATE函数中的参数就只有一个数据区域。

3、见证奇迹的时刻到了。在H2单元格中输入TJ两个字母就能快速得到体积信息啦！

这种即简单又快捷还不用辅助列的方式是不是很棒！简直是3全其美！周同学的问题终于有了完美的解决方案。

说真的，大家有没有发现宏表函数在解决很多问题的时候都非常简单快捷？这篇文章只是一个引子，下次文章将给大家专门介绍宏表函数！

＊＊＊＊部落窝教育－excel宏表函数＊＊＊＊

原创：龚春光/部落窝教育（未经同意，请勿转载）

批量输入公式批量修改公式快速查找公式显示公式部分计算结果保护公式隐藏公式显示所有公式把公式转换为数值显示另一个单元格的公式把表达式转换为计算结果快速查找公式错误原因

1批量输入公式

选取要输入的区域，在编辑栏中输入公式，按CTRL+ENTER即可批量填充公式。

2批量修改公式

如果是修改公式中的相同部分，可以直接用替换功能即可。

3快速查找公式

选取表格区域 - 按Ctrl+g打开定位窗口 - 定位条件 - 公式，即可选取表中所有的公式

4显示公式部分计算结果

选取公式中的要显示的部分表达式，按F9键

按F9键后的结果

想恢复公式，按esc退出编辑状态即可。

5保护公式

选取非公式的填写区域，取消单元格锁定。公式区域不必操作。

设置单元格格式后，还需要保护工作表：审阅 - 保护工作表。

6隐藏公式

隐藏公式和保护公式多了一步：选取公式所在单元格区域，设置单元格格式 - 保护 - 勾选“隐藏” - 保护工作表。

隐藏公式效果：

7显示所有公式

需要查看表中都设置了哪些公式时，你只需按alt+~组合键（或 公式选项卡 - 显示公式）

把公式转换为数值

8把公式转换为数值

公式转换数值一般方法，复制 - 右键菜单上点123（值）

9显示另一个单元格的公式

如果想在B列显示A列的公式，可以通过定义名称来实现。

公式 - 名称管理器 - 新建名称：G =get.cell(6,sheet3!a4)

在B列输入公式=G，即可显示A列的公式。

excel2013中新增了FORMULATEXT函数，可以直接获取公式文本。

10把表达式转换为计算结果

方法同上，只需要定义一个转换的名称即可。

zhi =Evaluate(b2)

在B列输入公式 =zhi即可把B列表达式转换为值

11快速查找公式错误原因

当一个很长的公式返回错误值，很多新手会手足无措，不知道哪里出错了。兰色介绍排查公式错误的技巧，3秒就可以找到错误。

下面兰色做了一个简单的小例子

【例】：如下图所示，单元格的公式返回值错误。要求排查出公式的哪部分出现了错误。

操作方法：

1、 打开单元格左上角绿三角，点“显示计算步骤”

2、在打开的“公式求值”窗口中，求值会自动停在即将出错的位置。这时通过和编辑栏中的公式比对，就可以找出产生错误的单元格。（D7）

如果公式中有多处错误，可以先修正前一次，然后再点显示计算步骤，查找下一处错误。

1、取绝对值

=ABS(数字)

2、取整

=INT(数字)

3、四舍五入

=ROUND(数字,小数位数)

二、判断公式

1、把公式产生的错误值显示为空

公式：C2

=IFERROR(A2/B2,"")

说明：如果是错误值则显示为空，否则正常显示。

2、IF多条件判断返回值

公式：C2

=IF(AND(A2<500,B2="未到期"),"补款","")

说明：两个条件同时成立用AND,任一个成立用OR函数。

三、统计公式

1、统计两个表格重复的内容

公式:B2

=COUNTIF(Sheet15!A:A,A2)

说明：如果返回值大于0说明在另一个表中存在，0则不存在。

2、统计不重复的总人数

公式：C2

=SUMPRODUCT(1/COUNTIF(A2:A8,A2:A8))

说明:用COUNTIF统计出每人的出现次数，用1除的方式把出现次数变成分母，然后相加。

四、求和公式

1、隔列求和

公式：H3

=SUMIF($A$2:$G$2,H$2,A3:G3)

或

=SUMPRODUCT((MOD(COLUMN(B3:G3),2)=0)*B3:G3)

说明：如果标题行没有规则用第2个公式

2、单条件求和

公式：F2

=SUMIF(A:A,E2,C:C)

说明：SUMIF函数的基本用法

3、单条件模糊求和

公式：详见下图

说明：如果需要进行模糊求和，就需要掌握通配符的使用，其中星号是表示任意多个字符，如"*A*"就表示a前和后有任意多个字符，即包含A。

4、多条件模糊求和

公式：C11

=SUMIFS(C2:C7,A2:A7,A11&"*",B2:B7,B11)

说明：在sumifs中可以使用通配符*

5、多表相同位置求和

公式：b2

=SUM(Sheet1:Sheet19!B2)

说明：在表中间删除或添加表后，公式结果会自动更新。

6、按日期和产品求和

公式：F2

=SUMPRODUCT((MONTH($A$2:$A$25)=F$1)*($B$2:$B$25=$E2)*$C$2:$C$25)

说明：SUMPRODUCT可以完成多条件求和

五、查找与引用公式

1、单条件查找公式

公式1：C11

=VLOOKUP(B11,B3:F7,4,FALSE)

说明：查找是VLOOKUP最擅长的，基本用法

2、双向查找公式

公式：

=INDEX(C3:H7,MATCH(B10,B3:B7,0),MATCH(C10,C2:H2,0))

说明：利用MATCH函数查找位置，用INDEX函数取值

3、查找最后一条符合条件的记录。

公式：详见下图

说明：0/(条件)可以把不符合条件的变成错误值，而lookup可以忽略错误值

4、多条件查找

公式:详见下图

说明:公式原理同上一个公式

5、指定区域最后一个非空值查找

公式;详见下图

说明：略

6、按数字区域间取对应的值

公式：详见下图

公式说明：VLOOKUP和LOOKUP函数都可以按区间取值，一定要注意，销售量列的数字一定要升序排列。

六、字符串处理公式

1、多单元格字符串合并

公式：c2

=PHONETIC(A2:A7)

说明：Phonetic函数只能对字符型内容合并，数字不可以。

2、截取除后3位之外的部分

公式：

=LEFT(D1,LEN(D1)-3)

说明：LEN计算出总长度,LEFT从左边截总长度-3个

3、截取-前的部分

公式:B2

=Left(A1,FIND("-",A1)-1)

说明：用FIND函数查找位置，用LEFT截取。

4、截取字符串中任一段的公式

公式:B1

=TRIM(MID(SUBSTITUTE($A1," ",REPT(" ",20)),20,20))

说明:公式是利用强插N个空字符的方式进行截取

5、字符串查找

公式：B2

=IF(COUNT(FIND("河南",A2))=0,"否","是")

说明: FIND查找成功，返回字符的位置，否则返回错误值，而COUNT可以统计出数字的个数，这里可以用来判断查找是否成功。

6、字符串查找一对多

公式：B2

=IF(COUNT(FIND({"辽宁","黑龙江","吉林"},A2))=0,"其他","东北")

说明：设置FIND第一个参数为常量数组，用COUNT函数统计FIND查找结果

七、日期计算公式

1、两日期相隔的年、月、天数计算

A1是开始日期（2011-12-1），B1是结束日期(2013-6-10)。计算：

相隔多少天？=datedif(A1,B1,"d") 结果：557

相隔多少月? =datedif(A1,B1,"m") 结果：18

相隔多少年? =datedif(A1,B1,"Y") 结果：1

不考虑年相隔多少月？=datedif(A1,B1,"Ym") 结果：6

不考虑年相隔多少天？=datedif(A1,B1,"YD") 结果：192

不考虑年月相隔多少天？=datedif(A1,B1,"MD") 结果：9

datedif函数第3个参数说明：

"Y" 时间段中的整年数。

"M" 时间段中的整月数。

"D" 时间段中的天数。

"MD" 天数的差。忽略日期中的月和年。

"YM" 月数的差。忽略日期中的日和年。

"YD" 天数的差。忽略日期中的年。

2、扣除周末天数的工作日天数

公式：C2

=NETWORKDAYS.INTL(IF(B2

说明：返回两个日期之间的所有工作日数，使用参数指示哪些天是周末，以及有多少天是周末。周末和任何指定为假期的日期不被视为工作日

在HR同事电脑中，经常看到海量的Excel表格，员工基本信息、提成计算、考勤统计、合同管理....看来再完备的HR系统也取代不了Excel表格的作用。一周前，交给小助理木炭一个任务，尽可能多的收集HR工作中的Excel公式。进行了整理编排，于是有了这篇本平台史上最全HR的Excel公式+数据分析技巧集。

一、员工信息表公式

1、计算性别(F列)

=IF(MOD(MID(E3,17,1),2),"男","女")

2、出生年月(G列)

=TEXT(MID(E3,7,8),"0-00-00")

3、年龄公式(H列)

=DATEDIF(G3,TODAY(),"y")

4、退休日期 (I列)

=TEXT(EDATE(G3,12*(5*(F3="男")+55)),"yyyy/mm/dd aaaa")

5、籍贯(M列)

=VLOOKUP(LEFT(E3,6)*1,地址库!E:F,2,)

注：附带示例中有地址库代码表

6、社会工龄(T列)

=DATEDIF(S3,NOW(),"y")

7、公司工龄(W列)

=DATEDIF(V3,NOW(),"y")&"年"&DATEDIF(V3,NOW(),"ym")&"月"&DATEDIF(V3,NOW(),"md")&"天"

8、合同续签日期(Y列)

=DATE(YEAR(V3)+LEFTB(X3,2),MONTH(V3),DAY(V3))-1

9、合同到期日期(Z列)

=TEXT(EDATE(V3,LEFTB(X3,2)*12)-TODAY(),"[<0]过期0天;[<30]即将到期0天;还早")

10、工龄工资(AA列)

=MIN(700,DATEDIF($V3,NOW(),"y")*50)

11、生肖(AB列)

=MID("猴鸡狗猪鼠牛虎兔龙蛇马羊",MOD(MID(E3,7,4),12)+1,1)

二、员工考勤表公式

1、本月工作日天数(AG列)

=NETWORKDAYS(B$5,DATE(YEAR(N$4),MONTH(N$4)+1,),)

2、调休天数公式(AI列)

=COUNTIF(B9:AE9,"调")

3、扣钱公式(AO列)

婚丧扣10块，病假扣20元，事假扣30元，矿工扣50元

=SUM((B9:AE9={"事";"旷";"病";"丧";"婚"})*{30;50;20;10;10})

四、员工数据分析公式

1、本科学历人数

=COUNTIF(D:D,"本科")

2、办公室本科学历人数

=COUNTIFS(A:A,"办公室",D:D,"本科")

3、30~40岁总人数

=COUNTIFS(F:F,">=30",F:F,"<40")

五、其他公式

1、提成比率计算

=VLOOKUP(B3,$C$12:$E$21,3)

2、个人所得税计算

假如A2中是应税工资，则计算个税公式为：

=5*MAX(A2*{0.6,2,4,5,6,7,9}%-{21,91,251,376,761,1346,3016},)

3、工资条公式

=CHOOSE(MOD(ROW(A3),3)+1,工资数据源!A$1,OFFSET(工资数据源!A$1,INT(ROW(A3)/3),,),"")

注：

A3:标题行的行数+2,如果标题行在第3行，则A3改为A5

工资数据源!A$1:工资表的标题行的第一列位置

4、Countif函数统计身份证号码出错的解决方法

由于Excel中数字只能识别15位内的，在Countif统计时也只会统计前15位，所以很容易出错。不过只需要用 &"*" 转换为文本型即可正确统计。

=Countif(A:A,A2&"*")

六、利用数据透视表完成数据分析

1、各部门人数占比

统计每个部门占总人数的百分比

2、各个年龄段人数和占比

公司员工各个年龄段的人数和占比各是多少呢？

3、各个部门各年龄段占比

分部门统计本部门各个年龄段的占比情况

4、各部门学历统计

各部门大专、本科、硕士和博士各有多少人呢？

5、按年份统计各部门入职人数

每年各部门入职人数情况

附：HR工作中常用分析公式

1.【新进员工比率】＝已转正员工数/在职总人数

2.【补充员工比率】＝为离职缺口补充的人数/在职总人数

3.【离职率】（主动离职率/淘汰率＝离职人数/在职总人数=离职人数/(期初人数+录用人数)×100％

4.【异动率】＝异动人数/在职总人数

5.【人事费用率】＝（人均人工成本*总人数）/同期销售收入总数

6.【招聘达成率】=（报到人数+待报到人数）/（计划增补人数+临时增补人数）

7.【人员编制管控率】=每月编制人数/在职人数

8.【人员流动率】=（员工进入率+离职率）/2

9.【离职率】=离职人数/（（期初人数+期末人数）/2）

10.【员工进入率】=报到人数/期初人数

11.【关键人才流失率】=一定周期内流失的关键人才数/公司关键人才总数

12.【工资增加率】=（本期员工平均工资—上期员工平均工资）/上期员工平均工资

13.【人力资源培训完成率】=周期内人力资源培训次数/计划总次数

14.【部门员工出勤情况】=部门员工出勤人数/部门员工总数

15.【薪酬总量控制的有效性】=一定周期内实际发放的薪酬总额/计划预算总额

16.【人才引进完成率】=一定周期实际引进人才总数/计划引进人才总数

17.【录用比】=录用人数/应聘人数*100%

18.【员工增加率】 =（本期员工数—上期员工数）/上期员工数

【好东西记得分享哦！！！】

【好东西记得分享哦！！！】

【好东西记得分享哦！！！】

上午好，伙伴们！丢掉Excel帮助文件，跟小编一起轻松学常用的十大Excel函数。

一、IF函数

作用：条件判断，根据判断结果返回值。

用法：IF(条件,条件符合时返回的值，条件不符合时返回的值)

案例：假如国庆节放假7天，我就去旅游，否则就宅在家。

=IF(A1=7,"旅游","宅在家")，因为A1单元格是3，只放假3天，所以返回第二参数，宅在家。

二、时间函数

TODAY函数返回日期。NOW函数返回日期和时间。比如要获取今天的日期，可以输入：=TODAY()，要获取日期时间，可以输入：=NOW()

计算部落窝教育EXCEL贯通班上线多少天了，可以使用：=TODAY()-开始日期

三、最大值函数

excel最大值函数常见的有两个，分别是Max函数和Large函数。

案例：分别取出产品A、产品B、产品C在2015年6月1日-6月10日的最大产量。

在B12单元格输入公式：=Max(B2:B11)，然后向右拖动复制得到产品B和产品C的最大产量。前面我们说了excel取最大值函数有MAX函数和Large函数，那么Large函数一样可以做到，公式为=Large(B2:B11,1)。

Max函数只取最大值，而large函数会按顺序选择大，比如第一大的、第二大的、第三大的。

四、条件求和：SUMIF函数

作用：根据指定的条件汇总。

用法：=SUMIF(条件范围,要求,汇总区域)

SUMIF的第三个参数可以忽略，第三个参数忽略的时候，第一个参数应用条件判断的单元格区域就会用来作为需要求和的区域。

五、条件计数

说到Excel条件计数，下面几个函数伙伴们需要了解一下。

COUNT函数：数字控，只要是数字，包含日期时间也算是数值，都统计个数。

案例：A1：B6区域，用count函数统计出的数字单元格个数为4。日期和时间也是属于数字，日期和时间就是特殊的数字序列。

COUNTA函数（COUNT+A）：统计所有非空单元格个数。

输入公式=COUNTA(A1:C5)，返回6，也就是6个单元格有内容。

COUNTIF函数（COUNT+IF）：统计符合条件的单元格个数。

语法：=countif（统计的区域，“条件”）

统计男性有多少人：=COUNTIF(B2:B8,"男")

六、查找函数

VLOOKUP(查找值,查找区域,返回查找区域的第几列,精确还是模糊查找)

E4单元格输入公式：=VLOOKUP(E2,A:B,2,)

我们都知道excel函数公式很强大，运用好了对我们制表很有帮助，但是excel函数公式实在是太多了，根本记不住，下面跟大家分享一些常常会用到的函数公式。

一、对于数字的处理：

1、取绝对值

=ABS(数字)

2、取整

=INT(数字)

3、四舍五入

=ROUND(数字,小数位数)

二、统计公式：

1、统计两个表格重复的内容

公式:B2

=COUNTIF(Sheet15!A:A,A2)

说明：如果返回值大于0说明在另一个表中存在，0则不存在。

2、统计不重复的总人数

公式：C2

=SUMPRODUCT(1/COUNTIF(A2:A8,A2:A8))

说明:用COUNTIF统计出每人的出现次数，用1除的方式把出现次数变成分母，然后相加。

在完成excel表格统计之后，以免后期不小心修改数据，我们可以将excel表格转换成pdf格式。高版本的office可以直接将excel另存为pdf，低版本或者想要批量转换的可以用迅捷pdf转换器来完成转换。

三、求和公式

1、隔列求和

公式：H3

=SUMIF($A$2:$G$2,H$2,A3:G3)

或

=SUMPRODUCT((MOD(COLUMN(B3:G3),2)=0)*B3:G3)

说明：如果标题行没有规则用第2个公式

2、单条件求和

公式：F2

=SUMIF(A:A,E2,C:C)

说明：SUMIF函数的基本用法

3、单条件模糊求和

公式：详见下图

说明：如果需要进行模糊求和，就需要掌握通配符的使用，其中星号是表示任意多个字符，如"*A*"就表示a前和后有任意多个字符，即包含A

4、多条件模糊求和

公式：C11

=SUMIFS(C2:C7,A2:A7,A11&"*",B2:B7,B11)

说明：在sumifs中可以使用通配符*

5、多表相同位置求和

公式：b2

=SUM(Sheet1:Sheet19!B2)

说明：在表中间删除或添加表后，公式结果会自动更新。

6、按日期和产品求和

公式：F2

=SUMPRODUCT((MONTH($A$2:$A$25)=F$1)*($B$2:$B$25=$E2)*$C$2:$C$25)

说明：SUMPRODUCT可以完成多条件求和

好啦，以上就是比较常用的excel公式啦，当然，excel函数公式远远不止这些，但是以上公式如果能熟练应用也会非常提高工作效率哦。