LOOKUP函数是我们常用的查找函数之一，其语法决定，想要得到正确的查询结果，必须对查询的数据进行升序排序，但是一般情况下我们都不会先排序在查询，而是采用：=LOOKUP(1,0/(B3:B9=H3),C3:C9)类似结构的语法来完成查询。但是，对于上述方法，大多同学一知半解……

一、应用场景。

目的：查询销售员对应的销量。

方法：

1、在目标单元格中输入公式：=LOOKUP(1,0/(B3:B9=H3),C3:C9)。

2、选定数据源，【条件格式】-【新建规则】-【使用公式确定要设置格式的单元格】，在【为符合此公式的值设置格式】中输入：=($B3=$H$3)。

3、单击右下角【格式】-【填充】，选取填充色，并【确定】完成查询设置。

二、公式解读。

（一）、(B3:B9=H3)的运算结果。

1、如果A=B，会返回结果TRUE，TRUE在运算中相当于数字1。

2、如果A<>B，会返回结果FALSE，FALSE在运算中相当于数字0。

所以：(B3:B9=H3)的运算结果是有TRUE和FALSE构成的一组值，结果如下图：

（二），提取所需值

1、0/(B3:B9=H3)的结果我们可以归纳为：0，#p/0！，#p/0！，#p/0！，#p/0！，#p/0！，#p/0！。如下图：

2、LOOKUP函数:特征1：查找时可以忽略错误值且，这样一组数值忽略后只剩下一个值0。

3、LOOKUP函数特征2：当查找的值不存在时，按照小于此值的最大值进行匹配。故设置查找值为1，从而实现查询的目的。

备注：

“0/”的目的就是把符合条件的值变为0，不符合条件的变为错误，利用LOOKUP函数的特征查找到符合条件的值。

三、多条件查询。

目的：查询销售员在相应地区的销售额。

方法：

在目标单元格中输入公式：=IFERROR(LOOKUP(1,0/((B3:B9=H3)*(E3:E9=I3)),C3:C9),"")。

释义：

1、原理和单条件查询是一样的。

2、TRUE*TRUE=1，TRUE*FALSE=0。

各位亲，如果对多条件查询不理解，可以在评论区留言提问哦！

来自：Excel不加班（ID：Excelbujiaban）作者：卢子

关于查找这个问题几乎每天都会有读者问到，新手喜欢用VLOOKUP函数，而高手钟爱于LOOKUP函数。

今天就来根据读者的实际问题，看LOOKUP函数如何搞定各种查找问题？

1.根据名称查找对应的编码。

正常查找对应值用VLOOKUP函数，这里是逆向查找，会使查找难度变得非常大，而用LOOKUP函数反而更简单。

LOOKUP函数的经典查找模式：

=LOOKUP(1,0/(查找区域=查找值),返回区域)

这里的1跟0是固定的，记住这一点就可以。

有一部分读者就这样写公式，结果也能出来。

=LOOKUP(1,0/(E2:E12=A2),D2:D12)

其实这种写法是错误的，运气好，答案对了而已。现在新增加名称，就得到错误值。

查找的时候，区域要加绝对引用，否则下拉的时候区域就会改变，从而导致出错。

正确的方法应该是动画这种。

2.根据编码查找对应的名称。

这里加了绝对引用怎么也出错了？

这个是很常见的现象，很多人在录入数据的时候，两边设置的格式不同，这就导致了查找出错。

正确的方法应该转换成统一的格式。

=LOOKUP(1,0/($D$2:$D$12=--A2),$E$2:$E$12)=LOOKUP(1,0/($D$2:$D$12&""=A2),$E$2:$E$12)

文本转数值，在前面加--，数字转文本，在后面&""。

3.根据查找内容的后5位数字，在查找区域查找后5位相同的内容。

从右边提取字符用RIGHT函数，5就代表提取5位。

=RIGHT(A2,5)

两边都用RIGHT函数提取，然后合并起来即可。

=LOOKUP(1,0/(RIGHT(A2,5)=RIGHT($D$2:$D$64,5)),$D$2:$D$64)

不过这样查找不到对应值会显示错误值，不美观。

这时IFERROR函数就派上用场了，让错误值显示空白。

=IFERROR(LOOKUP(1,0/(RIGHT(A2,5)=RIGHT($D$2:$D$64,5)),$D$2:$D$64),"")

最后，有一小部分人的习惯不好，经常使用合并单元格或者多输入一些空格之类的，这种最好改掉，否则会给你带来不便！

vlookup函数是excel表格中高级的用法，通过vlookup函数我们可以调用符合条件的数据，在大量调用时可以节省我们查找复制excel数据的时间，今天我就教下大家vlookup函数的使用方法吧。

vlookup函数的使用方法

如图我准备了一张员工入职时间表，员工有非常多，如果我要在这里面一一找出张三李四王五等人的入职时间的话，可以通过查找黏贴的方式，但是这样的效率就很低了，特别是要找的人多的话，那使用vlookup函数是最简单的方法。

接下来我们就需要根据vlookup函数的公式来做调整，使vlookup函数的基本公式变成我们excel表格需要的公式，vlookup函数的语法结构是VLOOKUP(lookup_value,table_array, col_index_num, [range_lookup])。

如我们的表格，我们要查找的是人名，那么对应的lookup_value就是D2张三，而table_array查找区域就是A2到B14这个区域，那么table_array就写$A$2:$B$14。

接下来我们再看col_index_num，这个就是返回值代表在查找区域中返回哪一列的数据，而入职时间在第二列，所以这里就填写2就可以了。而[range_lookup]代表精确查找，我们输入0就可以了。

这样子我们就限定了E2是取A2到B14这个区域的入职时间，那么我们输入完公式后，直接按回车键运行一下，就可以取到姓名为张三的入职时间了。

取完一个正确的数据后，我们要把公式应用到下方的单元格中，只需要将鼠标移动到E2单元格的右下角，鼠标符号变成十字加号后按住鼠标左键往下拉就可以了。

这样vlookup函数的使用方法就教大家了，是不是觉得很简单，只要记好vlookup函数的公式，大家都能成为excel高手。

霸气走火就是我，我就是百度经验作者：ixlxt7Xzsl7，百度经验和百家号首发原创内容分享。

Excel中，数据查询从来不是一个新鲜的话题，基本上每天都在用，但是高效快捷的查询技巧，并不是每个人都会的。本节结合实例，学习LOOKUP函数如何搞定各种查询问题。

一、逆向查询。

目的：查询对应人员的学号。

方法：

在目标单元格中输入公式：=LOOKUP(1,0/(B3:B9=H3),A3:A9)。

解读：我们先来看，B3:B9=H3，也就是说判断B3:B9中的值是否等于H3,因此判断结果是{0,0,1,0,0,0,0}，因为之后第二个值等于H3中的值。{0,0,1,0,0,0,0}作为分母，被0除，得出的结果就是{错误值,错误值,0,错误值,错误值,错误值,错误值}。在这个数组中进行查找，会查找不到，那么将会匹配比1小的最大值，也就是0，所以就查找到了H3对应值的位置。

万能公式：

=LOOKUP(1,0/(查找区域=查找值），返回区域）。

二、单条件查询。

目的：根据序号查找对应的姓名。

方法：

在目标单元格中输入公式：=LOOKUP(1,0/(A3:A9=H3),B3:B9)。

三、多条件查询。

目的：查询“王东”的成绩。

方法：

在目标单元格输入公式：=LOOKUP(1,0/((B3:B9=H3)*(D3:D9=I3)),C3:C9)。

万能公式：

=Lookup(1,0/((条件1）*（条件2）……条件N），返回值的范围）。

四、根据指定的部分内容，查找全部内容。

目的：根据身份证号的后四位，查询身份证号码。

方法：

在对应的目标单元格输入公式：=LOOKUP(1,0/(RIGHT(C3,4)=I3),C3:C9)。

解读：

利用函数RIGHT提取身份证号的后4位，然后和单元格I3中的值比较，得到数据组，然后进一步的对比，得出结果。

前言：今天给大家介绍一种LOOKUP从文本中提取数字的用法。

题解

函数解释

是不是很好用的函数，在我们平时处理数据的过程中会经常遇到这样的问题，今天你学会了这个函数的用法，再遇到这样的问题是不是就会很快解决了。

结语:原创不易啊！喜欢的朋友可以为我“赞赏”和“点赞”，非常感谢大家的支持。

第一种用法：普通查找

在H2中输入公式“=LOOKUP(1,0/(C2:C12=G2),E2:E12)”：

其中：

(C2:C12=G2)：

{FALSE;FALSE;FALSE;FALSE;FALSE;TRUE;FALSE;FALSE;FALSE;FALSE;FALSE)}

{0;0;0;0;0;1;0;0;0;0;0}

0/(C2:C12=G2)：

{#p/0!;#p/0!;#p/0!;#p/0!;#p/0!;0;#p/0!;#p/0!;#p/0!;#p/0!;#p/0!}

LOOKUP查找时忽略非法值，直接返回0对应的E2:E12区域中对应位置的值。

第二种用法：逆向查找

在H2中输入公式“=LOOKUP(1,0/(C2:C12=G2),B2:B12)”：

第三种用法：多条件查找

在I2中输入公式“=LOOKUP(1,0/(B2:B12=G2)*(E1:E12=H2),C2:C12)”：

第四种用法：查找最后一条记录

在B11中输入公式“=LOOKUP(1,0/(B2:B10<>""),B2:B10)”：

第五种用法：区间查找

在C2中输入公式“=LOOKUP(B2,$H$2:$H$5,$I$2:$I$5)”：

第六种用法：模糊查找

在B9中输入公式“=LOOKUP(9^9,FIND(A9,$A$2:$A$5),$B$2:$B$5)”：

9^9是9的9次方，表示一个极大的数。

第七种用法：查找最后一次进货日期

在B11中输入公式“=LOOKUP(1,0/(B2:B10<>""),$A$2:$A$10)”：

第八种用法：关键字提取

在B2中输入公式“=LOOKUP(9^9,FIND({"路由器","交换机","打印一体机","投影仪"},A2),{"路由器","交换机","打印一体机","投影仪"})”：

第九种用法：拆分合并单元格

在B2中输入公式“=LOOKUP("作",$A$2:A2)”：

lookup查找汉字是按照汉语拼音的顺序来查找的，作（拼音zuo)已经是拼音中比较靠后的了，所以用“座”可以查找区域中最后一个单元格内容，

第十种用法：合并单元格的查询

在D2中输入公式“=LOOKUP("作",INDIRECT("a1:a"&MATCH(E2,B1:B12,0)))”：

MATCH(E2,B1:B12,0)部分，精确查找E2单元格的姓名在B列中的位置。返回结果为9，

用字符串"A1:A"连接MATCH函数的计算结果9，变成新字符串"A1:A9"。

用INDIRECT函数返回文本字符串"A1:A9"的引用。

如果MATCH函数的计算结果是5，这里就变成"A1:A5"。同理，如果MATCH函数的计算结果是10，这里就变成"A1:A10"。也就是这个引用区域会根据E2姓名在B列中的位置动态调整。

最后用=LOOKUP("座",引用区域)返回该区域中最后一个文本的内容。

=LOOKUP("作",A1:A9)，返回A1：A9单元格区域中最后一个文本，也就是信息系。

转载自百家号作者：解晴说Excel

都知道Ｖlookup函数可用于查找数据，非常方便。其实，它是从Lookup函数进化而来的。Lookup函数的用途绝不少于Vlookup，有时候，它还更方便点。

Lookup入门基本功

例如，我们知道了供应商编号，想在供应商信息表中找到对应的联系人，那我们就可以用公式“=LOOKUP(A3,A7:A13,C7:C13)”或“=LOOKUP(A3,A7:C13)”查找。

向量形式的语法：=lookup(找谁,去哪里找,找到后要什么)数组形式的语法：=lookup(找谁,去哪里找)

向量形式的公式，会在第二个参数指定的范围中查找第一个参数，找到后，返回第三个参数对应的单元格内容。

数组形式的公式，在第二个参数的第一列或第一行查找第一个参数，找到后返回第二个参数最后一列或一行对应的单元格内容。

Lookup注意事项

和vlookup不同，lookup函数默认就支持逆序查找，也就是说查找后可以获得查找数据左侧的结果。

咦，要查找的“雪碧”的编号不是“A-0011”吗？为什么不对了呢？

其实，在使用lookup基本的公式前，必须对数据表按照我们要查找的关键字类别进行升序排列，否则，就会得到错误的结果。

在查找前还要排序？那如果我的表格增加了数据，岂不是每次查找之前都要重新排序，太麻烦了。我不想排序，怎么办？

Lookup函数进阶

公式：=LOOKUP(1,0/(B7:B13=A3),A7:A13)

把公式变成了“=lookup(1,0/(哪里找=找谁),找到后要什么）”这种形式之后，不管原始的数据是什么顺序排列的，都可以得到正确的结果。

解释：

公式中的“0/(B7:B13=A3)”经过Excel计算将会得到“{#p/0!;#p/0!;#p/0!;0;#p/0!;#p/0!;#p/0!}”这样的结果，也就是说Excel会将B7:B13中的每一个单元格和A3进行对比，如果不相等，就会得到“#p/0!”；如果相等，就会得到“0”。

而Lookup函数在查找时会自动忽略“#p/0!”等非法的值，这样就只剩下我们需要的值啦。

相关阅读：《WPS Excel经典函数：Vlookup怎么用》。

学习，为了更好的生活。欢迎点赞、评论、关注和点击头像。

提起查找函数，大家第一时间想到的肯定是Vlookup，其实大多数人不知道，Lookup才是查找函数之王，它几乎能高效地实现Vlookup函数的所有功能，部分功能是Vlookup函数无法比拟的。

一、语法结构和基本使用方法。

应用场景：当需要查询一行或一列并查找另一行或列中的相同位置的值时。

语法结构：

LOOKUP(lookup_value, lookup_vector, [r]result_vecto)

1、Lookup_value：必需。在向量中搜索的值。

2、Lookup_Vector:必需。只包含一行或一列的区域。此区域中的值必需按照升序排列，否则无法返回正确的结果。文本不区分大小写。

3、result_vector ：可选。只包含一行或一列的区域。result_vector 参数必须与 lookup_vector 参数大小相同。其大小必须相同。

易解语法结构：Lookup(查找的值，查找值所在的范围，返回值所在的范围）。

使用形式：

1、向量形式

可使用Lookup的这种形式在一行或一列中搜索值。

方法：

在目标单元格中输入公式：=LOOKUP(H3,A3:A9,C3:C9)。

2、数组形式。

数组是要搜索的行和列中的值的集合。要使用数组，必需对数据排序。其功能一般用Vlookup函数和Hlookup函数来替代，不建议用哪个数组形式。

方法：

在目标单元格中输入公式：=VLOOKUP(H3,B3:C9,2,0)。

二、Lookup函数实现逆向查找功能。

方法：

1、对数据进行升序排序。

2、在目标单元格中输入公式：=LOOKUP(H3,C3:C9,B3:B9)。

3、Ctrl+Enter填充。

备注：

逆向查找之前，首先要对超找的内容进行升序排序，之后进行查找工作。

三、Lookup函数万能查找（单条件、多条件）。

在前面的学习中我们已经知道，Lookup函数想要实现正确的查找，首先要对查找值所在的范围（Lookup函数的第二个参数）进行升序排序。如果不想排序怎么办了？

1、单条件：

方法：

在目标单元格中输入公式：=LOOKUP(1,0/(B3:B9=H3),C3:C9)。

公式解析：

我们先来看，B3:B9=H3，也就是说判断B3:B9中的值是否等于H3,因此判断结果是{0,1,0,0,0,0,0}，因为之后第二个值等于H3中的值。{0,1,0,0,0,0,0}作为分母，被0除，得出的记过就是{错误值,0,错误值,错误值,错误值,错误值,错误值}。在这个数组中进行查找，会查找不到，那么将会匹配比1小的最大值，也就是0，所以就查找到了H3对应值的位置。

2、多条件：

方法：

在目标单元格中输入公式：=LOOKUP(1,0/((B3:B9=H3)*(E3:E9=I3)),C3:C9)。

备注：

1、此公式是Lookup函数最经典、最万能的公式。可以归纳为：

=Lookup(1,0/((条件1）*（条件2）……条件N），返回值的范围）。

2、从上述的万能公式中我们可以看出，Lookup不仅可以但条件查找，也可以多条件查找。

四、Lookup函数多层次区间条件查找。

方法：

在目标单元格中输入公式：=LOOKUP(C3,$I$3:$J$6)。

Excel中合并单元格，小编一直觉得是制表的大忌，让我们后续数据处理增加不少难度。但仍然还是有伙伴因为一些原因用了合并单元格。这位伙伴就是遇到这样的麻烦。询问Excel中合并单元格查询公式问题。

需要根据E2单元格的销售员，查询销售出去的订单对应的产品代码。

F2单元格公式为：=LOOKUP("座",INDIRECT("a1:a"&MATCH(E2,$C$1:$C$9,)))

公式有点小小的难度。一起来解读一下：

MATCH(E2,$C$1:$C$9,)，查找E2在C列中是位置，返回5。

INDIRECT("a1:a"&MATCH(E2,$C$1:$C$9,))：返回引用单元格区域，得到值为：INDIRECT("a1:a"&5)，即：a1：a5单元格区域。

LOOKUP("座",引用区域)代表：返回引用区域中的最后一个文本。在E2公式中是返回a1：a5单元格区域的最后一个文本，也就是A446580684。

今天分享一个超级强大的查找函数LOOKUP。

一、函数解析

lookup函数的参数有二种形式，一是向量，二是数组

1、向量

LOOKUP（①查找值，②查找值所在区域，③返回的结果）

②为单行区域或单列区域，查找值所在区域必须先排序，否则出错。

③可以省略

没有精确匹配对象时，返回小于等于目标值的最大值

2、数组

LOOKUP（①查找值，②二维数组）

二、经典用法案例

逆向查询、单条件和多条件查询通用公式：

=LOOKUP(1,0/(条件),目标区域或数组)

其中，条件可以是多个逻辑判断相乘组成的多条件数组。

=LOOKUP(1,0/((条件1)*( 条件2)* ( 条件N)),目标区域或数组)

公式说明：

①((条件1)*( 条件2)* ( 条件N))，所有条件满足返回TRUE，否则返回FALSE。

②以0/((条件1)*( 条件2)* ( 条件N))构建一个0、#p/0!组成的数组，避免了查找范围必须升序列排序的弊端。（因为True在运算时当作1，False在运算时当作0，所以0/TRUE返回0，0/FALSE返回#p/0!）

③再用1作为查找值，即可查找最后一个满足非空单元格条件的记录。

1、单条件逆向查询：根据姓名查询工号

在G2单元格输入公式：=LOOKUP(1,0/($B$2:$B$19=F2),$A$2:$A$19)

2、多条件查询：根据姓名和部门查询办公室

在H2单元格输入公式：=LOOKUP(1,0/(($B$2:$B$19=F2)*($C$2:$C$19=G2)),$D$2:$D$19)

3、查询最后一次出现的数据

在F2单元格输入公式：=LOOKUP(1,0/($B$2:$B$19=E2),$C$2:$C$19)

4、查询A列中的最后一个文本

在C1单元格输入公式：=LOOKUP("々",A:A )或=LOOKUP("座",A:A )

"々"通常被看做是一个编码较大的字符，它的输入方法为组合键。第一参数写成"々" 和“座”都可以返回一列或一行中的最后一个文本。+41385>

+41385>

5、查询A列中的最后一个数值

在C2单元格输入公式：=LOOKUP(9E307,A:A)

9E307被认为是接近Excel规范与限制允许键入最大数值的数，用它做查询值，可以返回一列或一行中的最后一个数值。

6、查询A列中的最后一个单元格内容

在C3单元格输入公式：=LOOKUP(1,0/(A:A<>""),A:A)

(A:A<>"")是判断不为空

7、根据简称查询全称

A列是客户的简称，要求根据D列的客户全称对照表，在B列写出客户的全称。

在B2单元格输入公式：=IFERROR(LOOKUP(1,0/FIND(A2,D:D),D:D,"")

公式说明：

①0/FIND(A2,D:D)，用FIND函数查询A2单元格“湖南永怡”在D列的起始位置，得到一个由错误值和数值组成的数组。

②使用IFERROR函数来屏蔽公式查询不到对应结果时返回的错误值。

8、多个区间的条件判断

根据加油站的年销售量，确定油站的等级。

在G2单元格输入公式：

=LOOKUP(F2,{0;2000;4000;6000;8000;10000},$B$3:$B$8)

或者=LOOKUP(F2,$A$2:$B$8）

这种方法查找区域必须升序排序。

9、提取单元格内的数字

在B2单元格输入公式:

=-LOOKUP(1,-LEFT(A2,ROW($1:$99)))

公式说明：

①-LEFT(A2,ROW($1:$99))用LEFT函数从A2单元格左起第一个字符开始，依次返回长度为ROW($1:$99)也就是1至99的字符串，添加负号后，数值转换为负数，含有文本字符的字符串则变成错误值。

②LOOKUP函数使用1作为查询值，在由负数、0和错误值构成的数组中，忽略错误值提取最后一个等于或小于1的数值。

③最后再使用负号，将提取出的负数转为正数。

我是EXCEL学习微课堂，如果我的分享对您有帮助，欢迎点赞、收藏、评论和转发！更多的EXCEL技能，可以关注百家号“EXCEL学习微课堂”。