求和，一直是Excel中不变的话题，但是对于求和，并不是所有的同学都能够掌握，尤其是条件求和……常见的求和函数有SUM、SUMIF、SUMIFS三种。

一、SUM函数。

作用：对指定范围内的值进行求和运算。

语法：=SUM（数值或单元格引用区域）。

SUM函数常见问题及解决办法：

1、计算结果显示：#####。

原因：SUM函数所在的列太窄，无法显示结果。

方法：

将列宽调整到合适的宽度即可。

2、计算结果明显错误。

原因：数值为文本类型。

方法：

将对应的值调整为“常规”或“数值”类型即可。

3、求和结果不自动更新。

原因：【计算选项】为“手动”。

方法：

1、【公式】-【计算选项】，选择【自动】。

2、按F9强制更新。（缺点：没计算一次都要按F9强制更新）。

二、SUMIF函数。

作用：对指定范围内满足条件的值进行求和。

语法：=SUMIF（条件范围，条件，[求和范围]）。当条件范围和求和范围一样时，求和范围可以省略。

方法：

在目标单元格中输入公式：=SUMIF(D3:D9,H3,C3:C9)。

SUMIF函数常见问题及解决办法：

1、当条件匹配字符超过255个时，将返回不正确的结果。

解决办法：空值条件字符在255个范围之内。

三、SUMIFS函数。

作用：对指定范围内同时满足多个条件的值进行求和。

语法：=SUMIFS（求和范围，条件范围1，条件1，条件范围2，条件2,……条件范围N，条件N）。

方法：

在目标单元格中输入公式：=SUMIFS(C3:C9,D3:D9,H3,E3:E9,I3)。

SUMIFS函数常见问题及解决办法：

1、计算结果为“0”。

原因：条件为文本值。

方法：

将条件中的文本条件用""括起来。正确的公式是：=SUMIFS(C3:C9,D3:D9,"男",E3:E9,"北京")。而不是：=SUMIFS(C3:C9,D3:D9,男,E3:E9,北京)或其中一个没有括号。

结束语：

本文对求和函数SUM、SUMIF、SUMIFS的常见用法及错误进行了分析，希望对大家今后的求和需求有所帮助。另：每个函数的常见错误并不是指定在函数后面制定的，SUMIF函数也可能出现SUMIFS函数的常见错误，所以大家有加以灵活应用哦！

求和，是最常见的统计工作，但花样繁多的求和要求和条件，常常让不少人限入苦思冥想不得其解的困惑之中，今天运用EXCEL函数与公式，总结从初级到高级的10个求和技巧，与大家一起学习和交流。

初级篇

1、运用“=”、“+”来计算

这是最基础的求和方法，适合无规律或指定单元格求和。如下图：计算1、3、5月份的销售量。J2单元格：=E2+G2+I2，然后，向下复制

2、运用函数SUM求和

这是基础求和函数，适合连续区域求和，高级应用多为与其他函数结合形成SUM数组公式。说明一点，SUM函数的参数，可以是单元格区间，也可以是单个单元格。如下图：计算1、3、5月份的销售量。J2单元格：=SUM(E2,G2,I2)，然后，向下复制

中级篇

3、忽略文本跨列求和

如下图，计算全部销售人员的销售额。C10单元格：=SUM(A2:I7)

利用Excel中sum函数本身对文本类型数值自动忽略的规定，所以，可以用来直接对跨列的数值型数据求和。

4、单条件求和，运用求和函数：SUMIF。

如图，计算1月份冰箱的销售量。K2单元格：=SUMIF($D$2:$D$18,"冰箱",$E$2:$E$18)

SUMIF函数基本结构：SUMIF（条件区域，条件，求和区域）

5、多条件求和，运用求和函数：SUMIFS。

如图，计算销售一部1月份相机销售量。L2单元格：=SUMIFS($E$2:$E$18,$A$2:$A$18,"销售一部",D$2:D$18,"相机")

SUMIFS函数基本结构：SUMIF（求和区域，条件区域1，条件1，条件区域2，条件2...）

6、避开错误值求和。

如下图：计算1-5月份总销售量。C12单元格：=SUMIF(A2:E10,"<9.9E+307")

应用函数SUMIF设置条件完成，其中设置条件"<9.9E+307"，其含义是，9.9*10^307，即9.9乘10的307次方，9.9E+307是一个极大的数值，根据EXCEL的通过规则：数值<文本

7、通配符求和

如下图：计算1月份包含电脑的的总销量。G2单元格：=SUMIF(C2:C18,"*电脑",D2:D18)

应用函数SUMIF设置条件完成，通配符*代表任何字符或字符串，只要总字符不超过255个，设置条件"*电脑"，或“*电脑*”，在选定区域中查找包含“电脑”的所有商品，在计算区域求和。

8、快速累计求和

利用“$”对求和区域首个单元格进行绝对引用，马上就能对一列数值快速累计求和，如下图，C2单元格：=SUM($B$2:B2)，向下复制即可。

9、求和的快捷键："Alt + =",选中要求和的区域和拟计算结果的空白区域，一键即可在空白区域产生求和结果

高级篇

10、求和之王：SUMPRODUCT

SUMPRODUCT函数跟SUM函数的数组公式条件求和语法一样。

=SUMPRODUCT((条件区域=条件)*求和区域)

如上面案例，计算1月份冰箱的销售量。K2单元格：=SUMIF($D$2:$D$18,"冰箱",$E$2:$E$18)，也可以写成：=SUMPRODUCT((D2:D18="冰箱")*E2:E18)

如上面案例，计算销售一部1月份相机销售量。L2单元格：=SUMIFS($E$2:$E$18,$A$2:$A$18,"销售一部",D$2:D$18,"相机")，也可写成：=SUMPRODUCT((A2:A18="销售一部")*(D2:D18="相机")*E2:E18)

下面，举个复杂一点点的例子，昨天，世界杯开始，首场比赛，俄罗斯队5：0大胜沙特队，拟统计本次世界杯，各小组球队进、失球队总数。

以A组为例，第一场有真实比分，其余为模拟分。就可以用SUMPRODUCT计算，进球数：J2单元格：=SUMPRODUCT(($B$2:$B$7=$I3)*($C$2:$C$7))+SUMPRODUCT(($F$2:$F$7=$I3)*($E$2:$E$7))；失球数：K2单元格：=SUMPRODUCT(($B$2:$B$7=$I3)*($E$2:$E$7))+SUMPRODUCT(($F$2:$F$7=$I3)*($C$2:$C$7))

SUMPRODUCT与其他函数结合还可以解决你意想不到的求和需求，以后我们会专门进行分享。请关注后，期待好文。

每天学习一点点，每天进步一点点，积硅步，必能致千里，得大成。

求和函数是Excel中应用最广泛的函数之一，其中SUMIF函数又是条件求和的主力干将。但对于SUMIF函数的应用技巧，你全都掌握吗？

一、语法结构。

SUMIF(range,criteria,[sum_range])。

易解结构：SUMIF(条件所在的单元格区域，条件，[求和的实际单元格])。

备注：

参数range、criteria是必须的，sum_range是可选的。如果第三个参数缺省，默认的是对第一个参数区域求和。

二、单字段单条件求和。

方法：

在目标单元格中输入公式：=SUMIF(E3:E9,H3,C3:C9)。

三、单字段多条件求和。

方法：

在目标单元格中输入公式：=SUM(SUMIF(E3:E9,{"上海","北京","苏州"},C3:C9))。

四、单字段模糊条件求和。

目的：计算出姓名中含有“小”的销售总额。

方法：

在目标单元格中输入公式：=SUMIF(B3:B9,"*小*",C3:C9)。

五、排除错误求和。

目的：计算销售总额。

方法：

在目标单元格中输入公式：=SUMIF(C3:C9,"<9e307")。

备注：

1、用SUM函数求和返回错误值。

2、9e307是Excel中能接受的最大值，计算小于最大值的和。得到我们想要的结果。

六、隔列求和。

方法：

在目标单元格中输入公式：=SUMIF($C$3:$H$3,I$3,$C4:$H4)。

Offset函数是 Excel 中用于返回距指定单元格或单元格区指定行数和列数区域的引用；它共有五个参数，前三个为必选项，后两个为可选项；其中第一个参数为引用单元格或单元格区域；第二、三个参数分别为行数和列数，它们不能超过表格范围，否则会返回错误；另外，行数和列数还有正负之分，取值不同，引用区域也不同。Offset函数可与Sum函数、Match函数组合使用，例如与Sum函数组合求一片选定区域的和。以下就是 Excel Offset函数的使用方法及与Sum函数组合的具体操作实例，实例中操作所用版本均为 Excel 2016。

一、Excel Offset函数语法

1、表达式：OFFSET(Reference, Rows, Cols, [Height], [Width])

中文表达示：OFFSET(引用单元格, 行数, 列数, [返回引用高度], [返回引用宽度])

2、说明：

A、Reference 是对单元格或相邻单元格的引用，否则会返回 #VALUE 错误。

B、Rows 距引用单元格左右上角或下角的行数；当 Rows 为正数时，表示距引用单元格左下角的行数；当 Rows 为负时，表示距引用单元格左上角的行数；如果指定的 Rows 超出表格范围，将返回 #REF! 错误。

C、Cols 距引用单元格左边或右边的行数；当 Cols 为正时，表示距引用单元格右边的行数；当 Cols 为负时，表示距引用单元格左边的行数。如果指定的 Cols 超出表格范围，也返回 #REF! 错误。

D、Height 和 Width 为可选项，Height 表示返回引用的高度；Width 表示返回引用的宽度；当引用一个单元格时，Height 和 Width 都为1；当引用多个单元格时，Height 和 Width 可以都指定与引用单元格同样的高度和宽度，也可指定为大于引用单元格的高度和宽度。如果省略 Height 和 Width，将返回与引用单元格同等大小的区域。

二、Excel Offset函数的使用方法及实例

（一）引用一个单元格

1、返回引用单元格左下角的指定值

A、把公式 =OFFSET(D5,2,-2,1,1) 复制到 H2 单元格，按回车，则返回“黑色T恤”，操作过程步骤，如图1所示：

B、公式说明：引用单元格为 D5；行数为 2，列数为 -2，高度和宽度都为 1，公式的意思是：返回 D5 左下角距 D5 2 行与两列的单元格的引用；符合 Rows 为正时，返回引用单元格左下角的值；Cols 为负时，返回引用单元格左边的值。返回一个单元格的值，把高度和宽度都设置为 1 或省略，否会发生错误。

2、返回引用单元格左上角的指定值

A、把上面公式 =OFFSET(D5,2,-2,1,1) 中的 2 改为 -2，就可以返回引用单元格左上角的指定值，操作过程步骤，如图2所示：

B、说明：公式改为 =OFFSET(D5,-2,-2,1,1) 后，按回车，返回“长袖白衬衫”，正是 D5 左上角单元格的值，且距 D5 2 行 2 列。

3、返回引用单元格右下角的指定值

A、把上面公式 =OFFSET(D5,2,-2,1,1) 中的 -2 改为 2，则公式变为 =OFFSET(D5,2,2,1,1)，如图3所示：

B、按回车，返回 872，正是在 D5 右下角的值且距 D5 2 行 2 列，如图4所示：

（二）对多个单元格的引用并求和

1、把公式 =SUM(OFFSET(D5:E6,2,2,2,2)) 复制到 H2 单元格，按回车，返回结果 8021，操作过程步骤，如图5所示：

2、公式说明：

A、公式先用 OFFSET(D5:E6,2,2,2,2) 选定一片单元格区域，所选定的区域为在 D5:E6 右下角且距 D5:E6 左上角的顶点 2 行 2 列，也就是 F7:G8 这四个单元格，如图6所示：

B、为什么是 F7:G8 这四个单元格？因为高度和宽度都为 2。选定单元格后，再用 Sum 求它们的和，所以结果为 8021。

3、把高度和宽度都改为 3，则公式变为 =SUM(OFFSET(D5:E6,2,2,3,3))，此时，OFFSET(D5:E6,2,2,3,3) 选中的单元格区域为 F7:H9，如图7所示：

按回车，返回结果为 10546，如图8所示：

由此可知：返回的高度和宽度不必与引用单元格 D5:E6 一致。

4、把高度和宽度都改为 -3，则公式变为 =SUM(OFFSET(D5:E6,2,2,-3,-3))，此时，OFFSET(D5:E6,2,2,-3,-3) 选中的单元格区域为 D5:F7，如图9所示：

按回车，返回结果为 5398，如图10所示：

由此可知：当高度和宽度都变为负数时，返回的单元格区域会向左移。

求和函数Sum系列，是Excel的基础函数，也是常用函数之一，但是对于求和，并不是所有的同学都能够掌握，尤其是条件求和…常见的函数SUM、SUMIF、SUMIFS都是求和函数，它们的区别是：SUM：是直接求和；SUMIF：单条件求和；SUMIFS：多个条件求和。

求和函数语法结构及解读：

SUM函数：=sum（区域1，区域2，.....区域n），求参数中所有区域的和

SUMIF函数：=sumif（查找区域，条件，求和区域），按给定条件指定单元格求和

SUMIFS函数：=sumifs（求和区域，查找区域1，条件1，查找区域2，条件2.....查找区域n，条件n），指定区域内同时满足多个条件的值进行求和

一、SUM函数。

语法结构：=sum（区域1，区域2，.....区域n）

目的作用：对指定区域内的值进行求和运算

案例演示：在某公司职员中，要获得所有职员的总工资，使用SUM函数：

二、SUMIF函数。

语法结构：sumif（查找区域，条件，求和区域）

目的作用：对指定区域内满足条件的值进行求和

案例演示：在某公司职员中，要获得运营部职员的工资总额，使用SUMIF函数：

三、SUMIFS函数。

语法结构：=sumifs（求和区域，查找区域1，条件1，查找区域2，条件2.....查找区域n，条件n）

目的作用：对指定区域内同时满足多个条件的值进行求和00000

案例演示：在某公司职员中，要获得运营部男职员的工资总额，用SUMIFS函数：

今天的课程就到这里，如果您喜欢这堂课程，请帮忙点赞和转发哦，感谢您的支持！

Excel中可能我们碰到的最多的就是数据求和处理，对于绝大多数人来讲，学习Excel最初开始碰到的函数应该就是SUM求和函数。这个函数也是在Excel中最简单也是最实用的一个函数。但是除了SUM函数，Excel还有以下的9种求和操作，作为职场中人，大家都应该知道。

场景1：单一行数正常数据求和

问题：求出每个产品上半年销售总量

函数=SUM(B2:G2)

场景2：多行多列数据求和

问题：求出上半年所有产品的销售总额

函数=SUM(B2:H6)

场景3：单一条件求和

问题：求出销售2部的销售总金额

函数=SUMIF(C:C,F5,D:D)

场景4：多条件数据求和

问题：求出销售2部B产品的销售总额

函数=SUMIFS(D:D,C:C,F11,B:B,G11)

场景5：相同颜色数据求和

问题：对每天底纹为黄色的数据进行求和

求和函数=sum(黄色)

求和函数=count(黄色)

操作步骤：

第一步：ctrl+F的方式，点击格式—底纹，底纹颜色选择为我们要查找的黄色。这样操作的意义在于首先确定我们需要定位的单元格内容及地址。

第二步：对单元格区域内的颜色进行定义名称。点击公式—定义名称，名称改为：黄色；公式为=所选取的所有底纹为黄颜色的单元格地址。

第三步：直接用函数公式进行求和计算。对黄色区域进行求和=sum（黄色）；对黄色区域的单元格进行计数=count（黄色）

场景:6：按综合权重进行求和

问题：根据每个人考核项百分比进行计算比求和

函数=SUMPRODUCT($D$3:$F$3,D4:F4)

场景7：通配符进行条件求和

问题：求出姓名中为3个字的总销售量

函数=SUMIF(B:B,"???",C:C)

场景8：数据区间内求和

问题：对完成率在40%~50%的人员销售总额进行求和

函数=SUMIFS(C:C,E:E,"<50%",E:E,">=40%")

场景9：对筛选数据进行动态求平均（不计算隐藏的单元格数据）

问题：求出人员的平均分数（不计算隐藏单元格内容）

函数=AGGREGATE(3,5,C2:C9)

现在你对数据求和有足够多了解了吗？赶快去试试吧~

求和是WPS\Excel中最常见的操作。例如，给你一份个人资金支出明细表，你会怎样计算一段时间内总共花了多少钱，用微信花了多少钱，用微信购买水果花了多少钱呢？让我们一起图解SUM、SUMIF和SUMIFS的用法和区别吧。

一、SUM。

直接使用SUM函数就可以计算出总共花了多少钱，这个大家都懂的。

二、SUMIF。

用微信花了多少钱，这个问题中只有一个限制条件“微信”，可以用SUMIF函数来实现。

三、SUMIFS。

用微信购买水果花了多少钱呢？这个问题中有两个限制条件“微信”和“买水果”，可以用SUMIFS来实现。

最后我们就得到了三个不同的求和结果。

解释。

如图，颜色相同的部分是相对应的哦。SUM函数最单纯，直接在括号中输入目标所在单元格就可以了，可以输入一个区域或多个区域。

SUMIF函数可以理解为“SUM+IF”，用于计算满足一个条件的数值的和。本例中的条件是“微信”，“微信”在“C3:C16”单元格，因此第一个参数是就是“C3:C16”，第二个参数就是“微信”或C3，第三个参数是要计算的数据所在区域，也就是“B3:B16”。

SUMIFS函数可以理解为“SUM+IF+IF+……（IFS就是多个IF)”，用于计算多个条件下的数值的和。本例要计算的是钱，钱在“B3:B16”单元格，条件是“微信”和“买水果”，“微信”在“C3:C16”单元格，“买水果”在“D3:D16”单元格，因此输入公式“=SUMIFS(B3:B16,C3:C16,C3,D3:D16,D3)”。

在使用SUM、SUMIF和SUMIFS前，我们可以提取出问题中的所有关键字，区分出要计算的是什么，有什么条件。对于一个问题进行说明\修饰的词语就是条件啦，被说明的就是求和对象啦。最后对照上图，相信很容易就能得到我们想要的结果啦。

对于这三个函数，你还有什么疑问吗？

谢谢阅读，欢迎点赞、评论、关注和点击头像。

Excel中的SUM函数有一个特殊的表示方法，可以快速对多个表格进行汇总，这个可是很好用的技巧哟。我们继续接上次的例子，假设每个月的销售记录都是一张表，每个月的数据格式都是相同的，如图所示：

先来看一下第一个最简单的汇总方式，汇总所有月份的邹宇的电视机的销售量：

=SUM('*'!C2)

回车后函数变为=SUM('1月:6月'!C2)，结果为449，是不是非常简单实用？

Tips：

*是通配符，代表所有字符，用在这里的意思是代表除了公示外（汇总）所有表格。如果工作簿中还存在其他工作表，为确保结果的准确性，建议表示为：

=SUM('*月'!C2)

以上只是一个很简单的例子，现在我们就来说一个比较实用的，我们将要汇总每个月的总销售量，如图：

要汇总每个月的销售量，该如何做？

有些勤劳的小伙伴可能会说了，这很简单呀，直接SUM函数然后分别引用就可以啦。如下所示:

1月：=SUM('1月'!C:C)

2月：=SUM('2月'!C:C)

……

6月：=SUM('6月'!C:C)

当然这也是一种不错的办法，不过作为Excel我们就应该考虑扩展性，假如是12个月？或者是按照销售人员分表，那不得上百个表呀？难道还得一个一个更改公示吗？如果时间充足，那也无可厚非，但是作为懒惰的我是绝对不允许这样的事情发生的。现在每个表格的名称已经知道，那就使用引用呗。如下：

=SUM("A2""!C:C")

如下图所示，得到的结果是#VALUE!，警告出错，原因是里面的引用区域仅仅是文本而非区域，那该怎么办呢？

别急，这时另一个函数INDIRECT就该派上用场了，这个函数可以对文本进行引用，也叫间接引用，也就是说只有通过“小三”才能获得引用，是这样的：

=SUM(INDIRECT(A3 & "!C:C"))

结果如图：

换一个角度来说，INDIRECT就是能把一个单元格中的文本变为区域的引用，其实也很简单的哟。

是不是一个简单的SUM函数却有很强大的功能？希望大家在函数的学习过程中能够举一反三，争取得到更多的技巧！！

今天要给大家介绍一个重量级函数,都坐稳了,它太重

SUM函数。。。

切~~什么鬼？又想骗流量？先别走开,下面的内容你不一定知道

切~~老娘才不看,SUM函数那么简单,我小学一年级就会用

好吧！要看的继续翻,不看的让他后悔没看完

首先介绍SUM函数的最基本的

基本用法

=SUM(E2:F2)

连续区域求和

求12月的总业绩

=SUM(G2:O2)

不连续区域求和

求1,5,9月的总业绩

=SUM(G2,K2,O2)

条件求和

求业绩大于8000的和

=SUM((E2:E13>8000)*E2:E13)

多条件求和

求仓库二业绩大于6000总业绩

=SUM((E2:E13="仓库二")*(F2:F13>6000)*F2:F13)

交叉求和

求两个区域交叉处的和,既橘色区域

=SUM(H3:K9 J7:M12)

求库存

=SUM(E$2:E2)-SUM(F$2:F2)

合并单元格求和

=SUM(E2:E$13)-SUM(F3:F$13)

前N名求和

=SUM(LARGE(E2:E12,ROW(1:5)))

1，连续区域快速求和。

快捷键： Alt+=组合键快速求和。

2，交叉区域求和。

公式中用空格连接两个单元格区域，表示对两个区域的交集部分求和。

3，不连续区域快速求和。

4，隔列求和。

5，合并单元格快速求和。

输入公式方法:选中合并单元格,在编辑栏中输入求和公式,按ctrl+enter完成输入。

6，绝对相对引用求累计数。

7，对 1 - 500累加快速求和。

8，SUM函数条件求和。

SUM函数条件求和需要运用数组公式。

在实际运用中，运用SUMIF函数进行条件求和更简单。