相对于高大上的函数公式技巧，在实际的工作中，我们经常使用的反倒是一些常见的函数公式，如果能对常用的函数公式了如指掌，对工作效率的提高绝对不止一点……

一、条件判断：IF函数。

目的：判断成绩所属的等次。

方法：

1、选定目标单元格。

2、在目标单元格中输入公式：=IF(C3>=90,"优秀",IF(C3>=80,"良好",IF(C3>=60,"及格","不及格")))。

3、Ctrl+Enter填充。

解读：

IF函数是条件判断函数，根据判断结果返回对应的值，如果判断条件为TRUE，则返回第一个参数，如果为FALSE，则返回第二个参数。

二、条件求和：SUMIF、SUMIFS函数。

目的：求男生的总成绩和男生中分数大于等于80分的总成绩。

方法：

1、在对应的目标单元格中输入公式：=SUMIF(D3:D9,"男",C3:C9)或=SUMIFS(C3:C9,C3:C9,">=80",D3:D9,"男")。

解读：

1、SUMIF函数用于单条件求和。暨求和条件只能有一个。易解语法结构为：SUMIF（条件范围，条件，求和范围）。

2、SUMIFS函数用于多条件求和。暨求和条件可以有多个。易解语法结构：SUMIFS（求和范围，条件1范围，条件1，条件2范围，条件2,……条件N范围，条件N）。

三、条件计数：COUNTIF、COUNTIFS函数。

目的：计算男生的人数或男生中成绩>=80分的人数。

方法：

1、在对应的目标单元格中输入公式：=COUNTIF(D3:D9,"男")或=COUNTIFS(D3:D9,"男",C3:C9,">=80")。

解读：

1、COUNTIF函数用于单条件计数，暨计数条件只能有一个。易解语法结构为：COUNTIF(条件范围，条件).

2、COUNTIFS函数用于多条件计数，暨计数条件可以有多个。易解语法结构为：COUNTIFS（条件范围1，条件1，条件范围2，条件2……条件范围N，条件N）。

四、数据查询：VLOOKUP函数。

目的：查询相关人员对应的成绩。

方法：

在目标单元格中输入公式：=VLOOKUP(H3,B3:C9,2,0)。

解读：

函数VLOOKUP的基本功能就是数据查询。易解语法结构为：VLOOKUP（查找的值，查找范围，找查找范围中的第几列，精准匹配还是模糊匹配）。

五、逆向查询：LOOKUP函数。

目的：根据学生姓名查询对应的学号。

方法：

在目标单元格中输入公式：=LOOKUP(1,0/(B3:B9=H3),A3:A9)。

解读：

公式LOOKUP函数的语法结构为：LOOKUP（查找的值，查找的条件，返回值的范围）。本示例中使用的位变异用法。查找的值为1，条件为0。根据LOOKUP函数的特点，如果 LOOKUP函数找不到 lookup_value，则该函数会与 lookup_vector 中小于或等于 lookup_value 的最大值进行匹配。

六、查询好搭档：INDEX+MATCH 函数

目的：根据姓名查询对应的等次。

方法：

在目标单元格中输入公式：=INDEX(E3:E9,MATCH(H3,B3:B9,0))。

解读：

1、INDEX函数：返回给定范围内行列交叉处的值。

2、MATCH函数：给出指定值在指定范围内的所在位置。

3、公式：=INDEX(E3:E9,MATCH(H3,B3:B9,0))，查询E3:E9中第MATCH(H3,B3:B9,0)行的值，并返回。

七、提取出生年月：TEXT+MID函数。

目的：从指定的身份证号码中提取出去年月。

方法：

1、选定目标单元格。

2、输入公式：=TEXT(MID(C3,7,8),"00-00-00")。

3、Ctrl+Enter填充。

解读：

1、利用MID函数从C3单元格中提取从第7个开始，长度为8的字符串。

2、利用TEXT函数将字符的格式转换为“00-00-00”的格式，暨1965-08-21。

八、计算年龄：DATEDIF函数。

目的：根据给出的身份证号计算出对应的年龄。

方法：

1、选定目标单元格。

2、输入公式：=DATEDIF(TEXT(MID(C3,7,8),"00-00-00"),TODAY(),"y")&"周岁"。

3、Ctrl+Enter填充。

解读：

1、利用MID获取C3单元格中从第7个开始，长度为8的字符串。

2、用Text函数将字符串转换为：00-00-00的格式。暨1965-08-21。

3、利用DATEDIF函数计算出和当前日期（TODAY（））的相差年份（y）。

九、中国式排名：SUMPRODUCT+COUNTIF函数。

目的：对成绩进行排名。

方法：

1、选定目标单元格。

2、在目标单元格中输入公式：=SUMPRODUCT((C$3:C$9>C3)/COUNTIF(C$3:C$9,C$3:C$9))+1。

3、Ctrl+Enter填充。

解读：公式的前半部分(C$3:C$9>C3)返回的是一个数组，区域C$3:C$9中大于C3的单元格个数。后半部分COUNTIF(C$3:C$9,C$3:C$9)可以理解为：*1/COUNTIF(C$3:C$9,C$3:C$9),公式COUNTIF(C$3:C$9,C$3:C$9)返回的值为1，只是用于辅助计算。所以上述公式也可以简化为：=SUMPRODUCT((C$3:C$9>C3)*1)+1。

大家常用EXCEL函数吗？那么你们对函数的了解情况是怎么样呢？你最拿手的有吗？真的不是打击大家，不要以为函数简单你就会，你听过T、N两个函数吗？你懂这两个函数吗？ 知道这两个函数的人应该是千里挑一，而精通这2个函数更是……

好了，就不卖关子了，今天就来聊聊这两个史上最简单的函数。

1、对金额进行累计 对B列的金额进行累计。

=N(C1)+B2公式居然如此简单，N函数究竟是干嘛的？N就是将文本转换成0，我们在算累计的时候是不需要C1这个标题的。如果没有这个转换，会出错，文本是不能直接计算的。

=C1+B2

2、判断等级对英语成绩进行判断等级，大于60分显示及格，否则显示挂科。

=IF(N(B2)>60,”及格”,”挂科”)直接判断的话，交白卷是文本大于60，会显示错误，通过N将交白卷转换成0，这样就能正确判断。

3、统计次数 统计2个字符的人员出现了几次。

N这里就是将逻辑值TRUE转换成1，FALSE转换成0，这样SUMPRODUCT函数就可以统计。

4、隔4行求和 统计每个季度的总数量，直接用SUM+OFFSET数组公式求和出错？

这里需要嵌套一个N函数进行降维，才能顺利求和，按Ctrl+Shift+Enter三键结束。=SUM(N(OFFSET(B1,ROW(1:4)*4,0)))

当然这里只是为了说明N函数的用法，实际上这个直接用SUM函数就可以搞定。=SUM(B:B)/2

5、高大上的查询多个对应值 我们都知道VLOOKUP函数一次只能查询一个对应值，但是配合N却可以突破自己的限制，实现查找多个对应值。这个要通过在编辑栏按F9键才能看出来。

直接输入公式，按Ctrl+shift+Enter三键结束。适用版本Excel2016。

=TEXTJOIN(“，”,1,IFERROR(VLOOKUP(N(IF({1},–TRIM(MID(SUBSTITUTE(D2,”，”,REPT(“”,50)),{1,2,3,4,5,6,7,8,9}*50-49,50)))),A:B,2,0),””))N(IF({1}是一个很神奇的套路，通过这个套路可以实现很多原本就实现不了的功能，比如VLOOKUP函数查找多个对应值。

N函数基本就这样，T函数跟N函数类似，只是T适用于文本，这个大家自己动手尝试。

还是那句老话，你知道了多并不是你会的就多，有些东西看上去非常的简单，但在使用的时候就会怎么想也想不起来，那是因为你刚开始时对它的轻视而造成的，所以请大家对学习过的东西要“温故而知新”，大家同意我的说法吗？如果有什么错误的地方也欢迎您的批评指正，同时欢迎您的关注、评论和点赞！让我们更加效率的完成自己的工作！

一、LOOKUP函数。

作用：提取查询。

语法：=LOOKUP（查询值，查询范围）

方法：

在目标单元格中输入公式：=LOOKUP(9^9,C:C)、=LOOKUP(9^9,D:D)。

解读：

当需要查询最后一条相关记录时，查询值用一个很大的值9^9来替代，实现向下匹配。

二、TEXT函数。

作用：返回间隔分钟数。

语法：=TEXT(值，格式代码)。

方法：

在目标单元格中输入公式：=TEXT(G6-G4,"[m]分钟")。

三、INDEX+MATCH组合函数。

作用：动态查询所需的值。

方法：

在目标单元格中输入公式：=INDEX($B$3:$F$9,MATCH($B$13,$B$3:$B$9,0),MATCH(C$12,$B$2:$F$2,0))。

四、SUM函数。

作用：合并单元格求和。

方法：

在目标单元格中输入公式：=SUM(D3:D9)-SUM(E4:E9)。

五、NETWORKDAYS.INTL函数。

作用：计算两个日期之间的工作日天数。

语法：=NETWORKDAYS.INTL（开始日期，结束日期，周末方式，其它节假日）。

周末统计方式有：

方法：

在目标单元格中输入公式：=NETWORKDAYS.INTL(C3,D3,1)、=NETWORKDAYS.INTL(C3,D3,1,F4:F6)。

解读：

从实际的应用中给我们可以看出，如果省略第四个参数，默认为没有请假情况。

就业等位来【这些Excel公式，简单却超实用！】①查找重复内容公式：=IF(COUNTIF(A:A,A2)>1,"重复","") ②求和：=SUM(K2:K56) ——对K2到K56这一区域进行求和 ③平均数：=AVERAGE(K2:K56) ——对K2 K56这一区域求平均数 ④排名： =RANK(K2，K$2:K$56) ——对55人的成绩进行排名。 @央视新闻：就业等位来【快转走！常用Excel公式都在这儿了！】求和、平均数、最大值、标准差……如何查找重复值；如何自动标出符合条件的数值……进阶版Excel超实用技巧。存好！有用！

版权声明：如涉及版权问题，请作者持权属证明与本网联系

来源：央视新闻

现在的你还在因为不会Excel函数而烦恼吗？其实在我们处理复杂的数据时候，如果能有几个Excel函数的帮助，那必定会事半功倍！

今天为大家分享5个Excel中常用的函数，希望能给你带来帮助.

一、计算性别（注：按照实际表格单元格，修改函数里面坐标）

函数：=IF(MOD(MID(B2:B6,17,1),2),"男","女")

二、计算出生日期（注：按照实际表格单元格，修改函数里面坐标）

函数： =TEXT(MID(B2:B6,7,8),"0-00-00")

三、计算生肖（注：按照实际表格单元格，修改函数里面坐标）

函数：=MID("猴鸡狗猪鼠牛虎兔龙蛇马羊",MOD(MID(B2:B6,7,4),12)+1,1)

四、计算年龄（注：按照实际表格单元格，修改函数里面坐标）

函数：=YEAR(TODAY())-MID(B2,7,4)

五、倒计时（注：输入指定日期如开学日期：2018.9.1）

函数：=DATE(2018,9,1)-TODAY()

以上就是今天为大家分享的所有Excel函数啦！喜欢的话帮忙转发分享下，让我们身边的小伙伴一起学习。

工作效率，一直是我们追求的目标。在Excel中，提高效率的方法很多，最常用的就是对各种技巧的熟练掌握。今天我们要学习的10个Excel实操技巧，对工作效率的提高，绝对不是一点点。

一、自适应调整列宽。

目的：极速调整列宽，显示单元格全部内容。

方法：

1、选定需要调整列宽的列。

2、移动鼠标至选定的任意两列分割线处，待鼠标变成左右双向箭头时，双击。

解读：

1、想要双击显示单元格的全部内容，必须取消“自动换行”。

2、如果没有取消“自动换行”，双击行标可以自动显示全部内容。

二、快速隐藏多列、多行。

目的：对不需要显示或保密的多列或多行内容快速隐藏。

方法：

1、选定目标行或列。

2、移动光标至选定的任意两行行标或列标中间，待鼠标变成双向箭头时，拖动鼠标。

解读：

1、拖动鼠标时如果拖动的幅度较小（小于当前行或列的宽度），则不会隐藏行或列，只是对行高或列宽进行调整。

2、拖动的幅度大于临近行或列的高度或宽度时，可以快速的实现隐藏功能。

三、快速取消隐藏行、列。

目的：对隐藏的多行、多列快速的进行显示。

方法：

1、选定需要取消隐藏的行或列。

2、移动鼠标，待鼠标变成双向箭头时，双击。

四、多单元格数据批量输入。

目的：批量输入演示数据或固定内容。

方法：

1、选定目标单元格。

2、输入公式：=RANDBETWEEN(10,100)或“Excel函数公式”。

3、Ctrl+Enter填充。

解读：

1、函数RANDBETWEEN的主要作用是生成指定两个数之间的随机数。

2、输入指定内容时，无需等号。

五、多工作表批量输入。

目的：在多个工作表中批量输入演示数据或指定内容。

方法：

1、选定任意表格的目标单元格。

2、按住Ctrl键，选定其它工作表。

3、输入公式:=RANDBETWEEN(10,100)或“Excel函数公式”。

3、Ctrl+Enter填充。

六、快速的输入：对号，错号。

目的：快速用对号或错号对数据进行标记。

方法：

1、选定目标单元格。

2、设置目标单元格的字体为：Wingdings 2。

3、输入大写R或S。

七、按月填充日期。

目的：对当前日期按月快速填充。

方法：

1、选定目标单元格并输入需要填充的日期。

2、拖动填充柄，并单击右下角的箭头，选择【按月填充】。

八、单元格内强制换行。

目的：调整内容显示，强制换行。

方法：

在目标内容后按Alt+Enter快捷键。

九、快速添加前缀。

目的：给序号添加前缀：函数公式。

方法：

1、选定目标单元格。

2、快捷键Ctrl+1打开设置单元格格式，选择【分类】中的【自定义】，在【类型】中输入：Excel函数-0。

3、【确定】。

十、快速输入有规律的长数字。

方法：

1、66万的后面有4个零，所以公式为：=66**4。

2、90亿，9的后面有9个零，所以公式为：=9**9。

结束语：

如果我们对实际操作中的技巧能够熟练掌握，相信对我们的工作效率提高的绝对不是一点点……欢迎大家在留言区讨论交流，同时别忘了点赞、转发哦！

批量输入公式批量修改公式快速查找公式显示公式部分计算结果保护公式隐藏公式显示所有公式把公式转换为数值显示另一个单元格的公式把表达式转换为计算结果快速查找公式错误原因

1批量输入公式

选取要输入的区域，在编辑栏中输入公式，按CTRL+ENTER即可批量填充公式。

2批量修改公式

如果是修改公式中的相同部分，可以直接用替换功能即可。

3快速查找公式

选取表格区域 - 按Ctrl+g打开定位窗口 - 定位条件 - 公式，即可选取表中所有的公式

4显示公式部分计算结果

选取公式中的要显示的部分表达式，按F9键

按F9键后的结果

想恢复公式，按esc退出编辑状态即可。

5保护公式

选取非公式的填写区域，取消单元格锁定。公式区域不必操作。

设置单元格格式后，还需要保护工作表：审阅 - 保护工作表。

6隐藏公式

隐藏公式和保护公式多了一步：选取公式所在单元格区域，设置单元格格式 - 保护 - 勾选“隐藏” - 保护工作表。

隐藏公式效果：

7显示所有公式

需要查看表中都设置了哪些公式时，你只需按alt+~组合键（或 公式选项卡 - 显示公式）

把公式转换为数值

8把公式转换为数值

公式转换数值一般方法，复制 - 右键菜单上点123（值）

9显示另一个单元格的公式

如果想在B列显示A列的公式，可以通过定义名称来实现。

公式 - 名称管理器 - 新建名称：G =get.cell(6,sheet3!a4)

在B列输入公式=G，即可显示A列的公式。

excel2013中新增了FORMULATEXT函数，可以直接获取公式文本。

10把表达式转换为计算结果

方法同上，只需要定义一个转换的名称即可。

zhi =Evaluate(b2)

在B列输入公式 =zhi即可把B列表达式转换为值

11快速查找公式错误原因

当一个很长的公式返回错误值，很多新手会手足无措，不知道哪里出错了。兰色介绍排查公式错误的技巧，3秒就可以找到错误。

下面兰色做了一个简单的小例子

【例】：如下图所示，单元格的公式返回值错误。要求排查出公式的哪部分出现了错误。

操作方法：

1、 打开单元格左上角绿三角，点“显示计算步骤”

2、在打开的“公式求值”窗口中，求值会自动停在即将出错的位置。这时通过和编辑栏中的公式比对，就可以找出产生错误的单元格。（D7）

如果公式中有多处错误，可以先修正前一次，然后再点显示计算步骤，查找下一处错误。

收藏的Excel函数大全公式再多，几天不用也会忘记。怎么才能不忘？你需要了解公式的运行原理。兰色今天不再推送一大堆函数公式，而是根据提问最多的问题，精选出6个实用的，然后详细的解释给大家。

1、计算两个时间差

=TEXT(B2-A2,"[m]分钟")

兰色注：

Text函数（数字,格式）：可以把数字或文本格式化显示，如同单元格自定义格式效果。"[m]分钟"：在表示时间的自定义格式中，小时为h，分种是m，秒是s，所以如果是间隔小时，把m替换成h。而加[ ]则是可以显示大于24小时的小时数、60分种的分钟数。

2、计算到期时间

=EDATE($A2,$B2)

EDate（开始时间,间隔月数)：N月后的日期。如间隔月数为负则表示N月前的日期。

3、隔列求和公式

按标题求和

=SUMIF($A$2:$G$2,H$2,A3:G3)

因为有规则的标题，所以隔列求和转换为条件求和公式

如果没有标题

=SUMPRODUCT((MOD(COLUMN(B3:G3),2)=0)*B3:G3)

Column(区域):取得区域的所在列数，构成一组数字。MOD（数字,2）：一个数字除以2的余数。如果余数是0表示该数字为偶数，否则为奇数（条件）**B3:G3：在公式中经常会见到这样的结构。条件成立时返回的是True（运算时等同于1），不成立返回的是False（运算时等同于0）。两组数据相乘的结果是满足条件的数会保留下来，不满足的会变成0。Sumproduct：它和Sum函数的主要区别是，这里可以直接执行数组运算的求和，而Sum函数需要按三键输入。

4、超链接公式

=HYPERLINK("#"&B2&"!A1","进入")

Hyperplink函数：在Excel中能用公式创建超链接的，只有Hyperplink函数，它可以把一个字符串转换为超链接。"#"&B2&"!A1"：B列是工作表中，连接后 "#工作表名!A1"，前面加#表示本工作簿

5、跨表批量取值

=INDIRECT(B2&"!b10")

Indirect函数：它的作用是把单元格地址串转换为引用。如本例中 B2&"!b10" 连接起来虽然是工作表名！单元格，但它只是个字符串而已，并不会把单元格中的值取出来。利用Indirect转换后则可以取单元格中的值了。

6、提取不重复值

数组公式：按三键输入

｛=INDEX(A$1:A$99,MATCH(0,COUNTIF(C$1:C1,A$1:A$99),0))&""｝

COUNTIF(C$1:C1,A$1:A$99)：让C列本公式上面的姓名在A列逐个用Countif函数统计个数，如果不存在（正是要提取的唯一值）结果为0，然后用Match(0,统计的个数,0)查找0所在的行数。INdex（区域,行数）:可以根据位置提取出相对应的值。

兰色说：Excel函数公式的学习也需要循序渐进，如果上面的解释你看的还是不明白，就要从函数的基础用法学起了。

End.

来自：Excel精英培训

一、员工信息表公式

1、计算性别(F列)

=IF(MOD(MID(E3,17,1),2),"男","女")

2、出生年月(G列)

=TEXT(MID(E3,7,8),"0-00-00")

3、年龄公式(H列)

=DATEDIF(G3,TODAY(),"y")

4、退休日期(I列)

=TEXT(EDATE(G3,12*(5*(F3="男")+55)),"yyyy/mm/dd aaaa")

5、籍贯(M列)

=VLOOKUP(LEFT(E3,6)*1,地址库!E:F,2,)

注：附带示例中有地址库代码表

6、社会工龄(T列)

=DATEDIF(S3,NOW(),"y")

7、公司工龄(W列)

=DATEDIF(V3,NOW(),"y")&"年"&DATEDIF(V3,NOW(),"ym")&"月"&DATEDIF(V3,NOW(),"md")&"天"

8、合同续签日期(Y列)

=DATE(YEAR(V3)+LEFTB(X3,2),MONTH(V3),DAY(V3))-1

9、合同到期日期(Z列)

=TEXT(EDATE(V3,LEFTB(X3,2)*12)-TODAY(),"[<0]过期0天;[<30]即将到期0天;还早")

10、工龄工资(AA列)

=MIN(700,DATEDIF($V3,NOW(),"y")*50)

11、生肖(AB列)

=MID("猴鸡狗猪鼠牛虎兔龙蛇马羊",MOD(MID(E3,7,4),12)+1,1)

二、员工考勤表公式

1、本月工作日天数(AG列)

=NETWORKDAYS(B$5,DATE(YEAR(N$4),MONTH(N$4)+1,),)

2、调休天数公式(AI列)

=COUNTIF(B9:AE9,"调")

3、扣钱公式(AO列)

婚丧扣10块，病假扣20元，事假扣30元，矿工扣50元

=SUM((B9:AE9={"事";"旷";"病";"丧";"婚"})*{30;50;20;10;10})

四、员工数据分析公式

1、本科学历人数

=COUNTIF(D:D,"本科")

2、办公室本科学历人数

=COUNTIFS(A:A,"办公室",D:D,"本科")

3、30~40岁总人数

=COUNTIFS(F:F,">=30",F:F,"<40")

五、其他公式

1、提成比率计算

=VLOOKUP(B3,$C$12:$E$21,3)

2、个人所得税计算

假如A2中是应税工资，则计算个税公式为：

=5*MAX(A2*{0.6,2,4,5,6,7,9}%-{21,91,251,376,761,1346,3016},)

3、工资条公式

=CHOOSE(MOD(ROW(A3),3)+1,工资数据源!A$1,OFFSET(工资数据源!A$1,INT(ROW(A3)/3),,),"")

注：

A3:标题行的行数+2,如果标题行在第3行，则A3改为A5

工资数据源!A$1:工资表的标题行的第一列位置

4、Countif函数统计身份证号码出错的解决方法

由于Excel中数字只能识别15位内的，在Countif统计时也只会统计前15位，所以很容易出错。不过只需要用 &"*" 转换为文本型即可正确统计。

=Countif(A:A,A2&"*")

六、利用数据透视表完成数据分析

1、各部门人数占比

统计每个部门占总人数的百分比

2、各个年龄段人数和占比

公司员工各个年龄段的人数和占比各是多少呢？

3、各个部门各年龄段占比

分部门统计本部门各个年龄段的占比情况

4、各部门学历统计

各部门大专、本科、硕士和博士各有多少人呢？

5、按年份统计各部门入职人数

每年各部门入职人数情况

我们都知道excel函数公式很强大，运用好了对我们制表很有帮助，但是excel函数公式实在是太多了，根本记不住，下面跟大家分享一些常常会用到的函数公式。

一、对于数字的处理：

1、取绝对值

=ABS(数字)

2、取整

=INT(数字)

3、四舍五入

=ROUND(数字,小数位数)

二、统计公式：

1、统计两个表格重复的内容

公式:B2

=COUNTIF(Sheet15!A:A,A2)

说明：如果返回值大于0说明在另一个表中存在，0则不存在。

2、统计不重复的总人数

公式：C2

=SUMPRODUCT(1/COUNTIF(A2:A8,A2:A8))

说明:用COUNTIF统计出每人的出现次数，用1除的方式把出现次数变成分母，然后相加。

在完成excel表格统计之后，以免后期不小心修改数据，我们可以将excel表格转换成pdf格式。高版本的office可以直接将excel另存为pdf，低版本或者想要批量转换的可以用迅捷pdf转换器来完成转换。

三、求和公式

1、隔列求和

公式：H3

=SUMIF($A$2:$G$2,H$2,A3:G3)

或

=SUMPRODUCT((MOD(COLUMN(B3:G3),2)=0)*B3:G3)

说明：如果标题行没有规则用第2个公式

2、单条件求和

公式：F2

=SUMIF(A:A,E2,C:C)

说明：SUMIF函数的基本用法

3、单条件模糊求和

公式：详见下图

说明：如果需要进行模糊求和，就需要掌握通配符的使用，其中星号是表示任意多个字符，如"*A*"就表示a前和后有任意多个字符，即包含A

4、多条件模糊求和

公式：C11

=SUMIFS(C2:C7,A2:A7,A11&"*",B2:B7,B11)

说明：在sumifs中可以使用通配符*

5、多表相同位置求和

公式：b2

=SUM(Sheet1:Sheet19!B2)

说明：在表中间删除或添加表后，公式结果会自动更新。

6、按日期和产品求和

公式：F2

=SUMPRODUCT((MONTH($A$2:$A$25)=F$1)*($B$2:$B$25=$E2)*$C$2:$C$25)

说明：SUMPRODUCT可以完成多条件求和

好啦，以上就是比较常用的excel公式啦，当然，excel函数公式远远不止这些，但是以上公式如果能熟练应用也会非常提高工作效率哦。