SumProduct函数是 Excel 中用于数组求和的函数，它有三种表达式，一种为参数全是数组，另两种为前几个参数为条件，最后一个参数为求和区域。SumProduct函数的计算方法为将一个数组的元素与另一个数组的对应元素相乘，然后把所有乘积相加。在应用过程中，即可写一个条件求和，也可以用And/Or组合多条件求和。以下就是Excel SumProduct函数三个表达式与用And/Or组合多条件求和的具体操作方法，实例中操作所用版本均为 Excel 2016。

一、Excel SumProduct函数语法

1、表达式1：SUMPRODUCT(array1, [array2], [array3], ...)

说明：SumProduct 参数全是数组，最少要有一个数组，最多可有 255 数组；计算方法为：每个数组的对应元素相乘，然后求和；非数值当作0处理；每个数组必须有相同的维数。

2、表达式2：SUMPRODUCT(--(条件1)，[--(条件2)，...],(求和区域))

说明：表达式中用 [] 括起来的为可选参数，条件前面的 -- 是把逻辑值转为数值以便于计算。

3、表达式3：SUMPRODUCT((条件1)*[（条件2)，...]*(求和区域))

说明：表达式3是表达式2的另一种写法。

二、Excel SumProduct函数使用举例

（一）表达式1举例

1、假如要求一个服装销量表的所有服装的营业额。选中 G2 ，把公式 =SUMPRODUCT(E2:E9,F2:F9) 复制到 G2，按回车，则求出所有服装的营业额；操作过程步骤，如图1所示：

2、公式说明：计算时，用 E2:E9 中的每个元素乘 F2:F9 中对应的元素并把它们相加，即 89 * 892 + 89 * 874 + 80 * 569 + 99 * 982 + 198 * 897 + 65 * 528 + 185 * 563 + 299 * 159 = 663534。

（二）表达式2举例

1、假如要求“分类”为“衬衫”、销售“地区”为“广州”的“销量”。选中 G2 单元格，把公式 =SUMPRODUCT(--($C$2:$C$12="衬衫"),--($D$2:$D$12="广州"),($F2:$F12)) 复制到 G2，按回车，则求得结果 819；操作过程步骤，如图2所示：

2、公式说明：

公式 =SUMPRODUCT(--($C$2:$C$12="衬衫"),--($D$2:$D$12="广州"),($F2:$F12)) 中 $C$2:$C$12 是对 C2:C12 的绝对引用，以便返回数组；($C$2:$C$12="衬衫") 判断数组中每个是否等于“衬衫”，等于返回真，否则返回假；-- 将真假逻辑值转为数值。条件2与条件1是一个意思；$F2:$F12 为求和区域，$F2 表示对 F 列绝对引用，对行相对引用，即拖动时，列不变、行变。

（三）表达式3举例

1、把表达式2举例中的公式改为表达式3。选中 G3 单元格，把公式 =SUMPRODUCT(($C$2:$C$12="衬衫")*($D$2:$D$12="广州")*($F2:$F12)) 复制到 G3，如图3所示：

2、按回车，同样求得结果 819，如图4所示：

三、Excel SumProduct函数多条件求和

（一）用 And（*）组合多条件求和

1、有一个服装销售表和一个库存表，假如要在库存表中查看销量。选中 E2 单元格，把公式 =SUMPRODUCT((销售!$A$2:$A$12=库存!$A2)*(销售!$C$2:$C$12=库存!$C2)*(销售!$F$2:$F$12)) 复制到 E2，按回车，则求出“编号”为 WS-560 的销量；把鼠标移到 E2 单元格右下角的单元格填充柄上，按住左键，往下拖，则统计出其它服装的销量；操作过程步骤，如图5所示：

2、公式说明：

=SUMPRODUCT((销售!$A$2:$A$12=库存!$A2)*(销售!$C$2:$C$12=库存!$C2)*(销售!$F$2:$F$12))

A、选中 E2 单元格，按住 Alt，按一次 M，按一次 V，打开“公式求值”窗口，每单击一次“求值”计算一步，一直单击直到计算出最终结果，操作过程步骤，如图6所示：

B、公式中条件1 (销售!$A$2:$A$12=库存!$A2) 是把“销售表”与“库存表”用“编号”连接起来，条件2 (销售!$C$2:$C$12=库存!$C2) 是要求“销售表”中的“分类”等于“库存表”中对应的分类，(销售!$F$2:$F$12)) 是求区域。

C、条件1(销售!$A$2:$A$12=库存!$A2) 表示如果“销售表”中的“编号”等于“库存表”中对应“编号”，则返回真，否则返回假，最终返回一个以真（True）假（False)为元素的数组，如图7所示：

D、条件2 (销售!$C$2:$C$12=库存!$C2) 最终也返回一个由真假元素组成的数组，然后把条件1的元素与条件2对应的元素相乘，两个为 True 的元素相乘返回 True、为 False 的返回 False，并把 True 转为 1、False 转为 0。

E、(销售!$F$2:$F$12)) 返回一个由“销售表”F 列数值组成的数组，如图8所示：

此时，仅还有两个数组，把它们对应的数值相乘，然后把相乘结果相加，从而计算出最终结果。

（二）同时用 And（*）与 Or（+）组合多条件求和

1、假如要统计广州和深圳的服装销量之和。把公式 =SUMPRODUCT((F2:F12)*((D2:D12="广州")+(D2:D12="深圳"))) 复制到 G2 单元格，按回车，则统计符合条件的服装销量之和，操作过程步骤，如图9所示：

2、公式说明：

公式中 (F2:F12) 是求和区域，(D2:D12="广州")+(D2:D12="深圳") 是用加号（+）组成的两个表示“或”关系的条件，即统计 F2:F12 中要么在广州要么在深圳销售的服装销量之和。

3、再加一个条件，假如要统计在广州和深圳销售的且分类为雪纺的服装销量之和，公式可以这样写：=SUMPRODUCT((F2:F12)*((D2:D12="广州")+(D2:D12="深圳"))*(C2:C12="雪纺"))。

逻辑函数，顾名思义就是用来判断值的真假，进行检验的函数，在Excel中有着广泛的应用。

一、AND、OR、NOT。

1、目的：统计未“缺考”人数的总分。

方法：

在目标单元格中输入公式：=IF(OR(C3="",D3="",E3="")," ",SUM(C3:E3))。

解读：

1、条件OR(C3="",D3="",E3="")的意思为C3、D3、E3中如果有一个单元格为空，公式=IF(OR(C3="",D3="",E3="")," ",SUM(C3:E3))返回空值，否则返回SUM(C3:E3）。

2、OR函数的作用可以理解为“或”。

2、目的：所有科目都缺考的人员成绩不予计算。

方法：

在目标单元格中输入公式：=IF(AND(C3="",D3="",E3=""),"",SUM(C3:E3))。

解读：

1、条件AND(C3="",D3="",E3="")的意思是C3、D3、E3中的三个单元格的值如果全部为空，公式=IF(AND(C3="",D3="",E3=""),"",SUM(C3:E3))返回空值，否则返回SUM(C3:E3)。

2、AND函数的作用可以理解为“并且”。

3、目的：判断每个科目的成绩，如果全部大于等于60分，责任合格，否则不合格。

方法：

在目标单元格中输入公式：=IF(AND(C3>=60,D3>=60,E3>=60),"合格","不合格")。

解读：

1、条件AND(C3>=60,D3>=60,E3>=60)的意思是如果C3、D3、E3三个单元格的值全部大于等于60，则返回“合格”，否则返回“不合格”。

4、目的：3科中有至少1科成绩大于等于60则为“及格”，否则为“不及格”。

方法：

在目标单元格中输入公式：=IF(OR(C3>=60,D3>=60,E3>=60),"及格","不及格")。

解读：

1、条件OR(C3>=60,D3>=60,E3>=60)的意思就是3科中至少有1科成绩大于等于60分，则返回“及格”，如果都小于60分，则返回“不及格”。

5、目的：判断“英语”成绩是否及格。

方法:

在目标单元格中输入公式：=IF(NOT(E3>=60),"不及格","及格")。

解读：

1、条件NOT(E3>=60)等同于C3<60，公式：=IF(NOT(E3>=60),"不及格","及格")就可以变换为:=IF(C3<60,"不及格","及格")。

2、NOT函数的作用就可以理解为“相反”。

6、目的：隐藏公式以外的其它错误。

方法：

在目标单元格中输入公式：=IFERROR(SUM(C3:E3)/COUNT(C3:E3),"")。

解读：

如果公式得不到正确的计算结果，则返回参数二的值。本示例中参数二的值为空，所以不予显示。

       用来判断真假值，或者进行复合检验的Excel函数，我们称为逻辑函数。在Excel中提供了六种逻辑函数。即AND、OR、NOT、FALSE、IF、TRUE函数。这章我们主要讲解AND、OR、NOT三个函数。详细介绍见下：

（一）AND函数

      所有参数的逻辑值为真时返回 TRUE；只要一个参数的逻辑值为假即返回 FALSE。简言之，就是当AND的参数全部满足某一条件时，返回结果为TRUE，否则为FALSE。

      语法为AND(logical1,logical2, ...)，其中Logical1, logical2, ... 表示待检测的 1 到 30 个条件值，各条件值可能为TRUE，可能为 FALSE。 参数必须是逻辑值，或者包含逻辑值的数组或引用。举例说明：

      1、 在B2单元格中输入数字50，在C2中写公式=AND(B2>30,B2<60)。由于B2等于50的确大于30、小于60。所以两个条件值（logical）均为真，则返回结果为TRUE。

图1 AND函数示例1

      2、 如果 B1-B3 单元格中的值为 TRUE、FALSE、TRUE，显然三个参数并不都为真，所以 在B4单元格中的公式=AND(B1:B3) 等于 FALSE

图2 AND函数示例2

（二）OR函数

      OR函数指在其参数组中，任何一个参数逻辑值为 TRUE，即返回 TRUE。它与AND函数的区别在于，AND函数要求所有函数逻辑值均为真，结果方为真。而OR函数仅需其中任何一个为真即可为真。比如，上面的示例2，如果在B4单元格中的公式写为=OR(B1:B3)则结果等于TRUE　

图3 OR函数示例

（三）NOT函数

      NOT函数用于对参数值求反。当要确保一个值不等于某一特定值时，可以使用 NOT 函数。简言之，就是当参数值为TRUE时，NOT函数返回的结果恰与之相反，结果为FALSE.

      比如NOT(2+2=4)，由于2+2的结果的确为4，该参数结果为TRUE，由于是NOT函数，因此返回函数结果与之相反，为FALSE。

据许多调查显示，SUM、VLOOKUP、IF是使用量最大的三个函数，前两个函数我们都已经说过了，本次我们就一起来揭开IF函数的神秘面纱。

其实只要我们留心观察，生活中到处都充满了IF函数。

如果成绩大于60分，就能及格，否则就不及格；

如果明天下雨，我就不去露营；

如果有网，我就玩电脑，否则睡觉；

如果我是女生，我一定会嫁给他。

太多这样的例子，三天三夜都举不完。

如下是某个班级的学生成绩表，根据成绩等级评判标准，<60为不及格，60-70为及格，70-80为中等，80-90为良好，90-100为优秀，如何快速对学生进行成绩等级判定呢？

这时我们就要用到IF函数啦，先判断小于60分：=IF(C3<60,"不及格")。那60-70分的怎么判断呢？可能很多人都会想到按照数学上的方法为：=IF(C3<60,"不及格",IF(60≤C3<70,"及格"))

公式报错了。其实，在计算机中处理多条件时，和我们所学的数学的表达方式是有差别的。当条件为小于等于时，我们使用<=而不是使用≤，同理大于等于使用>=。

对于多条件，我们还需要使用到另外的两个函数AND和OR，AND表示并且的意思，只有当所有的条件都为真时，结果才为真，其余都为假；OR表示或者的意思，当条件中全部为假时，结果才为假，其余均为真。二者的语法如下：

=AND(条件1，条件2，条件n)

=OR(条件1，条件2，条件n)

则上述的公式可以更改为：

=IF(C2<60,"不及格",IF(AND(C2>=60,C2<70),"及格",IF(AND(C2>=70,C2<80),"中等",IF(AND(C2>=80,C2<90),"良好",IF(AND(C2>=90,C2<100),"优秀")))))，结果如下：

针对本例中的成绩判断，其实如果我们换一个思路，公式可以简化很多，也就不用使用AND函数。我们从高等级向低等级判断，如果大于等于90为优秀，如果不大于90但是大于等于80为优秀，只有当成绩不是优秀时，才会继续判断，所示此时第二个条件中没必要再判断是否小于90，如下：

=IF(C2>=90,"优秀",IF(C2>=80,"良好",IF(C2>=70,"中等",IF(C2>=60,"及格","不及格"))))。这样是不是简洁了许多？在

Excel函数和公式的运用中，有时候我们要多角度的考虑问题，这样才能写出更高效的公式！！！

IF函数家族起到的主要是辅助的作用，其实也不用学得太深，只要知道常用的方法就行了，如果大家学了数组函数之后，IF函数还会有一些更高级的用法，此处先不说。

IF函数是WPS Excel中常用的条件判断函数，常和逻辑函数AND、OR和NOT一起使用，本文将通过实例说明怎样使用IF函数和逻辑函数。

IF的基本用法。

IF函数的语法为“IF(条件，条件成立时的结果，条件不成立时的结果)”。

实例：假设某地法定结婚年龄为：男不小于于二十二周岁，女小于于二十周岁。以下几个人，可以结婚吗？

解决：这个问题一个简单的IF公式就可以解决了，相信大家都会，就不多赘述了。

IF和AND一起使用。

实例：假设某地法定结婚年龄为：男不小于二十二周岁，女小于二十周岁。以下几对朋友可以结婚吗？

解决：公式如图所示，我们在条件中使用AND函数，表示括号中的两个条件要同时满足时，才可以结婚。

IF和OR一起使用。

实例：以下几对朋友结婚了，他们的孩子可以在上海落户吗？

解决：和上一个实例非常类似，只是将AND替换成了OR。OR函数括号中的两个条件只要有一个满足就可以了，当然如果都满足，也可以。

另外，如果你的表格整理成了上图表2的样子，也可以用“=IF(OR(B16,D16),"可以","不可以")”来获得结果。

IF和NOT一起使用。

实例：假设学校规定：给满分的人发放500元奖励。以下几位有奖励吗？

解决：NOT表示逻辑取反，通俗的地将就是括号中的条件不成立时，得到IF函数中第二个参数的值。用在这个例子中，也就是B6到B11的数值不等于100时，奖励是0。

NOT函数的解释听起来多少有点拗口，它又常常可以用别的方式替换，例如可以用“=IF(B15=100,500,0)”替换上述含NOT函数的IF公式，因而不常用。

多条件和ANDORNOT一起使用。

实例1：假设雅城规定：必须在当地缴纳社保满2年，并且名下没有房子，才可以购房。以下几对夫妇可以在雅城买房吗？

解决：这个例子中“社保满2年”的条件只要一方满足就可以了，因而用“OR(B8>=2,E8>=2)”，而这个条件和双方名下无房又必须同时成立，因而需要用到AND，最后我们就得到了图示的公式。

实例2：假设雅城规定：户籍地是雅城的，可以购买房子；外地人要求：在当地缴纳社保满2年，并且名下没有房子，才可以购房。以下几对夫妇可以在雅城买房吗？

解决：这个例子是上个例子的升华，比上个例子多了个选择，因而公式也变得复杂了。我特地标了颜色，希望朋友们没有看晕。

这样复杂的条件下，IF和ANDORNOT一起使用，根据不同的思路，可以写出不同的公式啦，不推荐写过长的IF公式。输入公式函数时，左括号和右括号建议同时输入。

谢谢阅读，每天学一点，省下时间充实自己其他能力。欢迎点赞、评论、关注和点击头像。

前面几节课，我们简单介绍了IF、OR、AND的用法，IF 单独使用的情况较多，但是OR、AND一般嵌入IF的函数中使用的概率较高，今天我们趁热打铁，讲讲这三者的使用方式~~

01 视频讲解

02 文字详解

案例：2项都在90分及以上值为"优秀"，有1项目90分及以上"良好"，否则"一般"。

公式使用：IF(AND(B4>=90,C4>=90),"优秀",IF(OR(B4>=90,C4>=90),"良好","一般"))

鼠标放置D4单元格右下角，变为黑色十字，双击往下自动填充公式

结果：

以上就是IF、OR、AND嵌套使用方法，有什么不明白的地方欢迎在下方留言，我们将及时给你答复~~

平时工作中，我们经常用到的函数可能就是：如果“IF”，根据字面意思理解，基本上就是如果什么什么，那么什么什么，否则什么什么。但是，有是我们需要对IF增加条件的情况，就难免会遇到And和Or了，字面意思上也就是什么和什么，什么或什么的情况。下面就给大家简单介绍下二者与IF函数的组合使用。

函数简析

1、IF函数

=IF(条件,条件为真返回值,条件为假返回值)，如：=IF（A2>=60，"及格"，"不及格"）

2、AND函数

=AND（条件1，条件2），同时满足

3、=OR（条件1，条件2），满足其一

实例演示

利用AND函数或OR函数与IF函数组合，判断不同条件下，某同志项目工作完成量是否达标

条件一：项目之一完成率超60%达标

公式：=IF(OR(C3>=60%,D3>=60%),"达标","不达标")

条件二：2个项目均超过60%达标

公式：=IF(AND(C3>=60%,D3>=60%),"达标","不达标")

小结

本文以Excel2007为例，理论上支持所有Excel版本。文中紧给大家做了AND和OR与IF函数简单的嵌套使用，可以根据自身使用情况，做多层嵌套效果，或三者混合嵌套效果，利用IF函数的输出结果可实现多层嵌套哟！

如果对您有所帮助，感谢点赞！关注获取更多电脑或Office经验分享！

经常使用Excel函数的小伙伴们都知道，在Excel中使用频率最高的还是那些比较简单的函数，其中IF函数就是高频率函数之一，那么，能不能用IF函数来进行多条件运算呢？

一、IF+AND：同时满足多个条件

目的：将“上海”地区的“男”通知标识为“Y”。

方法：

在目标单元格中输入公式：=IF(AND(D3="男",E3="上海"),"Y","")。

解读：

1、AND函数的语法：AND(条件1,=标准1，条件2=标准2……条件N=标准N）。如果每个条件和标准都相等，则返回TRUE，否则返回FALSE 。

2、用IF函数判断AND函数的返回结果，如果为TRUE，则返回“Y”，否则返回""。

二、IF+OR:满足多个条件中的一个即可。

目的：将性别为“男”或地区为“上海”的标记为“Y”。

方法：

在目标单元格中输入公式：=IF(OR(D3="男",E3="上海"),"Y","")。

解读：

1、OR函数的语法结构为：(条件1,=标准1，条件2=标准2……条件N=标准N）。如果任意参数的值为TRUE，则返回TRUE ,当所有条件为FALSE时，才返回FALSE。

2、用IF函数判断OR函数的返回结果，如果为TRUE,则返回“Y”，否则返回""。

if函数是 Excel 中的条件判断函数，它由条件与两个返回结果组成，当条件成立时，返回真，否则返回假。if函数中的条件既可以单条件，也可以是多条件；多条件组合有三种方式，一种为多个 if 嵌套，第二种为用 And（或 *）组合多个条件，第三种为用 Or（或 +）组合多个条件。用 And（或 *）组合条件是“与”的关系，用 Or(或 +）组合条件是“或”的关系，它们的写法比 if 嵌套简单。以下就是它们的具体操作方法，实例中操作所用版本均为 Excel 2016。

一、Excel if函数语法

1、表达式：IF（logical_test,[value_if_true],[value_if_false])

中文表达式：如果（条件，条件为真时执行的操作，条件为假时执行的操作）

2、说明：[value_if_true] 和 [value_if_false] 表示可选项，即它们可以不写，如图1所示：

按回车，返回 False，因为 E2 为 435，F2 为 528，E2 > F2 不成立，如图2所示：

另外，=IF(3 > 2,)，返回 0，此处 0 表示假。

二、Excel if函数单条件使用方法

1、一个服装销量表中，价格为0的表示已下架，否则表示正在出售，假如要把它们分别用“下架”和“出售中”标识出来，操作过程步骤，如图3所示：

2、操作过程步骤说明：选中 H2 单元格，输入公式 =IF(E2<=0,"下架","出售中")，按回车，则返回“出售中”；把鼠标移到 H2 右下角的单元格填充柄上，按住左键并往下拖，则所经过单元格全填充为“出售中”，按 Ctrl + S 保存，则价格为 0 的单元格用“下架”填充，其它单元格用“出售中”填充。

3、公式说明：公式 =IF(E2<=0,"下架","出售中") 中，E2<=0 为条件，当条件为真时，返回“下架”，否同返回“出售中”。

三、Excel if函数嵌套多条件使用方法

1、假如要标出服装销量表中，“大类”为“女装”、“价格”大于等于 80 且“销量”大于 800 的服装，操作过程步骤，如图4所示：

2、操作过程步骤说明：选中 H2 单元格，把公式 =IF(C2="女装",IF(E2>=80,IF(F2>800,"满足条件","不满足条件"),"不满足条件"),"不满足条件") 复制到 H2，按回车，则返回“不满足条件”；再次选中 H2，把鼠标移到 H2 的单元格填充柄上，按住左键并往下拖，则所经过单元格用“不满足条件”填充，按 Ctrl + S 保存，同样 H3 用“满足条件”填充，其它单元格仍用“不满足条件”填充。

3、公式说明：

=IF(C2="女装",IF(E2>=80,IF(F2>800,"满足条件","不满足条件"),"不满足条件"),"不满足条件")

由三个 if 组成，即在一个 if 中嵌套了两个 if。第一个 if 的条件为 C2="女装"，如果条件为真，则执行 IF(E2>=80,IF(F2>800,"满足条件","不满足条件"),"不满足条件")；否则返回“不满足条件”。第二个 if 的条件为 E2>=80，如果条件为真，则执行 IF(F2>800,"满足条件","不满足条件")，否则返回“不满足条件”。第三个 if 的条件为 F2>800，如果条件为真，返回“满足条件”，否则返回“不满足条件”。

提示：if 最多只能嵌套 64 个 if，尽管如此，在写公式过程中，尽量少嵌套 if；一方面便于阅读与修改，另一方面执行效率也高一些。

四、Excel if函数用 And 与 OR 组合多个条件使用方法

（一）用 And 组合多个条件，为“与”的关系

1、把上例中的多 if 嵌套公式 =IF(C2="女装",IF(E2>=80,IF(F2>800,"满足条件","不满足条件"),"不满足条件"),"不满足条件") 改为用 And 组合，操作过程步骤，如图5所示：

2、操作过程步骤说明：选中 H2 单元格，把公式 =IF(AND(C2="女装",E2>=80,F2>800),"满足条件","不满足条件") 复制到 H2，按回车，则返回“不满足条件”；同样往下拖并保存，返回跟上例一样的结果，说明公式正确。

3、公式说明：

=IF(AND(C2="女装",E2>=80,F2>800),"满足条件","不满足条件")

公式用 And 函数组合了三个条件，分别为 C2="女装",E2>=80,F2>800，当同时满足三个条件时（即 AND(C2="女装",E2>=80,F2>800) 返回“真”），返回“满足条件”，否则返回“不满足条件”。

4、用 * 代替 And

A、把公式　　=IF(AND(C2="女装",E2>=80,F2>800),"满足条件","不满足条件")

用 * 代替 And 后变为：

=IF((C2="女装")*(E2>=80)*(F2>800),"满足条件","不满足条件")

如图6所示：

B、按回车，返回“不满足条件”，往下拖保存后，也是返回一样的结果。

（二）用 Or 组合多个条件，为“或”的关系

1、把上例中的 And 组合多个条件公式 =IF(AND(C2="女装",E2>=80,F2>800),"满足条件","不满足条件") 改为用 Or 组合，操作过程步骤，如图7所示：

2、操作过程步骤说明：选中 H2 单元格，把公式 =IF(OR(C2="女装",E2>=80,F2>800),"满足条件","不满足条件") 复制到 H2，按回车，则返回“满足条件”；同样往下拖并保存，全部返回“满足条件”。

3、公式说明：

=IF(OR(C2="女装",E2>=80,F2>800),"满足条件","不满足条件")

公式用 Or 函数组合了三个条件，分别为 C2="女装",E2>=80,F2>800，即 OR(C2="女装",E2>=80,F2>800)，意思是：只要满足一个条件，就返回“真”；一条件都不满足才返回“假”。演示中，每条记录都满足一个条件，所以全返回“满足条件”。

4、用 + 代替 Or

A、把公式

=IF(OR(C2="女装",E2>=80,F2>800),"满足条件","不满足条件")

用 + 代替 Or 后变为：

=IF((C2="女装")+(E2>=80)+(F2>800),"满足条件","不满足条件")

如图8所示：

B、按回车，返回“满足条件”，往下拖保存后，也是全部返回“满足条件”，说明公式正确。

前期我们讲了

满足某个条件下求出所需值的if；

两个条件及以上只要满足其中1个条件即可求出所需值的or；

今天，给大家介绍的是同时满足两个及以上的条件求出所需值的and

视频讲解

文字详解

案例：每门课程都在80分及以上值为"TRUE"，反之"FALSE"。

公式使用：AND(B3>=80,C3>=80)

鼠标放置D3单元格右下角，变为黑色十字，双击往下自动填充公式

结果：

以上就是and函数的用法，有什么不明白的地方欢迎在下方留言，我们将及时给你答复~~

下期你最想学习哪个函数

也欢迎在底下给我们留言