我们在做人事档案的时候，经常要对个人的信息进行对比，例如不能录入重复的数据，而检测数据是否重复的最简单的方法就是判断身份证号是否重复。这时候我们想到的应该是COUNTIF函数。

一、常规做法（错误做法）。

方法：

在目标单元格中输入公式：=IF(COUNTIF($C$3:$C$10,C3)>1,"重复","")。

备注：

1、我们从计算的结果中可以发现，第1条记录和第7条记录中的身份证号确实一样，暨重复，但是第4条记录的身份证号与第1条和第7条的身份证号并不相同。那为什么还判断为“重复”呢？

2、问题剖析：虽然C列的身份证号存储类型为文本，但是COUNTIF函数在处理时，会将文本数值类型识别为数据类型进行处理。而在Excel中，当数字超过15位时，有效数字只保留15位，后面的全部视为0处理。因此COUNTIF函数会将C3、C6、C9识别为相同的内容。

二、正确做法。

方法：

在目标单元格中输入公式：=IF(COUNTIF($C$3:$C$10,C3&"*")>1,"重复","")。

备注：

1、比较两个公式，我们不难发现第二个公式中COUNTIF函数的条件参数（暨第二个参数）发生了变化，变成了C3&"*"。

2、使用通配符“*”的目的使其强行识别为文本进行统计，相当于告诉Excel：我们要统计的内容是以C3单元格开头的文本。

求和函数是Excel中应用最广泛的函数之一，其中SUMIF函数又是条件求和的主力干将。但对于SUMIF函数的应用技巧，你全都掌握吗？

一、语法结构。

SUMIF(range,criteria,[sum_range])。

易解结构：SUMIF(条件所在的单元格区域，条件，[求和的实际单元格])。

备注：

参数range、criteria是必须的，sum_range是可选的。如果第三个参数缺省，默认的是对第一个参数区域求和。

二、单字段单条件求和。

方法：

在目标单元格中输入公式：=SUMIF(E3:E9,H3,C3:C9)。

三、单字段多条件求和。

方法：

在目标单元格中输入公式：=SUM(SUMIF(E3:E9,{"上海","北京","苏州"},C3:C9))。

四、单字段模糊条件求和。

目的：计算出姓名中含有“小”的销售总额。

方法：

在目标单元格中输入公式：=SUMIF(B3:B9,"*小*",C3:C9)。

五、排除错误求和。

目的：计算销售总额。

方法：

在目标单元格中输入公式：=SUMIF(C3:C9,"<9e307")。

备注：

1、用SUM函数求和返回错误值。

2、9e307是Excel中能接受的最大值，计算小于最大值的和。得到我们想要的结果。

六、隔列求和。

方法：

在目标单元格中输入公式：=SUMIF($C$3:$H$3,I$3,$C4:$H4)。

1、取绝对值

=ABS(数字)

2、取整

=INT(数字)

3、四舍五入

=ROUND(数字,小数位数)

二、判断公式

1、把公式产生的错误值显示为空

公式：C2

=IFERROR(A2/B2,"")

说明：如果是错误值则显示为空，否则正常显示。

2、IF多条件判断返回值

公式：C2

=IF(AND(A2<500,B2="未到期"),"补款","")

说明：两个条件同时成立用AND,任一个成立用OR函数。

三、统计公式

1、统计两个表格重复的内容

公式:B2

=COUNTIF(Sheet15!A:A,A2)

说明：如果返回值大于0说明在另一个表中存在，0则不存在。

2、统计不重复的总人数

公式：C2

=SUMPRODUCT(1/COUNTIF(A2:A8,A2:A8))

说明:用COUNTIF统计出每人的出现次数，用1除的方式把出现次数变成分母，然后相加。

四、求和公式

1、隔列求和

公式：H3

=SUMIF($A$2:$G$2,H$2,A3:G3)

或

=SUMPRODUCT((MOD(COLUMN(B3:G3),2)=0)*B3:G3)

说明：如果标题行没有规则用第2个公式

2、单条件求和

公式：F2

=SUMIF(A:A,E2,C:C)

说明：SUMIF函数的基本用法

3、单条件模糊求和

公式：详见下图

说明：如果需要进行模糊求和，就需要掌握通配符的使用，其中星号是表示任意多个字符，如"*A*"就表示a前和后有任意多个字符，即包含A。

4、多条件模糊求和

公式：C11

=SUMIFS(C2:C7,A2:A7,A11&"*",B2:B7,B11)

说明：在sumifs中可以使用通配符*

5、多表相同位置求和

公式：b2

=SUM(Sheet1:Sheet19!B2)

说明：在表中间删除或添加表后，公式结果会自动更新。

6、按日期和产品求和

公式：F2

=SUMPRODUCT((MONTH($A$2:$A$25)=F$1)*($B$2:$B$25=$E2)*$C$2:$C$25)

说明：SUMPRODUCT可以完成多条件求和

五、查找与引用公式

1、单条件查找公式

公式1：C11

=VLOOKUP(B11,B3:F7,4,FALSE)

说明：查找是VLOOKUP最擅长的，基本用法

2、双向查找公式

公式：

=INDEX(C3:H7,MATCH(B10,B3:B7,0),MATCH(C10,C2:H2,0))

说明：利用MATCH函数查找位置，用INDEX函数取值

3、查找最后一条符合条件的记录。

公式：详见下图

说明：0/(条件)可以把不符合条件的变成错误值，而lookup可以忽略错误值

4、多条件查找

公式:详见下图

说明:公式原理同上一个公式

5、指定区域最后一个非空值查找

公式;详见下图

说明：略

6、按数字区域间取对应的值

公式：详见下图

公式说明：VLOOKUP和LOOKUP函数都可以按区间取值，一定要注意，销售量列的数字一定要升序排列。

六、字符串处理公式

1、多单元格字符串合并

公式：c2

=PHONETIC(A2:A7)

说明：Phonetic函数只能对字符型内容合并，数字不可以。

2、截取除后3位之外的部分

公式：

=LEFT(D1,LEN(D1)-3)

说明：LEN计算出总长度,LEFT从左边截总长度-3个

3、截取-前的部分

公式:B2

=Left(A1,FIND("-",A1)-1)

说明：用FIND函数查找位置，用LEFT截取。

4、截取字符串中任一段的公式

公式:B1

=TRIM(MID(SUBSTITUTE($A1," ",REPT(" ",20)),20,20))

说明:公式是利用强插N个空字符的方式进行截取

5、字符串查找

公式：B2

=IF(COUNT(FIND("河南",A2))=0,"否","是")

说明: FIND查找成功，返回字符的位置，否则返回错误值，而COUNT可以统计出数字的个数，这里可以用来判断查找是否成功。

6、字符串查找一对多

公式：B2

=IF(COUNT(FIND({"辽宁","黑龙江","吉林"},A2))=0,"其他","东北")

说明：设置FIND第一个参数为常量数组，用COUNT函数统计FIND查找结果

七、日期计算公式

1、两日期相隔的年、月、天数计算

A1是开始日期（2011-12-1），B1是结束日期(2013-6-10)。计算：

相隔多少天？=datedif(A1,B1,"d") 结果：557

相隔多少月? =datedif(A1,B1,"m") 结果：18

相隔多少年? =datedif(A1,B1,"Y") 结果：1

不考虑年相隔多少月？=datedif(A1,B1,"Ym") 结果：6

不考虑年相隔多少天？=datedif(A1,B1,"YD") 结果：192

不考虑年月相隔多少天？=datedif(A1,B1,"MD") 结果：9

datedif函数第3个参数说明：

"Y" 时间段中的整年数。

"M" 时间段中的整月数。

"D" 时间段中的天数。

"MD" 天数的差。忽略日期中的月和年。

"YM" 月数的差。忽略日期中的日和年。

"YD" 天数的差。忽略日期中的年。

2、扣除周末天数的工作日天数

公式：C2

=NETWORKDAYS.INTL(IF(B2

说明：返回两个日期之间的所有工作日数，使用参数指示哪些天是周末，以及有多少天是周末。周末和任何指定为假期的日期不被视为工作日

今天花点心思写一下excel中if函数的用法，可能在数据小的时候大家用不到这些函数，但是如果表格数据量非常大的时候，那么excel中if函数的节省时间的效果出出来了。

在使用if函数之前，我先把数据准备好，以一个班级的语文成绩为例，依照不及格<60，60<良<80,优秀>80来划分成绩等级。

当然了三个判定条件大家一开始理解不了，可以先从及格不及格简单的判定开始了解if函数的用法。那么在C2中判定及格与不及格的if函数写法是=IF(B2>=60,"及格","不及格")。

我们先点击C2单元格，然后在上方的公式输入框中输入我们的if函数，按回车键运行一下函数就可以了，然后通过C2单元格右下角的下拉复制功能，将函数应用到C2下方的其它单元格中就可以了。

简单的使用if函数判定成绩及格与不及格就弄好了，接下来我们再讲下有三个条件的if函数的使用方法，具体要用的if函数公式如下。=IF(B2<60,"不及格",IF(B2<80,"良","优秀"))。

上面的公式很好理解，第一个if函数如果分数小于60，就输出不及格，否得花就进行第二个if函数的判定，如果分数小于80就输出良，大于80就输入优秀。在D2中输入完公式后按回车键运行公式结果。

接下来就是把D2的公式应用到下方的单元格中，记住不要用复制，一定要点击D2右下角按住鼠标不放下拉就可以了。这样excel中if函数的使用的简单方法就教给大家了。霸气走火就是我，我就是百度经验作者：ixlxt7Xzsl7，百度经验和百家号首发原创内容分享。

一、员工信息表公式

1、计算性别(F列)

=IF(MOD(MID(E3,17,1),2),"男","女")

2、出生年月(G列)

=TEXT(MID(E3,7,8),"0-00-00")

3、年龄公式(H列)

=DATEDIF(G3,TODAY(),"y")

4、退休日期(I列)

=TEXT(EDATE(G3,12*(5*(F3="男")+55)),"yyyy/mm/dd aaaa")

5、籍贯(M列)

=VLOOKUP(LEFT(E3,6)*1,地址库!E:F,2,)

注：附带示例中有地址库代码表

6、社会工龄(T列)

=DATEDIF(S3,NOW(),"y")

7、公司工龄(W列)

=DATEDIF(V3,NOW(),"y")&"年"&DATEDIF(V3,NOW(),"ym")&"月"&DATEDIF(V3,NOW(),"md")&"天"

8、合同续签日期(Y列)

=DATE(YEAR(V3)+LEFTB(X3,2),MONTH(V3),DAY(V3))-1

9、合同到期日期(Z列)

=TEXT(EDATE(V3,LEFTB(X3,2)*12)-TODAY(),"[<0]过期0天;[<30]即将到期0天;还早")

10、工龄工资(AA列)

=MIN(700,DATEDIF($V3,NOW(),"y")*50)

11、生肖(AB列)

=MID("猴鸡狗猪鼠牛虎兔龙蛇马羊",MOD(MID(E3,7,4),12)+1,1)

二、员工考勤表公式

1、本月工作日天数(AG列)

=NETWORKDAYS(B$5,DATE(YEAR(N$4),MONTH(N$4)+1,),)

2、调休天数公式(AI列)

=COUNTIF(B9:AE9,"调")

3、扣钱公式(AO列)

婚丧扣10块，病假扣20元，事假扣30元，矿工扣50元

=SUM((B9:AE9={"事";"旷";"病";"丧";"婚"})*{30;50;20;10;10})

四、员工数据分析公式

1、本科学历人数

=COUNTIF(D:D,"本科")

2、办公室本科学历人数

=COUNTIFS(A:A,"办公室",D:D,"本科")

3、30~40岁总人数

=COUNTIFS(F:F,">=30",F:F,"<40")

五、其他公式

1、提成比率计算

=VLOOKUP(B3,$C$12:$E$21,3)

2、个人所得税计算

假如A2中是应税工资，则计算个税公式为：

=5*MAX(A2*{0.6,2,4,5,6,7,9}%-{21,91,251,376,761,1346,3016},)

3、工资条公式

=CHOOSE(MOD(ROW(A3),3)+1,工资数据源!A$1,OFFSET(工资数据源!A$1,INT(ROW(A3)/3),,),"")

注：

A3:标题行的行数+2,如果标题行在第3行，则A3改为A5

工资数据源!A$1:工资表的标题行的第一列位置

4、Countif函数统计身份证号码出错的解决方法

由于Excel中数字只能识别15位内的，在Countif统计时也只会统计前15位，所以很容易出错。不过只需要用 &"*" 转换为文本型即可正确统计。

=Countif(A:A,A2&"*")

六、利用数据透视表完成数据分析

1、各部门人数占比

统计每个部门占总人数的百分比

2、各个年龄段人数和占比

公司员工各个年龄段的人数和占比各是多少呢？

3、各个部门各年龄段占比

分部门统计本部门各个年龄段的占比情况

4、各部门学历统计

各部门大专、本科、硕士和博士各有多少人呢？

5、按年份统计各部门入职人数

每年各部门入职人数情况

（一）IF函数说明      

      IF函数用于执行真假值判断后，根据逻辑测试的真假值返回不同的结果，因此If函数也称之为条件函数。它的应用很广泛，可以使用函数 IF 对数值和公式进行条件检测。

     它的语法为IF(logical_test,value_if_true,value_if_false)。其中Logical_test表示计算结果为 TRUE 或 FALSE 的任意值或表达式。本参数可使用任何比较运算符。

     Value_if_true显示在logical_test 为 TRUE 时返回的值，Value_if_true 也可以是其他公式。Value_if_false logical_test 为 FALSE 时返回的值。Value_if_false 也可以是其他公式。

     简言之，如果第一个参数logical_test返回的结果为真的话，则执行第二个参数Value_if_true的结果，否则执行第三个参数Value_if_false的结果。IF函数可以嵌套七层，用 value_if_false 及 value_if_true 参数可以构造复杂的检测条件。

     Excel 还提供了可根据某一条件来分析数据的其他函数。例如，如果要计算单元格区域中某个文本串或数字出现的次数，则可使用 COUNTIF 工作表函数。如果要根据单元格区域中的某一文本串或数字求和，则可使用 SUMIF 工作表函数。

（二）IF函数应用

1、 输出带有公式的空白表单

图4 人事分析表1

      以图中所示的人事状况分析表为例，由于各部门关于人员的组成情况的数据尚未填写，在总计栏（以单元格G5为例）公式为： =SUM(C5:F5)

      我们看到计算为0的结果。如果这样的表格打印出来就页面的美观来看显示是不令人满意的。是否有办法去掉总计栏中的0呢？你可能会说，不写公式不就行了。当然这是一个办法，但是，如果我们利用了IF函数的话，也可以在写公式的情况下，同样不显示这些0。如何实现呢？只需将总计栏中的公式（仅以单元格G5为例）改写成：=IF(SUM(C5:F5),SUM(C5:F5),"")

     通俗的解释就是：如果SUM(C5:F5)不等于零，则在单元格中显示SUM(C5:F5)的结果，否则显示字符串。

几点说明：

（1） SUM(C5:F5)不等于零的正规写法是SUM(C5:F5)<>0，在EXCEL中可以省略<>0；

（2） ""表示字符串的内容为空，因此执行的结果是在单元格中不显示任何字符。

图5

2、 不同的条件返回不同的结果

      如果对上述例子有了很好的理解后，我们就很容易将IF函数应用到更广泛的领域。比如，在成绩表中根据不同的成绩区分合格与不合格。现在我们就以某班级的英语成绩为例具体说明用法。

图6

      某班级的成绩如图6所示，为了做出最终的综合评定，我们设定按照平均分判断该学生成绩是否合格的规则。如果各科平均分超过60分则认为是合格的，否则记作不合格。

      根据这一规则，我们在综合评定中写公式（以单元格B12为例）：=IF(B11>60,"合格","不合格")

      语法解释为，如果单元格B11的值大于60，则执行第二个参数即在单元格B12中显示合格字样，否则执行第三个参数即在单元格B12中显示不合格字样。

      在综合评定栏中可以看到由于C列的同学各科平均分为54分，综合评定为不合格。其余均为合格。

3、 多层嵌套函数的应用

     在上述的例子中，我们只是将成绩简单区分为合格与不合格，在实际应用中，成绩通常是有多个等级的，比如优、良、中、及格、不及格等。有办法一次性区分吗？可以使用多层嵌套的办法来实现。仍以上例为例，我们设定综合评定的规则为当各科平均分超过90时，评定为优秀。如图7所示。

图7

      说明：为了解释起来比较方便，我们在这里仅做两重嵌套的示例，您可以按照实际情况进行更多重的嵌套，但请注意Excel的IF函数最多允许七重嵌套。

      根据这一规则，我们在综合评定中写公式（以单元格F12为例）：=IF(F11>60,IF(AND(F11>90),"优秀","合格"),"不合格")

      语法解释为，如果单元格F11的值大于60，则执行第二个参数，在这里为嵌套函数，继续判断单元格F11的值是否大于90（为了让大家体会一下AND函数的应用，写成AND(F11>90)，实际上可以仅写F11>90），如果满足在单元格F12中显示优秀字样，不满足显示合格字样，如果F11的值以上条件都不满足，则执行第三个参数即在单元格F12中显示不合格字样。

     在综合评定栏中可以看到由于F列的同学各科平均分为92分，综合评定为优秀。

（三）根据条件计算值

      在了解了IF函数的使用方法后，我们再来看看与之类似的Excel提供的可根据某一条件来分析数据的其他函数。例如，如果要计算单元格区域中某个文本串或数字出现的次数，则可使用 COUNTIF 工作表函数。如果要根据单元格区域中的某一文本串或数字求和，则可使用 SUMIF 工作表函数。关于SUMIF函数在数学与三角函数中以做了较为详细的介绍。这里重点介绍COUNTIF的应用。

     COUNTIF可以用来计算给定区域内满足特定条件的单元格的数目。比如在成绩表中计算每位学生取得优秀成绩的课程数。在工资表中求出所有基本工资在2000元以上的员工数。

     语法形式为COUNTIF(range,criteria)。其中Range为需要计算其中满足条件的单元格数目的单元格区域。Criteria确定哪些单元格将被计算在内的条件，其形式可以为数字、表达式或文本。例如，条件可以表示为 32、"32"、">32"、"apples"。

1、成绩表

这里仍以上述成绩表的例子说明一些应用方法。我们需要计算的是：每位学生取得优秀成绩的课程数。规则为成绩大于90分记做优秀。如图8所示

图8

       根据这一规则，我们在优秀门数中写公式（以单元格B13为例）：=COUNTIF(B4:B10,">90")

      语法解释为，计算B4到B10这个范围，即jarry的各科成绩中有多少个数值大于90的单元格。

      在优秀门数栏中可以看到jarry的优秀门数为两门。其他人也可以依次看到。

2、 销售业绩表

      销售业绩表可能是综合运用IF、SUMIF、COUNTIF非常典型的示例。比如，可能希望计算销售人员的订单数，然后汇总每个销售人员的销售额，并且根据总发货量决定每次销售应获得的奖金。

      原始数据表如图9所示（原始数据是以流水单形式列出的，即按订单号排列）

图9 原始数据表

按销售人员汇总表如图10所示

图10 销售人员汇总表

      如图10所示的表完全是利用函数计算的方法自动汇总的数据。首先建立一个按照销售人员汇总的表单样式，如图所示。然后分别计算订单数、订单总额、销售奖金。

（1） 订单数 --用COUNTIF计算销售人员的订单数。以销售人员ANNIE的订单数公式为例。公式：=COUNTIF($C$2:$C$13,A17)

     语法解释为计算单元格A17(即销售人员ANNIE)在"销售人员"清单$C$2:$C$13的范围内（即图9所示的原始数据表）出现的次数。这个出现的次数即可认为是该销售人员ANNIE的订单数。

（2） 订单总额--用SUMIF汇总每个销售人员的销售额。以销售人员ANNIE的订单总额公式为例。公式：=SUMIF($C$2:$C$13,A17,$B$2:$B$13)

    此公式在"销售人员"清单$C$2:$C$13中检查单元格A17 中的文本（即销售人员ANNIE），然后计算"订单金额"列（$B$2:$B$13）中相应量的和。这个相应量的和就是销售人员ANNIE的订单总额。

（3） 销售奖金--用IF根据订单总额决定每次销售应获得的奖金。

     假定公司的销售奖金规则为当订单总额超过5万元时，奖励幅度为百分之十五，否则为百分之十。根据这一规则仍以销售人员ANNIE为例说明。公式为：=IF(C17<50000,10%,15%)*C17

     如果订单总额小于 50000则奖金为 10%；如果订单总额大于等于 50000，则奖金为 15%。

     至此，我们已完全了解了EXCEL函数的逻辑函数，相信大家在实际工作中会想出更多更有用的运用。

转载自百家号作者：Excel函数公式

Excel中的计数应用也是非常的普遍的，常用的函数有：COUNT、COUNTA、COUNTBLANK、COUNTIF、COUNTIFS等。今天我们来学习COUNTIF的5个超经典用法。

一、语法结构。

COUNTIF(range,criteria)。

参数：

range:必需。要计算非空单元格的区域。

criteria：必需。计数时的条件。可以是数字，表达式，文本等。

二、单条件统计。

目的：统计出“上海”地区的销售员。

方法：

在目标单元格中输入公式：=COUNTIF(E3:E9,"上海")。

解读：

单条件统计是COUNTIF函数的最基本用法，只需要根据语法结构直接使用即可。

三、单列多条件统计。

目的：统计出“北京”和“上海”地区的销售员。

方法：

在目标单元格中输入公式：=SUM(COUNTIF(E3:E9,{"北京","上海"}))。

解读：

利用COUNTIF函数分别统计出“北京”和“上海”的销售员个数，然后用SUM求和。

四、求销量大于50的人数。

目的：统计出销量大于等于50的销售员人数。

方法：

在目标单元格中输入公式：=COUNTIF(C3:C9,">=50")。

五、统计是否重复。

目的：检测销售员姓名是否重复。

方法：

在目标单元格中输入公式：=IF(COUNTIF(B$3:B3,B3)>1,"重复","")。

解读：

利用IF函数判断姓名是否重复，COUNTIF(B$3:B3,B3)>1为判断条件，如果从当前单元格开始到下一单元格，单元格内容的个数大于1，就返回“重复”，否则返回空值。

六、禁止重复录入数据。

目的：防止重复录入姓名。

方法：

1、选定目标单元格。

2、【数据】-【数据验证】，选择【允许】中的【自定义】，在【公式】中输入：=COUNTIF($B$3:$B$9,B3)=1。

3、单击【出错警告】标签，录入警告信息并【确定】。

据许多调查显示，SUM、VLOOKUP、IF是使用量最大的三个函数，前两个函数我们都已经说过了，本次我们就一起来揭开IF函数的神秘面纱。

其实只要我们留心观察，生活中到处都充满了IF函数。

如果成绩大于60分，就能及格，否则就不及格；

如果明天下雨，我就不去露营；

如果有网，我就玩电脑，否则睡觉；

如果我是女生，我一定会嫁给他。

太多这样的例子，三天三夜都举不完。

如下是某个班级的学生成绩表，根据成绩等级评判标准，<60为不及格，60-70为及格，70-80为中等，80-90为良好，90-100为优秀，如何快速对学生进行成绩等级判定呢？

这时我们就要用到IF函数啦，先判断小于60分：=IF(C3<60,"不及格")。那60-70分的怎么判断呢？可能很多人都会想到按照数学上的方法为：=IF(C3<60,"不及格",IF(60≤C3<70,"及格"))

公式报错了。其实，在计算机中处理多条件时，和我们所学的数学的表达方式是有差别的。当条件为小于等于时，我们使用<=而不是使用≤，同理大于等于使用>=。

对于多条件，我们还需要使用到另外的两个函数AND和OR，AND表示并且的意思，只有当所有的条件都为真时，结果才为真，其余都为假；OR表示或者的意思，当条件中全部为假时，结果才为假，其余均为真。二者的语法如下：

=AND(条件1，条件2，条件n)

=OR(条件1，条件2，条件n)

则上述的公式可以更改为：

=IF(C2<60,"不及格",IF(AND(C2>=60,C2<70),"及格",IF(AND(C2>=70,C2<80),"中等",IF(AND(C2>=80,C2<90),"良好",IF(AND(C2>=90,C2<100),"优秀")))))，结果如下：

针对本例中的成绩判断，其实如果我们换一个思路，公式可以简化很多，也就不用使用AND函数。我们从高等级向低等级判断，如果大于等于90为优秀，如果不大于90但是大于等于80为优秀，只有当成绩不是优秀时，才会继续判断，所示此时第二个条件中没必要再判断是否小于90，如下：

=IF(C2>=90,"优秀",IF(C2>=80,"良好",IF(C2>=70,"中等",IF(C2>=60,"及格","不及格"))))。这样是不是简洁了许多？在

Excel函数和公式的运用中，有时候我们要多角度的考虑问题，这样才能写出更高效的公式！！！

IF函数家族起到的主要是辅助的作用，其实也不用学得太深，只要知道常用的方法就行了，如果大家学了数组函数之后，IF函数还会有一些更高级的用法，此处先不说。

经常使用Excel函数的小伙伴们都知道，在Excel中使用频率最高的还是那些比较简单的函数，其中IF函数就是高频率函数之一，那么，能不能用IF函数来进行多条件运算呢？

一、IF+AND：同时满足多个条件

目的：将“上海”地区的“男”通知标识为“Y”。

方法：

在目标单元格中输入公式：=IF(AND(D3="男",E3="上海"),"Y","")。

解读：

1、AND函数的语法：AND(条件1,=标准1，条件2=标准2……条件N=标准N）。如果每个条件和标准都相等，则返回TRUE，否则返回FALSE 。

2、用IF函数判断AND函数的返回结果，如果为TRUE，则返回“Y”，否则返回""。

二、IF+OR:满足多个条件中的一个即可。

目的：将性别为“男”或地区为“上海”的标记为“Y”。

方法：

在目标单元格中输入公式：=IF(OR(D3="男",E3="上海"),"Y","")。

解读：

1、OR函数的语法结构为：(条件1,=标准1，条件2=标准2……条件N=标准N）。如果任意参数的值为TRUE，则返回TRUE ,当所有条件为FALSE时，才返回FALSE。

2、用IF函数判断OR函数的返回结果，如果为TRUE,则返回“Y”，否则返回""。

我们都知道excel函数公式很强大，运用好了对我们制表很有帮助，但是excel函数公式实在是太多了，根本记不住，下面跟大家分享一些常常会用到的函数公式。

一、对于数字的处理：

1、取绝对值

=ABS(数字)

2、取整

=INT(数字)

3、四舍五入

=ROUND(数字,小数位数)

二、统计公式：

1、统计两个表格重复的内容

公式:B2

=COUNTIF(Sheet15!A:A,A2)

说明：如果返回值大于0说明在另一个表中存在，0则不存在。

2、统计不重复的总人数

公式：C2

=SUMPRODUCT(1/COUNTIF(A2:A8,A2:A8))

说明:用COUNTIF统计出每人的出现次数，用1除的方式把出现次数变成分母，然后相加。

在完成excel表格统计之后，以免后期不小心修改数据，我们可以将excel表格转换成pdf格式。高版本的office可以直接将excel另存为pdf，低版本或者想要批量转换的可以用迅捷pdf转换器来完成转换。

三、求和公式

1、隔列求和

公式：H3

=SUMIF($A$2:$G$2,H$2,A3:G3)

或

=SUMPRODUCT((MOD(COLUMN(B3:G3),2)=0)*B3:G3)

说明：如果标题行没有规则用第2个公式

2、单条件求和

公式：F2

=SUMIF(A:A,E2,C:C)

说明：SUMIF函数的基本用法

3、单条件模糊求和

公式：详见下图

说明：如果需要进行模糊求和，就需要掌握通配符的使用，其中星号是表示任意多个字符，如"*A*"就表示a前和后有任意多个字符，即包含A

4、多条件模糊求和

公式：C11

=SUMIFS(C2:C7,A2:A7,A11&"*",B2:B7,B11)

说明：在sumifs中可以使用通配符*

5、多表相同位置求和

公式：b2

=SUM(Sheet1:Sheet19!B2)

说明：在表中间删除或添加表后，公式结果会自动更新。

6、按日期和产品求和

公式：F2

=SUMPRODUCT((MONTH($A$2:$A$25)=F$1)*($B$2:$B$25=$E2)*$C$2:$C$25)

说明：SUMPRODUCT可以完成多条件求和

好啦，以上就是比较常用的excel公式啦，当然，excel函数公式远远不止这些，但是以上公式如果能熟练应用也会非常提高工作效率哦。